;
;		         LocalePL © 1994 Marcin Orlowski
;
;	    ---------------------------------------------------------
;
;		***    ***    *********  ***    ***    ***    ***
;		***    ***    ***        ****  ****    ***    ***
;		***    ***    ***        *** ** ***    ***    ***
;		***    ***    ********   *** ** ***    **********
;		*** ** ***    ********   ***    ***    **********
;		*** ** ***    ***        ***    ***    ***    ***
;		****  **** ** ***     ** ***    *** ** ***    ***
;		***    *** ** ***     ** ***    *** ** ***    ***
;
;	    ---------------------------------------------------------
;
;			Mental Pictures Developed Here
;
;				Marcin Orlowski
;				ul. Radomska 38
;				71-002 Szczecin
;
;	 	SilverDream!'s BBS:  	091-540431  (24h non-stop)
;
;		Internet: 		orlowsps@uoo.univ.szczecin.pl
;
;
;
;
;
;
;--------------------------------------------------------------------
;
;			     LocalePL Installer
;
;                 MR SOFT /  WORLD FEDERATION OF MAD HACKERS
;
;--------------------------------------------------------------------
;
;     $VER: WFMH LocalePL v1.02 (04.08.94) - Skrypt instalacyjny
;

(set WedgeHelp
	(cat	"Pare slow na temat programu AssignWedge.\n"
		"Po jego uruchomieniu, w przypadku odwolania\n"
		"do nieistniejacego urzadzenia, zamiast\n"
		"standardowego, systemowego requestera pojawi\n"
		"sie okno zawierajace dodatkowe gadgety dzieki\n"
		"ktorym bez klopotow bedzie mozna owo urzadzenie\n"
		"(np: RAD, PF0) zamontowac, lub przypisac mu dowolny\n"
		"katalog (Assign). Kompletne archiwum z tym programem,\n"
		"oryginalna dokumentacja, oraz tekstem zrodlowym\n"
		"znajduje sie na tym dysku, w katalogu 'AssignWedge'.\n"
		"  UWAGA! Podczas instalacji skopiowany zostanie\n"
		"jedynie program glowny, archiwum pozostanie\n"
		"na dysku!\n\n"
		"Konwerter tekstu PrintIt 1.0\n"
		"Poniewaz do programu dolaczona jest instrukcja\n"
		"obslugi zatem od razu odsylam do niej"
		
	)
)

(set @abort-button "Przerwij Instalacje")

(set OS_Version (/ (getversion) 65536))
(if (< OS_Version 37)
	(abort  "\n\n\nAby wykorzystac pakiet LocalePL\n"
		"niezbedny jest conajmniej Kickstart 2.04!"
	)
		  
)

(complete 0)
(welcome
	"\n"
	"  ***    ***    *********  ***    ***    ***    ***\n"
	"  ***    ***    ***        ****  ****    ***    ***\n"
	"  ***    ***    ***        *** ** ***    ***    ***\n"
	"  ***    ***    ********   *** ** ***    **********\n"
	"  *** ** ***    ********   ***    ***    **********\n"
	"  *** ** ***    ***        ***    ***    ***    ***\n"
	"  ****  **** ** ***     ** ***    *** ** ***    ***\n"
	"  ***    *** ** ***     ** ***    *** ** ***    ***\n"
	"\n"
	"      ------------------------------------------\n"
	"            Locale PL 1.02     (04.08.1994)\n"
	"      ------------------------------------------"
)

(set IsMagicWB
	(askbool
            	(prompt  "\n\n\n\n\nCzy uzywasz MagicWB?")
            	(help "\n"
                      "             Tak, to moj ulubiony proszek!\n\n"
                      "   Jedyna roznica podczas instalacji pakietu\n"
                      "  dla uzytkowników MagicWB polega na skopiowaniu\n"
                      "  ikon narysowanych wlasnie na uzytek MagicWB\n"
                      "  (czyli 8 kolorow, ekran co najmniej 640x512).\n"
                      "  Jesli MagicWB nie uzywasz, zainstalowane beda\n"
                      "  klasyczne ikonki w stylu NewLook OS2.0+.\n\n")
            	(choices "Tak" "Nie")
            	(default 0)
	)
)

