;
; Installer script for MUIReaderX
;
; Copyright © 1996 Digital illusions
; All rights reserved!
;
; EMail: robin@hell.xs4all.nl
;
; $VER: MUIReaderX-Install 0.45 (13.10.96)

;=============================================================================
; English strings

(set #bad-kick
(cat "You must be using Kickstart 2.04 to install using this script!"
))

(set #where-muireaderx
(cat "Where would you like to install MUIReaderX ?\n"
     "(A drawer will be created)"
))

(set #where-UU
(cat "Where should UUEncode and UUDecode be copied to ?\n"
     "UUDecode.MRX needs it"
))

(set #where-MIME
(cat "Where should Base64Encode and Base64Decode be copied to ?\n"
     "UUMime.MRX needs it"
))

(set #copy-fonts "\nInstall supplied Fonts in FONTS: ?")
(set #copy-fonts-help
(cat "\nThis will install some fonts "
     "that are included in the MUIReaderX distribution."
))

(set #copy-UU "\nInstall supplied UU tools ?")
(set #copy-UU-help
(cat "\nThis will install some UU tools "
     "that are included in the MUIReaderX distribution."
))

(set #copy-MIME "\nInstall supplied Base64 tools ?")
(set #copy-MIME-help
(cat "\nThis will install some Base64 tools "
     "that are included in the MUIReaderX distribution."
))

(set #install-msg
(cat "\n\nMUIReaderX installation script.\n"
     "This script installs MUIReaderX on your Amiga.\n\n"
     "Read the Docs/MUIReaderX.guide file for more information\n"
     "on the distribution of MUIReaderX.\n\n"
     "MUIReaderX © 1996 Digital illusions\n"
     "All rights reserved."
))

(set #end-msg
(cat "\n\n\n\nMUIReaderX needs MUI v3.3+ and MCC_MailText.\n"
     "Don't forget to install them\n\n"
     "NOTE: Some example arexx scripts need rexxreqtools.library!\n"
))

;=============================================================================
; Setting default variables

(set @default-dest    "Xenolink:")
(set @default-fonts   "Fonts:")
(set @default-extras  "c:")
(set muireaderxdir    "")

;=============================================================================
; make sure we are running under a 2.04 ROM

(if (< (/ (getversion) 65536) 37)
(
    (abort #bad-kick)
))

;=============================================================================

(message #install-msg)

(welcome)

(set @cpu (database "cpu"))

(set muireaderxdestdir
  (tackon
    (askdir
      (prompt #where-muireaderx)
      (help @askdir-help)
      (default @default-dest)
    )
    "MUIReaderX"
  )
)

(set @default-dest muireaderxdestdir)

(set choise
  (askchoice
    (prompt "Which MUIReaderX version do you want to install ?")
    (help @askchoice-help)
    (choices  "68000"      ; 0
              "68020")     ; 1
    (if (= @cpu "68000") (default 0))
    (if (= @cpu "68010") (default 0))
    (if (= @cpu "68020") (default 1))
    (if (= @cpu "68030") (default 1))
    (if (= @cpu "68040") (default 1))
    (if (= @cpu "68060") (default 1))
  )
)

(makedir muireaderxdestdir)

(copyfiles
  (source (tackon muireaderxdir "/MUIReaderX.info"))
  (dest (tackon muireaderxdestdir "/"))
)

(makedir (tackon muireaderxdestdir "Docs"))
(makedir (tackon muireaderxdestdir "Icons"))
(makedir (tackon muireaderxdestdir "Rexx"))

(if (= choise 0)
  (copyfiles
    (source (tackon muireaderxdir "Bin/MUIReaderX.000"))
    (dest muireaderxdestdir)
    (newname "MUIReaderX")
  )
)

(if (= choise 1)
  (copyfiles
    (source (tackon muireaderxdir "Bin/MUIReaderX.020"))
    (dest muireaderxdestdir)
    (newname "MUIReaderX")
  )
)

(copyfiles
  (source (tackon muireaderxdir "Bin/MUIReaderX.info"))
  (dest muireaderxdestdir)
)

(copyfiles
  (source (tackon muireaderxdir "MUIReaderX.readme"))
  (dest muireaderxdestdir)
  (infos)
)

(copyfiles
  (source (tackon muireaderxdir "MUIReaderX.tags"))
  (dest muireaderxdestdir)
)

(copyfiles
  (source (tackon muireaderxdir "Docs.info"))
  (dest muireaderxdestdir)
)

(copyfiles
  (source (tackon muireaderxdir "Docs"))
  (dest (tackon muireaderxdestdir "Docs"))
  (all)
  (infos)
)

(copyfiles
  (source (tackon muireaderxdir "Icons.info"))
  (dest muireaderxdestdir)
)

(copyfiles
  (source (tackon muireaderxdir "Icons"))
  (dest (tackon muireaderxdestdir "Icons"))
  (all)
  (infos)
)

(copyfiles
  (source (tackon muireaderxdir "Rexx.info"))
  (dest muireaderxdestdir)
)

(copyfiles
  (source (tackon muireaderxdir "Rexx"))
  (dest (tackon muireaderxdestdir "Rexx"))
  (all)
  (infos)
)

(if
  (askbool
    (prompt #copy-fonts)
    (help #copy-fonts-help)
    (default 1)
  )
  (
    (copyfiles
      (source (tackon muireaderxdir "Fonts"))
      (dest @default-fonts)
      (all)
    )
  )
)

(if
  (askbool
    (prompt #copy-uu)
    (help #copy-uu-help)
    (default 1)
  )
  (
    (copyfiles
      (source (tackon muireaderxdir "Extra/"))
      (dest
        (askdir
          (prompt #where-UU)
          (help @askdir-help)
          (default @default-extras)
        )
      )
      (pattern "(UU#?)")
    )
  )
)

(if
  (askbool
    (prompt #copy-MIME)
    (help #copy-MIME-help)
    (default 1)
  )
  (
    (copyfiles
      (source (tackon muireaderxdir "Extra/"))
      (dest
        (askdir
          (prompt #where-MIME)
          (help @askdir-help)
          (default @default-extras)
        )
      )
      (pattern "(Base64#?)")
    )
  )
)

(message #end-msg)

;=============================================================================