*********************************************************************
*	initsistema by xele					    *
*	version mejorada del system-starter v2.0	            *
*	de troglobyte y sonny / darkness			    *
*********************************************************************

execbase = 4
allocmem = -$c6
openlib	= -$198
closelib = -$19e
freemem	= -$d2

*************************** registros blitter

bltcon0	equ	$dff040		
bltcon1	equ	$dff042
bltafwm	equ	$dff044
bltalwm	equ	$dff046
bltcpth	equ	$dff048
bltbpth	equ	$dff04c
bltapth	equ	$dff050
bltdpth	equ	$dff054	
bltsize	equ	$dff058
bltcmod	equ	$dff060
bltbmod	equ	$dff062
bltamod	equ	$dff064
bltdmod	equ	$dff066
bltcdat	equ	$dff070
bltbdat	equ	$dff072
bltadat	equ	$dff074


*********************************************************************

	SECTION Xele,CODE	; Codigo (CHIP/FAST)

InitSys	
	
	bsr.s	Alloc		; guardamos memoria bitplanes
	bsr.w	OSout		; Quitamos el control al Amiga OS
;	bsr.w	mt_init
	bsr.w	start		; Nuestro PROGRAMA !!!
;	bsr.w	mt_end
	bsr.w	OSin		; Devolvemos el control al Amiga OS
	bsr.s	free		; liberamos memoria bitplanes
salte	rts			; ADIOS !!!

	even

********************************************************************

alloc
	movea.l	execbase,a6
	move.l	#30720,d0
	move.l	#$10002,d1
	jsr	allocmem(a6)
	move.l	d0,plano1
	beq	salte	
	add.l	#10240,d0
	move.l	d0,plano2
	add.l	#10240,d0
	move.l	d0,plano3
	add.l	#10240,d0
	move.l	d0,plano4
	add.l	#10240,d0
	move.l	d0,plano5
	rts

free	movea.l	execbase,a6
	move.l	#30720,d0
	move.l	plano1,a1
	jsr	freemem(a6)
	clr.l	d0
	rts
	

OSout	movea.l	execbase,a6			; System Base
	lea	GfxLib,a1
	moveq	#0,d0
	jsr	-552(a6)		; OpenLibrary
	move.l	d0,GfxBase		; Save Graphics_lib base
	move.l	d0,a6
	move.l	38(a6),OldCopper	; gb_CopInit	Sys Copper
	move.l	34(a6),OldView		; gb_ActiView	Sys View
	jsr	-456(a6)		; Own Blitter
	lea	0.w,a1		;LoadView Null
	jsr	-222(a6)	;LoadView
	jsr	-270(a6)	;WaitTOF
	jsr	-270(a6)

	movea.l	execbase,a6			; System Base
	jsr	-132(a6)		; Forbid
	jsr	-150(a6)		; SuperState
	move.l	d0,SysStack		; System stack
	btst.b	#0,$129(a6)	; are we at least 68010? ($129=AttnFlags+1)
	beq.s	.68000			; nope.
	dc.w	$4e7a,$0801	;=movec.l vbr,d0 ; pero MDevPac no lo acepta
	move.l	d0,VectorBase		; Get Real VBR

.68000	move	$dff01c,IntEnaR		; Initialize custom chips
	move	$dff01e,IntReqR		; Save old valours first
	move	$dff002,DmaConR
	move	$dff010,AdkConR
	move	#%0111111111111111,$dff09a	; INTENA
	move	#%1100000000100000,$dff09a	* Enable desired IRQs
.Spr	move.l	$dff004,D0		; Wait RASTER to
	and.l	#$0001FF00,D0		; disable SPRITES
	bne.s	.Spr
	move	#%0111111111111111,$dff096	; DMACONW
	move	#%1000001111000000,$dff096	* Enable desired DMAs

	move	$dff07c,d0		;Ponerlo en/antes/despues de Copper?
	cmp.b	#$f8,d0
	bne.s	.NotAGA			; Not AGA
	move	#0,$dff1fc		* Fix AGA Res     (Ponerlo en Copper?)

.NotAGA	move.l	VectorBase,a0
	move.l	$6c(a0),Int3Save	; Save level 3 vector
	move.l	#INTER,$6c(a0)		; Set OUR! own interrupt

	move.l	#COPPER,$dff080			; Set OUR! Copper List
	rts

