; Nekron-Intro Nr.03/91
; Written by NEKRON for COMMANDO EAST in the Eastern-Hollidays´91!
; v1.0 ( 29-03-91 )

	INCDIR	df1:

************************* Library-Funktionen *********************

Execbase=	4
OldopenLib=	-408

************************* Definitionen ***************************

BACKSIZE=	40*200		320*200 Pixel-Screen
BITPLNS=	4		Anzahl der Backgr.Planes
SCREENSIZE=	68		Screenbreite des Scrollers
SCROLLSIZE=	48		Breite des ScrollBuffers
SINESIZE=	42		Breite des SinusScrollBuffers
SINEPOS=	40*53		SinusScroller Position
SPCL0=		$0555
SPCL1=		$0888		Starcolors
SPCL2=		$0ccc
WAIT1=		$03		Cursor Verzögerung
WAIT2=		$a5		TextDisplay Verzögerung
WAIT3=		$05		Fade Verzögerung
SIDESPEED=	5		Side Geschw.
SINUSSPEED=	4		Sinus Geschw.

MUSIC=		0		( Music on/off )
TRAINER=	0		( Trainer on/off )
DEBUG=		0		( 1= Debug on! )

************************* Hauptprogramm **************************

		SECTION	Nekron_Main,CODE_C

	IFNE	DEBUG
	OPT	d+
	ENDC

	IFEQ	DEBUG

Begin
	movem.l	a0-a6/d0-d7,-(SP)
	move.l	#Trapy,$0080.w
	trap	#0
	movem.l	(SP)+,a0-a6/d0-d7

	IFEQ	TRAINER
	jmp	$50000
	ENDC	
	rts
	ENDC

Trapy
	bsr	Install
rwait
	cmpi.b	#1,6(a6)
	bne	rwait
	bsr	StarMove
	bsr	mt_music
	bsr	TxOut
	bsr	SineScroll
	bsr	SideScroll

	clr.b	d0
	move.b	$bfec01,d0
	not.b	d0
	ror.b	#1,d0

	IFEQ	TRAINER
	cmpi.b	#$5f,d0
	bne	mainloop2
	bsr	Trainer
	bra	Reset
mainloop2
	ENDC
	cmpi.b	#$40,d0
	bne	rwait

	bra	Reset

*******************
* Installierungen *
*******************

Install
	move.l	(Execbase).w,a6
	lea	GfxName,a1
	jsr	OldopenLib(a6)
	move.l	d0,Gfxbase

	clr.b	$bfec01
	lea	$dff000,a6
	move.w	2(a6),d0
	move.w	$1c(a6),d1
	bset	#15,d0
	bset	#15,d1
	move.w	d0,OldDMACON
	move.w	d1,OldIRQENA

	IFEQ	DEBUG
	move.w	#$7fff,d0
	move.w	d0,$96(a6)
	move.w	d0,$9a(a6)
	move.w	#%1000001111100000,$96(a6)
	move.w	#%1100000000001111,$9a(a6)	Wegen Tastatur
	ENDC

	lea	Planes,a0
	move.l	#Background,d0
	moveq	#BITPLNS-1,d7
planloop
	move.w	d0,6(a0)
	swap	d0
	move.w	d0,2(a0)
	swap	d0
	add.l	#BACKSIZE,d0
	adda.w	#8,a0
	dbf	d7,planloop

	lea	ScrPlanes,a0
	moveq	#2-1,d7
	move.l	#Screen,d0
planloop2
	move.w	d0,6(a0)
	swap	d0
	move.w	d0,2(a0)
	swap	d0	
	adda.w	#8,a0
	add.w	#SCREENSIZE*70,d0
	dbf	d7,planloop2

	lea	Plane5,a0
	move.l	#SineScreen1,d0
	move.w	d0,6(a0)
	swap	d0
	move.w	d0,2(a0)

	lea	Screen,a0
	move.w	#(SCREENSIZE*70)*2/2,d0
