; Installationsskript CDDA WB-Interface
; erstellt für Installer 2.8.1996, Autor: Ralf Faubel

;   Copyright-Hinweise für Installer:

;     Installer and Installer project icon
;     (c) Copyright 1991-93 Commodore-Amiga, Inc. All Rights Reserved.
;     Reproduced and distributed under license from Commodore.

;     INSTALLER SOFTWARE IS PROVIDED "AS-IS" AND SUBJECT TO CHANGE;
;     NO WARRANTIES ARE MADE. ALL USE IS AT YOUR OWN RISK. NO LIABILITY
;     OR RESPONSIBILITY IS ASSUMED.

(set @user-level 2)
(set @language "deutsch")
(set @abort-button "Installation abbrechen")
(set @special-msg "Ein fataler Fehler ist aufgetreten !\nBitte wiederholen Sie die Installation.")
(set @error-msg (cat "'CDDA WB-Interface' wurde nicht komplett installiert. Bitte wiederholen Sie die Installation, "
                     "um eine lauffähige Version auf Ihrer Festplatte zu erhalten."))

(set sysdir (expandpath "SYS:"))
(set owndevice (expandpath ":"))

(complete 0)

(welcome "Willkommen zur Festplatten-Installation von 'CDDA WB-Interface'.\n")

(set mydir
      (askdir
            (prompt "Bitte wählen Sie das Laufwerk für 'CDDA WB-Interface'")
            (help "\nHilfe zur Laufwerksauswahl\n\n"
                  "Für 'CDDA WB-Interface' wird ein eigenes Verzeichnis auf der Festplatte benötigt. "
                  "Um dieses Verzeichnis anlegen zu können, müssen Sie hier die Festplatte "
                  "angeben, auf der es installiert werden soll (z.B. Work:, DH0:, etc)."
            )
            (newpath)
            (default @default-dest)
            (disk)
      )
)

(set @default-dest (tackon mydir "CDDA"))

(if (NOT (exists @default-dest))
      (makedir @default-dest
            (prompt "\nVerzeichnis für 'CDDA WB-Interface' erzeugen\n\n"
                    "Bitte klicken Sie 'Weiter' an, um für 'CDDA WB-Interface' das Verzeichnis '"
                    @default-dest "' zu erzeugen.")
            (confirm)
            (help "\nHilfe zu 'Verzeichnis erzeugen'\n\n"
                  "Auf dem von Ihnen ausgewählten Laufwerk wird das Unterverzeichnis "
                  "für 'CDDA WB-Interface' angelegt. Sollten Sie doch einen anderen Pfad als "
                  "'" @default-dest "' verwenden wollen, können Sie das Installationsprogramm "
                  "an dieser Stelle abbrechen. Beim Neustart geben Sie dann den von Ihnen "
                  "gewünschten Pfad an.\n\n"
                  "Als Verzeichnisname wird jedoch in jedem Fall 'CDDA' verwendet.\n")
            (infos)
      )
      (message "\nHinweis...\n\n"
               "Es existiert schon eine Version von CDDA WB-Interface auf Ihrem System. "
               "Die neue Installation wird alte Dateien überschreiben.\n\n"
               "Wenn Sie dies nicht wünschen, brechen Sie bitte an dieser Stelle die "
               "Installation ab. Beim erneuten Starten der Festplatteninstallation "
               "wählen Sie dann ein anderes Verzeichnis.\n")
)

(message "\nProgrammdateien kopieren\n\n"
         "Bitte klicken Sie 'Weiter' an, um die Programmdateien von 'CDDA WB-Interface' "
         "zu installieren.")

(copyfiles
      (prompt "Kopiere Programmdateien.")
      (help "")
      (source "")
      (dest @default-dest)
      (choices "CDDA WBI"
               "CDDA WBI.info"
               "CDDA"
               "LED"
               "Breakname")
      (optional force askuser)
)
(complete 60)
(copyfiles
      (prompt "Kopiere AmigaGuide-Datei.")
      (help "")
      (source "")
      (dest @default-dest)
      (choices "CDDA WBI.guide"
               "CDDA WBI.guide.info")
      (optional force askuser)
)
(Complete 80)
(if (NOT (exists "FONTS:Style.font"))
      (
            (makedir "FONTS:Style"
                  (prompt "Der Zeichensatz 'Style' wird installiert.")
                  (confirm)
                  (help "Im FONTS-Verzeichnis Ihrer Festplatte fehlt noch ein Zeichensatz, "
                        "der von 'CDDA WB-Interface' verwendet wird. Dieser wird jetzt kopiert.")
            )
            (complete 85)
            (copyfiles
                  (prompt "Kopiere Zeichensatz")
                  (help "")
                  (source "fonts/Style")
                  (dest "FONTS:Style")
                  (optional force askuser)
                  (all)
            )
            (complete 90)
            (copyfiles
                  (prompt "Kopiere Datei 'Style.font'")
                  (help "")
                  (source "fonts/Style.font")
                  (dest "FONTS:")
                  (optional force askuser)
            )
      )
)

(complete 100)

(message "\nInstallation beendet\n\n"
         "'CDDA WB-Interface' befindet sich nun im Verzeichnis:\n'" @default-dest "'")

(exit (quiet))