.Key disk
;
; Funktion    : Installerar COACH på en hårddisk
; Namn        : HD-Installering
; Sist ändrad : 1991-11-10
; Version     : 1.0
; (C)         : Nord Data 1991
;
Failat 30
  Assign FromCODisk: ""
IF "<disk>" EQ ""
  Echo "*N                  *E[;1mHårddisk-Installering v1.0*E[m*N"
  Echo "              Installering av COACH på hårddisk:*N"
  Echo "  *E[;33m1. Återstarta datorn med hårddisken.*N     (Ingen COACH-diskett i datorn.)*n"
  Echo "  2. Sätt in COACH-disketten i datorn.*n"
  Echo "  3. Klicka en gång på HD-Installering.*N     (På ikonen skall hjälptext synas.)*n"
  Echo "  4. Håll in SHIFT-tangenten.*n"
  Echo "  5. Dubbelklicka på önskad destinations hårddisk eller låda.*E[m*N"
  FromCODisk:c/ASK "                         *E[;1mTryck Return*E[m*N"
  Skip END
ELSE
  IF EXISTS "SYS:coach-logo"
    IF EXISTS "SYS:coach-v"
      Echo "*E[22B  *E[;33mCOACH går inte att installera på hårddisken.*N  Återstarta utan COACH-diskett i datorn.*E[m*E[10B"
      Wait 5
      Skip END
    ENDIF
  ENDIF
  IF NOT EXISTS "<disk>"
    Echo "*E[22B  *E[;33mKan inte hitta hårddisken:*E[m*N  *E[;1m<disk>*E[m*E[10B"
    Wait 5
    Skip END
  ENDIF
  FromCODisk:c/ASK "*E[10B  Skall COACH installeras på hårddisken:*N  *E[;1m<disk>*E[m [J/N] ? N*E[2D"
  IF NOT WARN
    Skip END
  ENDIF
  Assign ToCODisk: "<disk>"
  Cd ToCODisk:
  IF EXISTS "ToCODisk:COACH-v1.3/COACH"
    Echo "*E[22B  *E[;33mCOACH är redan installerad på hårddisken.*E[m*E[10B"
    Wait 5
    Skip END
  ENDIF
  Echo "*E[22B  Installerar COACH på hårddisken:*N  *E[;1m<disk>*E[m*N*N"
  Echo "  Skapar lådor"
  makedir ToCODisk:COACH-v1.3
  makedir ToCODisk:COACH-v1.3/Glosfiler
  copy FromCODisk:Glosfiler.info to ToCODisk:COACH-v1.3.info
  copy FromCODisk:Glosfiler.info to ToCODisk:COACH-v1.3
  echo "  Kopierar COACH..."
  copy FromCODisk:COACH to ToCODisk:COACH-v1.3
  copy FromCODisk:COACH.info to ToCODisk:COACH-v1.3
  copy FromCODisk:glos to ToCODisk:COACH-v1.3
  copy FromCODisk:COACH-l to ToCODisk:COACH-v1.3
  copy FromCODisk:COACH-logo to ToCODisk:COACH-v1.3
  copy FromCODisk:COACH-v to ToCODisk:COACH-v1.3
  copy FromCODisk:COACH-r to ToCODisk:COACH-v1.3
  copy FromCODisk:start.bat to ToCODisk:COACH-v1.3
  copy FromCODisk:startprg to ToCODisk:COACH-v1.3
  copy FromCODisk:AmigaBasic to ToCODisk:COACH-v1.3
  copy FromCODisk:IconX to ToCODisk:COACH-v1.3
  echo "  Kopierar typsnitt och libraries..."

  if NOT exists ToCODisk:fonts
    makedir ToCODisk:fonts
  ENDIF
  copy FromCODisk:fonts/coach.font ToCODisk:fonts
  makedir ToCODisk:fonts/coach
  copy FromCODisk:fonts/coach ToCODisk:fonts/coach quiet
  if NOT exists ToCODisk:libs
    makedir ToCODisk:libs
  ENDIF
  if not exists ToCODisk:libs/diskfont.library
    copy FromCODisk:libs/diskfont.library ToCODisk:Libs
  ENDIF
  if not exists ToCODisk:libs/diskfont.bmap 
    copy FromCODisk:libs/diskfont.bmap ToCODisk:Libs
  ENDIF
  if not exists ToCODisk:libs/intuition.bmap
    copy FromCODisk:libs/intuition.bmap ToCODisk:Libs
  ENDIF
  if not exists ToCODisk:libs/graphics.bmap
    copy FromCODisk:libs/graphics.bmap ToCODisk:Libs
  ENDIF
  if not exists ToCODisk:libs/dos.bmap
    copy FromCODisk:libs/dos.bmap ToCODisk:Libs
  ENDIF
  if not exists ToCODisk:libs/exec.bmap
    copy FromCODisk:libs/exec.bmap ToCODisk:Libs
  ENDIF
  if not exists ToCODisk:libs/translator.library
    copy FromCODisk:libs/translator.library ToCODisk:Libs
  ENDIF
  if NOT exists ToCODisk:devs
    makedir ToCODisk:devs
  ENDIF
  copy FromCODisk:devs/narrator.device ToCODisk:devs

  Cd ""
  Echo "*E[22B                    *E[;1mInstalleringen är klar!*E[m*E[6B"
  FromCODisk:c/ASK "                         *E[;1mTryck Return*E[m*N"
ENDIF
Lab END
Assign ToCODisk:
Assign FromCODisk:
Failat 10