;POUR CHARGER LES DATAS TAPEZ:
;
;RI		RETURN
;MODULE		RETURN
;MT_DATA	RETURN RETURN
;
;PUIS TAPEZ
;G BEGIN	RETURN RETURN
;
;SUPPRIMEZ LES LIGNES SUIVANTES SI VOTRE VERSION DU SEKA
;NE COMPORTE PAS LA COMMANDE Y

>EXTERN "MODULE",MT_DATA

org $30000	;EMPLACEMENT EN MEMOIRE
load $30000	;DE NOTRE PROGRAMME

BEGIN:
JMP START
;=====================================================================
EXECBASE=4
OPENLIBRARY=-408
CLOSELIBRARY=-414
SUPERSTATE=-150
USERSTATE=-156	
FORBID=-132
PERMIT=-138
ADDINTSERVER=-168
REMINTSERVER=-174
Open=-30
Close=-36
Read=-42

;=====================================================================
BLTCON0=$DFF040		
BLTCON1=$DFF042
BLTAFWM=$DFF044
BLTALWM=$DFF046
BLTCPTH=$DFF048
BLTCPTL=$DFF04A
BLTBPTH=$DFF04C
BLTBPTL=$DFF04E
BLTAPTH=$DFF050
BLTAPTL=$DFF052
BLTDPTH=$DFF054
BLTDPTL=$DFF056
BLTSIZE=$DFF058
BLTCMOD=$DFF060
BLTBMOD=$DFF062
BLTAMOD=$DFF064
BLTDMOD=$DFF066
BLTCDAT=$DFF070
BLTBDAT=$DFF072
BLTADAT=$DFF074
DMACONR=$DFF002
;==================================
BPL_X		=	320		;LARGEUR
BPL_Y		=	256		;HAUTEUR
BPL_DEPTH	=	4		;NOMBRE DE PLAN
BPL_WIDTH	=	BPL_X/8		;LARGEUR EN MOTS
BPL_SIZE	=	BPL_WIDTH*BPL_Y	;TAILLE ECRAN

NB_COLOR	=	16		;NOMBRE DE COULEUR
;==================================
SCREEN=$40000			;L'IMAGE SE TROUVE A $40000

MT_DATA=SCREEN+[40*256*4]	;MODULE MUSIQUE

FINDATA=MT_DATA+141898

;==================================
START:    
MOVEM.L D0-D7/A0-A6,-(A7)	;SAUVE REGISTRES
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR FORBID(A6)    		;SAUTE SOUS PROGRAMME: INTERDIT MULTITACHE
JSR OPENLIB  			;SAUTE SOUS PROGRAMME: OUVERTURE LIBRAIRIES

BSR.L	CLR_SCREEN		;EFFACE ECRAN

BSR.L INIT_MUSIQUE		;INITIALISATION DE LA MUSIQUE

BSR.L SETCOPPER			;SAUTE SOUS PROGRAMME: MET EN PLACE LISTE COPPER
BSR.L NEWIRQ3			;SAUTE SOUS PROGRAMME: MET EN PLACE ROUTINE D'INTERRRUPTION

INIT_CALCULS:

CLR.W	COOR_Y			;INIT LES PARAMETRES DE
CLR.W	COOR_X			;LA FONCTION
CLR.L	CURRENT_ADR_Y		;

BSR	CYCLE_COURBE_COULEUR	;VA A ROUTINE CYCLE COULEURS


PAS_FINI:
CMP.W	#BPL_Y,COOR_Y
BGE.S	WAIT
BSR	CALCUL_FONCTION		;1 LIGNE A CHAQUE FOIS.
CLR.W	TIME_BETWEEN_2_CYCLE
BRA	PAS_FINI		

WAIT:
CMP.B #$10,$DFF006		;ATTENDANT 200 IEME LIGNE RASTER
BNE.S WAIT			;SINON RETOURNE A WAIT

BSR.L	CYCLE_COURBE_COULEUR

BTST #$0A,$DFF016
BNE PASTEST
ADD.W #1,ITI
CMP.W #8,ITI
BNE OKITI
MOVE.W #0,ITI
OKITI:
JMP INIT_CALCULS
PASTEST:

BTST	#6,$BFE001		;ATTENDANT PRESSION SUR BOUTON GAUCHE SOURIS
BNE.S	WAIT			;SINON RETOURNE A WAIT
 				;SI OUI  FIN
END: 				;FIN:	
BSR.L STOP_MUSIQUE		;ARRET DE LA MUSIQUE
BSR.s STOPIRQ3        		;SAUTE SOUS PROGRAMME: STOPPE INTERRUPTION
BSR.L CLRCOPPER       		;SAUTE SOUS PROGRAMME: RESTAURE ANCIENNE LISTE COPPER
BSR.L CLOSELIB        		;SAUTE SOUS PROGRAMME: FERME LIBRAIRIES 
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR PERMIT(A6)      		;AUTORISE MULTITACHE
                      
MOVEM.L (A7)+,D0-D7/A0-A6	;RESTAURE REGISTRES
RTS
;========================
NEWIRQ3:			;MET EN PLACE NOTRE ROUTINE 
MOVE.L	EXECBASE,A6		;D'INTERRUPTION
lea	irqstr,a1
move.l	#5,d0
jsr	addintserver(a6)
move.l	d0,irq
beq.s	irqerror
rts
irqerror:
rts
;==========================
STOPIRQ3:			;RESTAURE ANCIENNE ROUTINE
movem.l	a0-a6/d0-d7,-(sp)	;D'INTERRUPTION
	tst.l	irq
	beq.s	irqoff1
	move.l	execbase,a6
	lea	irqstr,a1
	move.l	#32,d0
	jsr	remintserver(a6)
