*-----------------------------------------------------------------------------*
	INCDIR	DF0:Include/
	INCLUDE	CUSTOM.i
	INCLUDE	CIA.i
	INCLUDE	OFFSETS.i

	INCLUDE	MACROS.i

*-----------------------------------------------------------------------------*
PlaneWidth 	= 28
PlaneHeigth	= 152
Planes		= 4

ScWidth		= 44
ScHeigth	= 283
ScSize		= ScWidth*ScHeigth

Size		= 4

*-----------------------------------------------------------------------------*
START	movem.l	d0-a6,-(sp)

	move.l	$4.w,a6
	jsr	_LVOForbid(a6)

	moveq	#0,d0
	lea	GfxName(pc),a1
	jsr	_LVOOpenLibrary(a6)
	tst.l	d0
	beq.w	.Error

	move.l	d0,GfxBase
	move.l	d0,a6
	move.l	$22(a6),Temp_ActiView
	move.l	$26(a6),Temp_CopList1
	move.l	$32(a6),Temp_CopList2

	sub.l	a1,a1
	jsr	_LVOLoadView(a6)

	jsr	_LVOWaitTOF(a6)
	jsr	_LVOWaitTOF(a6)

	lea	$dff000,a6
	move.w	$02(a6),Temp_DMACON
	move.w	$10(a6),Temp_ADKCON
	move.w	$1c(a6),Temp_INTENA
	move.l	$6c.w,Temp_Lev3Int

	move.w	#$7fff,$96(a6)
	move.w	#$7fff,$9a(a6)
	move.w	#$7fff,$9c(a6)
	move.w	#$7f00,$9e(a6)

	lea	LEV3_INTERRUPT(pc),a0
	move.l	a0,$6c.w

	bsr.w	Calc_Tables

	move.w	#%1000001111000000,$96(a6)
	move.w	#%1100000000100000,$9a(a6)

*-----------------------------------------------------------------------------*
	move.w	#2,KzAdd
	move.w	#6,Zadd
	move.w	#6,Xmove
	move.w	#3,Ymove
.Loop	Frame	311
	bsr.w	Zoomer
	btst	#6,$bfe001
	bne.s	.Loop

*-----------------------------------------------------------------------------*
	move.l	Temp_ActiView(pc),a1
	move.l	GfxBase(pc),a6
	jsr	_LVOLoadView(a6)

	lea	$dff000,a6
	move.w	#$7fff,$96(a6)
	move.w	#$7fff,$9a(a6)
	move.w	#$7fff,$9e(a6)

	move.l	Temp_CopList1(pc),$80(a6)
	move.l	Temp_CopList2(pc),$84(a6)
	move.l	Temp_Lev3Int(pc),$6c.w

	move.w	Temp_ADKCON(pc),d0
	or.w	#$8000,d0
	move.w	d0,$9e(a6)

	move.w	Temp_DMACON(pc),d0
	or.w	#$8000,d0
	move.w	d0,$96(a6)

	move.w	Temp_INTENA(pc),d0
	or.w	#$c000,d0
	move.w	d0,$9a(a6)

	move.l	$4.w,a6
	move.l	GfxBase(pc),a1
	jsr	_LVOCloseLibrary(a6)

.Error	jsr	_LVOPermit(a6)

	movem.l	(sp)+,d0-a6
	moveq	#0,d0
	rts

*-----------------------------------------------------------------------------*
Temp_ADKCON	dc.w	0
Temp_DMACON	dc.w	0
Temp_INTENA	dc.w	0
Temp_CopList1	dc.l	0
Temp_CopList2	dc.l	0
Temp_Lev3Int	dc.l	0
Temp_ActiView	dc.l	0

GfxBase		dc.l	0

GfxName		dc.b	'graphics.library',0
		even

*-----------------------------------------------------------------------------*
LEV3_INTERRUPT
	movem.l	d0-a6,-(SP)

	movem.l	(SP)+,d0-a6
	move.w	#%0000000000100000,$dff09c
	rte

*-----------------------------------------------------------------------------*
CALC_TABLES
	lea	ColTab1,a0
	lea	RotPic,a1
	lea	Palette1,a2
	move.w	#16*128-1,d2