OSin	move.l	VectorBase,a0
	move.l	Int3Save,$6c(a0)	; Reset Interrupts
	move	IntEnaR,d7		; Reset custom chips
	bset	#$f,d7
	move	d7,$dff09a		; Reset Interrupts
	move	IntReqR,d7
	bset	#$f,d7
	move	d7,$dff09c		; Reset interrupt request
	move	DmaConR,d7
	bset	#$f,d7
	move	d7,$dff096		; Reset DMAConw
	move	AdkConR,d7
	bset	#$f,d7
	move	d7,$dff09e		; Reset ADK

	move.l	GfxBase,a6
	movea.l	OldView,a1
	jsr	-222(a6)	;LoadView
	move.l	OldCopper,$dff080	; Reset System Copper
	jsr	-462(a6)		; DisOwn Blitter

	movea.l	execbase,a6			; System Base
	move.l	GfxBase,a1	; Close Graphics_lib
	jsr	-414(a6)	; CloseLibrary
	jsr	-138(a6)		; Permit
	move.l	SysStack,d0		; Systemstack
	jsr	-156(a6)		; UserState

	moveq.l	#0,D0
	rts

***************************************************************
***************** INTERRUPCION NIVEL 3 VBLANK *****************
***************************************************************

INTER	movem.l	A0-A6/D0-D7,-(sp)
	
;	bsr.w	mt_music
	bsr	rasterbars
	bsr	rasterbars

	move	#$20,$dff09c
	movem.l	(sp)+,A0-A6/D0-D7
	rte				

;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
rasterbars
;
;~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~	
;clear copperlist
	lea	bar1,a0		;primero borro la anteriores barras
	move.w	#121,d0		;poniendo la copperlist del mismo 
.clear
	clr.w	6(a0)		;color que el fondo
	lea	8(a0),a0	;lo hago mediante un bucle que borra
	dbra	d0,.clear	;la 2a word de la instruccion MOVE del copper

;copy bars to copperlist
	lea	bar1colors,a0	;ahora meto las barras en la copperlist
	lea	bar1cop,a1	;a1= offset de las barras dentro de copperlist
	clr.l	d2		;esto es por seguridad

	move.w	#9,d0		;numero de bars-1
.bucle
	lea	bar1,a2		;inicio copperlistbars
	move.w	(a1)+,d2	;calculo el offset de la barra dentro de la
	lsl.l	#3,d2		;copperlist (multiplico por 8: 2 words del Wait y 2 words del Move del copper)
	add.w	d2,a2		;a2 = es la direccion de la linea donde hay que escribir
	move.w	#13,d1		;numero de colors de la barra
.bucle2
	move.w	(a0)+,6(a2)	;el 6 hace saltar a la 2a word del Move del copper
	lea	8(a2),a2	;esto es lo mismo que sumarle 8 a la direccion que
	dbra	d1,.bucle2	;tiene a2
	dbra	d0,.bucle

;actualizo las posiciones de las barras	
	lea	bar1pos,a1	;comienzo de las variables de posicion dentro de la tabla
	lea	bar1cop,a2	;comienzo de las variables de offset dentro de la copperlist
	clr.l	d1		;esto es por seguridad

	move.l	#9,d0		;numero de bars-1
.bucle3		
	lea	tablepos,a0	;esta es la tabla de las posiciones por donde pasan las bars 
	move.w	(a1)+,d1	;d1 = pos dentro de la tabla susodicha
	lsl.l	#1,d1		;multiplico por 2 para averiguar la direccion en la tabla
	add.l	d1,a0		;sumo y en a0 me queda la direccion exacta de la proxima posicion
	move.w	(a0),(a2)+	;la copio a las variables offset de cada barra
	add.w	#1,-2(a1)	;y avanza un lugar dentro de la tabla de posiciones
	cmp.w	#180,-2(a1)	;si llega al final vuelve al principio (180 = n. posiciones)
	bne	.next
	clr.w	-2(a1)		;la posicion se pone a 0 (vuelve a comenzar)
.next	dbra	d0,.bucle3
	rts			;y eso es todo


