;POUR CHARGER LES DATAS TAPEZ:
;
;RI		RETURN
;FONT_RAW	RETURN
;FONT		RETURN RETURN
;
;
;PUIS TAPEZ
;G BEGIN	RETURN RETURN
;
;SUPPRIMEZ LES LIGNES SUIVANTES SI VOTRE VERSION DU SEKA
;NE COMPORTE PAS LA COMMANDE Y

>EXTERN "FONT_RAW",FONT

org $30000	;EMPLACEMENT EN MEMOIRE
load $30000	;DE NOTRE PROGRAMME

BEGIN:
JMP START
;=====================================================================
EXECBASE=4
OPENLIBRARY=-408
CLOSELIBRARY=-414
SUPERSTATE=-150
USERSTATE=-156	
FORBID=-132
PERMIT=-138
ADDINTSERVER=-168
REMINTSERVER=-174
Open=-30
Close=-36
Read=-42

;=====================================================================
BLTCON0=$DFF040		
BLTCON1=$DFF042
BLTAFWM=$DFF044
BLTALWM=$DFF046
BLTCPTH=$DFF048
BLTCPTL=$DFF04A
BLTBPTH=$DFF04C
BLTBPTL=$DFF04E
BLTAPTH=$DFF050
BLTAPTL=$DFF052
BLTDPTH=$DFF054
BLTDPTL=$DFF056
BLTSIZE=$DFF058
BLTCMOD=$DFF060
BLTBMOD=$DFF062
BLTAMOD=$DFF064
BLTDMOD=$DFF066
BLTCDAT=$DFF070
BLTBDAT=$DFF072
BLTADAT=$DFF074
DMACONR=$DFF002
;==================================
SCROLL=$41000			;LE FOND DU SCROLL
				;
FONT=SCROLL+[50*35*3*3]		;LE DESSIN DES CARACTERES SE TROUVE
				;JUSTE APRES LE FOND DU SCROLL

FINDATA=FONT+[40*256*3]		;FIN DES DATAS
				
;==================================
START:
MOVEM.L D0-D7/A0-A6,-(A7)	;SAUVE REGISTRES
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR FORBID(A6)			;SAUTE SOUS PROGRAMME: INTERDIT MULTITACHE
JSR OPENLIB			;SAUTE SOUS PROGRAMME: OUVERTURE LIBRAIRIES

CLEARSCROLL:			;ON EFFACE LE FOND DU SCROLL POUR EVITER
LEA SCROLL,A1			;D'AVOIR DES BIZARRERIES A L'ECRAN 
MOVE.W #25*35*3*3,D0
CLS:
MOVE.W #0,(A1)+
DBF D0,CLS

MOVE.L #TEXT,PTEXT		;ON MET LE POINTEUR DE LETTRE SUR LE DEBUT
MOVE.W #0,COMPT			;DU TEXTE. ET LE COMPTEUR A 0


BSR.L SETCOPPER			;SAUTE SOUS PROGRAMME: MET EN PLACE LISTE COPPER
BSR.s NEWIRQ3			;SAUTE SOUS PROGRAMME: MET EN PLACE ROUTINE D'INTERRRUPTION

WAIT:
CMP.B #$E0,$DFF006		;ATTENDANT 200 IEME LIGNE RASTER
BNE.S WAIT			;SINON RETOURNE A WAIT

BSR.L SCROLLING			;VA A LA ROUTINE DE SCROLLING

BSR.L SCROLLING_ROT		;VA A ROUTINE DE ROTATION

BTST	#6,$BFE001		;ATTENDANT PRESSION SUR BOUTON GAUCHE SOURIS
BNE.S	WAIT			;SINON RETOURNE A WAIT
 				;SI OUI  FIN
END: 				;FIN:	
BSR.s STOPIRQ3			;SAUTE SOUS PROGRAMME: STOPPE INTERRUPTION
BSR.L CLRCOPPER			;SAUTE SOUS PROGRAMME: RESTAURE ANCIENNE LISTE COPPER
BSR.L CLOSELIB			;SAUTE SOUS PROGRAMME: FERME LIBRAIRIES 
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR PERMIT(A6)			;AUTORISE MULTITACHE