.Loop2	moveq	#7,d1
.Loop1	moveq	#0,d0
	btst	d1,0*16*128(a1)
	beq.s	.B0
	bset	#0,d0
.B0	btst	d1,1*16*128(a1)
	beq.s	.B1
	bset	#1,d0
.B1	btst	d1,2*16*128(a1)
	beq.s	.B2
	bset	#2,d0
.B2	btst	d1,3*16*128(a1)
	beq.s	.B3
	bset	#3,d0
.B3	add.w	d0,d0
	add.w	d0,d0
	move.w	2(a2,d0.w),(a0)+
	dbf	d1,.Loop1
	addq.l	#1,a1
	dbf	d2,.Loop2		

CALC_COL2
	lea	ColTab2,a0
	lea	RotPic,a1
	lea	Palette2,a2
	move.w	#16*128-1,d2
.Loop2	moveq	#7,d1
.Loop1	moveq	#0,d0
	btst	d1,0*16*128(a1)
	beq.s	.B0
	bset	#0,d0
.B0	btst	d1,1*16*128(a1)
	beq.s	.B1
	bset	#1,d0
.B1	btst	d1,2*16*128(a1)
	beq.s	.B2
	bset	#2,d0
.B2	btst	d1,3*16*128(a1)
	beq.s	.B3
	bset	#3,d0
.B3	add.w	d0,d0
	add.w	d0,d0
	move.w	2(a2,d0.w),(a0)+
	dbf	d1,.Loop1
	addq.l	#1,a1
	dbf	d2,.Loop2		

CALC_COPLIST
	lea	CopCol1,a0
	lea	CopCol2,a1
	move.w	#PlaneHeigth/4-1,d0
	move.l	#$6355fffe,d1
	move.l	#$01a008a6,d2
.Loop	move.l	d1,(a0)+
	move.l	d1,(a1)+
	REPT	PlaneWidth
	move.l	d2,(a0)+
	move.l	d2,(a1)+
	ENDR
	add.l	#$02000000,d1
	move.l	d1,(a0)+
	move.l	d1,(a1)+
	REPT	PlaneWidth
	move.l	d2,(a0)+
	move.l	d2,(a1)+
	ENDR
	add.l	#$02000000,d1
	dbf	d0,.Loop

INIT_PLANES
	lea	BplPtr1(pc),a1
	lea	BplPtr2(pc),a2
	move.l	#Design,d0
	moveq	#5-1,d1
.lp1	move.w	d0,6(a1)
	move.w	d0,6(a2)
	swap.w	d0
	move.w	d0,2(a1)
	move.w	d0,2(a2)
	swap.w	d0
	add.l	#44*283,d0
	addq.l	#8,a1
	addq.l	#8,a2
	dbf	d1,.lp1
	rts

*-----------------------------------------------------------------------------*
SCROLL	lea	Design+42+256*ScWidth,a0
	WBLIT
	move.l	a0,$50(a6)
	move.l	a0,$54(a6)
	move.l	#$19f00002,$40(a6)
	move.l	#$ffff7fff,$44(a6)
	move.l	#$00080008,$64(a6)
	move.w	#12<<6+18,$58(a6)

	lea	Design+42+256*ScWidth+ScSize,a0
	WBLIT
	move.l	a0,$50(a6)
	move.l	a0,$54(a6)
	move.l	#$19f00002,$40(a6)
	move.l	#$ffff7fff,$44(a6)
	move.l	#$00080008,$64(a6)
	move.w	#12<<6+18,$58(a6)

	tst.b	Count
	beq.s	.Set
	subq.b	#1,Count
	rts	

.Set	lea	Design+43+245*ScWidth,a0
	lea	Font(pc),a1
	lea	FontOrd(pc),a2
	lea	FntSize(pc),a4
	move.l	TextPt(pc),a3

	move.b	(a3),d0
	tst.b	d0
	beq.s	.ReStrt
	cmp.b	#' ',d0
	beq.s	.Space

	moveq	#-1,d1