irqoff1:movem.l	(sp)+,a0-a6/d0-d7
	rts
irqstr:
	dc.l	0,0
	dc.b	2,-127
	dc.l	0,irqdat,interrupt
irqdat:	dc.l	0,0,0,0
irq:	dc.l	0
;============================
interrupt:			;NOTRE ROUTINE D'INTERRUPTION	
movem.l	a0-a6/d0-d7,-(sp)

BSR.L PLAY_MUSIQUE		;VA A LA ROUTINE POUR JOUER LA MUSIQUE
	
movem.l	(sp)+,a0-a6/d0-d7
rts
;============================
OPENLIB:  			;OUVERTURE DE LA LIBRAIRIE GRAPHIQUE
move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
lea gfxname,a1			;MET NOM DE LA LIBRAIRIE DANS A1
move.l #$0,d0           	;MET 0 DANS D0
jsr openlibrary(a6)		;OUVRE LIBRAIRIE
tst d0				;TESTE D0
beq.s error			;SI = A 0   VA A ERROR = SORTIE
move.l d0,gfxbase       	;SI NON, MET ADRESSE D0 DANS GFXBASE
add.l #$32,d0			;AJOUTE $32 A CETTE ADRESSE
move.l d0,coppertr      	;MET D0=ADRESSE ACTUELLE LISTE COPPER
rts				;DANS COPPERTR
even
gfxname: dc.b 'graphics.library',0 	;NOM DE LA LIBRAIRIE
even
gfxbase: dc.l 0				;POINTEUR POUR LA GRAPHICS LIBRARY
coppertr: dc.l 0			;POINTEUR POUR ADRESSE LISTE COPPER
;====================
CLOSELIB: 			;FERMETURE LIBRAIRIE
move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
move.l gfxbase,a1		;MET NOM DE LA LIBRAIRIE DANS A1
jsr closelibrary(a6)		;FERME LIBRAIRIE
rts
;====================
ERROR:				;SI ERREUR
illegal				;SORTIE
rts
;====================
SETCOPPER:			;MET EN PLACE NOTRE LISTE COPPER
move.l coppertr,a0		;MET ADRESSE ACTUEL COPPER DANS A0
move.l (a0),oldcopper		;MET CONTENU DANS OLDCOPPER
move.l #newcopper,(a0)		;MET NOTRE LISTE COPPER DANS A0
move.w #$81c0,$dff096		;ACTIVE LISTE COPPER
rts		
oldcopper: dc.l 0
;====================
CLRCOPPER:			;RESTAURE ANCIENNE LISTE COPPER
move.l coppertr,a0		;MET ANCIENNE ADRESSE DANS A0
move.l oldcopper,(a0)		;MET CONTENU DANS A0
move.w #$80a0,$dff096		;REACTIVE ANCIENNE COPPER
rts
;====================
WAIT_BLITTER:			;ROUTINE POUR ATTENDRE QUE LE BLITTER
BTST #14,DMACONR		;EST FINI SON PRECEDENT TRAVAIL
BNE.S WAIT_BLITTER
RTS
;===================
even
iti: dc.w 0
even
******************************************************************
CALCUL_FONCTION:
	MOVE.L	#SCREEN,D3		;*\D3= ADR DE LA LIGNE A
	ADD.L	CURRENT_ADR_Y,D3	;*/ TRACER

	LEA	SIN_TAB,A1		;* A1 = TABLE SINUS
	LEA	$100(A1),A2		;* A2 = TABLE COS
	CLR.W	COOR_X

	MOVE.L	#BPL_WIDTH-1,D7		;* D7 = NB D'OCTET

LOOP_CALCUL_FONCTION_EACH_BYTE:
	MOVEQ	#8-1,D6			;* D6 = NB DE BIT

LOOP_CALCUL_FONCTION_EACH_BIT:
	MOVEQ	#0,D0
	MOVEQ	#0,D1
	MOVE.W	COOR_X,D0
	MOVE.W	COOR_Y,D1

;* CALCUL DES DIFFERENTS PARAMETRES DE LA FONCTION
	MOVE.W	D0,D2		;* D2= ANGLE DU FUTUR COSINUS

	MOVE.W ITI,D5

	LSL.W	D5,D2		;*\X2 POUR OBTENIR LE MOT DU COS
				;*/ET PAR D5 POUR UN BEAU DESSIN.
	AND.W	#$3FE,D2	;* L'ANGLE DOIT ETRE ENTRE 0 ET 512 
	MOVE.W	(A2,D2.W),D2	;* D2= LE COSINUS
	MULS	#40,D2		;* ON LE MULTIPLIE PAR 40
	LSL.L	#1,D2		;*\ SAVANTE MANIPULATION POUR AVOIR
	CLR.W	D2		;* >LA VERITABLE VALEUR DE D2
	SWAP	D2		;*/