MOVEM.L (A7)+,D0-D7/A0-A6	;RESTAURE REGISTRES
RTS
;========================
NEWIRQ3:			;MET EN PLACE NOTRE ROUTINE 
MOVE.L	EXECBASE,A6		;D'INTERRUPTION
lea	irqstr,a1
move.l	#5,d0
jsr	addintserver(a6)
move.l	d0,irq
beq.s	irqerror
rts
irqerror:
rts
;==========================
STOPIRQ3:			;RESTAURE ANCIENNE ROUTINE
movem.l	a0-a6/d0-d7,-(sp)	;D'INTERRUPTION
	tst.l	irq
	beq.s	irqoff1
	move.l	execbase,a6
	lea	irqstr,a1
	move.l	#32,d0
	jsr	remintserver(a6)
irqoff1:movem.l	(sp)+,a0-a6/d0-d7
	rts
irqstr:
	dc.l	0,0
	dc.b	2,-127
	dc.l	0,irqdat,interrupt
irqdat:	dc.l	0,0,0,0
irq:	dc.l	0
;============================
interrupt:			;NOTRE ROUTINE D'INTERRUPTION	
movem.l	a0-a6/d0-d7,-(sp)

	
movem.l	(sp)+,a0-a6/d0-d7
rts
;============================
OPENLIB:			;OUVERTURE DE LA LIBRAIRIE GRAPHIQUE
move.l execbase,a6		;MET ADRESSE EXECBASE DANS A6
lea gfxname,a1			;MET NOM DE LA LIBRAIRIE DANS A1
move.l #$0,d0			;MET 0 DANS D0
jsr openlibrary(a6)		;OUVRE LIBRAIRIE
tst d0				;TESTE D0
beq.s error			;SI = A 0   VA A ERROR = SORTIE
move.l d0,gfxbase		;SI NON, MET ADRESSE D0 DANS GFXBASE
add.l #$32,d0			;AJOUTE $32 A CETTE ADRESSE
move.l d0,coppertr		;MET D0=ADRESSE ACTUELLE LISTE COPPER
rts				;DANS COPPERTR
even
gfxname: dc.b 'graphics.library',0 	;NOM DE LA LIBRAIRIE
even
gfxbase: dc.l 0				;POINTEUR POUR LA GRAPHICS LIBRARY
coppertr: dc.l 0			;POINTEUR POUR ADRESSE LISTE COPPER
;====================
CLOSELIB: 			;FERMETURE LIBRAIRIE
move.l execbase,a6		;MET ADRESSE EXECBASE DANS A6
move.l gfxbase,a1		;MET NOM DE LA LIBRAIRIE DANS A1
jsr closelibrary(a6)		;FERME LIBRAIRIE
rts
;====================
ERROR:				;SI ERREUR
illegal				;SORTIE
rts
;====================
SETCOPPER:			;MET EN PLACE NOTRE LISTE COPPER
move.l coppertr,a0		;MET ADRESSE ACTUEL COPPER DANS A0
move.l (a0),oldcopper		;MET CONTENU DANS OLDCOPPER
move.l #newcopper,(a0)		;MET NOTRE LISTE COPPER DANS A0
move.w #$81c0,$dff096		;ACTIVE LISTE COPPER
rts		
oldcopper: dc.l 0
;====================
CLRCOPPER:			;RESTAURE ANCIENNE LISTE COPPER
move.l coppertr,a0		;MET ANCIENNE ADRESSE DANS A0
move.l oldcopper,(a0)		;MET CONTENU DANS A0
move.w #$80a0,$dff096		;REACTIVE ANCIENNE COPPER
rts
;====================
WAIT_BLITTER:			;ROUTINE POUR ATTENDRE QUE LE BLITTER
BTST #14,DMACONR		;EST FINI SON PRECEDENT TRAVAIL
BNE.S WAIT_BLITTER
RTS
;===================
SCROLLING:			;ROUTINE DU SCROLLING
BSR.L SEARCH_CHAR		;AFFICHE UN NOUVEAU CARACTERE
BSR.L SCROLLTEXT		;SCROLLE LE FOND DU SCROLL
RTS
;===================	
SCROLLTEXT:			
LEA SCROLL+[50*35*3],A0		;ON POINTE A0 SUR LE FOND DU SCROLL
	
