;POUR CHARGER LES DATAS TAPEZ:
;RI		RETURN
;PIC_RAW	RETURN
;IMAGE		RETURN RETURN
;
;RI		RETURN
;FONT_RAW	RETURN
;FONT		RETURN RETURN
;
;
;PUIS TAPEZ
;G BEGIN	RETURN RETURN
;
;SUPPRIMEZ LES LIGNES SUIVANTES SI VOTRE VERSION DU SEKA
;NE COMPORTE PAS LA COMMANDE Y

>EXTERN "PIC_RAW",IMAGE
>EXTERN "FONT_RAW",FONT

org $30000	;EMPLACEMENT EN MEMOIRE
load $30000	;DE NOTRE PROGRAMME

BEGIN:
JMP START
;=====================================================================
EXECBASE=4
OPENLIBRARY=-408
CLOSELIBRARY=-414
SUPERSTATE=-150
USERSTATE=-156	
FORBID=-132
PERMIT=-138
ADDINTSERVER=-168
REMINTSERVER=-174
Open=-30
Close=-36
Read=-42

;=====================================================================
BLTCON0=$DFF040		
BLTCON1=$DFF042
BLTAFWM=$DFF044
BLTALWM=$DFF046
BLTCPTH=$DFF048
BLTCPTL=$DFF04A
BLTBPTH=$DFF04C
BLTBPTL=$DFF04E
BLTAPTH=$DFF050
BLTAPTL=$DFF052
BLTDPTH=$DFF054
BLTDPTL=$DFF056
BLTSIZE=$DFF058
BLTCMOD=$DFF060
BLTBMOD=$DFF062
BLTAMOD=$DFF064
BLTDMOD=$DFF066
BLTCDAT=$DFF070
BLTBDAT=$DFF072
BLTADAT=$DFF074
DMACONR=$DFF002
;==================================
IMAGE=$40000			;L'IMAGE SE TROUVE A $40000

VIDE=IMAGE+[40*256*3]		;UNE LIGNE VIDE

SCROLL=vide+40			;LE FOND DU SCROLL SE TROUVE JUSTE
				;APRES L'IMAGE
FONT=SCROLL+[50*35*3]		;LE DESSIN DES CARACTERES SE TROUVE
				;JUSTE APRES LE FOND DU SCROLL
FINDATA=FONT+[40*256*3]		;FIN DES DATAS
				
;==================================
START:    
MOVEM.L D0-D7/A0-A6,-(A7)	;SAUVE REGISTRES
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR FORBID(A6)    		;SAUTE SOUS PROGRAMME: INTERDIT MULTITACHE
JSR OPENLIB  			;SAUTE SOUS PROGRAMME: OUVERTURE LIBRAIRIES

CLEARSCROLL:			;ON EFFACE LE FOND DU SCROLL POUR EVITER
LEA SCROLL,A1			;D'AVOIR DES BIZARRERIES A L'ECRAN 
MOVE.W #25*35*3,D0
CLS:
MOVE.W #0,(A1)+
DBF D0,CLS

MOVE.L #TEXT,PTEXT		;ON MET LE POINTEUR DE LETTRE SUR LE DEBUT
MOVE.W #0,COMPT			;DU TEXTE. ET LE COMPTEUR A 0


BSR.L SETCOPPER			;SAUTE SOUS PROGRAMME: MET EN PLACE LISTE COPPER
BSR.s NEWIRQ3			;SAUTE SOUS PROGRAMME: MET EN PLACE ROUTINE D'INTERRRUPTION

WAIT:
CMP.B #$E0,$DFF006		;ATTENDANT 200 IEME LIGNE RASTER
BNE.S WAIT			;SINON RETOURNE A WAIT

BSR.L SCROLLING			;VA A LA ROUTINE DE SCROLLING

BSR.L SCROLLING_UP_DOWN		;VA A ROUTINE SCROLLING HAUT BAS

BTST	#6,$BFE001		;ATTENDANT PRESSION SUR BOUTON GAUCHE SOURIS
BNE.S	WAIT			;SINON RETOURNE A WAIT
 				;SI OUI  FIN