.Lp1	addq.l	#1,d1
	cmp.b	(a2,d1.w),d0
	bne.s	.Lp1	

	move.b	(a4,d1.w),Count

	add.l	d1,a1

	moveq	#2-1,d0
.Lp2	move.b	00*46(a1),00*ScWidth(a0)
	move.b	01*46(a1),01*ScWidth(a0)
	move.b	02*46(a1),02*ScWidth(a0)
	move.b	03*46(a1),03*ScWidth(a0)
	move.b	04*46(a1),04*ScWidth(a0)
	move.b	05*46(a1),05*ScWidth(a0)
	move.b	06*46(a1),06*ScWidth(a0)
	move.b	07*46(a1),07*ScWidth(a0)
	move.b	08*46(a1),08*ScWidth(a0)
	move.b	09*46(a1),09*ScWidth(a0)
	move.b	10*46(a1),10*ScWidth(a0)
	move.b	11*46(a1),11*ScWidth(a0)
	lea	ScSize(a0),a0
	lea	46*12(a1),a1
	dbf	d0,.Lp2

	addq.l	#1,TextPt
	rts

.ReStrt	move.l	#Text,TextPt
	rts

.Space	move.b	#4,Count
	addq.l	#1,TextPt
	rts

TextPt	dc.l	Text
Count	dc.b	0

Text	dc.b	'                                        '
	dc.b	'banal projects presents a new pack serie called '
	dc.b	'panimo                     panimo    ...    demojanoon      '
	dc.b	'          .nice layout was thought up by prayer.        '
	dc.b	' .code by epidemic.         .touch by ukulele.          '
	dc.b	'epidemic joined banal projects army section.'
	dc.b	'      ohjusmies on eri mies.                             '
	dc.b	'                                                 '
	dc.b	'. .. ...avopain avaruudessa... .. .                      '
	dc.b	'                                          ',0	

FntSize	dc.b	6,6,5,6,6,5,6,6,4,4,6,4,6,6,6,6,6,5,6,4,6,6,6,6,6,6
	dc.b	5,6,6,6,6,6,5,6,6,3,3
FontOrd	dc.b	'abcdefghijklmnopqrstuvwxyz123456789.,'
	even

*-----------------------------------------------------------------------------*
SWAP_PLANES
	lea	$dff000,a6

	movem.l	ShowCop(pc),d0-d1
	exg.l	d0,d1
	movem.l	d0-d1,ShowCop

	move.l	ShowCop(pc),$80(a6)
	tst.w	$88(a6)
	rts

ShowCop	dc.l	Copperlist1
WorkCop	dc.l	Copperlist2

*-----------------------------------------------------------------------------*
CALC_COORDS
	move.w	Xmove(pc),d0
	move.w	Ymove(pc),d1
	add.w	d0,Xcentre
	add.w	d1,Ycentre
	and.w	#511,Xcentre
	and.w	#511,Ycentre

	movem.w	Zptr(pc),d0-d1
	add.w	d1,d0
	and.w	#1023,d0
	move.w	d0,Zptr

	lea	Sin(pc),a0
	move.w	(a0,d0.w),d0
	add.w	#256+26,d0
	move.w	d0,Dist

	lea	Sin(pc),a0
	lea	Cos(pc),a1
	lea	Coords(pc),a2
	lea	XYcoord(pc),a3

