.key INARC/A,REXXPORT
.bra {
.ket }
.def REXXPORT ZPoint

; $VER: ImportPrepacked 1.0 (27.10.95) Copyright (c) Ralph Seichter
;
; Dies ist ein Skript für "Zodiac's Point" Release 3.11, mit dessen Hilfe
; man vorgepackte Datenpuffer auch unter Speicherknappheit sicherer ein-
; sortieren kann. Ein Empfangsarchiv wird ausgepackt und ein temporäres
; ARexx-Skript wird zwecks Datenimport generiert und ausgeführt.
;
; INSTALLATION
;
; Zunächst schalten Sie die Option "Automatisches Einsortieren nach dem
; Netcall" ab und speichern die ZP-Konfiguration. Tragen Sie dieses Skript
; *NICHT* als Entpacker-Kommando ein, da es zum manuellen Aufruf entworfen
; wurde. Als nächstes passen Sie die Einträge 'tempdir' und 'arctool' an
; Ihre Bedürfnisse an. Beachten Sie, daß der hinter 'tempdir' angegebene
; Verzeichnisname mit ':' oder '/' enden muß!

set tempdir T:    ; set tempdir dh1:viel/freier/platz/
set arctool LZX   ; set arctool LhA

; BENUTZUNG
;
; Bevor Sie dieses Skript starten, *MUSS* sich ZP im Hauptmenü befinden,
; damit die ARexx-Kommandos interpretiert werden können. Als Parameter sind
; dem Skript der Name des zu bearbeitenden Empfangsarchives sowie der Name
; des ZP-ARexx-Ports zu übergeben. Letztere Angabe ist optional, falls Sie
; nichts angeben wird "ZPoint" als Standardbelegung verwendet. Der eigent-
; liche Aufruf erfolgt dann aus einer Shell heraus, z.B. mittels
;
;    execute ImportPrepacked dh1:zpoint/out.pre ZPoint
;
; Wenn Sie den ARexx-Port angeben, denken Sie daran, daß zwischen Groß- und
; Kleinschreibung unterschieden wird!

set dstdir $tempdir$process-ImportPrepacked
set script T:ImportPrepacked-$process.rexx
if exists $dstdir
   delete $dstdir all
endif
makedir $dstdir
$arctool x {INARC} $dstdir/
echo "/** DO NOT EDIT! **/*noptions results*naddress *"{REXXPORT}*"" >$script
list $dstdir lformat "import *"%p%n*"*naddress command 'delete *"%p%n*"'" >>$script
echo "address command 'delete $dstdir all'" >>$script
sys:rexxc/rx $script
delete $script quiet
unset tempdir
unset arctool
unset dstdir
unset script

; EOF