AC_INIT(diskobject.c)

AC_PROG_CC
AC_ISC_POSIX
AC_PROG_AWK
AC_PROG_YACC
AC_PROG_LEX
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_RANLIB

AC_PATH_XTRA

AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS(fcntl.h limits.h sys/time.h unistd.h sys/select.h sys/resource.h sys/stat.h termio.h)

AC_C_CONST
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_HEADER_TIME
AC_STRUCT_TM

AC_FUNC_ALLOCA
AC_TYPE_SIGNAL
AC_FUNC_WAIT3
AC_CHECK_FUNCS(select strdup waitpid)

AC_TRY_LINK([
#include <stdlib.h>
#ifdef HAVE_SYS_TIME_H
#include <sys/time.h>
#endif
],[
  struct timeval tp;
  struct timezone tz;
  gettimeofday(&tp, &tz);
], AC_DEFINE(BSD_STYLE_GETTIMEOFDAY))

AC_CHECK_TYPE(caddr_t, char *)
AC_EGREP_HEADER([[XPointer[^a-zA-Z_]]], [$]x_includes[$]{x_includes:+/}X11/Xlib.h, , AC_DEFINE(XPointer, caddr_t))


dnl  On SunOS4, libXmu seems to be all in one unit forcing references
dnl  to libXt into the linking.  Only fix I can think of is to link with
dnl  libXt too, so that's what we'll do.

old_LIBS="$LIBS"
LIBS="$X_LIBS $X_PRE_LIBS -lXext -lXmu -lX11 $X_EXTRA_LIBS $LIBS"
AC_TRY_LINK([],[
  extern void XmuCopyISOLatin1Lowered(char *,char *);
  char foo[]="FOO";
  XmuCopyISOLatin1Lowered (foo, foo);
], XT_LIB_KLUDGE="", XT_LIB_KLUDGE="-lXt")
LIBS="$old_LIBS"
AC_SUBST(XT_LIB_KLUDGE)

AC_SUBST(x_includes)
AC_SUBST(x_libraries)
AC_OUTPUT(Makefile libami/Makefile)