***************************************************************
***************** PROGRAMA PRINCIPAL **************************
***************************************************************
start

	lea	CopBPLS,a0	; Inicializamos la Copper con
	move.l	plano1,d0	; las direcciones donde estan los
	move	d0,6(a0)	; graficos de los BitPlanes que usamos
	swap	d0		; activa solo los necesarios
	move	d0,2(a0)
	move.l	plano2,d0	; plano2
	move	d0,14(a0)
	swap	d0
	move	d0,10(a0)
	move.l	plano3,d0	; plano3
	move	d0,22(a0)
	swap	d0
	move	d0,18(a0)
;	move.l	plano4,d0	; plano4
;	move	d0,30(a0)
;	swap	d0
;	move	d0,26(a0)
;	move.l	plano5,d0	; y plano5
;	move	d0,38(a0)
;	swap	d0
;	move	d0,34(a0)

*****************************************************************

MAIN


;salimos con el boton izquierdo del raton.

LMB	btst 	#6,$bfe001	; Apreto Raton izquierdo ?
	bne.s 	LMB		; NO = Salta a MAIN
	rts			; SI = Volvemos para salir

;	include	"sourcesxele:players/player2.1.asm"

************** waitblitter ************************
bwait
	btst	#14,$dff002
	btst	#14,$dff002
	bne	bwait
	rts

*****************************************************************
***************** COPPER LIST ***********************************
*****************************************************************

	SECTION Graficos,DATA_C		; Datos   (CHIP)

COPPER	dc.w $100,$3200			* BPLCONtrol0 [3 BPLS]
	dc.w $102,$0000,$104,$0000	* BPLCON1,BPLCON2
	dc.w $108,$0000,$10A,$0000	* BPLMODulos
	dc.w $08e,$2881,$090,$28C1	* DIWindow Size YX
	dc.w $092,$0038,$094,$00D0	* DDFetch

CopBPLS	dc.w $00e0,$0000,$00e2,$0000	* BPL1PT = BitPlane1Pointers
	dc.w $00e4,$0000,$00e6,$0000	* BPL2
	dc.w $00e8,$0000,$00eA,$0000
;	dc.w $00eC,$0000,$00eE,$0000	* Como solo usamos 3 planos
;	dc.w $00F0,$0000,$00F2,$0000	* no hace falta que pongamos estos
;	dc.w $00F4,$0000,$00F6,$0000	* BPL6

colors	dc.w $180,$000,$182,$fff,$184,$f44,$186,$f66	* Colores 0-7
	dc.w $188,$f88,$18a,$faa,$18c,$fcc,$18e,$fee
;	dc.w $190,$00f,$192,$009,$194,$da7,$196,$c96	* 8-15
;	dc.w $198,$fff,$19a,$b52,$19c,$b40,$19e,$930
;	dc.w $1a0,$000,$1a2,$fff,$1a4,$b00,$1a6,$900	* 16-23
;	dc.w $1a8,$ccc,$1aa,$aaa,$1ac,$060,$1ae,$050
;	dc.w $1b0,$00f,$1b2,$009,$1b4,$da7,$1b6,$c96	* 24-31
;	dc.w $1b8,$fff,$1ba,$b52,$1bc,$b40,$1be,$930

	;122 lineas en total

bar1	dc.w	$7601,$fffe,$180,$000	
	dc.w	$7701,$fffe,$180,$000
	dc.w	$7801,$fffe,$180,$000
	dc.w	$7901,$fffe,$180,$000
	dc.w	$7a01,$fffe,$180,$000
	dc.w	$7b01,$fffe,$180,$000
	dc.w	$7c01,$fffe,$180,$000
	dc.w	$7d01,$fffe,$180,$000
	dc.w	$7e01,$fffe,$180,$000
	dc.w	$7f01,$fffe,$180,$000
	dc.w	$8001,$fffe,$180,$000
	dc.w	$8101,$fffe,$180,$000
	dc.w	$8201,$fffe,$180,$000
	dc.w	$8301,$fffe,$180,$000
	dc.w	$8401,$fffe,$180,$000	
	dc.w	$8501,$fffe,$180,$000
	dc.w	$8601,$fffe,$180,$000
	dc.w	$8701,$fffe,$180,$000
	dc.w	$8801,$fffe,$180,$000
	dc.w	$8901,$fffe,$180,$000
	dc.w	$8a01,$fffe,$180,$000
	dc.w	$8b01,$fffe,$180,$000
	dc.w	$8c01,$fffe,$180,$000
	dc.w	$8d01,$fffe,$180,$000
	dc.w	$8e01,$fffe,$180,$000
	dc.w	$8f01,$fffe,$180,$000
	dc.w	$9001,$fffe,$180,$000
	dc.w	$9101,$fffe,$180,$000
	dc.w	$9201,$fffe,$180,$000	
	dc.w	$9301,$fffe,$180,$000
	dc.w	$9401,$fffe,$180,$000
	dc.w	$9501,$fffe,$180,$000
	dc.w	$9601,$fffe,$180,$000
	dc.w	$9701,$fffe,$180,$000
	dc.w	$9801,$fffe,$180,$000
	dc.w	$9901,$fffe,$180,$000
	dc.w	$9a01,$fffe,$180,$000
	dc.w	$9b01,$fffe,$180,$000
	dc.w	$9c01,$fffe,$180,$000
	dc.w	$9d01,$fffe,$180,$000
	dc.w	$9e01,$fffe,$180,$000
	dc.w	$9f01,$fffe,$180,$000
	dc.w	$a001,$fffe,$180,$000	
	dc.w	$a101,$fffe,$180,$000	
	dc.w	$a201,$fffe,$180,$000
	dc.w	$a301,$fffe,$180,$000
	dc.w	$a401,$fffe,$180,$000
	dc.w	$a501,$fffe,$180,$000
	dc.w	$a601,$fffe,$180,$000
	dc.w	$a701,$fffe,$180,$000
	dc.w	$a801,$fffe,$180,$000
	dc.w	$a901,$fffe,$180,$000
	dc.w	$aa01,$fffe,$180,$000
	dc.w	$ab01,$fffe,$180,$000
	dc.w	$ac01,$fffe,$180,$000
	dc.w	$ad01,$fffe,$180,$000
	dc.w	$ae01,$fffe,$180,$000
	dc.w	$af01,$fffe,$180,$000		
	dc.w	$b001,$fffe,$180,$000		
	dc.w	$b101,$fffe,$180,$000		
	dc.w	$b201,$fffe,$180,$000		
	dc.w	$b301,$fffe,$180,$000		
	dc.w	$b401,$fffe,$180,$000		
	dc.w	$b501,$fffe,$180,$000		
	dc.w	$b601,$fffe,$180,$000		
	dc.w	$b701,$fffe,$180,$000
	dc.w	$b801,$fffe,$180,$000
	dc.w	$b901,$fffe,$180,$000
	dc.w	$ba01,$fffe,$180,$000
	dc.w	$bb01,$fffe,$180,$000
	dc.w	$bc01,$fffe,$180,$000
	dc.w	$bd01,$fffe,$180,$000
	dc.w	$be01,$fffe,$180,$000
	dc.w	$bf01,$fffe,$180,$000
	dc.w	$c001,$fffe,$180,$000
	dc.w	$c101,$fffe,$180,$000
	dc.w	$c201,$fffe,$180,$000
	dc.w	$c301,$fffe,$180,$000
	dc.w	$c401,$fffe,$180,$000
	dc.w	$c501,$fffe,$180,$000
	dc.w	$c601,$fffe,$180,$000
	dc.w	$c701,$fffe,$180,$000
	dc.w	$c801,$fffe,$180,$000
	dc.w	$c901,$fffe,$180,$000
	dc.w	$ca01,$fffe,$180,$000
	dc.w	$cb01,$fffe,$180,$000
	dc.w	$cc01,$fffe,$180,$000
	dc.w	$cd01,$fffe,$180,$000
	dc.w	$ce01,$fffe,$180,$000
	dc.w	$cf01,$fffe,$180,$000
	dc.w	$d001,$fffe,$180,$000
	dc.w	$d101,$fffe,$180,$000
	dc.w	$d201,$fffe,$180,$000
	dc.w	$d301,$fffe,$180,$000
	dc.w	$d401,$fffe,$180,$000
	dc.w	$d501,$fffe,$180,$000
	dc.w	$d601,$fffe,$180,$000
	dc.w	$d701,$fffe,$180,$000
	dc.w	$d801,$fffe,$180,$000
	dc.w	$d901,$fffe,$180,$000
	dc.w	$da01,$fffe,$180,$000
	dc.w	$db01,$fffe,$180,$000
	dc.w	$dc01,$fffe,$180,$000
	dc.w	$dd01,$fffe,$180,$000
	dc.w	$de01,$fffe,$180,$000
	dc.w	$df01,$fffe,$180,$000
	dc.w	$e001,$fffe,$180,$000
	dc.w	$e101,$fffe,$180,$000
	dc.w	$e201,$fffe,$180,$000
	dc.w	$e301,$fffe,$180,$000
	dc.w	$e401,$fffe,$180,$000
	dc.w	$e501,$fffe,$180,$000
	dc.w	$e601,$fffe,$180,$000
	dc.w	$e701,$fffe,$180,$000
	dc.w	$e801,$fffe,$180,$000
	dc.w	$e901,$fffe,$180,$000
	dc.w	$ea01,$fffe,$180,$000
	dc.w	$eb01,$fffe,$180,$000
	dc.w	$ec01,$fffe,$180,$000
	dc.w	$ed01,$fffe,$180,$000
	dc.w	$ee01,$fffe,$180,$000
	dc.w	$ef01,$fffe,$180,$000
