*****************************************************************
* Level 6 Sidmon module player by John 'BOIL' van Dijk		*
* Written in DevPac 2.14 (With a few changes also for SEKA)	*
* This means no variation in speed on NTSC/PAL machines and	*
* no variation accessing disks etc.				*
* runs 50 times a second (erm .. well .. almost .. -0,9% off!)	*
* 37 or 38 is normal speed.					*
*****************************************************************


	SECTION		SEGMENT0,CODE_C
SEG0
	bra	Start
	dc.b	'Jungle Command level 6 Sidmon player by Boil'

Start	movem.l	d0-d7/a0-a6,-(a7)

	jsr	Music		;initialize music pointers

	move.w	#$4000,$dff09a	;turn off interrupts
	move.b	#$00,$bfde00	;initialize timers
	move.b	#$00,$bfd400
	move.b	#$37,$bfd500	;speed ( up=slower => down=faster)
	move.b	#$81,$bfdd00
	move.b	#$11,$bfde00
	move.l 	$78,Old
	move.l 	#NewIrq,$78	;set level 6 vector on new routine
	move.w	#$c000,$dff09a	;turn the interrupts back on
	move.w	#$800f,$dff096	;turn on soundchannels

Mouse	btst 	#10,$dff016	;wait for something (here right mouse)
	bne 	Mouse

	move.w	#$4000,$dff09a	;put everything back and leave
	move.b	#$01,$bfdd00
	move.l 	Old,$78
	move.w	#$c000,$dff09a
	move.w	#$f,$dff096
	movem.l	(a7)+,d0-d7/a0-a6
	moveq	#0,d0
	rts





NewIrq	movem.l	d0-d7/a0-a6,-(a7)	;new level 6 interrupt

	jsr	Music+$16a		;play music
	move.b	$bfdd00,d0		;tigger timer again
	move.w	#$2000,$dff09c

	movem.l	(a7)+,d0-d7/a0-a6
	rte				;leave interrupt

Old	ds.l	1

Music	incbin	df2:mod.sidmon