.loop	movem.w	(a2)+,d0/d1/d2		;x1,y1,z1

	move.w	Ky(pc),d7
	move.w	(a1,d7.w),d3
	move.w	d3,d4
	move.w	(a0,d7.w),d5
	move.w	d5,d6
	muls.w	d0,d3
	muls.w	d2,d5
	add.l	d3,d5
	asr.l	#8,d5			;x2

	muls.w	d0,d6
	muls.w	d2,d4
	sub.l	d6,d4
	asr.l	#8,d4			;z2

	move.w	Kx(pc),d7
	move.w	(a1,d7.w),d0
	move.w	d0,d2
	move.w	(a0,d7.w),d3
	move.w	d3,d6
	muls.w	d1,d0
	muls.w	d4,d3
	sub.l	d3,d0
	asr.l	#8,d0			;y3

	muls.w	d1,d6
	muls.w	d4,d2
	add.l	d6,d2
	asr.l	#8,d2			;z3

	move.w	Kz(pc),d7
	move.w	(a1,d7.w),d1
	move.w	d1,d3
	move.w	(a0,d7.w),d4
	move.w	d4,d6		
	muls.w	d5,d1
	muls.w	d0,d4
	sub.l	d4,d1
	asr.l	#8,d1

	muls.w	d5,d6
	muls.w	d0,d3
	add.l	d6,d3
	asr.l	#8,d3

	muls.w	Dist(pc),d1
	asr.l	#8,d1
	add.w	Xcentre(pc),d1
	move.w	d1,(a3)+

	muls.w	Dist(pc),d3
	asr.l	#8,d3
	add.w	Ycentre(pc),d3
	move.w	d3,(a3)+	

	cmp.w	#9999,(a2)
	bne.w	.loop

	move.w	Kz(pc),d0
	move.w	KzAdd(pc),d1
	add.w	d1,d0
	and.w	#1023,d0
	move.w	d0,Kz
	rts

*-----------------------------------------------------------------------------*
SetByte	MACRO
	move.w	d0,d2
	move.w	d1,d3
	asr.w	#7,d2
	and.w	d5,d2
	and.w	d6,d3
	add.w	d2,d3
	move.w	(a0,d3.w),\1*4(a1)
	add.w	a3,d0
	add.w	a4,d1
	ENDM

*-----------------------------------------------------------------------------*
ZOOMER	bsr.w	Swap_Planes
	bsr.w	Scroll
	bsr.w	Calc_Coords

	lea	XYcoord(pc),a0

	move.w	00(a0),d0
	move.w	02(a0),d1
	move.w	04(a0),d2
	move.w	06(a0),d3

	move.w	d2,d4
	sub.w	d0,d4
	muls.w	#128,d4
	divs.w	#PlaneWidth*8/Size,d4
	move.w	d4,Xadd1

	move.w	d3,d5
	sub.w	d1,d5
	muls.w	#128,d5
	divs.w	#PlaneWidth*8/Size,d5
	move.w	d5,Yadd1
	
	move.w	00(a0),d0
	move.w	02(a0),d1
	move.w	08(a0),d2
	move.w	10(a0),d3
	
	move.w	d2,d4
	sub.w	d0,d4
	muls.w	#128,d4
	divs.w	#PlaneWidth*8/Size,d4
	move.w	d4,Xadd2

	move.w	d3,d5
	sub.w	d1,d5
	muls.w	#128,d5
	divs.w	#PlaneWidth*8/Size,d5
	move.w	d5,Yadd2

	moveq	#0,d0
	move.w	0(a0),d0
	muls.w	#64,d0
	move.w	d0,a5

	moveq	#0,d4
	move.w	2(a0),d4
	muls.w	#64,d4

	WBLIT
	move.l	#$09f00000,$40(a6)
	move.l	#$ffffffff,$44(a6)
	move.l	#$00020002,$64(a6)

	move.l	WorkCop(pc),a1

	lea	CopCol1-CopperList1+6(a1),a1
	lea	[PlaneWidth*4+4](a1),a2

	move.w	Xadd1(pc),a3
	move.w	Yadd1(pc),a4

	move.w	#$00fe,d5
	move.w	#$7f00,d6
	moveq	#PlaneHeigth/Size-1,d7

.Loop2	move.w	a5,d0
	move.w	d4,d1

	lea	ColTab1,a0
	SetByte	00
	SetByte	01
	lea	ColTab2,a0
	SetByte	02
	SetByte	03
	SetByte	04
	SetByte	05
	SetByte	06
	SetByte	07
	SetByte	08
	SetByte	09
	SetByte	10
	SetByte	11
	SetByte	12
	SetByte	13
	SetByte	14
	SetByte	15
	SetByte	16
	SetByte	17
	SetByte	18
	lea	ColTab1,a0
	SetByte	19
	SetByte	20
	SetByte	21
	SetByte	22
	SetByte	23
	SetByte	24
	SetByte	25
	SetByte	26

	WBLIT
	move.l	a1,$50(a6)
	move.l	a2,$54(a6)
	move.w	#27<<6+1,$58(a6)

	lea	2*[PlaneWidth*4+4](a1),a1
	lea	2*[PlaneWidth*4+4](a2),a2
	add.w	Xadd2(pc),a5
	add.w	Yadd2(pc),d4
	dbf	d7,.Loop2
	rts