BSR.L WAIT_BLITTER		;ON ATTEND QUE LE BLITTER EST FINI SON 
				;PRECEDENT TRAVAIL

LEA SCROLL+[50*35*3]-2,A1	;ON POINTE A1 SUR 16 PIXELS AVANT 
				;LE FOND DU SCROLL. 2 = 16 PIXELS

MOVE.L A0,BLTAPTH		;MET ADRESSE DE A0 DANS SOURCE BLITTER A
MOVE.L A1,BLTDPTH		;MET ADRESSE DE A1 DANS DESTINATION BLITTER D
MOVE.W #0,BLTAMOD		;MET 0 DANS MODULO SOURCE A
MOVE.W #0,BLTDMOD		;MET 0 DANS MODULO DESTINATION D
MOVE.L #$FFFFFFFF,BLTAFWM	;MASQUE DU 1ER ET DU DERNIER MOT
MOVE.L #$C9F00000,BLTCON0	;MET MIMTERN ET DECALAGE DANS BLTCON0
				;$C = $F - $4 = 16 - 4 = 12
				;4 PIXELS DE DECALAGE VERS LA GAUCHE

				;$9 -> POUR 1 SOURCE BLITTER
				;$F0 -> MINTERM POUR COPIE DIRECTE
				;$0000 -> MIS A 0 CAR SOURCE B INITULISE	

MOVE.W #[35*64*3]+25,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
				;TAILLE = [HAUTEUR * 64]+[LARGEUR/2]
RTS
;============
SEARCH_CHAR:
ADD.W #1,COMPT			;AJOUTE 1 AU COMPTEUR
CMP.W #8,COMPT			;COMPARE A 8 CAR 8 * 4 PIXELS DE DECALAGE
				;EGALE A 32 SOIT LA LARGEUR D'UNe LETTRE
BNE.L SEARCHAR3			;SI PAS EGAL A 8 ON SORT
MOVE.W #0,COMPT			;SI OUI ON REMET COMPTEUR A 0
				;ET ON CONTINU

MOVE.L PTEXT,A0			;MET POINTEUR TEXTE DANS A0
CLR.L D0			;ON EFFACE CONTENU DE D0
MOVE.B (A0),D0			;MET LE CONTENU DU POINTEUR TEXTE DANS D0
LEA COMPTEUR_CHAR,A1		;EN POINTE A1 SUR LA TABLE DES LETTRES
CLR.L D1			;ON EFFACE CONTENU DE D1
MOVE.B #-1,D1			;ON MET -1 DANS D1

SEARCHAR1:

ADD.B #1,D1			;ON AJOUTE 1 A D1         
CMP.B (A1)+,D0			;ON COMPARE LES LETTRES DE LA TABLE
				;AVEC CELLE CONTENU DANS D0
BNE SEARCHAR1			;SI PAS LA MEME ON RECOMMENCE AVEC LA
				;LETTRE SIUVANTE DANS LA TABLE
				;SI C'EST LA MEME ON CONTINU
MULU #4,D1			;ON MULTIPLIE D1 PAR 4
LEA TABLE_CHAR,A0		;ON POINTE A0 SUR LE DEBUT DE LA TABLE
				;D'ADRESSE DES IMAGES DES LETTRES
MOVE.L (A0,D1),A2		;ET ON MET L'ADRESSE DE LA LETTRE DANS A2