;* LES CALCULS CI-DESSOUS SONT SUR LE MEME PRINCIPE QUE CI-DESSUS
	MOVE.W	D2,D4		
	MOVE.W	D1,D2
	SUB.W	D4,D2
	LSL.W	#3,D2		;VALEUR 3 PEUT ETRE CHANGEE
	AND.W	#$3FE,D2
	MOVE.W	(A2,D2.W),D2
	MULS	#32,D2
	LSL.L	#1,D2
	CLR.W	D2
	SWAP	D2
	MOVE.W	D2,D4
;* LES CALCULS CI-DESSOUS SONT SUR LE MEME PRINCIPE QUE CI-DESSUS

	MOVE.W	D1,D2 
	LSL.W	#2,D2		;VALEUR 2 PEUT ETRE CHANGEE
	AND.W	#$3FE,D2
	MOVE.W	(A1,D2.W),D2
	MULS	#40,D2
	LSL.L	#1,D2
	CLR.W	D2
	SWAP	D2

;* LES CALCULS CI-DESSOUS SONT SUR LE MEME PRINCIPE QUE CI-DESSUS
	SUB.W	D2,D0
	MOVE.W	D0,D2
	LSL.W	#3,D2		;VALEUR 3 PEUT ETRE CHANGEE
	AND.W	#$3FE,D2
	MOVE.W	(A1,D2.W),D2
	MULS	#64,D2
	LSL.L	#1,D2
	CLR.W	D2
	SWAP	D2
	ADD.W	D4,D2
	
;* ARRIVE ICI ON A LA COULEUR DANS D2.
;* ON NE RACALCULE PAS A CHAQUE FOIS L'ADRESSE DU POINT POUR GAGNER
;* DU TEMPS D'EXECUTION.
	MOVE.W	COOR_X,D0	;*\
	AND.W	#$0007,D0	;* >D0= DU BIT OU SE TROUVE LE POINT
	NEG.W	D0		;* /
	ADDQ.W	#7,D0		;*/
	AND.W	#NB_COLOR-1,D2	;*\ -1 POUR QUE LA COULEUR RESTE
	OR.W	#1,D2		;*/ ENTRE 1 ET NB_COLOR
	
	MOVE.L	D3,A0		;*\A0= ADR DE L'OCTET OU SE TROUVE
			 	;*/ LE POINT ACTUEL
;* TRACE LE POINT DONT LA COULEUR EST DANS D2	
	MOVEQ	#BPL_DEPTH-1,D4
EACH_BPL:
	LSR.W	#1,D2
	BCC.S	CLR_BIT_IN_THIS_BPL
	BSET	D0,(A0)
	ADD.L	#BPL_SIZE,A0
	DBF	D4,EACH_BPL
	BRA.S	POINT_FINISH
CLR_BIT_IN_THIS_BPL:
	BCLR	D0,(A0)
	ADD.L	#BPL_SIZE,A0
	DBF	D4,EACH_BPL
POINT_FINISH:

;* CONTINUE DE TRACER DES POINTS DANS L'OCTET COURANT
;* ET SI ILS SONT TOUS FAITS ON PASSE APRES.
	ADDQ.W	#1,COOR_X
	DBF	D6,LOOP_CALCUL_FONCTION_EACH_BIT

;* CONTINUE DE TRACER DANS LES OCTETS
;* ET SI ILS SONT TOUS FAIT ON S'EN VA.
	ADDQ.L	#1,D3
	DBF	D7,LOOP_CALCUL_FONCTION_EACH_BYTE

;* ON INCREMENTE LES PARAMETRES POUR FAIRE
;* LA LIGNE SUIVANTE LA PROCHAINE FOIS
	ADD.L	#BPL_WIDTH,CURRENT_ADR_Y
	ADDQ.W	#1,COOR_Y
	RTS

COOR_X:		DC.W	1
COOR_Y:		DC.W	1
CURRENT_ADR_Y:	DC.L	1

***********************************************************
* CETTE ROUTINE S'OCCUPE DU CYCLE COULEUR
CYCLE_COURBE_COULEUR:
	SUBQ.W	#1,TIME_BETWEEN_2_CYCLE
	TST.W	TIME_BETWEEN_2_CYCLE
	BGT	FIN_CYCLE_COURBE_COULEUR

	LEA	ADR_CMAP_IN_CLIST,A0
	ADDQ.L	#2,A0		;* A0 --> REGISTRE COULEUR.

	LEA	TAB_DEGRADE_COULEUR,A1

	MOVE.W	CURRENT_POS_TAB_DEGRADE_COULEUR,D0

	MOVEQ	#NB_COLOR-1,D2

LOOP_CYCLE_COURBE_COULEUR:
	AND.W	#NB_COLOR-1,D0
	MOVE.W	D0,D1
	ADD.W	D1,D1
	MOVE.W	(A1,D1.W),(A0)
	ADDQ.L	#4,A0
	ADDQ.W	#1,D0

	DBF	D2,LOOP_CYCLE_COURBE_COULEUR

	ADDQ.W	#1,CURRENT_POS_TAB_DEGRADE_COULEUR
	MOVE.W	#5,TIME_BETWEEN_2_CYCLE
FIN_CYCLE_COURBE_COULEUR:
	RTS

TIME_BETWEEN_2_CYCLE:			DC.W	1
CURRENT_POS_TAB_DEGRADE_COULEUR:	DC.W	1
TAB_DEGRADE_COULEUR:
	DC.W	$0F00,$0D02,$0B04,$0906
	DC.W	$0708,$050A,$030C,$010E,$F
	DC.W	$010E,$030C,$050A,$0708
	DC.W	$0906,$0B04,$0D02