;	dc.w	$f001,$fffe,$180,$000
	
	dc.w $ffff,$fffe,$ffff,$fffe	; Doble End of COPPER

mt_data
;	incbin	"sourcesxele:modulos/mod.cold_station"

******************************************************************
************** DATOS DEL PROGRAMA ********************************
******************************************************************

	SECTION FastData,DATA		; Datos (FAST/CHIP)

GfxLib		dc.b	"graphics.library",0,0
IntEnaR		dc.w	0
IntReqR		dc.w	0
DmaConR		dc.w	0
AdkConR		dc.w	0
SysStack	dc.l	0
Int3Save	dc.l	0
GfxBase		dc.l	0
OldCopper	dc.l	0
OldView		dc.l	0
VectorBase	dc.l	0
plano1		dc.l	0
plano2		dc.l	0
plano3		dc.l	0
plano4		dc.l	0
plano5		dc.l	0
linemode	dc.w	$4a


;datos de la rutina rasterbars

;estos colores se copiaran en la copperlist en el offset indicado
;por bar1cop,bar2cop ,etc , se haran en un orden preestablecido y
;en la posicion indicada por la tabla de mas abajo

bar1colors
		dc.w	$770,$990,$bb0,$cc0,$dd0,$ee0,$ff0
		dc.w	$ee0,$dd0,$cc0,$bb0,$990,$770,$550
bar2colors
		dc.w	$707,$909,$b0b,$c0c,$d0d,$e0e,$f0f
		dc.w	$e0e,$d0d,$c0c,$b0b,$909,$707,$505
bar3colors
		dc.w	$070,$090,$0b0,$0c0,$0d0,$0e0,$0f0
		dc.w	$0e0,$0d0,$0c0,$0b0,$090,$070,$050
bar4colors
		dc.w	$700,$900,$b00,$c00,$d00,$e00,$f00
		dc.w	$e00,$d00,$c00,$b00,$900,$700,$500
bar5colors
		dc.w	$077,$099,$0bb,$0cc,$0dd,$0ee,$0ff
		dc.w	$0ee,$0dd,$0cc,$0bb,$099,$077,$055
bar6colors
		dc.w	$007,$009,$00b,$00c,$00d,$00e,$00f
		dc.w	$00e,$00d,$00c,$00b,$009,$007,$005
bar7colors
		dc.w	$777,$999,$bbb,$ccc,$ddd,$eee,$fff
		dc.w	$eee,$ddd,$ccc,$bbb,$999,$777,$555
bar8colors
		dc.w	$007,$008,$b00,$c00,$d00,$00e,$00f
		dc.w	$e00,$d00,$c00,$00b,$009,$700,$500
bar9colors
		dc.w	$700,$900,$b00,$c00,$d00,$e00,$f00
		dc.w	$e00,$d00,$c00,$b00,$900,$700,$500
bar10colors
		dc.w	$770,$990,$bb0,$cc0,$dd0,$ee0,$ff0
		dc.w	$ee0,$dd0,$cc0,$bb0,$990,$770,$550


bar1cop		dc.w	0
bar2cop		dc.w	0
bar3cop		dc.w	0
bar4cop		dc.w	0
bar5cop		dc.w	0
bar6cop		dc.w	0
bar7cop		dc.w	0
bar8cop		dc.w	0
bar9cop		dc.w	0
bar10cop	dc.w	0