clrloop1
	clr.w	(a0)+
	dbf	d0,clrloop1

	lea	ScrollBuffer,a0
	move.w	#(SCROLLSIZE*20)*2/2,d0
clrloop2
	clr.w	(a0)+
	dbf	d0,clrloop2

	lea	SineScreen1,a0
	lea	SineScreen2,a1
	move.w	#BACKSIZE/2,d0
clrloop3
	clr.w	(a0)+
	clr.w	(a1)+
	dbf	d0,clrloop3

	IFEQ	DEBUG
	move.l	#CopperList,$80(a6)
	clr.w	$88(a6)
	ENDC

	moveq	#7,d0
	lea	StarAdr,a0
starloop2
	move.l	(a0)+,a1
	move.l	(a0)+,a2
	move.w	a1,6(a2)
	move.l	a1,d1
	swap	d1
	move.w	d1,2(a2)
	dbf	d0,starloop2

	bsr	mt_init

	bsr	SetText

	rts

****************
* Reset System *
****************
	
Reset
	IFEQ	DEBUG
	bsr	mt_end
	move.w	OldDMACON,$96(a6)
	move.w	OldIRQENA,$9a(a6)
	move.l	Gfxbase,a5
	move.l	38(a5),$80(a6)
	clr.w	$88(a6)
	rte
	ENDC

	IFNE	DEBUG
	rts
	ENDC

************************* SubProgramme! **************************

***********
* Trainer *
***********

	IFEQ	TRAINER
Trainer
	lea	$50000,a0
	move.l	#$4e714e71,d0
	move.l	d0,$2a04(a0)
	move.l	d0,$2ae6(a0)
	move.l	d0,$2a44(a0)
	move.l	d0,$23c6(a0)
	move.l	d0,$2488(a0)
	move.l	#$6000000c,d0
	move.l	d0,$3c4a(a0)
	move.l	d0,$5c7a(a0)
	move.l	d0,$25a0(a0)
	move.w	#$4e71,$25c4(a0)
	move.l	#$6000fffc,$2824(a0)
	move.l	#$60000012,$2294(a0)
	rts
	ENDC

***********************
* NoiseTracker Replay *
***********************
	
	IFEQ	MUSIC
	INCLUDE	"NTReplay.s"
	ENDC

*******************
* Sterne bewegen! *
*******************

StarMove
	move.w	#50,d0
	lea	Stars1,a0
	lea	Stars2,a1
	lea	Stars3,a2
starloop3
	;bchg	#0,3(a0)
	;bne	star2
	addi.b	#1,1(a0)
star2
	addi.b	#2,1(a1)
	addi.b	#3,1(a2)
	adda.l	#8,a0
	adda.l	#8,a1
	adda.l	#8,a2
	dbf	d0,starloop3
	rts

****************
* Cursor TxOut *
****************

TxOut
	addi.b	#1,Counter
	cmpi.b	#WAIT1,Counter
	bne	txend
	clr.b	Counter

	move.l	PlanePointer,a0
	moveq	#8-1,d7
txout1
	move.b	#0,(a0)
	move.b	#$ff,40*200(a0)
	move.b	#$ff,2*40*200(a0)	Kill old Cursor
	move.b	#$ff,3*40*200(a0)
	adda.l	#40,a0
	dbf	d7,txout1

	clr.w	d0
	move.l	PlanePointer,a0
	move.l	TxPointer,a1
	lea	Charset,a2
	move.b	(a1)+,d0
	tst.b	d0
	beq	txend
	move.l	a1,TxPointer
	cmpi.b	#$0a,d0
	bne	txout2
	add.l	#40*8,OldPlPointer
	move.l	OldPlPointer,PlanePointer
	bra	setcurs
txout2
	cmpi.b	#$20,d0			
	bhi	txout3			Charakter-Test!
	move.b	#" ",d0
	bra	txout5
txout3
	cmpi.b	#$5b,d0
	blo	txout4
	move.b	#" ",d0
	bra	txout5
