;	Extra voor Kickstart V1.2
;	Ontdekt de SCA, ByteBandit en ByteWarrior en laadt ze niet in
;	en schrijft indien gewenst VirusProtector V4.0 over het virus heen.

;	Dit Programma in kickstart zetten vanaf adres $fc2600
;	Dit is op disk blok 20.

;	Op block 21 en 22 moet het BootBlock komen staan.

;	Verder moet in de strap routine het volgende veranderd worden:

;	lea	44(a5),a1
;	jsr	12(a4)

;	moet worden:

;	jmp	$fc2600

;	Op disk is dit block nummer 326 vooraan ergens ??





	org	$fc2600
	load	$7c000
CheckBB:
	move.w	#[eindtabel-tabel/6]-1,d3
	lea	tabel(pc),a0
CheckLoop:
	move.w	(a0)+,d0
	move.l	(a0)+,d1
	move.l	0(a4,d0.w),d2
	cmp.l	d2,d1		;als B15 van d0 = 1 dan iets dat 
				;overgeslagen moet worden
	beq.s	Virus		;Dit BootBlock is niet bekend
	dbra	d3,CheckLoop
				;Geen virus gevonden ga terug

	lea	44(a5),a1
	jsr	12(a4)
	jmp	$fe8a30		;Dos van V1.2


Virus:	
	move.w	#$3ff,d0	;Grote van normale install routine
	move.l	a4,a0
	move.l	#$fc2800,a1
loop2:	move.b	(a1)+,(a0)+
	dbra	d0,loop2
	MOVEM.L	D1-D7/A0-A6,-(SP)	;Registers op stack 
	LEA	INTUITIONNAME(PC),A1	
	CLR.L	D0		;Version = 0
	JSR	-$228(A6)	;Open intuition library
	MOVE.L	D0,A6		;A6 -> IntuitionBase
	MOVE.L	#60,D1		;Hoogte van alert
	CLR.L	D0		;Recoverble Alert
	LEA	alert(pc),A0	;HAAL POINTER NAAR ALERT VAN STACK
	JSR	-90(A6)		;Display alert
	MOVE.L	D0,-(SP)	;RETURN WAARDE OP STACK
	MOVE.L	A6,A1		;IntuitionBase --> A1
	MOVE.L	$4,A6		;ExecBase naar A6
	JSR	-414(A6)	;CloseLibrary
	MOVE.L	(SP)+,D0	;RETURN WAARDE VAN DISPLAY ALERT
	MOVEM.L	(SP)+,D1-D7/A0-A6	;VAN STACK
	tst.b	d0
	beq.s	stop

INSTALLBB:
	lea	44(a5),A1	;IoStruct naar A5
	MOVE.W	#$1,28(A1)	;Reset Commando
	JSR	-456(A6)	;Voeruit
	lea	44(a5),A1		;IOStruct naar A1
	MOVE.W	#$3,28(A1)	;WRITE COMMAND
	MOVE.L	#$400,36(A1)	;$400 BYTES
	MOVE.L	a4,40(A1)	;BEGIN BOOTBLOK
	CLR.L	44(A1)		;ADRES 0 OP DISK
	JSR	-456(A6)
	lea	44(a5),A1	
	MOVE.W	#$4,28(A1)	;UPDATE COMMAND
	JSR	-456(A6)

stop:
	move.l	#$ff4290,a0
	clr.l	d0
	jmp	$fe8a30

IntuitionName:
	dc.b	'intuition.library',0
	even




Alert:
	dc.w	90
	dc.b	16
	dc.b	'Warning: This disk is infected with a '
	dc.b	'Virus! ',0
	dc.b	1
	dc.w	18
	dc.b	32
	dc.b	'Left Mousebutton: Kill the Virus,'
	dc.b    ' Right Mousebutton: Continue',0
	dc.b	0

	even

	even
Tabel:
	dc.w	$1ae		;ByteBandit $1ae(a4),$4eae fd9c
	dc.l	$4eaefd9c	;Check op jsr -612(a6)

	dc.w	$96		;ByteWarrior
	dc.l	$4eaefd9c	;Check op jsr -612(a6)

	dc.w	$56		;SCA-Virus
	dc.l	$4bf900df	;lea	$DFF000,a5
EindTabel:
	even
Extra:
dc.b	'Send new Viruses to Pieter van Leuven, Koestraat 47,'
dc.b	' 5688 AG  Oirschot'