***************************************************************
* CETTE ROUTINE EFFACE LES BITPLANS
CLR_SCREEN:
	MOVE.W	#BPL_WIDTH*BPL_Y*BPL_DEPTH/4-1,D0

	LEA	SCREEN,A0
LOOP_CLR_SCREEN:
	CLR.L	(A0)+
	DBF	D0,LOOP_CLR_SCREEN
	RTS	

***************************************************************
SIN_TAB	DC.w  $0000,$0192,$0324,$04B6,$0647,$07D9,$096A,$0AFB
	dc.w  $0C8B,$0E1B,$0FAB,$1139,$12C8,$1455,$15E2,$176D
	dc.w  $18F8,$1A82,$1C0B,$1D93,$1F19,$209F,$2223,$23A6
	dc.w  $2528,$26A8,$2826,$29A3,$2B1F,$2C98,$2E11,$2F87
	dc.w  $30FB,$326E,$33DE,$354D,$36BA,$3824,$398C,$3AF2
	dc.w  $3C56,$3DB8,$3F17,$4073,$41CE,$4325,$447A,$45CD
	dc.w  $471C,$4869,$49B4,$4AFB,$4C3F,$4D81,$4EBF,$4FFB
	dc.w  $5133,$5269,$539B,$54CA,$55F5,$571D,$5842,$5964
	dc.w  $5A82,$5B9D,$5CB4,$5DC7,$5ED7,$5FE3,$60EC,$61F1
	dc.w  $62F2,$63EF,$64E8,$65DD,$66CF,$67BD,$68A6,$698C
	dc.w  $6A6D,$6B4A,$6C24,$6CF9,$6DCA,$6E96,$6F5F,$7023
	dc.w  $70E2,$719E,$7255,$7307,$73B5,$745F,$7504,$75A5
	dc.w  $7641,$76D9,$776C,$77FA,$7884,$7909,$798A,$7A05
	dc.w  $7A7D,$7AEF,$7B5D,$7BC5,$7C29,$7C89,$7CE3,$7D39
	dc.w  $7D8A,$7DD6,$7E1D,$7E5F,$7E9D,$7ED5,$7F09,$7F38
	dc.w  $7F62,$7F87,$7FA7,$7FC2,$7FD8,$7FE9,$7FF6,$7FFD
	dc.w  $7fff,$7FFD,$7FF6,$7FE9,$7FD8,$7FC2,$7FA7,$7F87
	dc.w  $7F62,$7F38,$7F09,$7ED5,$7E9D,$7E5F,$7E1D,$7DD6
	dc.w  $7D8A,$7D39,$7CE3,$7C89,$7C29,$7BC5,$7B5D,$7AEF
	dc.w  $7A7D,$7A05,$798A,$7909,$7884,$77FA,$776C,$76D9
	dc.w  $7641,$75A5,$7504,$745F,$73B5,$7307,$7255,$719E
	dc.w  $70E2,$7023,$6F5F,$6E96,$6DCA,$6CF9,$6C24,$6B4A
	dc.w  $6A6D,$698C,$68A6,$67BD,$66CF,$65DD,$64E8,$63EF
	dc.w  $62F2,$61F1,$60EC,$5FE3,$5ED7,$5DC7,$5CB4,$5B9D
	dc.w  $5A82,$5964,$5842,$571D,$55F5,$54CA,$539B,$5269
	dc.w  $5133,$4FFB,$4EBF,$4D81,$4C3F,$4AFB,$49B4,$4869
	dc.w  $471C,$45CD,$447A,$4325,$41CE,$4073,$3F17,$3DB8
	dc.w  $3C56,$3AF2,$398C,$3824,$36BA,$354D,$33DE,$326E
	dc.w  $30FB,$2F87,$2E11,$2C98,$2B1F,$29A3,$2826,$26A8
	dc.w  $2528,$23A6,$2223,$209F,$1F19,$1D93,$1C0B,$1A82
	dc.w  $18F8,$176D,$15E2,$1455,$12C8,$1139,$0FAB,$0E1B
	dc.w  $0C8B,$0AFB,$096A,$07D9,$0647,$04B6,$0324,$0192
	dc.w  $0000,$FE6E,$FCDC,$FB4A,$F9B9,$F827,$F696,$F505
	dc.w  $F375,$F1E5,$F055,$EEC7,$ED38,$EBAB,$EA1E,$E893
	dc.w  $E708,$E57E,$E3F5,$E26D,$E0E7,$DF61,$DDDD,$DC5A
	dc.w  $DAD8,$D958,$D7DA,$D65D,$D4E1,$D368,$D1EF,$D079
	dc.w  $CF05,$CD92,$CC22,$CAB3,$C946,$C7DC,$C674,$C50E
	dc.w  $C3AA,$C248,$C0E9,$BF8D,$BE32,$BCDB,$BB86,$BA33
	dc.w  $B8E4,$B797,$B64C,$B505,$B3C1,$B27F,$B141,$B005
	dc.w  $AECD,$AD97,$AC65,$AB36,$AA0B,$A8E3,$A7BE,$A69C
	dc.w  $A57E,$A463,$A34C,$A239,$A129,$A01D,$9F14,$9E0F
	dc.w  $9D0E,$9C11,$9B18,$9A23,$9931,$9843,$975A,$9674
	dc.w  $9593,$94B6,$93DC,$9307,$9236,$916A,$90A1,$8FDD
	dc.w  $8F1E,$8E62,$8DAB,$8CF9,$8C4B,$8BA1,$8AFC,$8A5B
	dc.w  $89BF,$8927,$8894,$8806,$877C,$86F7,$8676,$85FB
	dc.w  $8583,$8511,$84A3,$843B,$83D7,$8377,$831D,$82C7
	dc.w  $8276,$822A,$81E3,$81A1,$8163,$812B,$80F7,$80C8
	dc.w  $809E,$8079,$8059,$803E,$8028,$8017,$800A,$8003
	dc.w  $8000,$8003,$800A,$8017,$8028,$803E,$8059,$8079
	dc.w  $809E,$80C8,$80F7,$812B,$8163,$81A1,$81E3,$822A
	dc.w  $8276,$82C7,$831D,$8377,$83D7,$843B,$84A3,$8511
	dc.w  $8583,$85FB,$8676,$86F7,$877C,$8806,$8894,$8927
	dc.w  $89BF,$8A5B,$8AFC,$8BA1,$8C4B,$8CF9,$8DAB,$8E62
	dc.w  $8F1E,$8FDD,$90A1,$916A,$9236,$9307,$93DC,$94B6
	dc.w  $9593,$9674,$975A,$9843,$9931,$9A23,$9B18,$9C11
	dc.w  $9D0E,$9E0F,$9F14,$A01D,$A129,$A239,$A34C,$A463
	dc.w  $A57E,$A69C,$A7BE,$A8E3,$AA0B,$AB36,$AC65,$AD97
	dc.w  $AECD,$B005,$B141,$B27F,$B3C1,$B505,$B64C,$B797
	dc.w  $B8E4,$BA33,$BB86,$BCDB,$BE32,$BF8D,$C0E9,$C248
	dc.w  $C3AA,$C50E,$C674,$C7DC,$C946,$CAB3,$CC22,$CD92
	dc.w  $CF05,$D079,$D1EF,$D368,$D4E1,$D65D,$D7DA,$D958
	dc.w  $DAD8,$DC5A,$DDDD,$DF61,$E0E7,$E26D,$E3F5,$E57E
	dc.w  $E708,$E893,$EA1E,$EBAB,$ED38,$EEC7,$F055,$F1E5
	dc.w  $F375,$F505,$F696,$F827,$F9B9,$FB4A,$FCDC,$FE6E
	dc.w  $0000,$0192,$0324,$04B6,$0647,$07D9,$096A,$0AFB
	dc.w  $0C8B,$0E1B,$0FAB,$1139,$12C8,$1455,$15E2,$176D
	dc.w  $18F8,$1A82,$1C0B,$1D93,$1F19,$209F,$2223,$23A6
	dc.w  $2528,$26A8,$2826,$29A3,$2B1F,$2C98,$2E11,$2F87
	dc.w  $30FB,$326E,$33DE,$354D,$36BA,$3824,$398C,$3AF2
	dc.w  $3C56,$3DB8,$3F17,$4073,$41CE,$4325,$447A,$45CD
	dc.w  $471C,$4869,$49B4,$4AFB,$4C3F,$4D81,$4EBF,$4FFB
	dc.w  $5133,$5269,$539B,$54CA,$55F5,$571D,$5842,$5964
	dc.w  $5A82,$5B9D,$5CB4,$5DC7,$5ED7,$5FE3,$60EC,$61F1
	dc.w  $62F2,$63EF,$64E8,$65DD,$66CF,$67BD,$68A6,$698C
	dc.w  $6A6D,$6B4A,$6C24,$6CF9,$6DCA,$6E96,$6F5F,$7023
	dc.w  $70E2,$719E,$7255,$7307,$73B5,$745F,$7504,$75A5
	dc.w  $7641,$76D9,$776C,$77FA,$7884,$7909,$798A,$7A05
	dc.w  $7A7D,$7AEF,$7B5D,$7BC5,$7C29,$7C89,$7CE3,$7D39
	dc.w  $7D8A,$7DD6,$7E1D,$7E5F,$7E9D,$7ED5,$7F09,$7F38
	dc.w  $7F62,$7F87,$7FA7,$7FC2,$7FD8,$7FE9,$7FF6,$7FFD