LEA SCROLL+[50*35*3],A3			;ON POINTE A3 SUR LA POSITION SCROLL+46
ADD.L #44,A3			;SOIT A 46*8 = 368 PIXELS A DROITE DU 
				;COIN SUPERIEUR DROIT DU FOND DE SCROLL
				;SOIT DANS LA PARTIE INVISIBLE DU SCROLL	

BSR.L WAIT_BLITTER		;ON ATTENDS LE BLITTER	
MOVE.L A2,BLTAPTH		;ON MET ADRESSE DE A2 DANS SOURCE BLITTER A
MOVE.L A3,BLTDPTH		;ON MET ADRESSE DE A3 DANS DESTINATION BLITTER D

MOVE.W #40-4,BLTAMOD		;ON MET 40-4 DANS MODULO SOURCE A
				;CAR NOTRE LETTRE FAIT 32 PIXELS DE LARGE SOIT
				;4 MOTS (4*8=32) ET L'IMAGE QUI LA CONTIENT
				;FAIT 320 PIXELS DE LARGE SOIT 40 MOTS
	
MOVE.W #50-4,BLTDMOD		;ON MET 50-4 DANS MODULO DESTINATION D
				;CAR LE FOND DE SCROLL FAIT 400 PIXELS DE LARGE
				;SOIT 50 MOTS

MOVE.L #$09F00000,BLTCON0	;$0 -> PAS DE DECALAGE DE LA SOURCE A
				;$9 -> POUR 1 SOURCE BLITTER A
				;$F0 -> MINTERM POUR COPIE DIRECTE

MOVE.W #[35*3*64]+2,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
				;TAILLE = [HAUTEUR * 64]+[LARGEUR/2]

ADD.L #1,PTEXT			;ON AJOUTE 1 AU POINTEUR DE TEXTE
MOVE.L PTEXT,A0			;ON MET POINTEUR DE TEXTE DANS A0
TST.B (A0)			;SI PAS EGAL A 0
BNE SEARCHAR3			;ON VA A SEARCHAR3
MOVE.L #TEXT,PTEXT		;SINON ON REMET POINTEUR DE TEXTE AU DEBUT
				;DU TEXTE A SCROLLER

SEARCHAR3:
RTS

EVEN
COMPT: DC.W 0			;COMPTEUR 
PTEXT: DC.L 0			;POINTEUR DE TEXTE
;=================================================================
COMPTEUR_CHAR:
		DC.B ' ABCDEFGHI'	;TABLE DES CARACTERES
		DC.B 'JKLMNOPQRS'	;TELS QU'ILS SONT DISPOSES
		DC.B 'TUVWXYZ.,:'	;DANS NOTRE IMAGE	
		DC.B '()@#!?-*^/'
		DC.B '0123456789'

EVEN
FONT1=FONT		;ADRESSES DES LETTRES PAR LIGNES
FONT2=FONT+[3*35*40] 
FONT3=FONT+[6*35*40]
FONT4=FONT+[9*35*40]
FONT5=FONT+[12*35*40]
EVEN 
TABLE_CHAR:		;ADRESSES DES LETTRES

DC.L FONT1,FONT1+4,FONT1+8,FONT1+12,FONT1+16,FONT1+20
DC.L FONT1+24,FONT1+28,FONT1+32,FONT1+36
DC.L FONT2,FONT2+4,FONT2+8,FONT2+12,FONT2+16,FONT2+20
DC.L FONT2+24,FONT2+28,FONT2+32,FONT2+36
DC.L FONT3,FONT3+4,FONT3+8,FONT3+12,FONT3+16,FONT3+20
DC.L FONT3+24,FONT3+28,FONT3+32,FONT3+36
DC.L FONT4,FONT4+4,FONT4+8,FONT4+12,FONT4+16,FONT4+20
DC.L FONT4+24,FONT4+28,FONT4+32,FONT4+36
DC.L FONT5,FONT5+4,FONT5+8,FONT5+12,FONT5+16,FONT5+20
DC.L FONT5+24,FONT5+28,FONT5+32,FONT5+36
EVEN