*-----------------------------------------------------------------------------*
Zptr	dc.w	768
Zadd	dc.w	0

Xmove	dc.w	0
Ymove	dc.w	0

KzAdd	dc.w	0

Xadd1	dc.w	0
Yadd1	dc.w	0
Xadd2	dc.w	0
Yadd2	dc.w	0

Kx	dc.w	0*2
Ky	dc.w	0*2
Kz	dc.w	0*2

Dist	dc.w	0
XCentre	dc.w	147
YCentre	dc.w	87

Coords	dc.w	-200,-80,000
	dc.w	+200,-80,000
	dc.w	-200,+80,000
	dc.w	+200,+80,000
	dc.w	9999

XYcoord	blk.w	128,0

Sin	DC.W	$0000,$0003,$0006,$0009,$000C,$000F,$0012,$0015
	DC.W	$0019,$001C,$001F,$0022,$0025,$0028,$002B,$002E
	DC.W	$0031,$0034,$0037,$003B,$003E,$0041,$0044,$0047
	DC.W	$004A,$004D,$0050,$0053,$0056,$0059,$005B,$005E
	DC.W	$0061,$0064,$0067,$006A,$006D,$0070,$0072,$0075
	DC.W	$0078,$007B,$007D,$0080,$0083,$0086,$0088,$008B
	DC.W	$008D,$0090,$0093,$0095,$0098,$009A,$009D,$009F
	DC.W	$00A2,$00A4,$00A6,$00A9,$00AB,$00AD,$00B0,$00B2
	DC.W	$00B4,$00B6,$00B9,$00BB,$00BD,$00BF,$00C1,$00C3
	DC.W	$00C5,$00C7,$00C9,$00CB,$00CD,$00CF,$00D0,$00D2
	DC.W	$00D4,$00D6,$00D7,$00D9,$00DB,$00DC,$00DE,$00DF
	DC.W	$00E1,$00E2,$00E4,$00E5,$00E6,$00E8,$00E9,$00EA
	DC.W	$00EC,$00ED,$00EE,$00EF,$00F0,$00F1,$00F2,$00F3
	DC.W	$00F4,$00F5,$00F6,$00F7,$00F7,$00F8,$00F9,$00F9
	DC.W	$00FA,$00FB,$00FB,$00FC,$00FC,$00FD,$00FD,$00FD
	DC.W	$00FE,$00FE,$00FE,$00FF,$00FF,$00FF,$00FF,$00FF
Cos	DC.W	$00FF,$00FF,$00FF,$00FF,$00FF,$00FF,$00FE,$00FE
	DC.W	$00FE,$00FD,$00FD,$00FD,$00FC,$00FC,$00FB,$00FB
	DC.W	$00FA,$00F9,$00F9,$00F8,$00F7,$00F7,$00F6,$00F5
	DC.W	$00F4,$00F3,$00F2,$00F1,$00F0,$00EF,$00EE,$00ED
	DC.W	$00EC,$00EA,$00E9,$00E8,$00E6,$00E5,$00E4,$00E2
	DC.W	$00E1,$00DF,$00DE,$00DC,$00DB,$00D9,$00D7,$00D6
	DC.W	$00D4,$00D2,$00D0,$00CF,$00CD,$00CB,$00C9,$00C7
	DC.W	$00C5,$00C3,$00C1,$00BF,$00BD,$00BB,$00B9,$00B6
	DC.W	$00B4,$00B2,$00B0,$00AD,$00AB,$00A9,$00A6,$00A4
	DC.W	$00A2,$009F,$009D,$009A,$0098,$0095,$0093,$0090
	DC.W	$008D,$008B,$0088,$0086,$0083,$0080,$007D,$007B
	DC.W	$0078,$0075,$0072,$0070,$006D,$006A,$0067,$0064
	DC.W	$0061,$005E,$005B,$0059,$0056,$0053,$0050,$004D
	DC.W	$004A,$0047,$0044,$0041,$003E,$003B,$0037,$0034
	DC.W	$0031,$002E,$002B,$0028,$0025,$0022,$001F,$001C
	DC.W	$0019,$0015,$0012,$000F,$000C,$0009,$0006,$0003
	DC.W	$0000,$FFFC,$FFF9,$FFF6,$FFF3,$FFF0,$FFED,$FFEA
	DC.W	$FFE6,$FFE3,$FFE0,$FFDD,$FFDA,$FFD7,$FFD4,$FFD1
	DC.W	$FFCE,$FFCB,$FFC8,$FFC4,$FFC1,$FFBE,$FFBB,$FFB8
	DC.W	$FFB5,$FFB2,$FFAF,$FFAC,$FFA9,$FFA6,$FFA4,$FFA1
	DC.W	$FF9E,$FF9B,$FF98,$FF95,$FF92,$FF8F,$FF8D,$FF8A
	DC.W	$FF87,$FF84,$FF82,$FF7F,$FF7C,$FF79,$FF77,$FF74
	DC.W	$FF72,$FF6F,$FF6C,$FF6A,$FF67,$FF65,$FF62,$FF60
	DC.W	$FF5D,$FF5B,$FF59,$FF56,$FF54,$FF52,$FF4F,$FF4D
	DC.W	$FF4B,$FF49,$FF46,$FF44,$FF42,$FF40,$FF3E,$FF3C
	DC.W	$FF3A,$FF38,$FF36,$FF34,$FF32,$FF30,$FF2F,$FF2D
	DC.W	$FF2B,$FF29,$FF28,$FF26,$FF24,$FF23,$FF21,$FF20
	DC.W	$FF1E,$FF1D,$FF1B,$FF1A,$FF19,$FF17,$FF16,$FF15
	DC.W	$FF13,$FF12,$FF11,$FF10,$FF0F,$FF0E,$FF0D,$FF0C
	DC.W	$FF0B,$FF0A,$FF09,$FF08,$FF08,$FF07,$FF06,$FF06
	DC.W	$FF05,$FF04,$FF04,$FF03,$FF03,$FF02,$FF02,$FF02
	DC.W	$FF01,$FF01,$FF01,$FF00,$FF00,$FF00,$FF00,$FF00
	DC.W	$FF00,$FF00,$FF00,$FF00,$FF00,$FF00,$FF01,$FF01
	DC.W	$FF01,$FF02,$FF02,$FF02,$FF03,$FF03,$FF04,$FF04
	DC.W	$FF05,$FF06,$FF06,$FF07,$FF08,$FF08,$FF09,$FF0A
	DC.W	$FF0B,$FF0C,$FF0D,$FF0E,$FF0F,$FF10,$FF11,$FF12
	DC.W	$FF13,$FF15,$FF16,$FF17,$FF19,$FF1A,$FF1B,$FF1D
	DC.W	$FF1E,$FF20,$FF21,$FF23,$FF24,$FF26,$FF28,$FF29
	DC.W	$FF2B,$FF2D,$FF2F,$FF30,$FF32,$FF34,$FF36,$FF38
	DC.W	$FF3A,$FF3C,$FF3E,$FF40,$FF42,$FF44,$FF46,$FF49
	DC.W	$FF4B,$FF4D,$FF4F,$FF52,$FF54,$FF56,$FF59,$FF5B
	DC.W	$FF5D,$FF60,$FF62,$FF65,$FF67,$FF6A,$FF6C,$FF6F
	DC.W	$FF72,$FF74,$FF77,$FF79,$FF7C,$FF7F,$FF82,$FF84
	DC.W	$FF87,$FF8A,$FF8D,$FF8F,$FF92,$FF95,$FF98,$FF9B
	DC.W	$FF9E,$FFA1,$FFA4,$FFA6,$FFA9,$FFAC,$FFAF,$FFB2
	DC.W	$FFB5,$FFB8,$FFBB,$FFBE,$FFC1,$FFC4,$FFC8,$FFCB
	DC.W	$FFCE,$FFD1,$FFD4,$FFD7,$FFDA,$FFDD,$FFE0,$FFE3
	DC.W	$FFE6,$FFEA,$FFED,$FFF0,$FFF3,$FFF6,$FFF9,$FFFC
	DC.W	$0000,$0003,$0006,$0009,$000C,$000F,$0012,$0015
	DC.W	$0019,$001C,$001F,$0022,$0025,$0028,$002B,$002E
	DC.W	$0031,$0034,$0037,$003B,$003E,$0041,$0044,$0047
	DC.W	$004A,$004D,$0050,$0053,$0056,$0059,$005B,$005E
	DC.W	$0061,$0064,$0067,$006A,$006D,$0070,$0072,$0075
	DC.W	$0078,$007B,$007D,$0080,$0083,$0086,$0088,$008B
	DC.W	$008D,$0090,$0093,$0095,$0098,$009A,$009D,$009F
	DC.W	$00A2,$00A4,$00A6,$00A9,$00AB,$00AD,$00B0,$00B2
	DC.W	$00B4,$00B6,$00B9,$00BB,$00BD,$00BF,$00C1,$00C3
	DC.W	$00C5,$00C7,$00C9,$00CB,$00CD,$00CF,$00D0,$00D2
	DC.W	$00D4,$00D6,$00D7,$00D9,$00DB,$00DC,$00DE,$00DF
	DC.W	$00E1,$00E2,$00E4,$00E5,$00E6,$00E8,$00E9,$00EA
	DC.W	$00EC,$00ED,$00EE,$00EF,$00F0,$00F1,$00F2,$00F3
	DC.W	$00F4,$00F5,$00F6,$00F7,$00F7,$00F8,$00F9,$00F9
	DC.W	$00FA,$00FB,$00FB,$00FC,$00FC,$00FD,$00FD,$00FD
	DC.W	$00FE,$00FE,$00FE,$00FF,$00FF,$00FF,$00FF,$00FF

Palette1
	dc.w	$0180,$0dab,$0182,$0fe7,$0184,$0fd4,$0186,$0fc0
	dc.w	$0188,$0fb0,$018a,$0fa0,$018c,$0e80,$018e,$0d70
	dc.w	$0190,$0c60,$0192,$0b50,$0194,$0a40,$0196,$0840
	dc.w	$0198,$0640,$019a,$0430,$019c,$0fec,$019e,$0965
Palette2
	dc.w	$0180,$0978,$0182,$0cb5,$0184,$0ca2,$0186,$0c90
	dc.w	$0188,$0c80,$018a,$0c70,$018c,$0b60,$018e,$0a50
	dc.w	$0190,$0940,$0192,$0830,$0194,$0720,$0196,$0620
	dc.w	$0198,$0420,$019a,$0210,$019c,$0cb9,$019e,$0743

	dc.w	$0180,$0655,$0182,$0773,$0184,$0762,$0186,$0760
	dc.w	$0188,$0750,$018a,$0750,$018c,$0740,$018e,$0630
	dc.w	$0190,$0630,$0192,$0630,$0194,$0520,$0196,$0420
	dc.w	$0198,$0320,$019a,$0220,$019c,$0776,$019e,$0533

*-----------------------------------------------------------------------------*
COPPERLIST1
	dc.w	$0001,$fffe,$0100,$0000

	dc.w	$0120,$0000,$0122,$0000,$0124,$0000,$0126,$0000
	dc.w	$0128,$0000,$012a,$0000,$012c,$0000,$012e,$0000
	dc.w	$0130,$0000,$0132,$0000,$0134,$0000,$0136,$0000
	dc.w	$0138,$0000,$013a,$0000,$013c,$0000,$013e,$0000

	dc.w	$008e,$1c71,$0090,$37d1
	dc.w	$0092,$0030,$0094,$00d8
	dc.w	$0108,$0000,$010a,$0000
	dc.w	$0102,$0000,$0104,$0000
	dc.w	$0100,$5200

BplPtr1	dc.w	$00e0,$0000,$00e2,$0000,$00e4,$0000,$00e6,$0000
	dc.w	$00e8,$0000,$00ea,$0000,$00ec,$0000,$00ee,$0000
	dc.w	$00f0,$0000,$00f2,$0000

	dc.w	$0180,$0bc7,$0182,$0fff,$0184,$0eff,$0186,$0dff
	dc.w	$0188,$0def,$018a,$0cef,$018c,$0bdd,$018e,$0bcc
	dc.w	$0190,$0abb,$0192,$0cbb,$0194,$0eef,$0196,$0877
	dc.w	$0198,$0fee,$019a,$0aaa,$019c,$0998,$019e,$0c07
	dc.w	$01a0,$08a6,$01a2,$0ab6,$01a4,$0464,$01a6,$0bda
	dc.w	$01a8,$0c07,$01aa,$0c07,$01ac,$0c07,$01ae,$0c07
	dc.w	$01b0,$0c07,$01b2,$0c07,$01b4,$0c07,$01b6,$0c07
	dc.w	$01b8,$0c07,$01ba,$0c07,$01bc,$0c07,$01be,$0c07

CopCol1	blk.b	PlaneHeigth/2*[PlaneWidth*4+4],0

	dc.w	$ffdd,$fffe
	dc.w	$0a09,$fffe,$0180,$0464
	dc.w	$0b09,$fffe,$0180,$0ec6,$0182,$0ca7,$0184,$0866,$0186,$0cb7
	dc.w	$2009,$fffe,$0180,$0464
	dc.w	$2109,$fffe,$0180,$0bc7

	dc.w	$ffff,$fffe

COPPERLIST2
	dc.w	$0001,$fffe,$0100,$0000

	dc.w	$0120,$0000,$0122,$0000,$0124,$0000,$0126,$0000
	dc.w	$0128,$0000,$012a,$0000,$012c,$0000,$012e,$0000
	dc.w	$0130,$0000,$0132,$0000,$0134,$0000,$0136,$0000
	dc.w	$0138,$0000,$013a,$0000,$013c,$0000,$013e,$0000

	dc.w	$008e,$1c71,$0090,$37d1
	dc.w	$0092,$0030,$0094,$00d8
	dc.w	$0108,$0000,$010a,$0000
	dc.w	$0102,$0000,$0104,$0000
	dc.w	$0100,$5200

BplPtr2	dc.w	$00e0,$0000,$00e2,$0000,$00e4,$0000,$00e6,$0000
	dc.w	$00e8,$0000,$00ea,$0000,$00ec,$0000,$00ee,$0000
	dc.w	$00f0,$0000,$00f2,$0000

	dc.w	$0180,$0bc7,$0182,$0fff,$0184,$0eff,$0186,$0dff
	dc.w	$0188,$0def,$018a,$0cef,$018c,$0bdd,$018e,$0bcc
	dc.w	$0190,$0abb,$0192,$0cbb,$0194,$0eef,$0196,$0877
	dc.w	$0198,$0fee,$019a,$0aaa,$019c,$0998,$019e,$0c07
	dc.w	$01a0,$08a6,$01a2,$0ab6,$01a4,$0464,$01a6,$0bda
	dc.w	$01a8,$0c07,$01aa,$0c07,$01ac,$0c07,$01ae,$0c07
	dc.w	$01b0,$0c07,$01b2,$0c07,$01b4,$0c07,$01b6,$0c07
	dc.w	$01b8,$0c07,$01ba,$0c07,$01bc,$0c07,$01be,$0c07

CopCol2	blk.b	PlaneHeigth/2*[PlaneWidth*4+4],0

	dc.w	$ffdd,$fffe
	dc.w	$0a09,$fffe,$0180,$0464
	dc.w	$0b09,$fffe,$0180,$0ec6,$0182,$0ca7,$0184,$0866,$0186,$0cb7
	dc.w	$2009,$fffe,$0180,$0464
	dc.w	$2109,$fffe,$0180,$0bc7

	dc.w	$ffff,$fffe

*-----------------------------------------------------------------------------*
	incdir	DF1:
Font	incbin	PackFont.RAW
RotPic	incbin	Duck128.RAW
Design	incbin	Design.RAW

ColTab1	blk.w	128*128,0
ColTab2	blk.w	128*128,0