/*
    $VER: BretterLoeschen.zprx V1.1 (28.8.94) Copyright (c) Jan Ritzerfeld

    Dies ist ein ARexx-Skript für Zodiac's  Point,  mit  dem  man  auf
    bequeme  Weise  Bretter mit Hilfe von rexxreqtools.library löschen
    und auf Wunsch auch abbestellen kann.

    Sie dürfen dieses Skript beliebig kopieren,  solange  es  zusammen
    mit  Zodiac's  Point  eingesetzt wird, aber verändern Sie es bitte
    nicht ohne Erlaubnis des Autors.

    Sie erreichen den Autor wie folgt:

       Jan Ritzerfeld         Tel. : +49 2421 65177
       Dornheckweg 9          EMail: j.ritzerfeld@darkness.gun.de
       52355 Düren-Birgel

    Hinweise zur Installation:

    Kopieren sie dieses Skript in  das  Rexx-Verzeichnis  von  ZP  und
    fügen  sie  danach  der  Datei  'fkeys.zp'  auf Wunsch den Eintrag
    "F1:SYS:Rexxc/RX ZPOINT:Rexx/BretterLoeschen.zprx %s" hinzu.
*/

/* Der Konfigurations-Teil des Skriptes: */

maps = 'maps@darkness.gun.de'

del = 'DEL'


/* Das eigentliche Programm: Änderungen sind nicht mehr gestattet! */

GUILOCK ON
options failat 10
signal on syntax

parse arg zpPort
address value zpPort
options results

call addlib('rexxsupport.library',0,-30,0)

temp = 'T:bl'pragma('I')
call delete(temp)

NL = '0A'X

WHICHLEVEL
if (result ~= 'BOARDMENU') then
  do
  REQUESTNOTIFY 'Bitte gehen Sie ins Brett-Menu und stellen'NL'Sie den Balken auf das erste zu löschende Brett.'
  exit
  end

BOARDINFO LABEL
emp = result
say emp

REQUESTSTRING '"Lösch-Muster eingeben:" DEFAULT='emp
buffer = result
GUILOCK ON
if (buffer = '') then
  do
  REQUESTNOTIFY 'Abgebrochen'
  exit
  end

if open('tempfile',temp,'W') then
  do
  exitme = 0
    do until (exitme)
    JUMPTOBOARD 'NAME' buffer
    if (rc) then
      do
      BOARDINFO LABEL
      emp = result
      say emp

      REQUESTRESPONSE 'Brett' emp 'wirklich löschen?'
      if (rc) then
        do
        GUILOCK ON
        DELETE
        if (result = 0) then
          REQUESTRESPONSE 'Brett' emp 'konnte nicht gelöscht werden!'
        GUILOCK ON
        call writeln('tempfile',emp)
        end
      else
        DOWN
      end
    else
      exitme = 1
    end

  call close('tempfile')

  REQUESTRESPONSE 'Bretter auch abbestellen?'
  if (rc) then
    do
    JUMPTOBOARD 3
    ENTERBOARD
    WRITEMESSAGE temp 'RECEIVER' maps 'SUBJECT' del
    if (result = '') then
      REQUESTNOTIFY 'Konnte Nachricht an' maps 'nicht versenden!'
    BOARDMENU
    end

  GUILOCK ON
  call delete(temp)

  REQUESTNOTIFY 'Fertig mit Löschen'
  GUILOCK ON
  end

GUILOCK OFF
exit


syntax: /* Ein Fehler ist aufgetreten ! */

REQUESTNOTIFY 'Schade auch, Fehler in Zeile' SIGL ':' ERRORTEXT(rc) ':-('
GUILOCK OFF

exit