EVEN		;TEXTE A SCROLLER

TEXT: DC.B '             '
DC.B ' VOICI DONC NOTRE PREMIER ESSAI DE SCROLLING AU BLITTER '
DC.B '   CECI REPRESENTE UNE VERITABLE DEMO    SIMPLE MAIS UNE DEMO'
DC.B ' QUAND MEME    VOUS POUVEZ MODIFIER L IMAGE '
DC.B ' LA MUSIQUE  LES CARACTERES  LE TEXTE A VOUS DE JOUER '
DC.B '      POUR FINIR VOICI LA LISTE DES CARACTERES UTILISABLES '
DC.B ' ABCDEFGHIJKLMNOPQRSTUVWXYZ'
DC.B '.,:()@#!?-*^/0123456789'
dc.b '    ',0
fin:
EVEN
;====================
SCROLLING_ROT:		;ROUTINE DE ROTATION

ADD.W #1,CPT1		;AJOUTE 1 AU COMPTEUR

ADD.W #150,LO11		;AJOUTE 1 LIGNE (3*50) AU POINTEUR DE PLAN
ADD.W #150,LO12		
ADD.W #150,LO13		

CMP.W #70,CPT1		;COMPTEUR = A 70
BNE OK			;SINON VA A OK
MOVE.W #0,CPT1		;SI OUI  MET COMPTEUR A 0

SUB.W #150*70,LO11	;SOUSTRAIT 70 LIGNES AU POINTEUR PLAN
SUB.W #150*70,LO12	;
SUB.W #150*70,LO13	;

OK:

ADD.W #1,CPT2		;IDEM......

ADD.W #150,LO21
ADD.W #150,LO22
ADD.W #150,LO23

CMP.W #70,CPT2
BNE OK2
MOVE.W #0,CPT2

SUB.W #150*70,LO21
SUB.W #150*70,LO22
SUB.W #150*70,LO23

OK2:

RTS

EVEN
CPT1: DC.W 0
EVEN
CPT2: DC.W -35
EVEN

;====================
EVEN				;NOTRE LISTE COPPER
NEWCOPPER:
	DC.W	$008E,$2981	;DIMENSIONS DE L'ECRAN
	DC.W	$0090,$29D1	;256 LIGNES 

	DC.W	$0092,$0038,$0094,$00D0

	;POINTEURS ADRESSE DES PLANS DE L'IMAGE


	DC.W $00E0,	SCROLL+000-2/65536
	DC.W $00E2
LO11:	DC.W 		SCROLL+000-2 & 65535
	DC.W $00E8,	SCROLL+050-2/65536
	DC.W $00EA
LO12:	DC.W 		SCROLL+050-2 & 65535
	DC.W $00F0,	SCROLL+100-2/65536
	DC.W $00F2
LO13:	DC.W 		SCROLL+100-2 & 65535
	
	DC.W $00E4,	SCROLL+000/65536
	DC.W $00E6
LO21:	DC.W 		SCROLL+000 & 65535
	DC.W $00EC,	SCROLL+050/65536
	DC.W $00EE
LO22:	DC.W 		SCROLL+050 & 65535
	DC.W $00F4,	SCROLL+100/65536
	DC.W $00F6
LO23:	DC.W 		SCROLL+100 & 65535


	;REGISTRE POUR CHOISIR RESOLUTION	

	DC.W	$0100,$0000		;6 PLANS DUAL PLAYFIELS

	;DECALAGE ECRAN - INUTILISE ICI

	DC.W	$0102,$0000

	;PRIORITE DES PLANS ET SPRITES - INUTILISE ICI

	DC.W 	$0104,$0000

	;MODULOS DES PLANS

	DC.W	$0108,110		;MODULOS PLANS PAIRS
	DC.W 	$010A,-40-50-50-50 	;MODULOS INVERSE PLANS IMPAIRS

	;POINTEURS DES SPRITES - MIS A 0 SI PAS DE SPRITES

	DC.W	$0120,$0000,$0122,$0000
	DC.W	$0124,$0000,$0126,$0000
	DC.W	$0128,$0000,$012A,$0000	;PAS DE SPRITES
	DC.W	$012C,$0000,$012E,$0000
	DC.W	$0130,$0000,$0132,$0000
	DC.W	$0134,$0000,$0136,$0000
	DC.W	$0138,$0000,$013A,$0000
	DC.W	$013C,$0000,$013E,$0000

	;REGISTRES DES COULEURS

	DC.W	$0180,$0000	;COULEUR 00
	DC.W	$0182,$0A50	;COULEUR 01
	DC.W	$0184,$0DC0	;COULEUR 02
	DC.W	$0186,$0606	;COULEUR 03
	DC.W	$0188,$0818	;COULEUR 04
	DC.W	$018A,$0A2A	;COULEUR 05
	DC.W	$018C,$0D3D	;COULEUR 06
	DC.W	$018E,$0F5F	;COULEUR 07

	DC.W	$0190,$0000	;COULEUR 08
	DC.W	$0192,$0A50	;COULEUR 09
	DC.W	$0194,$0DC0	;COULEUR 10
	DC.W	$0196,$0606	;COULEUR 11
	DC.W	$0198,$0818	;COULEUR 12
	DC.W	$019A,$0A2A	;COULEUR 13
	DC.W	$019C,$0D3D	;COULEUR 14
	DC.W	$019E,$0F5F	;COULEUR 15

BARRE1: DC.W $A001,$FFFE,$0100,$6600

		DC.W $0102,$00F0
DC.W $A101,$FFFE,$0102,$00A5
DC.W $A201,$FFFE,$0102,$0087
DC.W $A301,$FFFE,$0102,$0069
DC.W $A401,$FFFE,$0102,$005A
DC.W $A501,$FFFE,$0102,$004B
DC.W $A601,$FFFE,$0102,$004B
DC.W $A701,$FFFE,$0102,$003C
DC.W $A801,$FFFE,$0102,$002D
DC.W $A901,$FFFE,$0102,$002D
DC.W $AA01,$FFFE,$0102,$001E
DC.W $AB01,$FFFE,$0102,$001E
DC.W $AC01,$FFFE,$0102,$000F
DC.W $AD01,$FFFE,$0102,$000F
DC.W $AE01,$FFFE,$0102,$000F
DC.W $AF01,$FFFE,$0102,$000F
DC.W $B001,$FFFE,$0102,$000F
DC.W $B101,$FFFE,$0102,$000F
DC.W $B201,$FFFE,$0102,$000F
DC.W $B301,$FFFE,$0102,$000F
DC.W $B401,$FFFE,$0102,$000F
DC.W $B501,$FFFE,$0102,$000F
DC.W $B601,$FFFE,$0102,$000F
DC.W $B701,$FFFE,$0102,$001E
DC.W $B801,$FFFE,$0102,$001E
DC.W $B901,$FFFE,$0102,$002D
DC.W $BA01,$FFFE,$0102,$002D
DC.W $BB01,$FFFE,$0102,$003C
DC.W $BC01,$FFFE,$0102,$004B
DC.W $BD01,$FFFE,$0102,$004B
DC.W $BE01,$FFFE,$0102,$005A
DC.W $BF01,$FFFE,$0102,$0069
DC.W $C001,$FFFE,$0102,$0087
DC.W $C101,$FFFE,$0102,$00A5
DC.W $C201,$FFFE,$0102,$00F0
DC.W $C301,$FFFE,$0102,$00F0

DC.W $0100,$0000		;RESOLUTION A 0

	;INSTRUCTIONS POUR AVOIR UN ECRAN PAL (256 LIGNES DE HAUT)

	DC.W $FFDF,$FFFE

DC.L $FFFFFFFE ;FIN LISTE COPPER
EVEN
FINDEMO: