(set WBVer (< 2424832 (getversion "exec.library" (resident))))

(if (= (run "TermiteTCPInstall:register" (safe)) 20)
    (
        (message "TermiteTCP must be registered before it can be installed.")
        (exit "Exiting..." (quiet))
    )
)

(set DiskType 
    (askchoice 
        (prompt "Install TermiteTCP to hard disk or floppy disk?")
        (help "You can either configure TermiteTCP to run from floppy disks, "
                "or from a hard disk if you have one.")
        (choices "Hard Disk" "Floppy Disk")
        (default 0)
    )
)

(if (= DiskType 0)
(
    (until Continue
        (set TermitePath
            (askdir
                (prompt "Where should the TTCP directory be created?")
                (help "The installation utility will create a new directory"
                        " called \"TTCP\" at the specified location.  TermiteTCP files"
                        " will be copied to this new directory.")
                (default @default-dest)
            )
        )
	
        (set Continue 
            (askbool
                (prompt "TermiteTCP will be installed to:"
                            "\n\n" (tackon TermitePath "TTCP") 
                            "\n\n\n\nRequired libraries will be copied to LIBS:")
                (help "TermiteTCP files will be copied to " (tackon TermitePath "TTCP") 
                        ".  If that directory does not exist, it will be created."
                        "  To change your selection, click on No, otherwise Proceed.")
                (choices "Proceed" "Go back")
            )
        )
    )

    (set TermiteDir (tackon TermitePath "TTCP"))

    (if (not (exists TermiteDir))
        (makedir TermiteDir (infos) )
    )

    (set InboxDir (tackon TermiteDir "Inbox"))
        (makedir InboxDir (infos) )

    (set SaveDir (tackon TermiteDir "SavedMail"))
        (makedir SaveDir (infos) )

    (set SentDir (tackon TermiteDir "SentMail"))
        (makedir SentDir (infos) )

    (set SentDir (tackon TermiteDir "Help"))
        (makedir SentDir (infos) )

    (set @execute-dir TermiteDir)
    (set @default-dest TermiteDir)
)
)

;
; Copy main TermiteTCP files
;

(if (= DiskType 0)
(
    (set OSVer (/ (getversion) 65536))
    (set ASLVer (/ (getversion "libs:asl.library") 65336))

    (if (< ASLVer 38)
        (
            (message "asl.library version " ASLVer " detected.\n"
                        "Version 38 required.\n\nasl.library v38 will be installed.")
            (copyfiles
                (source "TermiteTCPInstall:libs/asl.library")
                (dest "libs:")
            )
        )
    )

    (copyfiles
        (source "TermiteTCPInstall:TTCP")
        (dest @default-dest)
        (all)
        (infos)
    )

    (copyfiles
        (source "TTCP.inf")
        (dest TermitePath)
        (newname "TTCP.info")
    )


)
; else
(
    (set OSVer (/ (getversion) 65536))
    (set ASLVer (/ (getversion "libs:asl.library") 65336))

    (if (< ASLVer 38)
        (
            (message "asl.library version " ASLVer " detected.\n"
                        "Version 38 required.\n\nasl.library v38 will be installed.")
            (copyfiles
                (source "TermiteTCPInstall:libs/asl.library")
                (dest "libs:")
            )
        )
    )

    (message "A new, blank disk must be formatted for TermiteTCP to install onto.\n\n"
                "Please insert a new disk into drive df0: and click Proceed.\n\n"
                "* ALL DATA ON THE DISK IN DF0: WILL BE ERASED *\n\n"
                "(Now would be a good time to write-protect your TermiteTCP master disk.)")

    (if (= (exists "sys:system/format") 0) 
        (
            (message "Cannot format disk because SYS:System/Format is missing.")
            (abort)    
        )
    )

    (working "Formatting disk...")

    (run "sys:system/format drive df0: name TermiteTCP noicons ffs")

    (copyfiles
        (source "TermiteTCPInstall:TTCP")
        (dest "TermiteTCP:")
        (all)
        (infos)
    )

    (copyfiles
        (source "TermiteTCPInstall:Disk.info")
        (dest "TermiteTCP:")
    )

    (set @default-dest "TermiteTCP:")
)
)

(if (AND (= WBVer 1) (= (exists "SYS:Utilities/Multiview") 1))
    (Run "Run SYS:Utilities/Multiview TermiteTCPInstall:TTCP/ReadMeNow" (safe))
)