END: 				;FIN:	
BSR.s STOPIRQ3        		;SAUTE SOUS PROGRAMME: STOPPE INTERRUPTION
BSR.L CLRCOPPER       		;SAUTE SOUS PROGRAMME: RESTAURE ANCIENNE LISTE COPPER
BSR.L CLOSELIB        		;SAUTE SOUS PROGRAMME: FERME LIBRAIRIES 
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR PERMIT(A6)      		;AUTORISE MULTITACHE
                      
MOVEM.L (A7)+,D0-D7/A0-A6	;RESTAURE REGISTRES
RTS
;========================
NEWIRQ3:			;MET EN PLACE NOTRE ROUTINE 
MOVE.L	EXECBASE,A6		;D'INTERRUPTION
lea	irqstr,a1
move.l	#5,d0
jsr	addintserver(a6)
move.l	d0,irq
beq.s	irqerror
rts
irqerror:
rts
;==========================
STOPIRQ3:			;RESTAURE ANCIENNE ROUTINE
movem.l	a0-a6/d0-d7,-(sp)	;D'INTERRUPTION
	tst.l	irq
	beq.s	irqoff1
	move.l	execbase,a6
	lea	irqstr,a1
	move.l	#32,d0
	jsr	remintserver(a6)
irqoff1:movem.l	(sp)+,a0-a6/d0-d7
	rts
irqstr:
	dc.l	0,0
	dc.b	2,-127
	dc.l	0,irqdat,interrupt
irqdat:	dc.l	0,0,0,0
irq:	dc.l	0
;============================
interrupt:			;NOTRE ROUTINE D'INTERRUPTION	
movem.l	a0-a6/d0-d7,-(sp)

	
movem.l	(sp)+,a0-a6/d0-d7
rts
;============================
OPENLIB:  			;OUVERTURE DE LA LIBRAIRIE GRAPHIQUE
move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
lea gfxname,a1			;MET NOM DE LA LIBRAIRIE DANS A1
move.l #$0,d0           	;MET 0 DANS D0
jsr openlibrary(a6)		;OUVRE LIBRAIRIE
tst d0				;TESTE D0
beq.s error			;SI = A 0   VA A ERROR = SORTIE
move.l d0,gfxbase       	;SI NON, MET ADRESSE D0 DANS GFXBASE
add.l #$32,d0			;AJOUTE $32 A CETTE ADRESSE
move.l d0,coppertr      	;MET D0=ADRESSE ACTUELLE LISTE COPPER
rts				;DANS COPPERTR
even
gfxname: dc.b 'graphics.library',0 	;NOM DE LA LIBRAIRIE
even
gfxbase: dc.l 0				;POINTEUR POUR LA GRAPHICS LIBRARY
coppertr: dc.l 0			;POINTEUR POUR ADRESSE LISTE COPPER
;====================
CLOSELIB: 			;FERMETURE LIBRAIRIE
move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
move.l gfxbase,a1		;MET NOM DE LA LIBRAIRIE DANS A1
jsr closelibrary(a6)		;FERME LIBRAIRIE
rts
;====================
ERROR:				;SI ERREUR
illegal				;SORTIE
rts
;====================
SETCOPPER:			;MET EN PLACE NOTRE LISTE COPPER
move.l coppertr,a0		;MET ADRESSE ACTUEL COPPER DANS A0
move.l (a0),oldcopper		;MET CONTENU DANS OLDCOPPER
move.l #newcopper,(a0)		;MET NOTRE LISTE COPPER DANS A0
move.w #$81c0,$dff096		;ACTIVE LISTE COPPER
rts		
oldcopper: dc.l 0
;====================
CLRCOPPER:			;RESTAURE ANCIENNE LISTE COPPER
move.l coppertr,a0		;MET ANCIENNE ADRESSE DANS A0
move.l oldcopper,(a0)		;MET CONTENU DANS A0
move.w #$80a0,$dff096		;REACTIVE ANCIENNE COPPER
rts
;====================
WAIT_BLITTER:			;ROUTINE POUR ATTENDRE QUE LE BLITTER
BTST #14,DMACONR		;EST FINI SON PRECEDENT TRAVAIL
BNE.S WAIT_BLITTER
RTS
;===================

EVEN
CPTSCROLL: DC.W 1		;COMPTEUR POUR ATTENTE
EVEN

SCROLLING:			;ROUTINE DU SCROLLING
SUB.W #1,CPTSCROLL		;SOUTRAIT 1 AU COMPTEUR
CMP.W #0,CPTSCROLL		;COMPARE A 0
BNE PAS_DE_SCROLL		;SI PAS =   PAS DE SCROLLING
MOVE.W #1,CPTSCROLL		;MET VALEUR 1 DANS COMPTEUR
BSR.L SEARCH_CHAR		;AFFICHE UN NOUVEAU CARACTERE
BSR.L SCROLLTEXT		;SCROLLE LE FOND DU SCROLL
PAS_DE_SCROLL:
RTS
;===================	
SCROLLTEXT:			
LEA SCROLL,A0 			;ON POINTE A0 SUR LE FOND DU SCROLL
	
BSR.L WAIT_BLITTER		;ON ATTEND QUE LE BLITTER EST FINI SON 
				;PRECEDENT TRAVAIL

LEA SCROLL-2,A1			;ON POINTE A1 SUR 16 PIXELS AVANT 
				;LE FOND DU SCROLL. 2 = 16 PIXELS

MOVE.L A0,BLTAPTH		;MET ADRESSE DE A0 DANS SOURCE BLITTER A
MOVE.L A1,BLTDPTH		;MET ADRESSE DE A1 DANS DESTINATION BLITTER D
MOVE.W #0,BLTAMOD  		;MET 0 DANS MODULO SOURCE A
MOVE.W #0,BLTDMOD		;MET 0 DANS MODULO DESTINATION D
MOVE.L #$FFFFFFFF,BLTAFWM	;MASQUE DU 1ER ET DU DERNIER MOT

MOVE.W #$09F0,D5		;VALEUR 9F0 POUR BLTCON1 DANS D5
ADD.W VITESSE2,D5		;AJOUTE VALEUR DECALAGE

MOVE.W D5,BLTCON0 	   	;MET MIMTERN ET DECALAGE DANS BLTCON0
MOVE.W #$0000,BLTCON1		;$C = $F - $4 = 16 - 4 = 12
				;4 PIXELS DE DECALAGE VERS LA GAUCHE

				;$9 -> POUR 1 SOURCE BLITTER
				;$F0 -> MINTERM POUR COPIE DIRECTE
				;$0000 -> MIS A 0 CAR SOURCE B INITULISE	

MOVE.W #[35*64*3]+25,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
				;TAILLE = [HAUTEUR * 64]+[LARGEUR/2]
RTS
;============
EVEN
VITESSE:  DC.W 8		;COMPTEUR POUR NOUVELLE LETTRE
VITESSE2: DC.W $C000		;DECALAGE
EVEN

SEARCH_CHAR:
ADD.W #1,COMPT			;AJOUTE 1 AU COMPTEUR
MOVE.W VITESSE,D6		;MET VALEUR VITESSE DANS D6
MOVE.W COMPT,D5			;MET VALEUR COMPTEUR DANS D5
CMP.W D6,D5			;COMPARE A 8 CAR 8 * 4 PIXELS DE DECALAGE
				;EGALE A 32 SOIT LA LARGEUR D'UNE LETTRE
BNE.L SEARCHAR3			;SI PAS EGAL A 8 ON SORT
MOVE.W #0,COMPT			;SI OUI ON REMET COMPTEUR A 0
				;ET ON CONTINU

MOVE.L PTEXT,A0			;MET POINTEUR TEXTE DANS A0
CLR.L D0			;ON EFFACE CONTENU DE D0
MOVE.B (A0),D0			;MET LE CONTENU DU POINTEUR TEXTE DANS D0
LEA COMPTEUR_CHAR,A1		;EN POINTE A1 SUR LA TABLE DES LETTRES
CLR.L D1			;ON EFFACE CONTENU DE D1
MOVE.B #-1,D1			;ON MET -1 DANS D1

SEARCHAR1:

ADD.B #1,D1			;ON AJOUTE 1 A D1
CMP.B (A1)+,D0			;ON COMPARE LES LETTRES DE LA TABLE
				;AVEC CELLE CONTENU DANS D0