************************************************************************
EVEN
;CETTE ROUTINE PERMET DE JOUER TOUS LES MODULES DE SOUNDTRACKERS
;DE LA VERSION 1.0 A LA VERSION 2.6  AINSI QUE CERTAINS MODULES
;NOISETRACKER.

INIT_MUSIQUE:			;INITIALISATION DE LA MUSIQUE
mt_init:move.l	mt_rdata(pc),a0
	cmp.l	#"M.K.",$438(a0)
	bne	mt_st20
	lea	mt_forst23(pc),a2
	move.l	a2,mt_forst
	bra	ok1st23
mt_st20:
	lea	mt_forst20(pc),a2
	move.l	a2,mt_forst
ok1st23:	
	add.l	(a2),a0
	moveq	#$7f,d0
	moveq	#0,d1
mt_init1:
	move.l	d1,d2
	subq.w	#1,d0
mt_init2:
	move.b	(a0)+,d1
	cmp.b	d2,d1
	bgt.s	mt_init1
	dbf	d0,mt_init2
	addq.b	#1,d2

mt_init3:
	move.l	mt_rdata(pc),a0
	lea	mt_sample1(pc),a1
	asl.l	#8,d2
	asl.l	#2,d2
	add.l	4(a2),d2
	add.l	a0,d2
	move.l	8(a2),d0
mt_init4:
	move.l	d2,(a1)+
	moveq	#0,d1
	move.w	42(a0),d1
	asl.l	#1,d1
	add.l	d1,d2
	add.l	#$1e,a0
	dbf	d0,mt_init4

	lea	mt_sample1(PC),a0
	moveq	#0,d0
mt_clear:
	move.l	(a0,d0.w),a1
	clr.l	(a1)
	addq.w	#4,d0
	cmp.w	#$7c,d0
	bne.s	mt_clear

	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	clr.l	mt_partnrplay
	clr.l	mt_partnote
	clr.l	mt_partpoint
	move.l	mt_rdata(pc),a1
	add.l	12(a2),a1
	move.b	(a1),mt_maxpart+1
	rts

STOP_MUSIQUE:			;ARRET DE LA MUSIQUE
mt_end:	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	move.w	#$f,$dff096
	rts

PLAY_MUSIQUE:			;JOUE LA MUSIQUE
mt_music:
	addq.w	#1,mt_counter
mt_cool:cmp.w	#6,mt_counter
	bne.s	mt_notsix
	clr.w	mt_counter
	bra	mt_rout2

mt_notsix:
	lea	mt_aud1temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp1
	lea	$dff0a0,a5		
	bsr.s	mt_arprout
mt_arp1:lea	mt_aud2temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp2
	lea	$dff0b0,a5
	bsr.s	mt_arprout
mt_arp2:lea	mt_aud3temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp3
	lea	$dff0c0,a5
	bsr.s	mt_arprout
mt_arp3:lea	mt_aud4temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp4
	lea	$dff0d0,a5
	bra.s	mt_arprout
mt_arp4:rts

mt_arprout:
	move.b	2(a6),d0
	and.b	#$0f,d0
	tst.b	d0
	beq	mt_arpegrt
	cmp.b	#$01,d0
	beq.s	mt_portup
	cmp.b	#$02,d0
	beq.s	mt_portdwn
	cmp.b	#$0a,d0
	beq.s	mt_volslide
	rts

mt_portup:
	moveq	#0,d0
	move.b	3(a6),d0
	sub.w	d0,22(a6)
	cmp.w	#$71,22(a6)
	bpl.s	mt_ok1
	move.w	#$71,22(a6)
mt_ok1:	move.w	22(a6),6(a5)
	rts

mt_portdwn:
	moveq	#0,d0
	move.b	3(a6),d0
	add.w	d0,22(a6)
	cmp.w	#$538,22(a6)
	bmi.s	mt_ok2
	move.w	#$538,22(a6)
mt_ok2:	move.w	22(a6),6(a5)
	rts

mt_volslide:
	moveq	#0,d0
	move.b	3(a6),d0
	lsr.b	#4,d0
	tst.b	d0
	beq.s	mt_voldwn
	add.w	d0,18(a6)
	cmp.w	#64,18(a6)
	bmi.s	mt_ok3
	move.w	#64,18(a6)
mt_ok3:	move.w	18(a6),8(a5)
	rts
mt_voldwn:
	moveq	#0,d0
	move.b	3(a6),d0
	and.b	#$0f,d0
	sub.w	d0,18(a6)
	bpl.s	mt_ok4
	clr.w	18(a6)
mt_ok4:	move.w	18(a6),8(a5)
	rts

mt_arpegrt:
	move.w	mt_counter(PC),d0
	cmp.w	#1,d0
	beq.s	mt_loop2
	cmp.w	#2,d0
	beq.s	mt_loop3
	cmp.w	#3,d0
	beq.s	mt_loop4
	cmp.w	#4,d0
	beq.s	mt_loop2
	cmp.w	#5,d0
	beq.s	mt_loop3
	rts

mt_loop2:
	moveq	#0,d0
	move.b	3(a6),d0
	lsr.b	#4,d0
	bra.s	mt_cont
mt_loop3:
	moveq	#$00,d0
	move.b	3(a6),d0
	and.b	#$0f,d0
	bra.s	mt_cont
mt_loop4:
	move.w	16(a6),d2
	bra.s	mt_endpart
mt_cont:
	add.w	d0,d0
	moveq	#0,d1
	move.w	16(a6),d1
	lea	mt_arpeggio(PC),a0
mt_loop5:
	move.w	(a0,d0),d2
	cmp.w	(a0),d1
	beq.s	mt_endpart
	addq.l	#2,a0
	bra.s	mt_loop5
mt_endpart:
	move.w	d2,6(a5)
	rts

mt_rout2:
	move.l	mt_rdata(pc),a0
	move.l	a0,a3
	add.l	#$0c,a3
	move.l	a0,a2
	move.l	mt_forst,a4
	add.l	(a4),a2
	add.l	16(a4),a0
	move.l	mt_partnrplay(PC),d0
	moveq	#0,d1
	move.b	(a2,d0),d1
	asl.l	#8,d1
	asl.l	#2,d1
	add.l	mt_partnote(PC),d1
	move.l	d1,mt_partpoint
	clr.w	mt_dmacon

	lea	$dff0a0,a5
	lea	mt_aud1temp(PC),a6
	bsr	mt_playit
	lea	$dff0b0,a5
	lea	mt_aud2temp(PC),a6
	bsr	mt_playit
	lea	$dff0c0,a5
	lea	mt_aud3temp(PC),a6
	bsr	mt_playit
	lea	$dff0d0,a5
	lea	mt_aud4temp(PC),a6
	bsr	mt_playit
	move.w	#$01f4,d0
