*-----------------------------------------------------------------------------*
	INCDIR	DF1:INCLUDE/
	INCLUDE	CUSTOM.i
	INCLUDE	CIA.i
	INCLUDE	OFFSETS.i

	INCLUDE	MACROS.i

*-----------------------------------------------------------------------------*
PlaneWidth 	= 28
PlaneHeigth	= 152

ScWidth		= 44
ScHeigth	= 283
ScSize		= ScWidth*ScHeigth
Planes		= 5

Size		= 4

*-----------------------------------------------------------------------------*
	section	a,code_c

PACK	movem.l	d0-a6,-(sp)

	move.b	$dff006,Random

	jsr	StartUp
	jsr	Restore
	jsr	StartUp
	jsr	Main
	jsr	Restore

	movem.l	(sp)+,d0-a6
	moveq	#0,d0
	rts
	
*-----------------------------------------------------------------------------*
StartUp	move.l	$4.w,a6
	moveq	#0,d0
	lea	GfxName(pc),a1
	jsr	_LVOOpenLibrary(a6)

	move.l	d0,GfxBase
	move.l	d0,a6
	move.l	$22(a6),Temp_ActiView
	move.l	$26(a6),Temp_CopList1
	move.l	$32(a6),Temp_CopList2

	sub.l	a1,a1
	jsr	_LVOLoadView(a6)

	jsr	_LVOWaitTOF(a6)
	jsr	_LVOWaitTOF(a6)

	lea	$dff000,a6
	move.w	$02(a6),Temp_DMACON
	move.w	$10(a6),Temp_ADKCON
	move.w	$1c(a6),Temp_INTENA
	move.w	$a(a6),Yold

	move.w	#$7fff,$96(a6)
	move.w	#$7fff,$9a(a6)
	move.w	#$7fff,$9c(a6)
	move.w	#$7fff,$9e(a6)

	bsr.w	Calc_Tables
	bsr.w	Init_Sprites
	bsr.w	Write

	move.w	#%1000001111100000,$96(a6)
	move.w	#%1110000000000000,$9a(a6)

	lea	Music,a0			Module
	sub.l	a1,a1				Samples
	moveq	#0,d0				Auto Detect
	jsr	Player+0			P60_Init
	rts
	
*-----------------------------------------------------------------------------*
Main	move.w	#2,KzAdd
	move.w	#4,Zadd
	move.w	#4,Xmove
	move.w	#1,Ymove

	move.w	#$8010,$dff09c

.Loop	move.w	$dff01e,d0
	and.l	#$0010,d0
	beq.s	.Loop
	move.w	#$0010,$dff09c
	
	bsr.w	Swap_Planes
	bsr.w	Swap_Sprites
	bsr.w	Scroll
	bsr.w	Zoomer
	bsr.w	Pointer

	btst	#6,$bfe001
	bne.s	.Loop
	rts
	
*-----------------------------------------------------------------------------*
Restore	lea	$dff000,a6
	jsr	Player+8			;P60_End

	move.l	Temp_ActiView(pc),a1
	move.l	GfxBase(pc),a6
	jsr	_LVOLoadView(a6)

	lea	$dff000,a6
	move.w	#$7fff,$96(a6)
	move.w	#$7fff,$9a(a6)
	move.w	#$7fff,$9c(a6)
	move.w	#$7fff,$9e(a6)

	move.l	Temp_CopList1(pc),$80(a6)
	move.l	Temp_CopList2(pc),$84(a6)
	tst.w	$88(a6)
	tst.w	$8a(a6)

	move.w	Temp_ADKCON(pc),d0
	or.w	#$8000,d0
	move.w	d0,$9e(a6)

	move.w	Temp_DMACON(pc),d0
	or.w	#$8000,d0
	move.w	d0,$96(a6)

	move.w	Temp_INTENA(pc),d0
	or.w	#$c000,d0
	move.w	d0,$9a(a6)

	move.l	$4.w,a6
	move.l	GfxBase(pc),a1
	jsr	_LVOCloseLibrary(a6)
	rts

*-----------------------------------------------------------------------------*
Temp_ADKCON	dc.w	0
Temp_DMACON	dc.w	0
Temp_INTENA	dc.w	0
Temp_CopList1	dc.l	0
Temp_CopList2	dc.l	0
Temp_ActiView	dc.l	0

GfxBase		dc.l	0
Random		dc.w	0

GfxName		dc.b	'graphics.library',0
		even

*-----------------------------------------------------------------------------*
CALC_TABLES
	lea	RotPic1,a1
	lea	DuckPal1(pc),a2
	lea	DuckPal2(pc),a3

	move.b	Random(pc),d0
	bpl.s	.Duck

	lea	RotPic2,a1
	lea	PlsmPal1(pc),a2
	lea	PlsmPal2(pc),a3

.Duck	lea	ColTab1,a0
	lea	ColTab2,a4
	move.w	#16*128-1,d2
.Loop2	moveq	#7,d1
.Loop1	moveq	#0,d0
	btst	d1,0*16*128(a1)
	beq.s	.B0
	bset	#0,d0
.B0	btst	d1,1*16*128(a1)
	beq.s	.B1
	bset	#1,d0
.B1	btst	d1,2*16*128(a1)
	beq.s	.B2
	bset	#2,d0
.B2	btst	d1,3*16*128(a1)
	beq.s	.B3
	bset	#3,d0
.B3	add.w	d0,d0
	add.w	d0,d0
	move.w	2(a2,d0.w),(a0)+
	move.w	2(a3,d0.w),(a4)+
	dbf	d1,.Loop1
	addq.l	#1,a1
	dbf	d2,.Loop2		

CALC_COPLIST
	lea	CopCol1,a0
	lea	CopCol2,a1
	move.w	#PlaneHeigth/4-1,d0
	move.l	#$6355fffe,d1
	move.l	#$01a00795,d2
.Loop	move.l	d1,(a0)+
	move.l	d1,(a1)+
	REPT	PlaneWidth
	move.l	d2,(a0)+
	move.l	d2,(a1)+
	ENDR
	add.l	#$02000000,d1
	move.l	d1,(a0)+
	move.l	d1,(a1)+
	REPT	PlaneWidth
	move.l	d2,(a0)+
	move.l	d2,(a1)+
	ENDR
	add.l	#$02000000,d1
	dbf	d0,.Loop

INIT_PLANES
	lea	BplPtr1(pc),a1
	lea	BplPtr2(pc),a2
	move.l	#Design,d0
	moveq	#Planes-1,d1
.lp1	move.w	d0,6(a1)
	move.w	d0,6(a2)
	swap.w	d0
	move.w	d0,2(a1)
	move.w	d0,2(a2)
	swap.w	d0
	add.l	#ScSize,d0
	addq.l	#8,a1
	addq.l	#8,a2
	dbf	d1,.lp1
	rts

*-----------------------------------------------------------------------------*
INIT_SPRITES
	lea	SprPt1,a0
	lea	SprPt2,a1

	move.l	#Spr1,d0
	bsr.s	.Set
	move.l	#Spr2,d0
	bsr.s	.Set
	rts

.Set	move.w	d0,6(a0)
	move.w	d0,6(a1)
	swap.w	d0
	move.w	d0,2(a0)
	move.w	d0,2(a1)
	addq.l	#8,a0
	addq.l	#8,a1
	rts

SWAP_SPRITES
	tst.w	.Time
	beq.s	.Do
	subq.w	#1,.Time
	rts
	
.Do	move.w	#4,.Time

	lea	SprPt1+2*8,a0
	lea	SprPt2+2*8,a1
	move.l	#MaskSp1,d0
	bchg.b	#0,.Ctrl
	beq.s	.Ok
	move.l	#MaskSp2,d0
.Ok	bsr.s	.Set
	add.l	#84,d0
	bsr.s	.Set
	add.l	#84,d0
	bsr.s	.Set
	add.l	#84,d0
	bsr.s	.Set
	add.l	#84,d0
	bsr.s	.Set
	rts

.Ctrl	dc.w	0
.Time	dc.w	0

.Set	move.w	d0,6(a0)
	move.w	d0,6(a1)
	swap.w	d0
	move.w	d0,2(a0)
	move.w	d0,2(a1)
	swap.w	d0
	addq.l	#8,a0
	addq.l	#8,a1
	rts

Spr1	dc.w	$8f5b,$9800
	dc.w	%0000000000000000,%0000000000000000
	dc.w	%0000000000000000,%0000000000000000
	dc.w	%0000000000000000,%0000000000000000
	dc.w	%0000000000000000,%0000000000000000
	dc.w	%0000000000000000,%0000000000000000
	dc.w	%0000000000000000,%0000000000000000
	dc.w	%0000000000000000,%0000000000000000
	dc.w	%0000000000000000,%0000000000000000
	dc.l	0
Spr2	dc.w	$8f5b,$9880
	dc.w	%1111110000000000,%1111110000000000
	dc.w	%1111110000000000,%1000010000000000
	dc.w	%1111110000000000,%1000010000000000
	dc.w	%1111110000000000,%1000010000000000
	dc.w	%1111110000000000,%1000010000000000
	dc.w	%1111110000000000,%1111110000000000
	dc.w	%0000000000000000,%0000000000000000
	dc.w	%0000000000000000,%0000000000000000
	dc.l	0

MaskSp1	dc.w	$0cc8,$1f06
	dc.w	$0000,$0000,$0000,$0000,$0047,$0000,$0040,$0000
	dc.w	$00f0,$0000,$0180,$0000,$0002,$0000,$0208,$0000
	dc.w	$0180,$0000,$1002,$0000,$0003,$0000,$0002,$0000
	dc.w	$0102,$0000,$0004,$0000,$0818,$0000,$0100,$0000
	dc.w	$01c4,$0000,$0000,$0000,$0000,$0000,$0000,$0000

	dc.w	$0cd0,$1f06
	dc.w	$0808,$0000,$00c1,$0000,$02b0,$0000,$e060,$0000
	dc.w	$21b1,$0000,$4480,$0000,$683d,$0000,$0839,$0000
	dc.w	$0304,$0000,$c392,$0000,$a00d,$0000,$b5a3,$0000
	dc.w	$fbcb,$0000,$7f2e,$0000,$0a1c,$0000,$0a00,$0000
	dc.w	$2106,$0000,$0020,$0000,$12c9,$0000,$0000,$0000
	
	dc.w	$0cd8,$1f06
	dc.w	$04d1,$0000,$242f,$0000,$01d6,$0000,$067b,$0000
	dc.w	$8726,$0000,$fdbe,$0000,$93bb,$0000,$4370,$0000
	dc.w	$73bb,$0000,$3fda,$0000,$55dd,$0000,$a5f7,$0000
	dc.w	$2cff,$0000,$93b7,$0000,$515f,$0000,$53d5,$0000
	dc.w	$0239,$0000,$0883,$0000,$4011,$0000,$0000,$0000

	dc.w	$0ce0,$1f06
	dc.w	$fa70,$0000,$8677,$0000,$ecfb,$0000,$bfbd,$0000
	dc.w	$d2d7,$0000,$fbe9,$0000,$bfab,$0000,$3ebf,$0000
	dc.w	$df9f,$0000,$ef0b,$0000,$7b7f,$0000,$ff7f,$0000
	dc.w	$feff,$0000,$f7e7,$0000,$f9b6,$0000,$f7d7,$0000
	dc.w	$bdf7,$0000,$bfbd,$0000,$d4ef,$0000,$0000,$0000

	dc.w	$0ce8,$1f06
	dc.w	$f6ff,$0000,$ffff,$0000,$7f7f,$0000,$5fde,$0000
	dc.w	$77bf,$0000,$5ffd,$0000,$eff7,$0000,$dbff,$0000
	dc.w	$feff,$0000,$efff,$0000,$e7ff,$0000,$6fff,$0000
	dc.w	$fecf,$0000,$ebbf,$0000,$ffff,$0000,$3fdf,$0000
	dc.w	$efff,$0000,$e7ff,$0000,$bfff,$0000

MaskSp2	dc.w	$0cc8,$1f06
	dc.w	$0070,$0000,$0502,$0000,$0053,$0000,$1043,$0000
	dc.w	$0006,$0000,$24b8,$0000,$0018,$0000,$0007,$0000
	dc.w	$0004,$0000,$0000,$0000,$0400,$0000,$1040,$0000
	dc.w	$0010,$0000,$0000,$0000,$0001,$0000,$0100,$0000
	dc.w	$0601,$0000,$0184,$0000,$4002,$0000,$0000,$0000
	
	dc.w	$0cd0,$1f06
	dc.w	$0406,$0000,$900d,$0000,$1023,$0000,$7402,$0000
	dc.w	$52a3,$0000,$40c4,$0000,$90ae,$0000,$0215,$0000
	dc.w	$2917,$0000,$09d3,$0000,$800e,$0000,$a201,$0000
	dc.w	$0100,$0000,$0828,$0000,$0c21,$0000,$0002,$0000
	dc.w	$2009,$0000,$0103,$0000,$0000,$0000,$0000,$0000

	dc.w	$0cd8,$1f06
	dc.w	$acad,$0000,$cea6,$0000,$67fd,$0000,$b5dd,$0000
	dc.w	$deef,$0000,$5f7d,$0000,$fbfd,$0000,$9fff,$0000
	dc.w	$afff,$0000,$9975,$0000,$73ff,$0000,$fbdd,$0000
	dc.w	$ef7e,$0000,$a9dd,$0000,$3474,$0000,$6590,$0000
	dc.w	$7bd8,$0000,$a155,$0000,$0455,$0000,$0000,$0000

	dc.w	$0ce0,$1f06
	dc.w	$9833,$0000,$7579,$0000,$375c,$0000,$8cd6,$0000
	dc.w	$3b7b,$0000,$fbbf,$0000,$3df3,$0000,$bfeb,$0000
	dc.w	$fbf7,$0000,$ffbf,$0000,$9fff,$0000,$fdbf,$0000
	dc.w	$78ff,$0000,$53df,$0000,$bdec,$0000,$79ff,$0000
	dc.w	$fb0d,$0000,$7a35,$0000,$bae7,$0000,$0000,$0000

	dc.w	$0ce8,$1f06
	dc.w	$abfe,$0000,$fff7,$0000,$dfff,$0000,$fffd,$0000
	dc.w	$bfdf,$0000,$ff7f,$0000,$ffbf,$0000,$f7fb,$0000
	dc.w	$ffff,$0000,$ffff,$0000,$ffff,$0000,$ffff,$0000
	dc.w	$ff3b,$0000,$ff7e,$0000,$fbff,$0000,$7bff,$0000
	dc.w	$b7f7,$0000,$5fff,$0000,$1f31,$0000,$0000,$0000

*-----------------------------------------------------------------------------*
POINTER	move.w	Line(pc),d0
	move.b	$a(a6),d1
	sub.b	Yold(pc),d1
	ext.w	d1
	add.w	d1,d0
	cmp.w	#EndLine-1,d0
	ble.s	.Ok1
	move.w	#EndLine-1,d0
.Ok1	cmp.w	#StrLine-1,d0
	bge.s	.Ok2
	moveq	#StrLine-1,d0
.Ok2	move.w	d0,Line

	muls.w	#18,d0
	add.w	#$6b,d0
	move.b	d0,Spr1+0
	move.b	d0,Spr2+0
	addq.b	#8,d0
	move.b	d0,Spr1+2
	move.b	d0,Spr2+2

	lea	Names(pc),a0
	move.w	Line(pc),d0
	sub.w	#StrLine-1,d0
	add.w	d0,d0
	add.w	d0,d0
	move.l	(a0,d0.w),0.w

	move.w	$a(a6),Yold
	rts

Yold	dc.b	0
Xold	dc.b	0
Line	dc.w	0

Names	dc.l	name1,name2,name3,name4,name5,name6,name7,name8

*-----------------------------------------------------------------------------*
SCROLL	lea	Design+42+256*ScWidth,a0
	WBLIT
	move.l	a0,$50(a6)
	move.l	a0,$54(a6)
	move.l	#$19f00002,$40(a6)
	move.l	#$ffff7fff,$44(a6)
	move.l	#$00080008,$64(a6)
	move.w	#12<<6+18,$58(a6)

	lea	Design+42+256*ScWidth+ScSize,a0
	WBLIT
	move.l	a0,$50(a6)
	move.l	a0,$54(a6)
	move.l	#$19f00002,$40(a6)
	move.l	#$ffff7fff,$44(a6)
	move.l	#$00080008,$64(a6)
	move.w	#12<<6+18,$58(a6)

	cmp.b	#1,Count
	ble.s	.Set
	subq.b	#1,Count
	rts	

.Set	lea	Design+43+245*ScWidth,a0
	lea	Font1(pc),a1
	lea	FtOrd1(pc),a2
	lea	FtSize1(pc),a4
	move.l	TextPt(pc),a3

	move.b	(a3),d0
	tst.b	d0
	beq.s	.ReStrt
	cmp.b	#' ',d0
	beq.s	.Space

	moveq	#-1,d1
.Lp1	addq.l	#1,d1
	cmp.b	(a2,d1.w),d0
	bne.s	.Lp1

	move.b	(a4,d1.w),Count

	add.l	d1,a1

	moveq	#2-1,d0
.Lp2	move.b	00*46(a1),00*ScWidth(a0)
	move.b	01*46(a1),01*ScWidth(a0)
	move.b	02*46(a1),02*ScWidth(a0)
	move.b	03*46(a1),03*ScWidth(a0)
	move.b	04*46(a1),04*ScWidth(a0)
	move.b	05*46(a1),05*ScWidth(a0)
	move.b	06*46(a1),06*ScWidth(a0)
	move.b	07*46(a1),07*ScWidth(a0)
	move.b	08*46(a1),08*ScWidth(a0)
	move.b	09*46(a1),09*ScWidth(a0)
	move.b	10*46(a1),10*ScWidth(a0)
	move.b	11*46(a1),11*ScWidth(a0)
	lea	ScSize(a0),a0
	lea	46*12(a1),a1
	dbf	d0,.Lp2

	addq.l	#1,TextPt
	rts

.ReStrt	move.l	#Text1,TextPt
	rts