BNE SEARCHAR1			;SI PAS LA MEME ON RECOMMENCE AVEC LA
				;LETTRE SIUVANTE DANS LA TABLE
				;SI C'EST LA MEME ON CONTINU

CMP.B #'s',D0			;COMPARE LETTRE DU SCROLL AVEC SIGNE
BNE PAS_STOP			;SI PAS = ON CONTINU
MOVE.W #200,CPTSCROLL		;SINON MET 200 DANS COMPTEUR
PAS_STOP:

CMP.B #'a',D0
BNE VITESSEA
MOVE.W #32,VITESSE
MOVE.W #$F000,VITESSE2
VITESSEA:

CMP.B #'b',D0
BNE VITESSEB
MOVE.W #16,VITESSE
MOVE.W #$E000,VITESSE2
VITESSEB:

CMP.B #'c',D0
BNE VITESSEC
MOVE.W #8,VITESSE
MOVE.W #$C000,VITESSE2
VITESSEC:

CMP.B #'d',D0
BNE VITESSED
MOVE.W #4,VITESSE
MOVE.W #$8000,VITESSE2
VITESSED:

CMP.B #'e',D0
BNE VITESSEE
MOVE.W #2,VITESSE
MOVE.W #$0000,VITESSE2
VITESSEE:

CMP.B #'f',D0
BNE UPDOWN
MOVE.W #1,FLAG_SUP
UPDOWN:

MULU #4,D1			;ON MULTIPLIE D1 PAR 4
LEA TABLE_CHAR,A0		;ON POINTE A0 SUR LE DEBUT DE LA TABLE
				;D'ADRESSE DES IMAGES DES LETTRES
MOVE.L (A0,D1),A2		;ET ON MET L'ADRESSE DE LA LETTRE DANS A2

LEA SCROLL,A3			;ON POINTE A3 SUR LA POSITION SCROLL+46
ADD.L #46,A3			;SOIT A 46*8 = 368 PIXELS A DROITE DU 
				;COIN SUPERIEUR DROIT DU FOND DE SCROLL
				;SOIT DANS LA PARTIE INVISIBLE DU SCROLL	

BSR.L WAIT_BLITTER		;ON ATTENDS LE BLITTER	
MOVE.L A2,BLTAPTH		;ON MET ADRESSE DE A2 DANS SOURCE BLITTER A
MOVE.L A3,BLTDPTH		;ON MET ADRESSE DE A3 DANS DESTINATION BLITTER D

MOVE.W #40-4,BLTAMOD		;ON MET 40-4 DANS MODULO SOURCE A
				;CAR NOTRE LETTRE FAIT 32 PIXELS DE LARGE SOIT
				;4 MOTS (4*8=32) ET L'IMAGE QUI LA CONTIENT
				;FAIT 320 PIXELS DE LARGE SOIT 40 MOTS
	
MOVE.W #50-4,BLTDMOD		;ON MET 50-4 DANS MODULO DESTINATION D
				;CAR LE FOND DE SCROLL FAIT 400 PIXELS DE LARGE
				;SOIT 50 MOTS

MOVE.L #$09F00000,BLTCON0	;$0 -> PAS DE DECALAGE DE LA SOURCE A
				;$9 -> POUR 1 SOURCE BLITTER A
				;$F0 -> MINTERM POUR COPIE DIRECTE

MOVE.W #[35*3*64]+2,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
				;TAILLE = [HAUTEUR * 64]+[LARGEUR/2]

ADD.L #1,PTEXT			;ON AJOUTE 1 AU POINTEUR DE TEXTE
MOVE.L PTEXT,A0			;ON MET POINTEUR DE TEXTE DANS A0
TST.B (A0)			;SI PAS EGAL A 0
BNE SEARCHAR3			;ON VA A SEARCHAR3
MOVE.L #TEXT,PTEXT		;SINON ON REMET POINTEUR DE TEXTE AU DEBUT
				;DU TEXTE A SCROLLER

SEARCHAR3:
RTS

EVEN
COMPT: DC.W 0			;COMPTEUR 
PTEXT: DC.L 0			;POINTEUR DE TEXTE
;=================================================================
COMPTEUR_CHAR:
		DC.B ' ABCDEFGHI'	;TABLE DES CARACTERES
		DC.B 'JKLMNOPQRS'	;TELS QU'ILS SONT DISPOSES
		DC.B 'TUVWXYZ.,:'	;DANS NOTRE IMAGE	
		DC.B '()@#!?-*^/'
		DC.B '0123456789'
		DC.B 'abcdefghis'	;CARACTERES SPECIAUX
					;NON AFFICHABLES

EVEN
FONT1=FONT		;ADRESSES DES LETTRES PAR LIGNES
FONT2=FONT+[3*35*40] 
FONT3=FONT+[6*35*40]
FONT4=FONT+[9*35*40]
FONT5=FONT+[12*35*40]
EVEN 
TABLE_CHAR: 		;ADRESSES DES LETTRES

DC.L FONT1,FONT1+4,FONT1+8,FONT1+12,FONT1+16,FONT1+20
DC.L FONT1+24,FONT1+28,FONT1+32,FONT1+36
DC.L FONT2,FONT2+4,FONT2+8,FONT2+12,FONT2+16,FONT2+20
DC.L FONT2+24,FONT2+28,FONT2+32,FONT2+36
DC.L FONT3,FONT3+4,FONT3+8,FONT3+12,FONT3+16,FONT3+20
DC.L FONT3+24,FONT3+28,FONT3+32,FONT3+36
DC.L FONT4,FONT4+4,FONT4+8,FONT4+12,FONT4+16,FONT4+20
DC.L FONT4+24,FONT4+28,FONT4+32,FONT4+36
DC.L FONT5,FONT5+4,FONT5+8,FONT5+12,FONT5+16,FONT5+20
DC.L FONT5+24,FONT5+28,FONT5+32,FONT5+36

DC.L FONT1,FONT1,FONT1,FONT1,FONT1,FONT1,FONT1,FONT1,FONT1
DC.L FONT1,FONT1,FONT1,FONT1,FONT1,FONT1,FONT1,FONT1,FONT1

EVEN

EVEN		;TEXTE A SCROLLER

TEXT: DC.B '             '
DC.B ' VOICI DONC NOTRE aPREMIER ESSAI DE SCROLLINGf AU BLITTER '
DC.B ' b  CECI REPRESENTE cUNE VERITABLE DEMO d   SIMPLE MAIS UNE DEMO'
DC.B ' QUAND MEME    VOUS POUVEZ MODIFIER L IMAGE e'
DC.B ' LA MUSIQUE  LES CARACTERES  LE TEXTEs A VOUS DE JOUER '
DC.B '      POUR FINIR VOICI LA LISTE DES CARACTERES UTILISABLES '
DC.B ' ABCDEFGHIJKLMNOPQRSTUVWXYZ'
DC.B '.,:()@#!?-*^/0123456789'
dc.b '    ',0
fin:
EVEN
;====================
SCROLLING_UP_DOWN:		;ROUTINE SCROLLING HAUT BAS
CMP.W #1,FLAG_SUP		;TEST SI FLAG EST A 1 
BNE SCROLLING_UP_DOWN_FIN	;SINON PAS DE SCROLLING

MOVE.W FLAG_UD,D0		;MET VALEUR COMPTEUR DANS D0

ADD.W D0,BARRE1			;AJOUTE VALEUR A BARRE 1
ADD.W D0,BARRE2			;AJOUTE VALEUR A BARRE 2

CMP.W #$3001,BARRE1		;COMPARE BARRE1 A LIGNE $30
BNE SCR1			;SI PAS = ON CONTINU
NEG FLAG_UD			;SINON ON INVERSE SIGNE DU COMPTEUR
SCR1:

CMP.W #$F001,BARRE2		;COMPARE BARRE2 A LIGNE $F0
BNE SCR2			;SI PAS = ON CONTINU
NEG.W FLAG_UD			;SINON ON INVERSE SIGNE DU COMPTEUR
SCR2:

SCROLLING_UP_DOWN_FIN:
RTS

EVEN
FLAG_UD: DC.W $100		;VALEUR DU COMPTEUR
EVEN
FLAG_SUP: DC.W 0		;FLAG SCROLLING 
EVEN


