;	Extra voor Kickstart V1.2.1
;	Ontdekt de volgende virussen en laadt ze niet in.
;	SCA, ByteBandit en ByteWarrior

;	Dit Programma in kickstart zetten vanaf adres $ff3de4
;	Dit is op disk blok 415 onderaan.

;	Verder moet in de strap routine het volgende veranderd worden:

;	lea	44(a5),a1
;	jsr	12(a4)

;	moet worden:

;	jmp	$ff3de4

;	Op disk is dit block nummer 323 index nummer $1c2

	org	$ff3de4
	load	$7c000
CheckBB:
	move.w	#[eindtabel-tabel/6]-1,d3
	lea	tabel(pc),a0
CheckLoop:
	move.w	(a0)+,d0
	move.l	(a0)+,d1
	move.l	0(a4,d0.w),d2
	cmp.l	d2,d1		;als B15 van d0 = 1 dan iets dat 
				;overgeslagen moet worden
	beq.s	Virus		;Dit BootBlock is niet bekend
	dbra	d3,CheckLoop
stop:				;Geen virus gevonden ga terug
	lea	44(a5),a1
	jsr	12(a4)
	jmp	$fe85ca


Virus:	
	MOVEM.L	D1-D7/A0-A6,-(SP)	;Registers op stack 
	LEA	INTUITIONNAME(PC),A1	
	CLR.L	D0		;Version = 0
	JSR	-$228(A6)	;Open intuition library
	MOVE.L	D0,A6		;A6 -> IntuitionBase
	MOVE.L	#60,D1		;Hoogte van alert
	CLR.L	D0		;Recoverble Alert
	LEA	alert(pc),A0	;HAAL POINTER NAAR ALERT VAN STACK
	JSR	-90(A6)		;Display alert
	MOVE.L	D0,-(SP)	;RETURN WAARDE OP STACK
	MOVE.L	A6,A1		;IntuitionBase --> A1
	MOVE.L	$4.W,A6		;ExecBase naar A6
	JSR	-414(A6)	;CloseLibrary
	MOVE.L	(SP)+,D0	;RETURN WAARDE VAN DISPLAY ALERT
	MOVEM.L	(SP)+,D1-D7/A0-A6	;VAN STACK
	move.l	#$ff3fb6,a0	;Zet start van Dos in a0
				;Wordt normaal gedaan door het BB
	clr.l	d0
	jmp	$fe85ca

IntuitionName:
	dc.b	'intuition.library',0
	even




Alert:
	dc.w	90
	dc.b	16
	dc.b	'Warning: This disk is infected with a '
	dc.b	'Virus! ',0
	dc.b	1
	dc.w	$fa
	dc.b	32
	dc.b	'Press Mousebutton to continue'
	dc.b	0

	even

Tabel:
	dc.w	$1ae		;ByteBandit $1ae(a4),$4eae fd9c
	dc.l	$4eaefd9c	;Check op jsr -612(a6)

	dc.w	$96		;ByteWarrior
	dc.l	$4eaefd9c	;Check op jsr -612(a6)

	dc.w	$56		;SCA-Virus
	dc.l	$4bf900df	;lea	$DFF000,a5

	dc.w	$3fc		;ABC-Virus
	dc.l	$0007f400	;jmp $7f400
EindTabel:
	even