/****************************************************************************/
/* File   :ExtensionInfo.dopus                                              */
/* für Prg:DirectoryOpus                                                    */
/* Version:1.2                                                              */
/* Autor  :Jörg Pietsch                                                     */
/* Datum  :23 Mär 1995                                                      */
/* Beschreibung:                                                            */
/* Informationen über Dateiendungen vom vorher angeklickten File.           */
/****************************************************************************/
OPTIONS RESULTS               /* Rückgabewerte in Variable RESULT anfordern */
status 3        ; aktiv=result   /* Herausfinden, welches Fenster aktiv ist */
status 7 aktiv  ; seldat=result /* Anzahl der selektierten Dateien einlesen */
getselectedfiles; nliste=result    /* alle selektierten Dateinamen einlesen */

IF nliste="RESULT" THEN EXIT                /* Bei keiner Auswahl abbrechen */
IF ~EXISTS("S:ExtensionInfo.txt") THEN
  DO
   REQUEST "Kan ExtensionInfo.txt niet vinden!"
   EXIT
  END

ADDRESS COMMAND "COPY >NIL: S:ExtensionInfo.txt TO T:"

/* ------------------------------------------------------------------------ */
/* Files die keine Extension haben abwählen                                 */
/* ------------------------------------------------------------------------ */

DO NR=1 TO seldat      /* Vorgang für alle selektierten Dateien wiederholen */
  File=SUBWORD(nliste,NR,1)               /* Dateinamen aus der Liste holen */
  PT=LASTPOS(".",File)            /* Position des Punktes von hinten suchen */
  IF PT=0 THEN                     /* überprüfe, ob File eine Extension hat */
    DO
     SelectFile File 0 1                                  /* Datei abwählen */
    END
END

/* ------------------------------------------------------------------------ */
/* Files mit Extension nach Begriff durchsuchen                             */
/* ------------------------------------------------------------------------ */

status 7 aktiv  ; seldat=result /* Anzahl der selektierten Dateien einlesen */
getselectedfiles; nliste=result    /* alle selektierten Dateinamen einlesen */

DO NR=1 TO seldat      /* Vorgang für alle selektierten Dateien wiederholen */
  JA=0
  File=SUBWORD(nliste,NR,1)               /* Dateinamen aus der Liste holen */
  LP=LASTPOS(".",File)            /* Position des Punktes von hinten suchen */
  FL=LENGTH(File)                                    /* Filelänge ermitteln */
  Ext1=UPPER(RIGHT(File,FL-LP+1))                    /* Extension ermitteln */
  OPEN(Z,"T:ExtensionInfo.txt","R")                     /* Zum Lesen Öffnen */
   DO WHILE ~EOF(Z)     /* Datei ExtensionInfo.txt nach Begriff durchsuchen */
     Linie=READLN(Z)
     Ext2=UPPER(WORD(Linie,1))
     IF Ext2 = Ext1 THEN
       DO
        REQUEST Linie;JA=1
       END
   END
   IF JA=0 THEN
     DO
      REQUEST "Sorry, voor "||Ext1||" kan er geen verklaring gegeven worden!"
     END
   CLOSE(Z)
   SelectFile File 0 1                                    /* Datei abwählen */
END
ADDRESS COMMAND "DELETE >NIL: T:ExtensionInfo.txt"
EXIT