bar1pos		dc.w	0
bar2pos		dc.w	8
bar3pos		dc.w	16
bar4pos		dc.w	24
bar5pos		dc.w	32
bar6pos		dc.w	40
bar7pos		dc.w	48
bar8pos		dc.w	56
bar9pos		dc.w	64
bar10pos	dc.w	72

tablepos
	DC.W 53
	DC.W 55 
	DC.W 57 
	DC.W 59 
	DC.W 61 
	DC.W 63 
	DC.W 65 
	DC.W 67 
	DC.W 68 
	DC.W 70 
	DC.W 72 
	DC.W 74 
	DC.W 75 
	DC.W 77 
	DC.W 79 
	DC.W 81 
	DC.W 82 
	DC.W 84 
	DC.W 85 
	DC.W 87 
	DC.W 88 
	DC.W 90 
	DC.W 91 
	DC.W 92 
	DC.W 94 
	DC.W 95 
	DC.W 96 
	DC.W 97 
	DC.W 98 
	DC.W 99 
	DC.W 100 
	DC.W 101 
	DC.W 102 
	DC.W 103 
	DC.W 104 
	DC.W 104 
	DC.W 105 
	DC.W 105 
	DC.W 106 
	DC.W 106 
	DC.W 107 
	DC.W 107 
	DC.W 107 
	DC.W 107 
	DC.W 107 
	DC.W 107 
	DC.W 107 
	DC.W 107 
	DC.W 107 
	DC.W 107 
	DC.W 107 
	DC.W 106 
	DC.W 106 
	DC.W 105 
	DC.W 105 
	DC.W 104 
	DC.W 104 
	DC.W 103 
	DC.W 102 
	DC.W 101 
	DC.W 100 
	DC.W 99 
	DC.W 98 
	DC.W 97 
	DC.W 96 
	DC.W 95 
	DC.W 94 
	DC.W 92 
	DC.W 91 
	DC.W 90 
	DC.W 88 
	DC.W 87 
	DC.W 85 
	DC.W 84 
	DC.W 82 
	DC.W 80 
	DC.W 79 
	DC.W 77 
	DC.W 75 
	DC.W 74 
	DC.W 72 
	DC.W 70 
	DC.W 68 
	DC.W 67 
	DC.W 65 
	DC.W 63 
	DC.W 61 
	DC.W 59 
	DC.W 57 
	DC.W 55 
	DC.W 53 
	DC.W 52 
	DC.W 50 
	DC.W 48 
	DC.W 46 
	DC.W 44 
	DC.W 42 
	DC.W 40 
	DC.W 39 
	DC.W 37 
	DC.W 35 
	DC.W 33 
	DC.W 32 
	DC.W 30 
	DC.W 28 
	DC.W 26 
	DC.W 25 
	DC.W 23 
	DC.W 22 
	DC.W 20 
	DC.W 19 
	DC.W 17 
	DC.W 16 
	DC.W 15 
	DC.W 13 
	DC.W 12 
	DC.W 11 
	DC.W 10 
	DC.W 9 
	DC.W 8 
	DC.W 7 
	DC.W 6 
	DC.W 5 
	DC.W 4 
	DC.W 3 
	DC.W 3 
	DC.W 2 
	DC.W 2 
	DC.W 1 
	DC.W 1 
	DC.W 0 
	DC.W 0 
	DC.W 0 
	DC.W 0 
	DC.W 0 
	DC.W 0 
	DC.W 0 
	DC.W 0 
	DC.W 0 
	DC.W 0 
	DC.W 0 
	DC.W 1 
	DC.W 1 
	DC.W 2 
	DC.W 2 
	DC.W 3 
	DC.W 3 
	DC.W 4 
	DC.W 5 
	DC.W 6 
	DC.W 7 
	DC.W 8 
	DC.W 9 
	DC.W 10 
	DC.W 11 
	DC.W 12 
	DC.W 13 
	DC.W 15 
	DC.W 16 
	DC.W 17 
	DC.W 19 
	DC.W 20 
	DC.W 22 
	DC.W 23 
	DC.W 25 
	DC.W 27 
	DC.W 28 
	DC.W 30 
	DC.W 32 
	DC.W 33 
	DC.W 35 
	DC.W 37 
	DC.W 39 
	DC.W 40 
	DC.W 42 
	DC.W 44 
	DC.W 46 
	DC.W 48 
	DC.W 50 
	DC.W 52