mt_rls:	dbf	d0,mt_rls

	move.w	#$8000,d0
	or.w	mt_dmacon,d0
	move.w	d0,$dff096

	lea	mt_aud4temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice3
	move.l	10(a6),$dff0d0
	move.w	#1,$dff0d4
mt_voice3:
	lea	mt_aud3temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice2
	move.l	10(a6),$dff0c0
	move.w	#1,$dff0c4
mt_voice2:
	lea	mt_aud2temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice1
	move.l	10(a6),$dff0b0
	move.w	#1,$dff0b4
mt_voice1:
	lea	mt_aud1temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice0
	move.l	10(a6),$dff0a0
	move.w	#1,$dff0a4
mt_voice0:
	move.l	mt_partnote(PC),d0
	add.l	#$10,d0
	move.l	d0,mt_partnote
	cmp.l	#$400,d0
	bne.s	mt_stop
mt_higher:
	clr.l	mt_partnote
	addq.l	#1,mt_partnrplay
	moveq	#0,d0
	move.w	mt_maxpart(PC),d0
	move.l	mt_partnrplay(PC),d1
	cmp.l	d0,d1
	bne.s	mt_stop
	clr.l	mt_partnrplay
mt_stop:tst.w	mt_status
	beq.s	mt_stop2
	clr.w	mt_status
	bra.s	mt_higher
mt_stop2:
	rts

mt_playit:
	move.l	(a0,d1.l),(a6)
	addq.l	#4,d1
	moveq	#0,d2
	move.b	2(a6),d2
	and.b	#$f0,d2
	lsr.b	#4,d2

	move.b	(a6),d0
	and.b	#$f0,d0
	or.b	d0,d2
	tst.b	d2
	beq.s	mt_nosamplechange

	moveq	#0,d3
	lea	mt_samples(PC),a1
	move.l	d2,d4
	lsl.l	#2,d2
	mulu	#$1e,d4
	move.l	(a1,d2),4(a6)
	move.w	(a3,d4.l),8(a6)
	move.w	2(a3,d4.l),18(a6)
	move.w	4(a3,d4.l),d3
	tst.w	d3
	beq.s	mt_displace
	move.l	4(a6),d2
	add.l	d3,d2
	move.l	d2,4(a6)
	move.l	d2,10(a6)
	move.w	6(a3,d4.l),8(a6)
	move.w	6(a3,d4.l),14(a6)
	move.w	18(a6),8(a5)
	bra.s	mt_nosamplechange

mt_displace:
	move.l	4(a6),d2
	add.l	d3,d2
	move.l	d2,10(a6)
	move.w	6(a3,d4.l),14(a6)
	move.w	18(a6),8(a5)
mt_nosamplechange:
	move.w (a6),d0
	andi.w #$fff,d0			;it's the bug
	tst.w	d0			;of the real
	beq.s	mt_retrout		;source replay
	move.w	(a6),16(a6)
	move.w	20(a6),$dff096
	move.l	4(a6),(a5)
	move.w	8(a6),4(a5)
	move.w	(a6),d0
	andi.w #$fff,d0			;second bug
	move.w d0,6(a5)			;of the source
	move.w	20(a6),d0
	or.w	d0,mt_dmacon

mt_retrout:
	tst.w	(a6)
	beq.s	mt_nonewper
	move.w	(a6),22(a6)

mt_nonewper:
	move.b	2(a6),d0
	and.b	#$0f,d0
	cmp.b	#$0b,d0
	beq.s	mt_posjmp
	cmp.b	#$0c,d0
	beq.s	mt_setvol
	cmp.b	#$0d,d0
	beq.s	mt_break
	cmp.b	#$0e,d0
	beq.s	mt_setfil
	cmp.b	#$0f,d0
	beq.s	mt_setspeed
	rts

mt_posjmp:
	not.w	mt_status
	moveq	#0,d0
	move.b	3(a6),d0
	subq.b	#1,d0
	move.l	d0,mt_partnrplay
	rts

mt_setvol:
	move.b	3(a6),8(a5)
	rts

mt_break:
	not.w	mt_status
	rts

mt_setfil:
	moveq	#0,d0
	move.b	3(a6),d0
	and.b	#1,d0
	rol.b	#1,d0
	and.b	#$fd,$bfe001
	or.b	d0,$bfe001
	rts

mt_setspeed:
	move.b	3(a6),d0
	and.b	#$0f,d0
	beq.s	mt_back
	clr.w	mt_counter
	move.b	d0,mt_cool+3
mt_back:rts

mt_aud1temp:
	blk.w	10,0
	dc.w	1
	blk.w	2,0
mt_aud2temp:
	blk.w	10,0
	dc.w	2
	blk.w	2,0
mt_aud3temp:
	blk.w	10,0
	dc.w	4
	blk.w	2,0
mt_aud4temp:
	blk.w	10,0
	dc.w	8
	blk.w	2,0
mt_partnote:	dc.l	0
mt_partnrplay:	dc.l	0
mt_counter:	dc.w	0
mt_partpoint:	dc.l	0
mt_samples:	dc.l	0
mt_sample1:	blk.l	31,0
mt_maxpart:	dc.w	0
mt_dmacon:	dc.w	0
mt_status:	dc.w	0
mt_forst:	dc.l	0