txout4
	subi.b	#$20,d0
txout5
	asl.w	#3,d0

	moveq	#8-1,d7
txout6
	move.b	(a2,d0.w),d1
	or.b	d1,(a0)
	or.b	d1,40*200(a0)
	eor.b	d1,2*40*200(a0)
	eor.b	d1,3*40*200(a0)
	adda.l	#40,a0
	addi.w	#1,d0
	dbf	d7,txout6
	add.l	#1,PlanePointer
setcurs
	move.l	PlanePointer,a0
	moveq	#8-1,d7
	move.b	#$ff,d1
txout7
	or.b	d1,(a0)
	or.b	d1,40*200(a0)
	eor.b	d1,2*40*200(a0)		Set new Cursor
	eor.b	d1,3*40*200(a0)
	adda.l	#40,a0
	dbf	d7,txout7
txend
	rts

**************
* SideScroll *
**************

SideScroll
	bsr	Fade
	bsr	DoScroll
	rts

Fade
	cmpi.b	#WAIT2,Counter2		Text-Verzögerung
	beq	fade2
	addi.b	#1,Counter2
	rts
fade2
	addi.b	#1,Counter3		Fade-Verzögerung
	cmpi.b	#WAIT3,Counter3
	bne	fadeend
	clr.b	Counter3

	btst	#1,Status
	bne	fade3
	move.l	FadePointer1,a0
	move.l	FadePointer2,a1
	bra	fade4
fade3
	move.l	FadePointer2,a0
	move.l	FadePointer1,a1
fade4
	move.w	(a0)+,d0
	move.w	(a1)+,d1
	cmpi.w	#-1,d0
	bne	fade5
	move.l	#FadeTab1,FadePointer1
	move.l	#FadeTab2,FadePointer2
	clr.b	Counter2
	bsr	SetText
	bchg	#1,Status
	rts
fade5
	btst	#1,Status
	bne	fade6
	move.l	a0,FadePointer1
	move.l	a1,FadePointer2
	bra	fade8
fade6
	move.l	a0,FadePointer2
	move.l	a1,FadePointer1
fade8
	lea	FadeCol,a0
	move.w	d0,2(a0)
	move.w	d1,6(a0)
fadeend
	rts
	
SetText
	move.l	STxPointer,a0
	lea	Font,a1
	bchg	#0,Status
	bne	settx2
	lea	ScrollBuffer,a2
	bra	settx3
settx2
	lea	ScrollBuffer+SCROLLSIZE*20,a2
settx3
	move.w	#%0000100100000000,$40(a6)
	sf	$42(a6)
	move.l	a2,$54(a6)
	sf	$66(a6)
	move.w	#%0000010100011000,$58(a6)
blwait1	
	btst	#14,2(a6)
	bne	blwait1
setloop
	clr.l	d0
	clr.l	d1
	move.b	(a0)+,d0
	tst.b	d0
	beq	setback
	cmpi.b	#$0a,d0
	beq	settxend
	cmpi.b	#$20,d0
	bhi	settx4
	bra	settx5
settx4
	cmpi.b	#$5b,d0
	blo	settx6
settx5
	move.b	#$20,d0
settx6
	subi.b	#$20,d0
	divu	#20,d0
	move.w	d0,d1
	swap	d0
	mulu	#40*16,d1
	asl.w	#1,d0
	add.w	d1,d0
	lea	(a1,d0.w),a3
	move.w	#%0000100111110000,$40(a6)
	sf	$42(a6)
	st	$44(a6)
	st	$46(a6)
	move.l	a3,$50(a6)
	move.l	a2,$54(a6)
	move.w	#40-2,$64(a6)
	move.w	#SCROLLSIZE-2,$66(a6)
	move.w	#%0000010000000001,$58(a6)
blwait2
	btst	#14,2(a6)
	bne	blwait2
	adda.w	#2,a2
	bra	setloop
settxend
	move.l	a0,STxPointer
	rts
setback
	move.l	#SideText,STxPointer
	rts