(if (= IsMagicWB 0)
	(set wynik (askoptions
            	(prompt  "Czy chcesz zainstalowac:")
 	    	(help    WedgeHelp
                         "\n\n\n"
                         @askoptions-help
                )
            	(choices " Dodatkowe polskie czcionki"
			 " Pliki dla biblioteki ReqTools"
			 " Pliki dla programu ToolsDaemon"
			 " Pliki dla programu MUI-Builder 1.1"
			 " Program AssignWedge 1.1"
			 " Konwerter tekstu PrintIt 1.0"
			 " Polskie czcionki dla MagicWB"
		)

	   )
	)
	(set wynik (askoptions
            	(prompt  "Czy chcesz zainstalowac:")
 	    	(help    WedgeHelp
                         "\n\n\n"
                         @askoptions-help
                )
            	(choices " Dodatkowe polskie czcionki"
			 " Pliki dla biblioteki ReqTools"
			 " Pliki dla programu ToolsDaemon"
			 " Pliki dla programu MUI-Builder 1.1"
			 " Program AssignWedge 1.1"
			 " Konwerter tekstu PrintIt 1.0"
		)

	   )
	)
)


(copyfiles
	(source "Commodore/Fonts")
	(dest "FONTS:")
	(fonts)
	(all)
)
(complete 15)

(copyfiles
	(source "Commodore/WBStartup")
	(dest "SYS:WBStartup")
	(infos)
	(all)
)
(complete 25)

(copyfiles
       (source "Commodore/Keymaps")
       (dest "KEYMAPS:")
       (all)
)
(complete 30)

(if (= (exists "LOCALE:Catalogs/Polski/Sys" (noreq)) 2)
    (run "c/delete >NIL: LOCALE:Catalogs/Polski/Sys all")
)
;						 I tu jest pies pogrzebany....
(copyfiles
	(source "Commodore/Locale")
	(dest "LOCALE:")
	(infos)
	(all)
)
(complete 65)

;						Poczytaj mi Mamo...


;						Dodatkowe fonty
(if (bitand Wynik 1)
  (copyfiles
   	(source "Dodatki/Fonts")
   	(dest "FONTS:")
        (fonts)
 	(all)
  )
)
(complete 70)

;						ReqTools
(if (bitand Wynik 2)
  (copyfiles
	(source "Dodatki/Locale/catalogs/Polski/")
	(dest "Locale:catalogs/polski/")
	(pattern "reqtools#?")
)
)

;						ToolsDaemon
(if (bitand Wynik 4)
  (copyfiles
	(source "Dodatki/Locale/catalogs/Polski/")
	(dest "Locale:catalogs/polski")
	(pattern "tools#?")
  )
)

(if (bitand Wynik 8)
  (copyfiles
	(source "Dodatki/Locale/catalogs/Polski/")
	(dest "Locale:catalogs/Polski/")
	(pattern "MUIBuilder#?")
  )
)

;						AssignWedge
(if (bitand Wynik 16)
 (
  (copyfiles
	(source "Dodatki/Programy/AssignWedge/AssignWedge")
	(dest "SYS:WBStartup")
	(infos)
  )

  (copyfiles
	(source "Dodatki/Locale/catalogs/Polski/")
	(dest "Locale:catalogs/Polski/")
	(pattern "AssignWedge#?")
  )
 )
)
(complete 75)

;						Fonty do MagicWB
(if (OR (AND (= IsMagicWB 0) (bitand Wynik 64)) (= IsMagicWB 0))
  (copyfiles
	(source "MagicWB/Fonts")
	(dest "FONTS:")
        (fonts)
	(all)
  )
)
(complete 80)

;						PrintIt
(if (bitand Wynik 32)
 (
  (set PrintIt_dest
        (tackon
		(askdir
			(default @default-dest)
			(prompt  "Gdzie zyczysz sobie zainstalowac PrintIt?")
			(help    "\n\n\n\n"
				 " Z wyswietlonej listy wybierz urzadzenie lub katalog\n"
				 "    w ktorym chcialbys zainstalowac PrintIt v1.0.\n"
				 "    Program instalacyjny zalozy dodatkowy katalog\n"
				 "     o nazwie PrintIt i w nim umiesci co trzeba."
				 "\n\n\n\n\n\n"
				 @askdir-help
                        )
                )
        "PrintIt"
        )
  )

 (makedir PrintIt_dest (infos))

  (copyfiles
	(source "Dodatki/Programy/PrintIt")
	(dest PrintIt_dest)
	(infos)
	(all)
  )
 )
)
(complete 85)


(set Dok_dest
		(askdir
			(default @default-dest)
			(prompt  "Gdzie zyczysz sobie zainstalowac zalaczona\n"
                                 "dokumentacje do pakietu W.F.M.H. LocalePL?")
			(help    "\n\n\n"
				 " Z wyswietlonej listy wybierz urzadzenie lub katalog\n"
				 " w ktorym chcialbys zainstalowac dokumentacje.\n"
				 " Dokumentacja bedzie skopiowana bezposrednio do\n"
				 " wybranego katalogu (ewentualne podkatalogi nalezy\n"
				 " stworzyc wlasnorecznie).\n\n"
                                 "          Nie zapomnij jej potem przeczytac!"
                                 "\n\n\n\n"
                                 @askdir-help
                        )
                )
)
(copyfiles
	(source "Dokumentacja")
	(dest Dok_dest)
	(infos)
	(all)
)
(complete 95)

