;Open screen using a TagList.
;---------------------------
;This is another version of Redimension, but uses a taglist to initialise
;the screen.
;
;Press LMB to exit.

	opt	o+

	INCLUDE	"exec/exec_lib.i"
	INCLUDE	"games/games_lib.i"
	INCLUDE	"games/games.i
CALL	MACRO
	jsr	_LVO\1(a6)
	ENDM

	SECTION	"Redimension",CODE

;===========================================================================;
;                             INITIALISE DEMO
;===========================================================================;

Start:	MOVEM.L	A0-A6/D1-D7,-(SP)
	move.l	($4).w,a6
	lea	GMS_Name(pc),a1
	moveq	#$00,d0
	CALL	OpenLibrary
	move.l	d0,GMS_Base
	beq.s	.Error_GMS

	move.l	GMS_Base(pc),a6
	sub.l	a0,a0
	CALL	SetUserPrefs

	lea	ScreenTAGS(pc),a0
	CALL	Add_Screen
	tst.l	d0
	bne.s	.Error_Screen

	lea	Screen(pc),a0
	lea	Picture(pc),a1
	move.l	GS_MemPtr1(a0),PIC_Data(a1)
	CALL	LoadPic
	tst.w	d0
	bne.s	.ReturnToDOS

	lea	Screen(pc),a0		;Now show the screen/pic.
	CALL	Show_Screen

	bsr.s	Main

.ReturnToDOS
	move.l	GMS_Base(pc),a6
	lea	Screen(pc),a0
	CALL	Delete_Screen
.Error_Screen
	move.l	GMS_Base(pc),a1
	move.l	($4).w,a6
	CALL	CloseLibrary
.Error_GMS
	MOVEM.L	(SP)+,A0-A6/D1-D7
	moveq	#$00,d0
	rts

;===========================================================================;
;                                MAIN LOOP
;===========================================================================;

Main:	moveq	#JPORT1,d0		;Read from port 1
	moveq	#JT_ZBXY,d1
	CALL	Read_JoyPort		;Go get port status.
	btst	#MB_LMB,d0
	bne	.exit
	move.w	d0,d1
	ext.w	d0
	asr.w	#8,d1

	btst	#MB_RMB,d0
	bne.s	.RMB

	add.w	d1,GS_ScrWidth(a0)
	add.w	d0,GS_ScrHeight(a0)
	bra.s	.chksrx

.RMB	add.w	d1,GS_ScrXOffset(a0)
	add.w	d0,GS_ScrYOffset(a0)

.chksrx	cmp.w	#35,GS_ScrXOffset(a0)
	ble.s	.chkslx
	move.w	#35,GS_ScrXOffset(a0)

.chkslx	cmp.w	#-40,GS_ScrXOffset(a0)
	bge.s	.chksty
	move.w	#-40,GS_ScrXOffset(a0)

.chksty	cmp.w	#-20,GS_ScrYOffset(a0)
	bge.s	.chkty
	move.w	#-20,GS_ScrYOffset(a0)

.chkty	tst.w	GS_ScrHeight(a0)
	bge.s	.chkby
	clr.w	GS_ScrHeight(a0)

.chkby	cmp.w	#256,GS_ScrHeight(a0)
	ble.s	.chklx
	move.w	#256,GS_ScrHeight(a0)

.chklx	cmp.w	#0,GS_ScrWidth(a0)
	bge.s	.chkrx
	move.w	#0,GS_ScrWidth(a0)

.chkrx	cmp.w	#320,GS_ScrWidth(a0)
	ble.s	.done
	move.w	#320,GS_ScrWidth(a0)

.done	CALL	Wait_OSVBL		;Always wait for a VBL first.
	CALL	Remake_Screen		;Reposition the screen now.
	bra	Main
.exit	rts

;===========================================================================;
;                                  DATA
;===========================================================================;

GMS_Name:
	dc.b	"games.library",0
	even
GMS_Base:
	dc.l	0

AMT_PLANES =	5

Screen:	ds.b	GSV1_SIZEOF
	even

ScreenTAGS:
	dc.l	"TAGS",Screen
	dc.l	GSA_VERSION,GSV1
	dc.l	GSA_Palette,Palette
	dc.l	GSA_Planes,AMT_PLANES
	dc.l	GSA_ScrMode,LORES|COL12BIT
	dc.l	GSA_ScrType,INTERLEAVED
	dc.l	0

Palette	dc.w	$0000,$0130,$0FCB,$0FA9,$0D88,$0965,$0644,$0211
	dc.w	$0400,$0444,$0FF0,$0432,$0CC0,$0150,$0501,$0880
	dc.w	$0261,$0271,$0382,$0492,$05A3,$05B4,$0677,$06C4
	dc.w	$0788,$09AA,$0BCC,$0801,$0901,$0A02,$0701,$0601

Picture	dc.l	PCV1,0	;Version header.
	dc.l	0	;Source data.
	dc.w	320/8,256	;Width, Height.
	dc.w	AMT_PLANES	;Amount of Planes.
	dc.l	32	;Amount of colours.
	dc.l	Palette	;Source palette (remap).
	dc.w	LORES|COL12BIT	;Screen mode.
	dc.w	INTERLEAVED	;Destination
	dc.l	0	;Parameters.
	dc.l	.File
.File	dc.b	"GAMESLIB:data/IFF.Pic320",0
	even