;====================
EVEN				;NOTRE LISTE COPPER
NEWCOPPER:   
	DC.W	$008E,$2981	;DIMENSIONS DE L'ECRAN
	DC.W	$0090,$29D1	;256 LIGNES

	DC.W	$0092,$0038,$0094,$00D0

	;POINTEURS ADRESSE DES PLANS DE L'IMAGE

	DC.W $00E4,IMAGE+[40*0]/65536
	DC.W $00E6,IMAGE+[40*0] & 65535   
	DC.W $00EC,IMAGE+[40*1]/65536
	DC.W $00EE,IMAGE+[40*1] & 65535
	DC.W $00F4,IMAGE+[40*2]/65536
	DC.W $00F6,IMAGE+[40*2] & 65535

	DC.W $00E0,VIDE/65536
	DC.W $00E2,VIDE & 65535
	DC.W $00E8,VIDE/65536
	DC.W $00EA,VIDE & 65535
	DC.W $00F0,VIDE/65536
	DC.W $00F2,VIDE & 65535
	


	;REGISTRE POUR CHOISIR RESOLUTION	

	DC.W	$0100,$6600		;6 PLANS DUAL PLAYFIELDS

	;DECALAGE ECRAN - INUTILISE ICI

	DC.W	$0102,$0000

	;PRIORITE DES PLANS ET SPRITES - INUTILISE ICI

	DC.W 	$0104,$0000

	;MODULOS DES PLANS

	DC.W	$0108,-40	;MODULOS PLANS PAIRS
	DC.W 	$010A, 80	;MODULOS PLANS IMPAIRS

	;POINTEURS DES SPRITES - MIS A 0 SI PAS DE SPRITES

	DC.W	$0120,$0000,$0122,$0000
	DC.W	$0124,$0000,$0126,$0000
	DC.W	$0128,$0000,$012A,$0000	;PAS DE SPRITES
	DC.W	$012C,$0000,$012E,$0000
	DC.W	$0130,$0000,$0132,$0000
	DC.W	$0134,$0000,$0136,$0000
	DC.W	$0138,$0000,$013A,$0000
	DC.W	$013C,$0000,$013E,$0000

	;REGISTRES DES COULEURS

	DC.W	$0180,$0000	;COULEUR 00
	DC.W	$0182,$0A50	;COULEUR 01
	DC.W	$0184,$0DC0	;COULEUR 02
	DC.W	$0186,$0606	;COULEUR 03
	DC.W	$0188,$0818	;COULEUR 04
	DC.W	$018A,$0A2A	;COULEUR 05
	DC.W	$018C,$0D3D	;COULEUR 06
	DC.W	$018E,$0F5F	;COULEUR 07

	DC.W	$0190,$0000	;COULEUR 08
	DC.W	$0192,$0bbf	;COULEUR 09
	DC.W	$0194,$0f72	;COULEUR 10
	DC.W	$0196,$0611	;COULEUR 11
	DC.W	$0198,$0a31	;COULEUR 12
	DC.W	$019A,$0f51	;COULEUR 13
	DC.W	$019C,$0744	;COULEUR 14
	DC.W	$019E,$0f61	;COULEUR 15

BARRE1: DC.W $A001,$FFFE

DC.W $108,110		;MODULO = 10 + 50 + 50 

		;POINTEURS DE PLANS DU FOND DE SCROLL

		DC.W $00E0,SCROLL+[50*0]/65536	
		DC.W $00E2,SCROLL+[50*0] & 65535
		DC.W $00E8,SCROLL+[50*1]/65536
		DC.W $00EA,SCROLL+[50*1] & 65535
		DC.W $00F0,SCROLL+[50*2]/65536  
		DC.W $00F2,SCROLL+[50*2] & 65535


BARRE2: DC.W $A001+[$100*35],$FFFE

	DC.W $108,-40		
	
	DC.W $00E0,VIDE/65536
	DC.W $00E2,VIDE & 65535
	DC.W $00E8,VIDE/65536
	DC.W $00EA,VIDE & 65535
	DC.W $00F0,VIDE/65536
	DC.W $00F2,VIDE & 65535
	


	;INSTRUCTIONS POUR AVOIR UN ECRAN PAL (256 LIGNES DE HAUT)

	DC.W $FFDF,$FFFE

DC.L $FFFFFFFE ;FIN LISTE COPPER
EVEN
FINDEMO: