# configure.in --- Mesa GL Widget for X11 Toolkit Programming
# Copyright (C) 1995 by
#   Jeroen van der Zijp <jvz@cyberia.cfdrc.com>
#   Thorsten Ohl <Thorsten.Ohl@Physik.TH-Darmstadt.de>
#
# This library is free software; you can redistribute it and/or
# modify it under the terms of the GNU Library General Public
# License as published by the Free Software Foundation; either
# version 2 of the License, or (at your option) any later version.
#
# This library is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU Library General Public License for more details.
#
# You should have received a copy of the GNU Library General Public
# License along with this library; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
# $Id: configure.in,v 1.12 1995/06/08 09:51:06 ohl Exp $
#
########################################################################
AC_INIT([src/GLwDrawingArea.c])dnl
AC_CANONICAL_HOST
AC_PROG_INSTALL
AC_PROG_LN_S
AC_CHECK_PROG([POD2MAN], [pod2man], [pod2man])dnl
AC_CHECK_PROG([POD2HTML], [pod2html], [pod2html])dnl
AC_PROG_RANLIB
ARFLAGS="ruv"
AC_SUBST([ARFLAGS])dnl
AC_SUBST([SYS_CFLAGS])dnl
AC_SUBST([SYS_LDFLAGS])dnl
AC_PROG_CC
test "$CC" = "gcc" && SYS_CFLAGS="$SYS_CFLAGS -pipe -Wall"
AC_PROG_CPP
# Query Brian Paul's database for compiling Mesa:
case "$host" in
  *-hp-hpux*)
    SYS_CFLAGS="$SYS_CFLAGS -D_HPUX_SOURCE"
    test "$CC" = "gcc" || SYS_CFLAGS="$SYS_CFLAGS +O2 +Oall +Onolimit -Aa"
    ;;
  mips-sgi-irix4*)
    test "$CC" = "gcc" || SYS_CFLAGS="$SYS_CFLAGS -ansi -prototypes -float"
    ARFLAGS="rcv"
    ;;
  mips-sgi-irix5*)
    # On IRIX 5.3 -sopt causes a problem in drawpixels.c so we don't use it
    test "$CC" = "gcc" || \
      SYS_CFLAGS="$SYS_CFLAGS -ansi -prototypes -fullwarn -float"
    ARFLAGS="rcv"
    ;;
  mips-sgi-irix6*)
    #   1068 - integer conversion resulted in a change of sign
    #   1069 - integer conversion resulted in truncation
    #   1174 - variable was declared but never referenced
    #   1185 - enumerated type mixed with another type
    #   1209 - controlling expression is constant
    #   1474 - declaring a void parameter list with a typedef is nonstandard
    #   1552 - variable was set but never used
    test "$CC" = "gcc" || \
      SYS_CFLAGS="$SYS_CFLAGS -64 -ansi -prototypes -fullwarn \
                  -woff 1068,1069,1174,1185,1209,1474,1552"
    ARFLAGS="rcv"
    ;;
  *-linux*)
    SYS_CFLAGS="$SYS_CFLAGS -mieee-fp -DSHM"
    SYS_LDFLAGS="$SYS_LDFLAGS -mieee-fp"
    ;;
  *-netbsd*)
    ARFLAGS="rcv"
    ;;
  alpha-dec-osf*)
    test "$CC" = "gcc" || SYS_CFLAGS="$SYS_CFLAGS -std1 -DSHM"
    ;;
  sparc-sun-solaris2*)
    test "$CC" = "gcc" || SYS_CFLAGS="$SYS_CFLAGS -Xa"
    ;;
  *-ultrix*)
    test "$CC" = "gcc" || SYS_CFLAGS="$SYS_CFLAGS -Dconst=/**/"
    ARFLAGS="rusv"
    ;;
esac
AC_PATH_XTRA
AC_HEADER_STDC
AC_C_CONST
AC_C_INLINE
AC_CHECK_FUNCS(strchr memcpy memmove)dnl
AC_ARG_ENABLE(debug,
  [  --enable-debug          also compile debugging code],
  [case x$withval in
    xno) ;;
    x*)  AC_DEFINE([DEBUG]);;
   esac])dnl
AC_ARG_WITH(motif,
  [  --with-motif            also compile the Motif widgets (untested)],
  [case x$withval in
    xno) MOTIFOBJ="";;
    x*)  AC_CHECK_HEADER([Xm/Xm.h],
           [MOTIFOBJ="GLwMDrawingArea.o GLwCreateMDrawingArea.c"]);;
   esac],
  [MOTIFOBJ=""])dnl
AC_SUBST([MOTIFOBJ])dnl
AC_ARG_WITH(mesadir,
  [  --with-mesadir=PATH     use the Mesa tree rooted in PATH (default: ..)],
  [case x$withval in
    xno) mesa_srcdir="`pwd`";;
    x)   mesa_srcdir="`cd .. && pwd`";;
    x*)  mesa_srcdir="`cd $withval && pwd`";;
   esac],
  [mesa_srcdir="`cd .. && pwd`"])dnl
AC_SUBST([mesa_srcdir])dnl
AC_OUTPUT([Makefile src/Makefile include/GL/Makefile
           demos/Makefile man/Makefile])dnl