;					Ikonki MagicWB do wszystkiego
(if (bitand IsMagicWB 1)
 (
   (copyfiles
   	(source "MagicWB/Icons/FontPLPatch.info")
   	(dest "SYS:WBStartup")
   )

   (copyfiles
   	(source "MagicWB/Icons/LocalePL.doc.info")
   	(dest Dok_dest)
   )

   (copyfiles
   	(source "MagicWB/Icons/ZarysDziejów.doc.info")
   	(dest Dok_dest)
   )

   (if (bitand Wynik 32)
     (copyfiles
   	(source "MagicWB/Icons")
   	(dest PrintIt_dest)
   	(pattern "PrintIt#?")
     )
   )
 )
)
(complete 95)

(set ModKeymap
        (cat"\n\n   Nie obawiaj sie przy tym, ze twoje dotychczasowe\n"
                " preferencje zostana skasowane.Program instalacyjny\n"
                " zachowa Twoje dotychczasowe pliki preferencji,\n"
                " a ponadto podczas rekonfiguracji mapy klawiatury\n"
                " zachowa dotychczasowe ustawienie predkosci oraz\n"
                " przyspieszenia myszki oraz wszelkie parametry\n"
                " dotyczace klawiatury.")
)

(if (= 1 (askbool
	(prompt "\n\n\nCzy ustawic niezbedne parametry\n"
		"w preferencjach systemowych, tak aby\n"
		"LocalePL byly aktywne od razu po\n"
		"zainstalowaniu, czy tez wolisz zrobic to\n"
		"recznie?")
	(choices "Zrob to" "Wole sama")
	(help 	"\n   Jesli wolisz miec to z glowy, to wybierz wariant\n"
		" (Zrob to) co pozwoli Ci  na zaoszczedzenie paru\n"
		" jakze cennych chwilek..."
		ModKeymap)
                
       )
      )
 (

 (set Keymap
       (askchoice
          (prompt  "Jakiej klawiatury uzywasz?")
          (help    "\n"
                   "  Zaleznie od Twego wyboru ustawiona zostanie\n"
                   " odpowiednia mapa klawiatury"
		   ModKeymap)
          (choices "Angielskiej"
                   "Niemieckiej"
          )
       )
 )

 (if (AND (= IsMagicWB 0) (= (bitand Wynik 64) 0))
    (set prefs (askchoice
		(prompt "Ustawienie czcionek:")
  		(choices "Zostaw bez zmian"
                         "TopazPropPL i TopazPL"
                )
  		(help	 "\n Zostaw bez zmian\n"
                         " ----------------\n\n"
                         " Nie zmienia aktualnego ustawienia\n"
                         " czcionek...\n\n\n"
                         " Wariant 1\n"
  			 " ---------\n\n"
  			 " Proporcjonalny TopazPropPL jako czcionka\n"
  			 " ekranowa (menu) i pod ikonki, do reszty\n"
			 " zas klasyczny TopazPL\n\n\n"
			 " Jak widac, masz do dyspozycji jeden tylko\n"
			 " dodatkowy wariant, a to z tego powodu, ze\n"
			 " wyszystkie pozostale uzywaja polskich\n"
			 " czionek z pakietu MagicWB a przeciez takich\n"
			 " nie chciales zainstalowac...")
                )
     
     )           
  )

 (if (OR (= IsMagicWB 1) (bitand Wynik 64))
   (set prefs (askchoice
		(prompt "Ustawienie czcionek:")
  		(choices "Zostaw bez zmian"
                         "TopazPropPL i TopazPL"
  			 "TopazPropPL i XenPL"
  			 "XHelveticaPL i XenPL (1)"
  			 "XHelveticaPL i XenPL (2)"
  			 "XHelveticaPL, TopazPL i XenPL"
		)
  		(help	 "\n Zostaw bez zmian\n"
                         " ----------------\n\n"
                         " Nie zmienia aktualnego ustawienia\n"
                         " czcionek...\n\n\n"
                         " Wariant 1\n"
  			 " ---------\n\n"
  			 " Proporcjonalny TopazPropPL jako czcionka\n"
  			 " ekranowa (menu) i pod ikonki, do reszty\n"
			 " zas klasyczny TopazPL\n\n\n"
			 " Wariant 2\n"
			 " ---------\n\n"
			 " Proporcjonalny TopazPL jako czcionka\n"
  			 " ekranowa (menu) i pod ikonki, do reszty\n"
			 " zas XenPL. Wariant ten przeznaczony jest\n"
			 " raczej dla uzytkownikow MagicWB.\n"
			 " Moim zdaniem taki uklad jest lepszy niz...\n\n"
			 " Wariant 3\n"
			 " ---------\n\n"
			 " ...standardowe ustawienie dla MagicWB\n"
			 " (czyli XHelveticaPL (11) jako czcionka\n"
  			 " ekranowa (menu) i pod ikonki, do reszty\n"
			 " zas XenPL (9)), bowiem TopazPropPL jest znacznie\n"
			 " ladniejszy ale to kwestia gustu.\n\n"
			 " Wariant 4\n"
			 " ---------\n\n"
			 " Jak powyzszy wariant 3 ale czcionka ekranowa\n"
			 " ciut wieksza: XHelveticaPL (15).\n"
			 " Dla niezdecydowanych pozostaje juz ostatni...\n\n"
			 " Wariant 5\n"
			 " ---------\n\n"
			 " Pod ikonki TopazPropPL, Na ekran XHelvetica\n"
			 " 15 punktowa, zas jako czcionka systemowa\n"
			 " polecamy XENPL 13...\n\n\n\n\n\n\n\n\n\n\n"
			 " ...do tego wszystkiego mlode ziemniaczki saute,\n"
			 " kapustka gdzie niegdzie z groszkiem, oraz\n"
			 " renomowane wino spoldzielni Botwina\n"
			 " 'Janosik' (limited edition!) z 1994 roku....\n\n"
			 " Wesolych Swiat!"
		)
	      )
   )
  )
       (if (> prefs 0)
        (copyfiles
          (source "ENVARC:Sys/input.prefs")
          (dest   "ENVARC:Sys/STARE_PREFERENCJE")
        )
       )
        (copyfiles
          (source "ENVARC:Sys/locale.prefs")
          (dest   "ENVARC:Sys/STARE_PREFERENCJE")
        )
        (copyfiles
          (source "ENVARC:Sys/font.prefs")
          (dest   "ENVARC:Sys/STARE_PREFERENCJE")
        )
 
        (if (> prefs 0)
          (set Env_pat "#?")
          (set Env_pat "locale.prefs")
        )

	(copyfiles
	  (source (cat "Commodore/Prefs/Wariant" ("%ld" prefs)))
	  (dest "ENVARC:Sys")
          (pattern Env_pat)
 	)

(if (= keymap 0)
        ((run "c/ModPrefs ENVARC:Sys/input.prefs ENVARC:Sys/input.prefs AmigaPL-USA"))
        (run "c/ModPrefs ENVARC:Sys/input.prefs ENVARC:Sys/input.prefs AmigaPL-D")
)
        (run "SYS:Prefs/LOCALE ENVARC:Sys/locale.prefs USE")
        (run "SYS:Prefs/INPUT ENVARC:Sys/input.prefs USE")
        (if (> prefs 0)
         (run "SYS:Prefs/FONT ENVARC:Sys/font.prefs USE")
        )
 )
)
(complete 100)