DoScroll
	lea	ScrollBuffer,a0
	lea	Screen+SCREENSIZE*18-2,a1
	add.l	#SIDESPEED,SinePointer
	move.l	SinePointer,a2
	cmpa.l	#SineTabEnd,a2
	blo	doscroll2
	lea	SineTab,a2
	move.l	a2,SinePointer
doscroll2
	moveq	#2-1,d7
	move.l	a1,a3
doscroll3
	move.w	#%0000100100000000,$40(a6)
	sf	$42(a6)
	sf	$66(a6)
	move.l	a3,$54(a6)
	move.w	#%0000010000100010,$58(a6)
blwait4
	btst	#14,2(a6)
	bne	blwait4
	adda.w	#SCREENSIZE*70,a3
	dbf	d7,doscroll3

	moveq	#2-1,d7
	clr.l	d0
	clr.l	d1
	move.b	(a2),d0
	asl.b	#1,d0			*2,Ausschlag vergrößern!
	swap	d0
	asr.l	#4,d0			/16
	move.w	d0,d1			Rest nach d1 (ASH Wert!)
	swap	d0			Vorkommazahlen ins LSB
	asl.w	#1,d0			und *2 genommen (Wegen Blitter!)
	adda.w	d0,a1	
	or.w	#%0000100111110000,d1
	
doloop
	move.w	d1,$40(a6)
	sf	$42(a6)
	st	$44(a6)
	st	$46(a6)
	move.l	a0,$50(a6)
	move.l	a1,$54(a6)
	sf	$64(a6)
	move.w	#SCREENSIZE-48,$66(a6)
	move.w	#%0000010000011000,$58(a6)
blwait3
	btst	#14,2(a6)
	bne	blwait3
	adda.w	#SCROLLSIZE*20,a0
	adda.w	#SCREENSIZE*70,a1
	dbf	d7,doloop
	rts				

******************
* Sinus-Scroller *
******************

SineScroll
	subi.b	#1,Row
	bne	sinescroll2
	move.b	#16,Row
	bsr	SetChar
sinescroll2
	bsr	Scroll
	bsr	DoSine
	rts

SetChar
	clr.l	d0
	move.l	SineTxPointer,a0
	move.b	(a0)+,d0
	tst.b	d0
	bne	setchar2
	move.l	#SineTx,SineTxPointer
	bra	SetChar
setchar2
	move.l	a0,SineTxPointer
	cmpi.b	#$20,d0
	blo	setchar3
	cmpi.b	#$5b,d0
	blo	setchar4
setchar3
	move.b	#$20,d0
setchar4
	subi.b	#$20,d0
	divu	#20,d0
	move.w	d0,d1
	swap	d0
	asl.w	#1,d0
	mulu	#40*16,d1
	add.w	d1,d0
	lea	Font,a0
	lea	(a0,d0.w),a0
	lea	SineBuffer+SINESIZE-4,a1
	move.w	#%0000100111110000,$40(a6)
	sf	$42(a6)
	st	$44(a6)
	st	$46(a6)
	move.l	a0,$50(a6)
	move.l	a1,$54(a6)
	move.w	#40-2,$64(a6)
	move.w	#SINESIZE-2,$66(a6)
	move.w	#%0000010000000001,$58(a6)
blwait5
	btst	#14,2(a6)
	bne	blwait5
	rts

Scroll
	lea	SineBuffer+2,a0
	lea	SineBuffer,a1
	move.w	#%1111100111110000,$40(a6)
	sf	$42(a6)
	move.w	#%0001111111111111,$44(a6)
	st	$46(a6)
	move.l	a0,$50(a6)
	move.l	a1,$54(a6)
	move.w	#2,$64(a6)
	move.w	#2,$66(a6)
	move.w	#%0000010010010100,$58(a6)
blwait6
	btst	#14,2(a6)
	bne	blwait6
	rts

DoSine
	move.l	SinePointer2,a0
	lea	SineBuffer,a1
	lea	Plane5,a2
	bchg	#2,Status
	bne	sine2
	lea	SineScreen1+SINEPOS,a3
	move.l	#SineScreen2,d0
	bra	sine3
sine2
	lea	SineScreen2+SINEPOS,a3
	move.l	#SineScreen1,d0
sine3
	move.w	d0,6(a2)
	swap	d0
	move.w	d0,2(a2)

	move.w	#%0000100100000000,$40(a6)
	sf	$42(a6)
	move.l	a3,$54(a6)
	sf	$66(a6)
	move.w	#%0010001010010100,$58(a6)
blwait8
	btst	#14,2(a6)
	bne	blwait8

	moveq	#19-1,d6		10 Chars als Sinus
sineloop
	lea	FWMTab,a2
	moveq	#4-1,d7
sineloop2
	clr.l	d0
	move.b	(a0)+,d0
	cmpa.l	#SineTabEnd,a0
	blo	sine4
	lea	SineTab,a0
	bra	sineloop2
sine4
	asl.w	#1,d0
	mulu	#40,d0
	lea	(a3,d0.l),a4
	move.w	(a2)+,d0

	move.w	#%0000110111111100,$40(a6)
	sf	$42(a6)
	move.w	d0,$44(a6)
	move.w	d0,$46(a6)
	move.l	a4,$4c(a6)
	move.l	a1,$50(a6)
	move.l	a4,$54(a6)
	move.w	#40-2,$62(a6)
	move.w	#SINESIZE-2,$64(a6)
	move.w	#40-2,$66(a6)
	move.w	#%0000010000000001,$58(a6)
blwait7
	btst	#14,2(a6)
	bne	blwait7
	dbf	d7,sineloop2
	adda.l	#2,a1
	adda.l	#2,a3
	dbf	d6,sineloop

	add.l	#SINUSSPEED,SinePointer2
	cmp.l	#SineTabEnd,SinePointer2
	blo	dosinend
	move.l	#SineTab,SinePointer2
dosinend
	rts

************************* Gfx. & Daten etc. **********************

GfxName		dc.b	"graphics.library",0
		EVEN

Gfxbase		ds.l	1
OldDMACON	ds.w	1
OldIRQENA	ds.w	1
PlanePointer	dc.l	Background+40*40+3
OldPlPointer	dc.l	Background+40*40+3
FadePointer1	dc.l	FadeTab1
FadePointer2	dc.l	FadeTab2
TxPointer	dc.l	Text
STxPointer	dc.l	SideText
SineTxPointer	dc.l	SineTx
SinePointer	dc.l	SineTab
SinePointer2	dc.l	SineTab+90
Status		dc.b	0
Counter		dc.b	WAIT1-2
Counter2	dc.b	WAIT2-2
Counter3	dc.b	WAIT3-2
Row		dc.b	5
		EVEN

CopperList	dc.w	$008e,$2c81,$0090,$27f1
		dc.w	$0092,$0034,$0094,$00cd
		dc.w	$0108,$0000,$010a,$0000
		dc.w	$0102,$0000,$0104,%0000000000000001
		dc.w	$0100,$5200

Planes		dc.w	$00e0,$0000,$00e2,$0000
		dc.w	$00e4,$0000,$00e6,$0000
		dc.w	$00e8,$0000,$00ea,$0000
		dc.w	$00ec,$0000,$00ee,$0000
Plane5		dc.w	$00f0,$0000,$00f2,$0000

Sprite0		dc.w	$0120,$0000,$0122,$0000
Sprite1		dc.w	$0124,$0000,$0126,$0000
Sprite2		dc.w	$0128,$0000,$012a,$0000
Sprite3		dc.w	$012c,$0000,$012e,$0000
Sprite4		dc.w	$0130,$0000,$0132,$0000
Sprite5		dc.w	$0134,$0000,$0136,$0000
Sprite6		dc.w	$0138,$0000,$013a,$0000
Sprite7		dc.w	$013c,$0000,$013e,$0000

		dc.w	$0180,$0000,$0182,$0fff
		dc.w	$0184,$0fee,$0186,$0fdd
		dc.w	$0188,$0ecb,$018a,$0db9
		dc.w	$018c,$0ca7,$018e,$0b95
		dc.w	$0190,$0a83,$0192,$0971
		dc.w	$0194,$0860,$0196,$0750
		dc.w	$0198,$0640,$019a,$0530
		dc.w	$019c,$0230,$019e,$0120
		dc.w	$01a4,SPCL0,$01ac,SPCL1,$01b4,SPCL2

		dc.w	$6003,$fffe
		dc.w	$01a6,$0447,$01bc,$0447
		dc.w	$6303,$fffe
		dc.w	$01a6,$0448,$01bc,$0448
		dc.w	$6603,$fffe
		dc.w	$01a6,$0449,$01bc,$0449
		dc.w	$6903,$fffe
		dc.w	$01a6,$044a,$01bc,$044a
		dc.w	$6c03,$fffe
		dc.w	$01a6,$044b,$01bc,$044b
		dc.w	$6f03,$fffe
		dc.w	$01a6,$044c,$01bc,$044c
		dc.w	$7203,$fffe
		dc.w	$01a6,$044d,$01bc,$044d
		dc.w	$7503,$fffe
		dc.w	$01a6,$044e,$01bc,$044e
		dc.w	$7803,$fffe
		dc.w	$01a6,$044f,$01bc,$044f
		dc.w	$7b03,$fffe
		dc.w	$01a6,$055f,$01bc,$055f
		dc.w	$7e03,$fffe
		dc.w	$01a6,$066f,$01bc,$066f
		dc.w	$8103,$fffe
		dc.w	$01a6,$077f,$01bc,$077f
		dc.w	$8403,$fffe
		dc.w	$01a6,$088f,$01bc,$088f
		dc.w	$8703,$fffe
		dc.w	$01a6,$099f,$01bc,$099f
		dc.w	$8a03,$fffe
		dc.w	$01a6,$0aaf,$01bc,$0aaf
		dc.w	$8d03,$fffe
		dc.w	$01a6,$0bbf,$01bc,$0bbf
		dc.w	$9003,$fffe
		dc.w	$01a6,$0ccf,$01bc,$0ccf
		dc.w	$9303,$fffe
		dc.w	$01a6,$0ddf,$01bc,$0ddf
		dc.w	$9603,$fffe
		dc.w	$01a6,$0eef,$01bc,$0eef
		dc.w	$9903,$fffe
		dc.w	$01a6,$0fff,$01bc,$0fff
		dc.w	$9c03,$fffe
		dc.w	$01a6,$0eef,$01bc,$0eef
		dc.w	$9f03,$fffe
		dc.w	$01a6,$0ddf,$01bc,$0ddf
		dc.w	$a203,$fffe
		dc.w	$01a6,$0ccf,$01bc,$0ccf
		dc.w	$a503,$fffe
		dc.w	$01a6,$0bbf,$01bc,$0bbf
		dc.w	$a803,$fffe
		dc.w	$01a6,$0aaf,$01bc,$0aaf
		dc.w	$ab03,$fffe
		dc.w	$01a6,$099f,$01bc,$099f
		dc.w	$ae03,$fffe
		dc.w	$01a6,$088f,$01bc,$088f
		dc.w	$b103,$fffe
		dc.w	$01a6,$077f,$01bc,$077f
		dc.w	$b403,$fffe
		dc.w	$01a6,$066f,$01bc,$066f
		dc.w	$b703,$fffe
		dc.w	$01a6,$055f,$01bc,$055f
		dc.w	$ba03,$fffe
		dc.w	$01a6,$044f,$01bc,$044f
		dc.w	$be03,$fffe
		dc.w	$01a6,$044e,$01bc,$044e
		dc.w	$c103,$fffe
		dc.w	$01a6,$044d,$01bc,$044d
		dc.w	$c403,$fffe
		dc.w	$01a6,$044c,$01bc,$044c
		dc.w	$c703,$fffe
		dc.w	$01a6,$044b,$01bc,$044b
		dc.w	$ca03,$fffe
		dc.w	$01a6,$044a,$01bc,$044a
		dc.w	$cd03,$fffe
		dc.w	$01a6,$0449,$01bc,$0449
		dc.w	$d003,$fffe
		dc.w	$01a6,$0448,$01bc,$0448
		dc.w	$d303,$fffe
		dc.w	$01a6,$0447,$01bc,$0447
		dc.w	$d603,$fffe
		dc.w	$01a6,$0446,$01bc,$0446
		dc.w	$d903,$fffe
		dc.w	$01a6,$0445,$01bc,$0445
		dc.w	$dc03,$fffe
		dc.w	$01a6,$0444,$01bc,$0444
		dc.w	$df03,$fffe
		dc.w	$01a6,$0443,$01bc,$0443
		dc.w	$e203,$fffe
		dc.w	$01a6,$0442,$01bc,$0442
		dc.w	$e503,$fffe
		dc.w	$01a6,$0441,$01bc,$0441

		dc.w	$f40f,$fffe

		dc.w	$0100,$2200
		dc.w	$0108,SCREENSIZE-44,$010a,SCREENSIZE-44
		dc.w	$0092,$0030,$0094,$00d8

ScrPlanes	dc.w	$00e0,$0000,$00e2,$0000
		dc.w	$00e4,$0000,$00e6,$0000
FadeCol		dc.w	$0182,$0000,$0184,$0000
		dc.w	$0186,$0b05
		
		dc.w	$0,$0b


Star		dc.w	0,%0000000100000000
Dummy		dc.w	0,0

StarAdr		dc.l	Stars1,Sprite0,Dummy,Sprite1
		dc.l	Stars2,Sprite2,Dummy,Sprite3
		dc.l	Stars3,Sprite4,Dummy,Sprite5
		dc.l	Dummy,Sprite6,Dummy,Sprite7

FadeTab1	dc.w	$0000,$0100,$0200,$0300,$0400,$0500
		dc.w	$0600,$0701,$0802,$0903,$0a04,$0b05,-1
FadeTab2	dc.w	$0b05,$0a04,$0903,$0802,$0701,$0600
		dc.w	$0500,$0400,$0300,$0200,$0100,$0000,-1

FWMTab		dc.w	%1111000000000000
		dc.w	%0000111100000000
		dc.w	%0000000011110000
		dc.w	%0000000000001111

************************* Screens & ScrollBuffer *****************

Stars1		INCBIN	"Code/StarPlane1.BIN"
Stars2		INCBIN	"Code/StarPlane2.BIN"
Stars3		INCBIN	"Code/StarPlane3.BIN"
		EVEN

Screen		ds.b	(70*SCREENSIZE)*2
		EVEN

SineScreen1	ds.b	BACKSIZE
		EVEN

SineScreen2	ds.b	BACKSIZE
		EVEN

ScrollBuffer	ds.b	(20*SCROLLSIZE)*2
		EVEN

SineBuffer	ds.b	SINESIZE*20
		EVEN

************************* Externe Dateien ************************

Background	INCBIN	"Gfx/Blackboard.RAW"
		EVEN

Charset		INCBIN	"Gfx/FontObj"
		EVEN

Font		INCBIN	"Gfx/NekronFont.BLIT"
		EVEN

mt_data		INCBIN	"Sound/WHENWIN.MUS"
		EVEN

SineTab		INCBIN	"Code/SineTab.BIN"
SineTabEnd	EVEN

Text		INCBIN	"Code/Text.TX"
		dc.b	0
		EVEN

SideText	INCBIN	"Code/SideText.TX"
		dc.b	0
		EVEN

SineTx		dcb.b	8,$20
		INCBIN	"Code/SineText.TX"
		dc.b	0

		END