mt_forst20:	dc.l 472,600,14,470,600
mt_forst23:	dc.l $3b8,$438,$1e,$3b6,$43c
mt_arpeggio:
	dc.w $0358,$0328,$02fa,$02d0,$02a6,$0280,$025c
	dc.w $023a,$021a,$01fc,$01e0,$01c5,$01ac,$0194,$017d
	dc.w $0168,$0153,$0140,$012e,$011d,$010d,$00fe,$00f0
	dc.w $00e2,$00d6,$00ca,$00be,$00b4,$00aa,$00a0,$0097
	dc.w $008f,$0087,$007f,$0078,$0071,$0000,$0000,$0000
mt_rdata:	dc.l mt_data

;====================
EVEN				;NOTRE LISTE COPPER
NEWCOPPER:
	DC.W	$008E,$2B81	;DIMENSIONS DE L'ECRAN
	DC.W	$0090,$2BD1	;256 LIGNES

	DC.W	$0092,$0038,$0094,$00D0

	;POINTEURS ADRESSE DES PLANS DE L'IMAGE

	DC.W $00E0,SCREEN+[40*256*0]/65536
	DC.W $00E2,SCREEN+[40*256*0] & 65535   
	DC.W $00E4,SCREEN+[40*256*1]/65536
	DC.W $00E6,SCREEN+[40*256*1] & 65535
	DC.W $00E8,SCREEN+[40*256*2]/65536
	DC.W $00EA,SCREEN+[40*256*2] & 65535
	DC.W $00EC,SCREEN+[40*256*3]/65536
	DC.W $00EE,SCREEN+[40*256*3] & 65535

	;REGISTRE POUR CHOISIR RESOLUTION	

	DC.W	$0100,$4200		;5 PLANS+MODE COULEURS

	;DECALAGE ECRAN - INUTILISE ICI

	DC.W	$0102,$0000

	;PRIORITE DES PLANS ET SPRITES - INUTILISE ICI

	DC.W 	$0104,$0000

	;MODULOS DES PLANS

	DC.W	$0108,$000	;MODULOS PLANS PAIRS
	DC.W 	$010A,$000	;MODULOS PLANS IMPAIRS

	;POINTEURS DES SPRITES - MIS A 0 SI PAS DE SPRITES

	DC.W	$0120,$0000,$0122,$0000
	DC.W	$0124,$0000,$0126,$0000
	DC.W	$0128,$0000,$012A,$0000	;PAS DE SPRITES
	DC.W	$012C,$0000,$012E,$0000
	DC.W	$0130,$0000,$0132,$0000
	DC.W	$0134,$0000,$0136,$0000
	DC.W	$0138,$0000,$013A,$0000
	DC.W	$013C,$0000,$013E,$0000

	;REGISTRES DES COULEURS

	ADR_CMAP_IN_CLIST:

	DC.W	$0180,$0000	;COULEUR 00
	DC.W	$0182,$0FFF	;COULEUR 01
	DC.W	$0184,$0BDD	;COULEUR 02
	DC.W	$0186,$0899	;COULEUR 03
	DC.W	$0188,$0455	;COULEUR 04
	DC.W	$018A,$0333	;COULEUR 05
	DC.W	$018C,$0222	;COULEUR 06
	DC.W	$018E,$0111	;COULEUR 07
	DC.W	$0190,$0EEF	;COULEUR 08
	DC.W	$0192,$0CCF	;COULEUR 09
	DC.W	$0194,$099F	;COULEUR 10
	DC.W	$0196,$055F	;COULEUR 11
	DC.W	$0198,$000F	;COULEUR 12
	DC.W	$019A,$000A	;COULEUR 13
	DC.W	$019C,$0006	;COULEUR 14
	DC.W	$019E,$0003	;COULEUR 15

	DC.W	$01A0,$0DEF	;COULEUR 16	;LES COULEURS DE 16 A 31 SONT
	DC.W	$01A2,$0BEF	;COULEUR 17	;AUSSI CELLES DES SPRITES
	DC.W	$01A4,$0ADF	;COULEUR 18
	DC.W	$01A6,$07BD	;COULEUR 19	;LES COULEURS 16 A 31 NE SONT
	DC.W	$01A8,$058A	;COULEUR 20	;PAS UTILISEES DANS LE MODE
	DC.W	$01AA,$0357	;COULEUR 21	;HOLD AND MODIFY (HAM)
	DC.W	$01AC,$0234	;COULEUR 22
	DC.W	$01AE,$0011	;COULEUR 23
	DC.W	$01B0,$0FD0	;COULEUR 24
	DC.W	$01B2,$0FA0	;COULEUR 25
	DC.W	$01B4,$0E80	;COULEUR 26
	DC.W	$01B6,$0C60	;COULEUR 27
	DC.W	$01B8,$0A30	;COULEUR 28
	DC.W	$01BA,$0720	;COULEUR 29
	DC.W	$01BC,$0510	;COULEUR 30
	DC.W	$01BE,$0300	;COULEUR 31

	;INSTRUCTIONS POUR AVOIR UN ECRAN PAL (256 LIGNES DE HAUT)

	DC.W $FFDF,$FFFE


DC.L $FFFFFFFE ;FIN LISTE COPPER
EVEN
FINDEMO: