/* $VER: CPR.raz 1.2 (6.9.95)
 * Inspiré de CPR.ttx de Kenneth Yarnall distribué avec SAS C
 * Modifié par DBernard puis JM Forgeas
 *
 * Lance CPR sur un exécutable. Le nom de ce dernier est obtenu
 * en enlevant l'extension du fichier en cours d'édition.
 * Sinon une requête demande le nom de l'exécutable.
 */

OPTIONS RESULTS

PARSE ARG mode  /* mode CLI ou WB */

'GetFilePath'; path = RESULT

err = 0
dotpos = LASTPOS('.', path)

IF dotpos ~= 0 THEN DO
    ext = SUBSTR(path, dotpos+1)
    IF (ext ~= 'c' & ext ~= 'cpp' & ext ~= 'cxx' & ext ~= 'h') THEN err = 1
    ELSE IF ~EXISTS(LEFT(path, dotpos-1)) THEN err = 1
END
ELSE err = 1

IF (err = 1) THEN DO
    "ReqMulti B1 '_Lancer CPR' B3 _Annuler ACT STR1 T1 Exécutable CONVERT TEXT Le fichier en cours d'édition n'a pas\nd'exécutable correspondant.\n\nEntrez le nom de l'exécutable à tester"
    PARSE VAR RESULT button "," string1 "," string2
    IF (button = 'CANCEL') THEN EXIT 10
    ELSE DO
        string1 = STRIP(string1,'B','"')
        IF EXISTS(string1) THEN executable = string1
        ELSE EXIT 10
    END
END
ELSE executable = LEFT(path, dotpos-1)

'ExeDOSCmd ASYNC SCREEN CONSOLE CMD sc:c/cpr -' || mode executable