/* Arexx-Script für ZPoint und MailFilter */

/*
** $VER: Headerfilter.zp 1.0 (16.7.94)
**
** Übernimmt eine Headerzeile aus der aktuellen Mail in den Headerfilter,
** Wenn die Headerzeile länger als 80 Zeichen ist wird ihr ein '#?' oder
** '*' angehängt. In der Headerzeile vorkommende Jokerzeichen werden durch
** Voranstellen eines Hochkommas ausgeschaltet. Nach erfolgreicher Übernahme
** in den Filter öffnet sich das Fenster und der gerade übernommene Eintrag
** ist selektiert.
**
** Das Script benötigt zum Kopieren der Nachricht vom Clipboard in eine Datei
** das Programm 'Clip2Text'. Dieses Programm liegt dem MailFilter-Archiv bei,
** kopieren Sie es in das logische Verzeichnis 'C:'.
**
** Headerfilter.zp muß nach 'ZPOINT:Rexx' kopiert, und in die Usermenüs
** oder Funktionstastenbelegung eingetragen werden.
*/

/* Ergebnisse anfordern */

OPTIONS RESULTS



/* Name des Screens auslesen */

PARSE ARG screenname
ADDRESS VALUE screenname



/* Script beenden wenn wir uns nicht innerhelb eines Brettes befinden */

WHICHLEVEL

IF result ~= 'BOARD' THEN
   EXIT(0)



/* Aktuelle Mail mit Header auslagern */

SAVEMESSAGETOCLIP

IF rc ~= 1 THEN
   EXIT(10)

ADDRESS COMMAND 'Clip2Text UNIT 0 FILENAME T:Headerfilter-rexx.temp'



/* Testen, ob MailFilter gestartet ist. Wenn nicht, dann jetzt starten */

IF ~SHOW(PORTS,'MAILFILTER') THEN DO
   ADDRESS COMMAND
   'run >NIL: <NIL: MAILFILTER:MailFilter'

   DO 3 WHILE ~SHOW(PORTS,'MAILFILTER')
      'WaitForPort MAILFILTER'
   END

   IF rc = 5 THEN DO
      SAY 'Kann MailFilter nicht starten!'
      'Delete T:Headerfilter-rexx.temp'
      EXIT(10)
   END
END



/* Aktuellen ZPoint-Screen einstellen */

ADDRESS MAILFILTER

GETATTR screen

IF result ~= screenname THEN DO
   DEACTIVATE
   SETATTR screen screenname
END



/* Einen Header aus der Mail auswählen */

SELECTHEADER 'T:Headerfilter-rexx.temp'

IF rc ~= 0 THEN DO
   ADDRESS COMMAND 'Delete T:Headerfilter-rexx.temp QUIET'
   EXIT(0)
END



/* Header in den Headerfilter übernehmen und das */
/* Fenster auf dem aktuellen MicroDot-Screen öffnen */

headerzeile.pattern    = result
headerzeile.emppattern = ''
headerzeile.newsgroup  = ''
headerzeile.mailtype   = ''
headerzeile.action     = ''

ADDITEM TO header STEM headerzeile CONVERT POPUP



/* Prefs speichern */

IF rc = 0 THEN
   SAVE



/* TempDatei löschen */

ADDRESS COMMAND 'Delete T:Headerfilter-rexx.temp QUIET'



/* Beenden */

EXIT(0)