.Space	move.b	#4,Count
	addq.l	#1,TextPt
	rts

TextPt	dc.l	Text1
Count	dc.b	0

FtSize1	dc.b	6,6,4,6,6,4,6,6,3,4,6,4,6,6,6,6,6,4,6,4,6,6,6,6,6,6
	dc.b	4,5,5,6,5,5,5,5,5,3,3,3,6,3,3,5,6,5,3,3
FtOrd1	dc.b	"abcdefghijklmnopqrstuvwxyz123456789.,'^:;-*$#@"
	even

*-----------------------------------------------------------------------------*
WRITE	lea	FtOrd2(pc),a2
	lea	FtSize2(pc),a3
	lea	Text2(pc),a4
	lea	Design+10+75*ScWidth+2*ScSize,a5

.Lp5	moveq	#6,d2

.Lp4	lea	Font2(pc),a1
	move.l	a5,a0

	move.b	(a4)+,d0
	tst.b	d0
	beq.s	.Return
	cmp.b	#1,d0
	beq.s	.End
	cmp.b	#'¹',d0
	beq.s	.Space1
	cmp.b	#'²',d0
	beq.s	.Space2
	cmp.b	#' ',d0
	beq.s	.Space6

	moveq	#-1,d1
.Lp1	addq.l	#1,d1
	cmp.b	(a2,d1.w),d0
	bne.s	.Lp1	

	add.w	d1,d1
	move.w	d1,d7
	
	cmp.w	#656/8,d1
	blt.s	.Fok
	lea	Font3(pc),a1
	sub.w	#656/8,d1
.Fok
	move.w	d2,d3
	lsr.w	#4,d3
	add.w	d3,d3
	move.w	d2,d4
	and.w	#15,d4

	moveq	#2-1,d6
.Lp3	moveq	#17-1,d5
.Lp2	moveq	#0,d0
	move.w	(a1,d1.w),d0
	swap.w	d0
	lsr.l	d4,d0
	or.l	d0,(a0,d3.w)
	lea	656/8(a1),a1
	lea	ScWidth(a0),a0
	dbf	d5,.Lp2
	lea	ScSize-17*ScWidth(a0),a0
	dbf	d6,.Lp3

	add.w	(a3,d7.w),d2
	bra.s	.Lp4

.Return	lea	18*ScWidth(a5),a5
	bra.s	.Lp5
.End	rts

.Space1	addq.w	#1,d2
	bra.w	.Lp4
.Space2	addq.w	#2,d2
	bra.w	.Lp4
.Space6	addq.w	#8,d2
	bra.w	.Lp4

FtOrd2	dc.b	"ABCDEFGHIJKLMNOPQRSTUVWXYZ"
	dc.b	"abcdefghijklmnopqrstuvwxyz"
	dc.b	"0123456789.,'@:;*!?#()-+/$%^&"
	even

FtSize2	dc.w	9,9,9,9,9,8,10,9,6,9,9,9,10,9,9,9,9,9,9,9,9,9,10,9,9,9
	dc.w	9,9,9,9,9,8,10,9,6,9,9,7,10,9,9,9,9,8,9,9,9,9,10,9,9,9
	dc.w	9,7,9,9,9,9,9,8,9,9, 4,4,4,8,4,4,9,4,9,11,8,8,8,9,9,9,9,9,9

*-----------------------------------------------------------------------------*
SWAP_PLANES
	lea	$dff000,a6

	movem.l	ShowCop(pc),d0-d1
	exg.l	d0,d1
	movem.l	d0-d1,ShowCop

	move.l	ShowCop(pc),$80(a6)
	tst.w	$88(a6)
	rts

ShowCop	dc.l	Copperlist1
WorkCop	dc.l	Copperlist2

*-----------------------------------------------------------------------------*
CALC_COORDS
	move.w	Xmove(pc),d0
	move.w	Ymove(pc),d1
	add.w	d0,Xcentre
	add.w	d1,Ycentre
	and.w	#1023,Xcentre
	and.w	#1023,Ycentre

	movem.w	Zptr(pc),d0-d1
	add.w	d1,d0
	and.w	#1023,d0
	move.w	d0,Zptr

	lea	Sin(pc),a0
	move.w	(a0,d0.w),d0
	add.w	#256+16,d0
	move.w	d0,Dist

	lea	Sin(pc),a0
	lea	Cos(pc),a1
	lea	Coords(pc),a2
	lea	XYcoord(pc),a3

.loop	movem.w	(a2)+,d0/d1/d2		;x1,y1,z1

	move.w	Ky(pc),d7
	move.w	(a1,d7.w),d3
	move.w	d3,d4
	move.w	(a0,d7.w),d5
	move.w	d5,d6
	muls.w	d0,d3
	muls.w	d2,d5
	add.l	d3,d5
	asr.l	#8,d5			;x2

	muls.w	d0,d6
	muls.w	d2,d4
	sub.l	d6,d4
	asr.l	#8,d4			;z2

	move.w	Kx(pc),d7
	move.w	(a1,d7.w),d0
	move.w	d0,d2
	move.w	(a0,d7.w),d3
	move.w	d3,d6
	muls.w	d1,d0
	muls.w	d4,d3
	sub.l	d3,d0
	asr.l	#8,d0			;y3

	muls.w	d1,d6
	muls.w	d4,d2
	add.l	d6,d2
	asr.l	#8,d2			;z3

	move.w	Kz(pc),d7
	move.w	(a1,d7.w),d1
	move.w	d1,d3
	move.w	(a0,d7.w),d4
	move.w	d4,d6		
	muls.w	d5,d1
	muls.w	d0,d4
	sub.l	d4,d1
	asr.l	#8,d1

	muls.w	d5,d6
	muls.w	d0,d3
	add.l	d6,d3
	asr.l	#8,d3

	muls.w	Dist(pc),d1
	asr.l	#8,d1
	add.w	Xcentre(pc),d1
	move.w	d1,(a3)+

	muls.w	Dist(pc),d3
	asr.l	#8,d3
	add.w	Ycentre(pc),d3
	move.w	d3,(a3)+	

	cmp.w	#9999,(a2)
	bne.w	.loop

	move.w	Kz(pc),d0
	move.w	KzAdd(pc),d1
	add.w	d1,d0
	and.w	#1023,d0
	move.w	d0,Kz
	rts

*-----------------------------------------------------------------------------*
SetByte	MACRO
	move.w	d0,d2
	move.w	d1,d3
	asr.w	#7,d2
	and.w	d5,d2
	and.w	d6,d3
	add.w	d2,d3
	move.w	(a0,d3.w),\1*4(a1)
	add.w	a3,d0
	add.w	a4,d1
	ENDM

*-----------------------------------------------------------------------------*
ZOOMER	bsr.w	Calc_Coords

	lea	XYcoord(pc),a0

	move.w	00(a0),d0
	move.w	02(a0),d1
	move.w	04(a0),d2
	move.w	06(a0),d3

	move.w	d2,d4
	sub.w	d0,d4
	muls.w	#128,d4
	divs.w	#PlaneWidth*8/Size,d4
	move.w	d4,Xadd1

	move.w	d3,d5
	sub.w	d1,d5
	muls.w	#128,d5
	divs.w	#PlaneWidth*8/Size,d5
	move.w	d5,Yadd1
	
	move.w	00(a0),d0
	move.w	02(a0),d1
	move.w	08(a0),d2
	move.w	10(a0),d3
	
	move.w	d2,d4
	sub.w	d0,d4
	muls.w	#128,d4
	divs.w	#PlaneWidth*8/Size,d4
	move.w	d4,Xadd2

	move.w	d3,d5
	sub.w	d1,d5
	muls.w	#128,d5
	divs.w	#PlaneWidth*8/Size,d5
	move.w	d5,Yadd2

	moveq	#0,d0
	move.w	0(a0),d0
	muls.w	#32,d0
	move.w	d0,a5

	moveq	#0,d4
	move.w	2(a0),d4
	muls.w	#32,d4

	WBLIT
	move.l	#$09f00000,$40(a6)
	move.l	#$ffffffff,$44(a6)
	move.l	#$00020002,$64(a6)

	move.l	WorkCop(pc),a1

	lea	CopCol1-CopperList1+6(a1),a1
	lea	[PlaneWidth*4+4](a1),a2

	move.w	Xadd1(pc),a3
	move.w	Yadd1(pc),a4

	move.w	#$00fe,d5
	move.w	#$7f00,d6
	moveq	#PlaneHeigth/Size-1,d7

.Loop2	move.w	a5,d0
	move.w	d4,d1

	lea	ColTab1,a0
	SetByte	00
	SetByte	01
	lea	ColTab2,a0
	SetByte	02
	SetByte	03
	SetByte	04
	SetByte	05
	SetByte	06
	SetByte	07
	SetByte	08
	SetByte	09
	SetByte	10
	SetByte	11
	SetByte	12
	SetByte	13
	SetByte	14
	SetByte	15
	SetByte	16
	SetByte	17
	SetByte	18
	lea	ColTab1,a0
	SetByte	19
	SetByte	20
	SetByte	21
	SetByte	22
	SetByte	23
	SetByte	24
	SetByte	25
	SetByte	26

	WBLIT
	move.l	a1,$50(a6)
	move.l	a2,$54(a6)
	move.w	#27<<6+1,$58(a6)

	lea	2*[PlaneWidth*4+4](a1),a1
	lea	2*[PlaneWidth*4+4](a2),a2
	add.w	Xadd2(pc),a5
	add.w	Yadd2(pc),d4
	dbf	d7,.Loop2
	rts

*-----------------------------------------------------------------------------*
Zptr	dc.w	768
Zadd	dc.w	0

Xmove	dc.w	0
Ymove	dc.w	0

KzAdd	dc.w	0

Xadd1	dc.w	0
Yadd1	dc.w	0
Xadd2	dc.w	0
Yadd2	dc.w	0

Kx	dc.w	0*2
Ky	dc.w	0*2
Kz	dc.w	0*2

Dist	dc.w	0
XCentre	dc.w	140
YCentre	dc.w	80

Coords	dc.w	-120,-50,000
	dc.w	+120,-50,000
	dc.w	-120,+50,000
	dc.w	+120,+50,000
	dc.w	9999

XYcoord	blk.w	128,0

Sin	DC.W	$0000,$0003,$0006,$0009,$000C,$000F,$0012,$0015
	DC.W	$0019,$001C,$001F,$0022,$0025,$0028,$002B,$002E
	DC.W	$0031,$0034,$0037,$003B,$003E,$0041,$0044,$0047
	DC.W	$004A,$004D,$0050,$0053,$0056,$0059,$005B,$005E
	DC.W	$0061,$0064,$0067,$006A,$006D,$0070,$0072,$0075
	DC.W	$0078,$007B,$007D,$0080,$0083,$0086,$0088,$008B
	DC.W	$008D,$0090,$0093,$0095,$0098,$009A,$009D,$009F
	DC.W	$00A2,$00A4,$00A6,$00A9,$00AB,$00AD,$00B0,$00B2
	DC.W	$00B4,$00B6,$00B9,$00BB,$00BD,$00BF,$00C1,$00C3
	DC.W	$00C5,$00C7,$00C9,$00CB,$00CD,$00CF,$00D0,$00D2
	DC.W	$00D4,$00D6,$00D7,$00D9,$00DB,$00DC,$00DE,$00DF
	DC.W	$00E1,$00E2,$00E4,$00E5,$00E6,$00E8,$00E9,$00EA
	DC.W	$00EC,$00ED,$00EE,$00EF,$00F0,$00F1,$00F2,$00F3
	DC.W	$00F4,$00F5,$00F6,$00F7,$00F7,$00F8,$00F9,$00F9
	DC.W	$00FA,$00FB,$00FB,$00FC,$00FC,$00FD,$00FD,$00FD
	DC.W	$00FE,$00FE,$00FE,$00FF,$00FF,$00FF,$00FF,$00FF
Cos	DC.W	$00FF,$00FF,$00FF,$00FF,$00FF,$00FF,$00FE,$00FE
	DC.W	$00FE,$00FD,$00FD,$00FD,$00FC,$00FC,$00FB,$00FB
	DC.W	$00FA,$00F9,$00F9,$00F8,$00F7,$00F7,$00F6,$00F5
	DC.W	$00F4,$00F3,$00F2,$00F1,$00F0,$00EF,$00EE,$00ED
	DC.W	$00EC,$00EA,$00E9,$00E8,$00E6,$00E5,$00E4,$00E2
	DC.W	$00E1,$00DF,$00DE,$00DC,$00DB,$00D9,$00D7,$00D6
	DC.W	$00D4,$00D2,$00D0,$00CF,$00CD,$00CB,$00C9,$00C7
	DC.W	$00C5,$00C3,$00C1,$00BF,$00BD,$00BB,$00B9,$00B6
	DC.W	$00B4,$00B2,$00B0,$00AD,$00AB,$00A9,$00A6,$00A4
	DC.W	$00A2,$009F,$009D,$009A,$0098,$0095,$0093,$0090
	DC.W	$008D,$008B,$0088,$0086,$0083,$0080,$007D,$007B
	DC.W	$0078,$0075,$0072,$0070,$006D,$006A,$0067,$0064
	DC.W	$0061,$005E,$005B,$0059,$0056,$0053,$0050,$004D
	DC.W	$004A,$0047,$0044,$0041,$003E,$003B,$0037,$0034
	DC.W	$0031,$002E,$002B,$0028,$0025,$0022,$001F,$001C
	DC.W	$0019,$0015,$0012,$000F,$000C,$0009,$0006,$0003
	DC.W	$0000,$FFFC,$FFF9,$FFF6,$FFF3,$FFF0,$FFED,$FFEA
	DC.W	$FFE6,$FFE3,$FFE0,$FFDD,$FFDA,$FFD7,$FFD4,$FFD1
	DC.W	$FFCE,$FFCB,$FFC8,$FFC4,$FFC1,$FFBE,$FFBB,$FFB8
	DC.W	$FFB5,$FFB2,$FFAF,$FFAC,$FFA9,$FFA6,$FFA4,$FFA1
	DC.W	$FF9E,$FF9B,$FF98,$FF95,$FF92,$FF8F,$FF8D,$FF8A
	DC.W	$FF87,$FF84,$FF82,$FF7F,$FF7C,$FF79,$FF77,$FF74
	DC.W	$FF72,$FF6F,$FF6C,$FF6A,$FF67,$FF65,$FF62,$FF60
	DC.W	$FF5D,$FF5B,$FF59,$FF56,$FF54,$FF52,$FF4F,$FF4D
	DC.W	$FF4B,$FF49,$FF46,$FF44,$FF42,$FF40,$FF3E,$FF3C
	DC.W	$FF3A,$FF38,$FF36,$FF34,$FF32,$FF30,$FF2F,$FF2D
	DC.W	$FF2B,$FF29,$FF28,$FF26,$FF24,$FF23,$FF21,$FF20
	DC.W	$FF1E,$FF1D,$FF1B,$FF1A,$FF19,$FF17,$FF16,$FF15
	DC.W	$FF13,$FF12,$FF11,$FF10,$FF0F,$FF0E,$FF0D,$FF0C
	DC.W	$FF0B,$FF0A,$FF09,$FF08,$FF08,$FF07,$FF06,$FF06
	DC.W	$FF05,$FF04,$FF04,$FF03,$FF03,$FF02,$FF02,$FF02
	DC.W	$FF01,$FF01,$FF01,$FF00,$FF00,$FF00,$FF00,$FF00
	DC.W	$FF00,$FF00,$FF00,$FF00,$FF00,$FF00,$FF01,$FF01
	DC.W	$FF01,$FF02,$FF02,$FF02,$FF03,$FF03,$FF04,$FF04
	DC.W	$FF05,$FF06,$FF06,$FF07,$FF08,$FF08,$FF09,$FF0A
	DC.W	$FF0B,$FF0C,$FF0D,$FF0E,$FF0F,$FF10,$FF11,$FF12
	DC.W	$FF13,$FF15,$FF16,$FF17,$FF19,$FF1A,$FF1B,$FF1D
	DC.W	$FF1E,$FF20,$FF21,$FF23,$FF24,$FF26,$FF28,$FF29
	DC.W	$FF2B,$FF2D,$FF2F,$FF30,$FF32,$FF34,$FF36,$FF38
	DC.W	$FF3A,$FF3C,$FF3E,$FF40,$FF42,$FF44,$FF46,$FF49
	DC.W	$FF4B,$FF4D,$FF4F,$FF52,$FF54,$FF56,$FF59,$FF5B
	DC.W	$FF5D,$FF60,$FF62,$FF65,$FF67,$FF6A,$FF6C,$FF6F
	DC.W	$FF72,$FF74,$FF77,$FF79,$FF7C,$FF7F,$FF82,$FF84
	DC.W	$FF87,$FF8A,$FF8D,$FF8F,$FF92,$FF95,$FF98,$FF9B
	DC.W	$FF9E,$FFA1,$FFA4,$FFA6,$FFA9,$FFAC,$FFAF,$FFB2
	DC.W	$FFB5,$FFB8,$FFBB,$FFBE,$FFC1,$FFC4,$FFC8,$FFCB
	DC.W	$FFCE,$FFD1,$FFD4,$FFD7,$FFDA,$FFDD,$FFE0,$FFE3
	DC.W	$FFE6,$FFEA,$FFED,$FFF0,$FFF3,$FFF6,$FFF9,$FFFC
	DC.W	$0000,$0003,$0006,$0009,$000C,$000F,$0012,$0015
	DC.W	$0019,$001C,$001F,$0022,$0025,$0028,$002B,$002E
	DC.W	$0031,$0034,$0037,$003B,$003E,$0041,$0044,$0047
	DC.W	$004A,$004D,$0050,$0053,$0056,$0059,$005B,$005E
	DC.W	$0061,$0064,$0067,$006A,$006D,$0070,$0072,$0075
	DC.W	$0078,$007B,$007D,$0080,$0083,$0086,$0088,$008B
	DC.W	$008D,$0090,$0093,$0095,$0098,$009A,$009D,$009F
	DC.W	$00A2,$00A4,$00A6,$00A9,$00AB,$00AD,$00B0,$00B2
	DC.W	$00B4,$00B6,$00B9,$00BB,$00BD,$00BF,$00C1,$00C3
	DC.W	$00C5,$00C7,$00C9,$00CB,$00CD,$00CF,$00D0,$00D2
	DC.W	$00D4,$00D6,$00D7,$00D9,$00DB,$00DC,$00DE,$00DF
	DC.W	$00E1,$00E2,$00E4,$00E5,$00E6,$00E8,$00E9,$00EA
	DC.W	$00EC,$00ED,$00EE,$00EF,$00F0,$00F1,$00F2,$00F3
	DC.W	$00F4,$00F5,$00F6,$00F7,$00F7,$00F8,$00F9,$00F9
	DC.W	$00FA,$00FB,$00FB,$00FC,$00FC,$00FD,$00FD,$00FD
	DC.W	$00FE,$00FE,$00FE,$00FF,$00FF,$00FF,$00FF,$00FF

DuckPal1
	dc.w	$0180,$0dab,$0182,$0fe7,$0184,$0fd4,$0186,$0fc0
	dc.w	$0188,$0fb0,$018a,$0fa0,$018c,$0e80,$018e,$0d70
	dc.w	$0190,$0c60,$0192,$0b50,$0194,$0a40,$0196,$0840
	dc.w	$0198,$0640,$019a,$0430,$019c,$0fec,$019e,$0965
DuckPal2
	dc.w	$0180,$0978,$0182,$0cb5,$0184,$0ca2,$0186,$0c90
	dc.w	$0188,$0c80,$018a,$0c70,$018c,$0b60,$018e,$0a50
	dc.w	$0190,$0940,$0192,$0830,$0194,$0720,$0196,$0620
	dc.w	$0198,$0420,$019a,$0210,$019c,$0cb9,$019e,$0743
PlsmPal1
	dc.w	$0180,$0feb,$0182,$0eda,$0184,$0eca,$0186,$0db9
	dc.w	$0188,$0da9,$018a,$0c98,$018c,$0c88,$018e,$0b78
	dc.w	$0190,$0a78,$0192,$0a68,$0194,$0968,$0196,$0957
	dc.w	$0198,$0857,$019a,$0847,$019c,$0747,$019e,$0fec
PlsmPal2
	dc.w	$0180,$0cb9,$0182,$0ba8,$0184,$0ca8,$0186,$0a97
	dc.w	$0188,$0a87,$018a,$0976,$018c,$0966,$018e,$0966
	dc.w	$0190,$0866,$0192,$0856,$0194,$0756,$0196,$0746
	dc.w	$0198,$0646,$019a,$0636,$019c,$0636,$019e,$0cb9

*-----------------------------------------------------------------------------*
COPPERLIST1
	dc.w	$0001,$fffe,$0100,$0000

SprPt1	dc.w	$0120,$0000,$0122,$0000,$0124,$0000,$0126,$0000
	dc.w	$0128,$0000,$012a,$0000,$012c,$0000,$012e,$0000
	dc.w	$0130,$0000,$0132,$0000,$0134,$0000,$0136,$0000
	dc.w	$0138,$0000,$013a,$0000,$013c,$0000,$013e,$0000

	dc.w	$008e,$1c71,$0090,$37d1
	dc.w	$0092,$0030,$0094,$00d8
	dc.w	$0108,$0000,$010a,$0000
	dc.w	$0102,$0000,$0104,$001f
	dc.w	$0100,$5200

BplPtr1	dc.w	$00e0,$0000,$00e2,$0000,$00e4,$0000,$00e6,$0000
	dc.w	$00e8,$0000,$00ea,$0000,$00ec,$0000,$00ee,$0000
	dc.w	$00f0,$0000,$00f2,$0000

	dc.w	$0180,$0bc7,$0182,$0fff,$0184,$0eff,$0186,$0dff
	dc.w	$0188,$0def,$018a,$0cef,$018c,$0bdd,$018e,$0bcc
	dc.w	$0190,$0abb,$0192,$0cbb,$0194,$0eef,$0196,$0877
	dc.w	$0198,$0fee,$019a,$0aaa,$019c,$0998,$019e,$0786
	dc.w	$01a0,$08a6,$01a2,$0aa6,$01a4,$0464,$01a6,$0bda
	dc.w	$01a8,$0ab6,$01aa,$0c07,$01ac,$0c07,$01ae,$0c07
	dc.w	$01b0,$0c07,$01b2,$0c07,$01b4,$0c07,$01b6,$09a8
	dc.w	$01b8,$0468,$01ba,$0679,$01bc,$0899,$01be,$0ab9

	dc.w	$6009,$fffe
	dc.w	$01a8,$0feb,$01aa,$0feb,$01ac,$0feb,$01ae,$0feb
	dc.w	$01b0,$0fff,$01b2,$0fff,$01b4,$0fff,$01b6,$0fff
	dc.w	$01b8,$0000,$01ba,$0000,$01bc,$0000,$01be,$0000

CopCol1	blk.b	PlaneHeigth/2*[PlaneWidth*4+4],0
	dc.w	$01a8,$0ab6

	dc.w	$ffdd,$fffe
	dc.w	$0a09,$fffe,$01a0,$0464
	dc.w	$0b09,$fffe
	dc.w	$01a0,$0ec6,$01a2,$0ca7,$01a4,$0866,$01a6,$0cb7
	dc.w	$01a8,$0ec6,$01aa,$0ec6,$01ac,$0ec6,$01ae,$0ec6
	dc.w	$01b0,$0ec6,$01b2,$0ec6,$01b4,$0ec6,$01b6,$0ec6
	dc.w	$01b8,$0ec6,$01ba,$0ec6,$01bc,$0ec6,$01be,$0ec6

	dc.w	$2009,$fffe,$01a0,$0464
	dc.w	$2109,$fffe
	dc.w	$01a0,$08a6,$01a2,$0aa6,$01a4,$0464,$01a6,$0bda
	dc.w	$01a8,$0ab6,$01aa,$0c07,$01ac,$0c07,$01ae,$0c07
	dc.w	$01b0,$0c07,$01b2,$0c07,$01b4,$0c07,$01b6,$09a8
	dc.w	$01b8,$0468,$01ba,$0679,$01bc,$0899,$01be,$0ab9

	dc.w	$3809,$fffe,$009c,$8010

	dc.w	$ffff,$fffe

COPPERLIST2
	dc.w	$0001,$fffe,$0100,$0000

SprPt2	dc.w	$0120,$0000,$0122,$0000,$0124,$0000,$0126,$0000
	dc.w	$0128,$0000,$012a,$0000,$012c,$0000,$012e,$0000
	dc.w	$0130,$0000,$0132,$0000,$0134,$0000,$0136,$0000
	dc.w	$0138,$0000,$013a,$0000,$013c,$0000,$013e,$0000

	dc.w	$008e,$1c71,$0090,$37d1
	dc.w	$0092,$0030,$0094,$00d8
	dc.w	$0108,$0000,$010a,$0000
	dc.w	$0102,$0000,$0104,$001f
	dc.w	$0100,$5200

BplPtr2	dc.w	$00e0,$0000,$00e2,$0000,$00e4,$0000,$00e6,$0000
	dc.w	$00e8,$0000,$00ea,$0000,$00ec,$0000,$00ee,$0000
	dc.w	$00f0,$0000,$00f2,$0000

	dc.w	$0180,$0bc7,$0182,$0fff,$0184,$0eff,$0186,$0dff
	dc.w	$0188,$0def,$018a,$0cef,$018c,$0bdd,$018e,$0bcc
	dc.w	$0190,$0abb,$0192,$0cbb,$0194,$0eef,$0196,$0877
	dc.w	$0198,$0fee,$019a,$0aaa,$019c,$0998,$019e,$0786
	dc.w	$01a0,$08a6,$01a2,$0aa6,$01a4,$0464,$01a6,$0bda
	dc.w	$01a8,$0ab6,$01aa,$0c07,$01ac,$0c07,$01ae,$0c07
	dc.w	$01b0,$0c07,$01b2,$0c07,$01b4,$0c07,$01b6,$09a8
	dc.w	$01b8,$0468,$01ba,$0679,$01bc,$0899,$01be,$0ab9

	dc.w	$6009,$fffe
	dc.w	$01a8,$0feb,$01aa,$0feb,$01ac,$0feb,$01ae,$0feb
	dc.w	$01b0,$0fff,$01b2,$0fff,$01b4,$0fff,$01b6,$0fff
	dc.w	$01b8,$0000,$01ba,$0000,$01bc,$0000,$01be,$0000

CopCol2	blk.b	PlaneHeigth/2*[PlaneWidth*4+4],0
	dc.w	$01a8,$0ab6

	dc.w	$ffdd,$fffe
	dc.w	$0a09,$fffe,$01a0,$0464
	dc.w	$0b09,$fffe
	dc.w	$01a0,$0ec6,$01a2,$0ca7,$01a4,$0866,$01a6,$0cb7
	dc.w	$01a8,$0ec6,$01aa,$0ec6,$01ac,$0ec6,$01ae,$0ec6
	dc.w	$01b0,$0ec6,$01b2,$0ec6,$01b4,$0ec6,$01b6,$0ec6
	dc.w	$01b8,$0ec6,$01ba,$0ec6,$01bc,$0ec6,$01be,$0ec6

	dc.w	$2009,$fffe,$01a0,$0464
	dc.w	$2109,$fffe
	dc.w	$01a0,$08a6,$01a2,$0aa6,$01a4,$0464,$01a6,$0bda
	dc.w	$01a8,$0ab6,$01aa,$0c07,$01ac,$0c07,$01ae,$0c07
	dc.w	$01b0,$0c07,$01b2,$0c07,$01b4,$0c07,$01b6,$09a8
	dc.w	$01b8,$0468,$01ba,$0679,$01bc,$0899,$01be,$0ab9

	dc.w	$3809,$fffe,$009c,$8010

	dc.w	$ffff,$fffe

*-----------------------------------------------------------------------------*
Text1	dc.b	"                              "
	dc.b	"@#$banal projects$#@ presents panimo 2 "
	dc.b	"            $ code...epidemic $ gfx,design..."
	dc.b	"prayer $ touch...ukulele $       "
	dc.b	" here is some of our products, which couldn't fit into first"
	dc.b	" ^panimo^.     arvoitus ... mika on packserien nimi.  "
	dc.b	" 1 ilotalo   "
	dc.b	"  2 bordelli     3 panimo    @#$enjoy$#@         out of hiiva"
	dc.b	0

*-----------------------------------------------------------------------------*
; ¹	= 1 pixeli tyhjaa
; ²	= 2 pixelia tyhjaa
; space = 6 pixelia tyhjaa

StrLine	= 4						<- Ensimmainen rivi
EndLine	= 6    						<- Viimeinen rivi 

Text2	dc.b	"                        ",0 		2. rivi
	dc.b	"PANIMO. 2               ",0 		1. rivi
	dc.b	"                        ",0 		2. rivi
	dc.b	"Kemut           Intro ",0 		3. rivi
	dc.b	"So Small        ²Intro ",0 		4. rivi
	dc.b	"Charles 2ooo ²²²  Intro ",1 		5. rivi

*-----------------------------------------------------------------------------*
; tahan tulee filejen nimet diskilla

name1	dc.b	'Kemut.exe',0
	even
name2	dc.b	'So_Small.exe',0
	even
name3	dc.b	'Charles2ooo.exe',0
	even
name4	dc.b	'nimi',0
	even
name5	dc.b	'nimi',0
	even
name6	dc.b	'nimi',0
	even
name7	dc.b	'nimi',0
	even
name8	dc.b	'nimi',0
	even

*-----------------------------------------------------------------------------*
	incdir	DF1:
Font1	incbin	PackFont1.RAW
Font2	incbin	PackFont2.RAW
Font3	incbin	PackFont3.RAW
RotPic1	incbin	Duck128.RAW
RotPic2	incbin	Plasma1.RAW
Design	incbin	Design.RAW

Player	incbin	Player60A.BIN
Music	incbin	P60.PackMus1

	section	b,bss

ColTab1	ds.w	128*128
ColTab2	ds.w	128*128