(set sys (cat (getassign 'sys') "WBStartup'"))
(set progs "FontPLPatch")
(set koncowka ":")
(if (bitand Wynik 16)
    (
	(set progs (cat progs " i AssignWedge"))
        (set koncowka "y:")
    )
)

(message "Gotowe!\n"
	 "---------\n"
	 "Teraz najlepiej 'zresetuj' Amige, lub uruchom\n"
	 "wlasnorecznie program"
	 koncowka
         "\n"
	 progs
	 "\nz systemowego katalogu:\n'"
	 sys
	 "\noraz przeczytaj bardzo dokladnie zalaczona\n"
	 "dokumentacje, umieszczona w katalogu:\n'"
	 Dok_dest
         "'\n\nLocalePL © 1994 Marcin Orlowski\n"
	 "MR SOFT / World Federation of Mad Hackers"
)

(message "Wszelkie uwagi i sugestie na temat niniejszego\n"
	 "pakietu oraz ewentualne, zauwazone bledy a takze\n"
         "oplaty licencyjne prosze przesylac na jeden\n"
         "z ponizszych adresow:\n\n"
	 "Marcin Orlowski\n"
	 "ul. Radomska 38\n"
	 "71-002  Szczecin\n\n"
	 "SilverDream!'s BBS:  091-540431  (non-stop)\n\n"
	 "Internet: orlowsps@uoo.univ.szczecin.pl\n\n"
	 "MR SOFT / World Federation of Mad Hackers"
)

(run (cat ("run >nil: c/Most Dokumentacja/LocalePL.doc")))
(exit (QUIET))