; Skrypt instalacyjny programu Test Studio
; $VER: Instaluj 1.1 (14.06.95)


;==========================================================================
; ōcieūki dostėpu

(set dirname "TestStudio5")
(set logicname "TestStudio")
(set mainprogram "TestStudio")
(set prgprefs "Prefs/TestStudio/TestStudioV5.0.prefs")
(set prefsdir1 "ENVARC:TestStudio")
(set prefsdir2 "ENV:TestStudio")
(set tests "testy")
(set samples "sample")
(set docs "Instrukcja.guide")
(set testinfo "C/TestInfo")
(set reqtoolslib "Libs/reqtools.library")
(set iffparselib "Libs/iffparse.library")

;==========================================================================
; teksty komunikatów

(set #welcome-msg
  (cat
    "Jest to skrypt instalacyjny programu Test Studio.\n\n"
    "Pozwala on zainstalowaź program na dysku twardym.\n"
    "Na   dysku   twardym  powinno  znajdowaź  siė  co\n"
    "najmniej 500 KB wolnego miejsca.\n\n"
    "(c) by Īukasz Szelāg\n"
    "Wszelkie prawa zastrzeūone.\n"
  )
)
(set #where-main "Wybierz miejsce, gdzie utworzyź katalog programu.")
(set #copying-reqtools "\nKopiujė bibliotekė reqtools do Libs:...")
(set #copying-iffparse "\nKopiujė bibliotekė iffparse do Libs:...")
(set #modify-startup
  (cat
    "Do   poprawnej  pracy  programu,  konieczne  jest\n"
    "dopisanie   odpowiedniego  przypisania  do  pliku\n"
    "user-startup."
  )
)
(set #end-msg "Zresetuj komputer przed uruchomieniem programu")

;==========================================================================
; czėōź gīówna skryptu

; wyōwietlenie komunikatu informacyjnego
(message #welcome-msg)

; pobranie katalogu programu
(set maindir
  (askdir
    (prompt #where-main)
    (help @askdir-help)
    (default "SYS:")
  )
)

; skopiowanie programu gīównego
(copyfiles
 (source mainprogram)
  (dest (tackon maindir dirname))
  (infos)
)

; skopiowanie preferencji programu
(copyfiles
  (source prgprefs)
  (dest prefsdir1)
)
(copyfiles
  (source prgprefs)
  (dest prefsdir2)
)

; skopiowanie testów
(copyfiles
  (source tests)
  (dest (tackon (tackon maindir dirname) "testy"))
  (all)
  (infos)
)

; skopiowanie sampli
(copyfiles
  (source samples)
  (dest (tackon (tackon maindir dirname) "sample"))
  (all)
)

; skopiowanie dokumentacji
(copyfiles
  (source docs)
  (dest (tackon maindir dirname))
  (infos)
)

; skopiowanie programu dodatkowego TestInfo
(copyfiles
  (source testinfo)
  (dest "C:")
)

; skopiowanie biblioteki reqtools
(copylib
  (source reqtoolslib)
  (dest "Libs:")
  (confirm)
  (prompt #copying-reqtools)
  (help @copylib-help)
  (confirm)
)

; skopiowanie biblioteki iffparse
(copylib
  (source iffparselib)
  (dest "Libs:")
  (confirm)
  (prompt #copying-iffparse)
  (help @copylib-help)
  (confirm)
)

; modyfikacja pliku user-startup
(startup mainprogram
  (prompt #modify-startup)
  (help @startup-help)
  (command
    (cat "Assign " logicname ": ") (tackon maindir dirname))
)

; przypisanie katalogu programu
(makeassign logicname (tackon maindir dirname)
  (safe)
)