/*
   Arexx3: Rozbal.rexx

   Autor: Jan Petkov, (c)1996 pro AmigaReview

   Info: Tento Arexx script rozbali prislusny archiv do ciloveho adresare, typ
         archivu je stanoven podle tripismenne koncovky.
         Nekde pobliz tohoto zdrojaku by mel existova i Amiga Dos scritp, ktery
         umoznuje rychlejsi spousteni tohoto programu.

         Have fun. Be good. Enjoy Amiga.
*/

ARG soubor adresar

IF soubor = '?' THEN
   DO
      OPTIONS PROMPT 'SOUBOR/A, CILOVY ADRESAR/F: '
      PULL soubor adresar
   END

IF soubor = '' THEN
   DO
      SAY 'Pouziti:'
      SAY '  Rozbal <Soubor> [CilovyAdresar]'
      SAY '         <Soubor> musi koncit platnou koncovkou'
      SAY '         (.LHA, .LZH, .LZX, .RAR nebo .ARJ)'
      EXIT
   END
ELSE
   IF ~EXISTS(soubor) THEN
      DO
         SAY 'Soubor "'soubor'" nebyl nalezen.'
         EXIT
      END

koncovka = UPPER( RIGHT(soubor,3) )

ADDRESS COMMAND

SELECT
   WHEN koncovka ='LZH' | koncovka = 'LHA' THEN
      'LHA -X X' soubor '#?' adresar

   WHEN koncovka ='LZX' THEN
      'LZX -X X' soubor '#?' adresar

   WHEN koncovka = 'RAR' THEN
       CALL ZmenaAdresare('UNRAR X 'soubor' #?')

   WHEN koncovka = 'ARJ' THEN
       CALL ZmenaAdresare('UNARJ X 'soubor)

   OTHERWISE
      SAY 'Archiv "'soubor'" nebyl rozpoznan.'
      SAY 'Musi koncit na "LZH", "LHA", "LZX", "RAR" nebo "ARJ".'
      EXIT
END

EXIT


/* fce */
ZmenaAdresare:
   PARSE ARG rozbal_tool

   stary_adresar = PRAGMA('DIRECTORY')

   CALL PRAGMA('DIRECTORY',adresar)
   rozbal_tool
   CALL PRAGMA('D',stary_adresar)

   RETURN