;POUR CHARGER LES DATAS TAPEZ:
;
;
;RI		RETURN
;MODULE		RETURN
;MT_DATA	RETURN RETURN
;
;PUIS TAPEZ
;G BEGIN	RETURN RETURN
;
;SUPPRIMEZ LES LIGNES SUIVANTES SI VOTRE VERSION DU SEKA
;NE COMPORTE PAS LA COMMANDE Y

>EXTERN "MODULE",MT_DATA

org $30000	;EMPLACEMENT EN MEMOIRE
load $30000	;DE NOTRE PROGRAMME

BEGIN:
JMP START
;=====================================================================
EXECBASE=4
OPENLIBRARY=-408
CLOSELIBRARY=-414
SUPERSTATE=-150
USERSTATE=-156	
FORBID=-132
PERMIT=-138
ADDINTSERVER=-168
REMINTSERVER=-174
Open=-30
Close=-36
Read=-42

;=====================================================================
BLTCON0=$DFF040		
BLTCON1=$DFF042
BLTAFWM=$DFF044
BLTALWM=$DFF046
BLTCPTH=$DFF048
BLTCPTL=$DFF04A
BLTBPTH=$DFF04C
BLTBPTL=$DFF04E
BLTAPTH=$DFF050
BLTAPTL=$DFF052
BLTDPTH=$DFF054
BLTDPTL=$DFF056
BLTSIZE=$DFF058
BLTCMOD=$DFF060
BLTBMOD=$DFF062
BLTAMOD=$DFF064
BLTDMOD=$DFF066
BLTCDAT=$DFF070
BLTBDAT=$DFF072
BLTADAT=$DFF074
DMACONR=$DFF002
;==================================
ARRAY=$35000

DISPLAY=ARRAY+$10000	

MT_DATA=DISPLAY+[40*256*5]

FINDATA=MT_DATA+124472
			
;==================================
START:    
MOVEM.L D0-D7/A0-A6,-(A7)	;SAUVE REGISTRES
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR FORBID(A6)    		;SAUTE SOUS PROGRAMME: INTERDIT MULTITACHE
JSR OPENLIB  			;SAUTE SOUS PROGRAMME: OUVERTURE LIBRAIRIES

BSR.L SETUP			;MISE EN PLACE

BSR.L INIT_MUSIQUE		;INITIALISATION DE LA MUSIQUE

BSR.L SETCOPPER			;SAUTE SOUS PROGRAMME: MET EN PLACE LISTE COPPER
BSR.L NEWIRQ3			;SAUTE SOUS PROGRAMME: MET EN PLACE ROUTINE D'INTERRRUPTION

WAIT:
CMP.B #$E0,$DFF006		;ATTENDANT 200 IEME LIGNE RASTER
BNE.S WAIT			;SINON RETOURNE A WAIT

	BTST	#$0A,$DFF016	;TESTE BOUTON DROIT SOURIS
	BEQ.S	END
	BTST	#6,$BFE001	;TESTE BOUTON GAUCHE SOURIS
	BNE.S	WAIT

	MOVE.L	#ARRAY,A0	;Clear Array
	MOVE.W	#8192,D0
	MOVEQ.L	#0,D1
ClrAr2:	MOVE.L	D1,(A0)+
	DBF	D0,ClrAr2

	MOVE.L	#Display,A5
	MOVE.L	#Array,A6
	MOVE.W	#128,Dist
	MOVE.W	#64,XPos
	MOVE.W	#64,YPos
	JSR	Plot
	JSR	CalGrid
	JSR	DoPlot
	BRA	WAIT

END: 				;FIN:	
BSR.L STOP_MUSIQUE		;ARRET DE LA MUSIQUE
BSR.s STOPIRQ3        		;SAUTE SOUS PROGRAMME: STOPPE INTERRUPTION
BSR.L CLRCOPPER       		;SAUTE SOUS PROGRAMME: RESTAURE ANCIENNE LISTE COPPER
BSR.L CLOSELIB        		;SAUTE SOUS PROGRAMME: FERME LIBRAIRIES 
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR PERMIT(A6)      		;AUTORISE MULTITACHE
                      
MOVEM.L (A7)+,D0-D7/A0-A6	;RESTAURE REGISTRES
RTS
;========================
NEWIRQ3:			;MET EN PLACE NOTRE ROUTINE 
MOVE.L	EXECBASE,A6		;D'INTERRUPTION
lea	irqstr,a1
move.l	#5,d0
jsr	addintserver(a6)
move.l	d0,irq
beq.s	irqerror
rts
irqerror:
rts
;==========================
STOPIRQ3:			;RESTAURE ANCIENNE ROUTINE
movem.l	a0-a6/d0-d7,-(sp)	;D'INTERRUPTION
	tst.l	irq
	beq.s	irqoff1
	move.l	execbase,a6
	lea	irqstr,a1
	move.l	#32,d0
	jsr	remintserver(a6)
irqoff1:movem.l	(sp)+,a0-a6/d0-d7
	rts
irqstr:
	dc.l	0,0
	dc.b	2,-127
	dc.l	0,irqdat,interrupt
irqdat:	dc.l	0,0,0,0
irq:	dc.l	0
;============================
interrupt:			;NOTRE ROUTINE D'INTERRUPTION	
movem.l	a0-a6/d0-d7,-(sp)

BSR.L PLAY_MUSIQUE		;VA A LA ROUTINE POUR JOUER LA MUSIQUE
	
movem.l	(sp)+,a0-a6/d0-d7
rts
;============================
OPENLIB:  			;OUVERTURE DE LA LIBRAIRIE GRAPHIQUE
move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
lea gfxname,a1			;MET NOM DE LA LIBRAIRIE DANS A1
move.l #$0,d0           	;MET 0 DANS D0
jsr openlibrary(a6)		;OUVRE LIBRAIRIE
tst d0				;TESTE D0
beq.s error			;SI = A 0   VA A ERROR = SORTIE
move.l d0,gfxbase       	;SI NON, MET ADRESSE D0 DANS GFXBASE
add.l #$32,d0			;AJOUTE $32 A CETTE ADRESSE
move.l d0,coppertr      	;MET D0=ADRESSE ACTUELLE LISTE COPPER
rts				;DANS COPPERTR
even
gfxname: dc.b 'graphics.library',0 	;NOM DE LA LIBRAIRIE
even
gfxbase: dc.l 0				;POINTEUR POUR LA GRAPHICS LIBRARY
coppertr: dc.l 0			;POINTEUR POUR ADRESSE LISTE COPPER
;====================
CLOSELIB: 			;FERMETURE LIBRAIRIE
move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
move.l gfxbase,a1		;MET NOM DE LA LIBRAIRIE DANS A1
jsr closelibrary(a6)		;FERME LIBRAIRIE
rts
;====================
ERROR:				;SI ERREUR
illegal				;SORTIE
rts
;====================
SETCOPPER:			;MET EN PLACE NOTRE LISTE COPPER
move.l coppertr,a0		;MET ADRESSE ACTUEL COPPER DANS A0
move.l (a0),oldcopper		;MET CONTENU DANS OLDCOPPER
move.l #newcopper,(a0)		;MET NOTRE LISTE COPPER DANS A0
move.w #$81c0,$dff096		;ACTIVE LISTE COPPER
rts		
oldcopper: dc.l 0
;====================
CLRCOPPER:			;RESTAURE ANCIENNE LISTE COPPER
move.l coppertr,a0		;MET ANCIENNE ADRESSE DANS A0
move.l oldcopper,(a0)		;MET CONTENU DANS A0
move.w #$80a0,$dff096		;REACTIVE ANCIENNE COPPER
rts
;====================
************************************************************************
*             Set Up - Clear BitPlanes Used For Display                *
************************************************************************

SetUp:	

	MOVE.L	#Array,A0		;Clear Array
	MOVE.W	#$10000/2,D0
	MOVE.W	#0,D1
ClrAr:	MOVE.W	D1,(A0)+
	SUB.W	#1,D0
	BNE.S	ClrAr


	MOVE.L	#Display,A0		;Place Display Pointers
	LEA	ScreenPtrs,A1		;In Copper List
	MOVE.L	#10240,D0		;Plane Length
	MOVE.L	A0,D2
	MOVE.W	#4,D1
BplLoop:MOVE.W	D2,6(A1)
	SWAP	D2
	MOVE.W	D2,2(A1)
	SWAP	D2
	ADD.L	D0,D2
	ADDQ.W	#8,A1
	DBRA	D1,BplLoop


	MOVE.L	#Display,A0		;Clear Display
	MOVE.W	#25600,D0
	MOVE.W	#0,D1
ClrLoop:MOVE.W	D1,(A0)+
	DBRA	D0,ClrLoop	

	MOVE.L	#Display,A5
	MOVE.L	#Array,A6

	MOVE.W	#128,Dist
	MOVE.W	#64,XPos
	MOVE.W	#64,YPos
	MOVE.W	#0,Colour
	JSR	Plot
	JSR	CalGrid
	JSR	DoPlot
	RTS

*************************************************************************
*		Custom Pixel Plot Routine For 32 Colours                *
*************************************************************************

Plot:	MOVE.W	XPos,D1		;D1 - X Position
	MOVE.W	YPos,D2		;D2 - Y Position
	MOVE.W	D1,D6
	MOVE.W	D2,D7
	ASL	#8,D7
	ASL	#1,D6
	ADD.W	D6,D7
	MOVE.L	A6,A0
	ADD.W	D7,A0
	MOVE.W	(A0),D6
	ASR	#6,D6
	MOVE.W	D6,Colour
	MOVE.W	D1,D3
	ASR	#3,D3		;D3 - Whole X Words
	MOVE.W	D3,D4		;D4 - Whole X Words
	ADD.B	#$C,D4
	MOVE.W	D1,D3
	ASR	#4,D3
	ASL	#4,D3
	SUB.W	D3,D1		;D1 - Pixel Offset From Word
	MOVE.W	#15,D5
	SUB.W	D1,D5		;D5 - X Inverted Pixel Value
	ADD.B	#10,D2
	MULU	#40,D2		;D2 - Y Line Set in Words
	ADD.W	D4,D2		;D2 - Y Line + X Word
	MOVE.L	A5,A0		;DISPLAY
	ADD.W	D2,A0		;DISPLAY + Y Line + X Word
	MOVE.W	Colour,D1	;D1 - Binary Colour 0-31
	MOVE.W	#1,D2		;D2 - Plane Mask
	MOVE.W	#4,D3		;D3 - Counter For 5 Planes
PixSet:	BTST	D2,D1		;Test Colour
	BEQ.S	SkipSet
	BSET	D5,(A0)		;Set Pixel
	BRA.S	Next
SkipSet:	BCLR	D5,(A0)
Next:	ADD.W	#10240,A0	;Move To Next Plane
	ADDQ.W	#1,D2		;Adjust Plane Mask
	DBRA	D3,PixSet
	RTS

*************************************************************************
*		Generate Pseudo-Random Number From Seed			*
*************************************************************************

Random:	MOVE.W	Seed,D0
	MOVE.W	LastSeed,D1
	MOVE.B	$BFE401,D4
	MOVE.B	$BFD800,D5
	ADD.W	D0,D1
	ROL.W	D4,D1
	ADDI.W	#25186,D1
	ROL.W	D5,D1
	MOVE.W	D1,Seed
	MOVE.W	D0,LastSeed
	AND.W	#$1000,D1
	RTS	

*************************************************************************
*		 Midpoint Displacement on Fractal Grid			*		
*************************************************************************
*  FOR I=D TO 256-D STEP D : X(I)=.5*(X(D-I)+X(D+I))+(RANDOM/(8-LOOP))	*
*************************************************************************

CalGrid:	MOVE.W	#6,D7			;Iterations
Iterate:	MOVE.W	D7,Iterations
	MOVE.W	Dist,D0			;D0=D
	MOVE.W	#128,D1
	DIVU	D0,D1			;D1 = No of Iterations
	MOVE.W	D0,D2
	ASR	#1,D2
XIter:	MOVE.W	D2,XPos
	MOVEM.W	D0-D7,-(A7)	
YIter:	MOVE.W	Dist,D0
	MOVE.W	#128,D1
	DIVU	D0,D1
	MOVE.W	D0,D2
	ASR	#1,D2
YIter2:	MOVE.W	D2,YPos
	MOVEM.W	D0-D7,-(A7)	
	JSR	MidPt
	MOVEM.W	(A7)+,D0-D7
	ADD.W	D0,D2
	SUBQ.W	#1,D1
	BNE.S	YIter2
	MOVEM.W	(A7)+,D0-D7
	ADD.W	D0,D2
	SUBQ.W	#1,D1
	BNE.S	XIter
	MOVE.W	Dist,D0
	ASR	#1,D0
	MOVE.W	D0,Dist
	DBRA	D7,Iterate
	RTS
	
*************************************************************************
*			    MidPoint Displacement			*
*************************************************************************

MidPt:	MOVE.W	XPos,D0
	MOVE.W	YPos,D1
	MOVE.W	Dist,D3
	ASR	#1,D3
	SUB.W	D3,D1
	ASL	#1,D0
	ASL	#8,D1	
	ADD.W	D1,D0
	MOVE.L	A6,A0
	ADD.W	D0,A0
	MOVE.L	A0,A1
	MOVE.W	(A1),D0
	CMP.W	#0,D0
	BNE.S	Bottom
	MOVE.W	Dist,D1
	MOVE.L	A0,A1
	MOVE.L	A0,A2
	ADD.W	D1,A1
	SUB.W	D1,A2
	MOVE.W	(A1),D1
	MOVE.W	(A2),D2
	ADD.W	D1,D2
	ASR	#1,D2
	MOVE.W	D2,Pixel
	JSR	Random
	MOVE.W	Iterations,D3
	MOVE.W	#7,D4
	SUB.W	D3,D4
	ASR.W	D4,D1
	ADD.W	D1,Pixel
	MOVE.W	Pixel,(A0)
Bottom:	MOVE.W	XPos,D0
	MOVE.W	YPos,D1
	MOVE.W	Dist,D3
	ASR	#1,D3
	ADD.W	D3,D1
	ASL	#1,D0
	ASL	#8,D1	
	ADD.W	D1,D0
	MOVE.L	A6,A0
	ADD.W	D0,A0
	MOVE.L	A0,A1
	MOVE.W	(A1),D0
	CMP.W	#0,D0
	BNE.S	Left
	MOVE.W	Dist,D1
	MOVE.L	A0,A1
	MOVE.L	A0,A2
	ADD.W	D1,A1
	SUB.W	D1,A2
	MOVE.W	(A1),D1
	MOVE.W	(A2),D2
	ADD.W	D1,D2
	ASR	#1,D2
	MOVE.W	D2,Pixel
	JSR	Random
	MOVE.W	Iterations,D3
	MOVE.W	#7,D4
	SUB.W	D3,D4
	ASR.W	D4,D1
	ADD.W	D1,Pixel
	MOVE.W	Pixel,(A0)
Left:	MOVE.W	XPos,D0
	MOVE.W	YPos,D1
	MOVE.W	Dist,D3
	ASL	#1,D0
	SUB.W	D3,D0
	ASL	#8,D1	
	ADD.W	D1,D0
	MOVE.L	A6,A0
	ADD.W	D0,A0
	MOVE.L	A0,A1
	MOVE.W	(A1),D0
	CMP.W	#0,D0
	BNE.S	Right
	MOVE.W	Dist,D1
	ASR	#1,D1
	ASL	#8,D1
	MOVE.L	A0,A1
	MOVE.L	A0,A2
	ADD.W	D1,A1
	SUB.W	D1,A2
	MOVE.W	(A1),D1
	MOVE.W	(A2),D2
	ADD.W	D1,D2
	ASR	#1,D2
	MOVE.W	D2,Pixel
	JSR	Random
	MOVE.W	Iterations,D3
	MOVE.W	#7,D4
	SUB.W	D3,D4
	ASR.W	D4,D1
	ADD.W	D1,Pixel
	MOVE.W	Pixel,(A0)
Right:	MOVE.W	XPos,D0
	MOVE.W	YPos,D1
	MOVE.W	Dist,D3
	ASL	#1,D0
	ADD.W	D3,D0
	ASL	#8,D1	
	ADD.W	D1,D0
	MOVE.L	A6,A0
	ADD.W	D0,A0
	MOVE.L	A0,A1
	MOVE.W	(A1),D0
	CMP.W	#0,D0
	BNE.S	Middle
	MOVE.W	Dist,D1
	ASR	#1,D1
	ASL	#8,D1
	MOVE.L	A0,A1
	MOVE.L	A0,A2
	ADD.W	D1,A1
	SUB.W	D1,A2
	MOVE.W	(A1),D1
	MOVE.W	(A2),D2
	ADD.W	D1,D2
	ASR	#1,D2
	MOVE.W	D2,Pixel
	JSR	Random
	MOVE.W	Iterations,D3
	MOVE.W	#7,D4
	SUB.W	D3,D4
	ASR.W	D4,D1
	ADD.W	D1,Pixel
	MOVE.W	Pixel,(A0)
Middle:	MOVE.W	XPos,D0
	MOVE.W	YPos,D1
	ASL	#1,D0
	ASL	#8,D1	
	ADD.W	D1,D0
	MOVE.L	A6,A0
	ADD.W	D0,A0
	MOVE.L	A0,A1
	MOVE.W	(A1),D0
	CMP.W	#0,D0
	BNE.S	FMiddle
	MOVE.W	Dist,D1
	MOVE.L	A0,A1
	MOVE.L	A0,A2
	MOVE.L	A0,A3
	MOVE.L	A0,A4
	SUB.W	D1,A1
	SUB.W	D1,A2
	ADD.W	D1,A3
	ADD.W	D1,A4
	ASR	#1,D1
	ASL	#8,D1
	SUB.W	D1,A1
	SUB.W	D1,A3
	ADD.W	D1,A2
	ADD.W	D1,A4
	MOVE.W	(A1),D1
	MOVE.W	(A2),D2
	MOVE.W	(A3),D3
	MOVE.W	(A4),D4
	ADD.W	D1,D2
	ASR	#1,D2
	ADD.W	D3,D4
	ASR	#1,D4
	ADD.W	D2,D4
	ASR	#1,D4
	MOVE.W	D4,Pixel
	JSR	Random
	MOVE.W	Iterations,D3
	MOVE.W	#7,D4
	SUB.W	D3,D4
	ASR.W	D4,D1
	ADD.W	D1,Pixel
	MOVE.W	Pixel,(A0)
FMiddle:	RTS

*************************************************************************
*				 Do Plot				*
*************************************************************************

DoPlot:	MOVE.W	#1,XPos
	MOVE.W	#1,YPos
PlLoop:	JSR	Plot
	ADDQ.W	#1,XPos
	CMP.W	#127,XPos
	BNE.S	PlLoop
	MOVE.W	#1,XPos
	ADDQ.W	#1,YPos
	CMP.W	#127,YPos
	BNE.S	PlLoop
	RTS
;==============================
XPos		DC.W	0
YPos		DC.W	0
Colour		DC.W	0	

RandomNum	DC.W	0
Seed		DC.W	$1564
LastSeed	DC.W	$7461

Dist		DC.W	0
Iterations	DC.W	0
Pixel		DC.W	0
;===================================================
EVEN
;CETTE ROUTINE PERMET DE JOUER TOUS LES MODULES DE SOUNDTRACKERS
;DE LA VERSION 1.0 A LA VERSION 2.6  AINSI QUE CERTAINS MODULES
;NOISETRACKER.

INIT_MUSIQUE:			;INITIALISATION DE LA MUSIQUE
mt_init:move.l	mt_rdata(pc),a0
	cmp.l	#"M.K.",$438(a0)
	bne	mt_st20
	lea	mt_forst23(pc),a2
	move.l	a2,mt_forst
	bra	ok1st23
mt_st20:
	lea	mt_forst20(pc),a2
	move.l	a2,mt_forst
ok1st23:	
	add.l	(a2),a0
	moveq	#$7f,d0
	moveq	#0,d1
mt_init1:
	move.l	d1,d2
	subq.w	#1,d0
mt_init2:
	move.b	(a0)+,d1
	cmp.b	d2,d1
	bgt.s	mt_init1
	dbf	d0,mt_init2
	addq.b	#1,d2

mt_init3:
	move.l	mt_rdata(pc),a0
	lea	mt_sample1(pc),a1
	asl.l	#8,d2
	asl.l	#2,d2
	add.l	4(a2),d2
	add.l	a0,d2
	move.l	8(a2),d0
mt_init4:
	move.l	d2,(a1)+
	moveq	#0,d1
	move.w	42(a0),d1
	asl.l	#1,d1
	add.l	d1,d2
	add.l	#$1e,a0
	dbf	d0,mt_init4

	lea	mt_sample1(PC),a0
	moveq	#0,d0
mt_clear:
	move.l	(a0,d0.w),a1
	clr.l	(a1)
	addq.w	#4,d0
	cmp.w	#$7c,d0
	bne.s	mt_clear

	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	clr.l	mt_partnrplay
	clr.l	mt_partnote
	clr.l	mt_partpoint
	move.l	mt_rdata(pc),a1
	add.l	12(a2),a1
	move.b	(a1),mt_maxpart+1
	rts

STOP_MUSIQUE:			;ARRET DE LA MUSIQUE
mt_end:	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	move.w	#$f,$dff096
	rts

PLAY_MUSIQUE:			;JOUE LA MUSIQUE
mt_music:
	addq.w	#1,mt_counter
mt_cool:cmp.w	#6,mt_counter
	bne.s	mt_notsix
	clr.w	mt_counter
	bra	mt_rout2

mt_notsix:
	lea	mt_aud1temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp1
	lea	$dff0a0,a5		
	bsr.s	mt_arprout
mt_arp1:lea	mt_aud2temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp2
	lea	$dff0b0,a5
	bsr.s	mt_arprout
mt_arp2:lea	mt_aud3temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp3
	lea	$dff0c0,a5
	bsr.s	mt_arprout
mt_arp3:lea	mt_aud4temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp4
	lea	$dff0d0,a5
	bra.s	mt_arprout
mt_arp4:rts

mt_arprout:
	move.b	2(a6),d0
	and.b	#$0f,d0
	tst.b	d0
	beq	mt_arpegrt
	cmp.b	#$01,d0
	beq.s	mt_portup
	cmp.b	#$02,d0
	beq.s	mt_portdwn
	cmp.b	#$0a,d0
	beq.s	mt_volslide
	rts

mt_portup:
	moveq	#0,d0
	move.b	3(a6),d0
	sub.w	d0,22(a6)
	cmp.w	#$71,22(a6)
	bpl.s	mt_ok1
	move.w	#$71,22(a6)
mt_ok1:	move.w	22(a6),6(a5)
	rts

mt_portdwn:
	moveq	#0,d0
	move.b	3(a6),d0
	add.w	d0,22(a6)
	cmp.w	#$538,22(a6)
	bmi.s	mt_ok2
	move.w	#$538,22(a6)
mt_ok2:	move.w	22(a6),6(a5)
	rts

mt_volslide:
	moveq	#0,d0
	move.b	3(a6),d0
	lsr.b	#4,d0
	tst.b	d0
	beq.s	mt_voldwn
	add.w	d0,18(a6)
	cmp.w	#64,18(a6)
	bmi.s	mt_ok3
	move.w	#64,18(a6)
mt_ok3:	move.w	18(a6),8(a5)
	rts
mt_voldwn:
	moveq	#0,d0
	move.b	3(a6),d0
	and.b	#$0f,d0
	sub.w	d0,18(a6)
	bpl.s	mt_ok4
	clr.w	18(a6)
mt_ok4:	move.w	18(a6),8(a5)
	rts

mt_arpegrt:
	move.w	mt_counter(PC),d0
	cmp.w	#1,d0
	beq.s	mt_loop2
	cmp.w	#2,d0
	beq.s	mt_loop3
	cmp.w	#3,d0
	beq.s	mt_loop4
	cmp.w	#4,d0
	beq.s	mt_loop2
	cmp.w	#5,d0
	beq.s	mt_loop3
	rts

mt_loop2:
	moveq	#0,d0
	move.b	3(a6),d0
	lsr.b	#4,d0
	bra.s	mt_cont
mt_loop3:
	moveq	#$00,d0
	move.b	3(a6),d0
	and.b	#$0f,d0
	bra.s	mt_cont
mt_loop4:
	move.w	16(a6),d2
	bra.s	mt_endpart
mt_cont:
	add.w	d0,d0
	moveq	#0,d1
	move.w	16(a6),d1
	lea	mt_arpeggio(PC),a0
mt_loop5:
	move.w	(a0,d0),d2
	cmp.w	(a0),d1
	beq.s	mt_endpart
	addq.l	#2,a0
	bra.s	mt_loop5
mt_endpart:
	move.w	d2,6(a5)
	rts

mt_rout2:
	move.l	mt_rdata(pc),a0
	move.l	a0,a3
	add.l	#$0c,a3
	move.l	a0,a2
	move.l	mt_forst,a4
	add.l	(a4),a2
	add.l	16(a4),a0
	move.l	mt_partnrplay(PC),d0
	moveq	#0,d1
	move.b	(a2,d0),d1
	asl.l	#8,d1
	asl.l	#2,d1
	add.l	mt_partnote(PC),d1
	move.l	d1,mt_partpoint
	clr.w	mt_dmacon

	lea	$dff0a0,a5
	lea	mt_aud1temp(PC),a6
	bsr	mt_playit
	lea	$dff0b0,a5
	lea	mt_aud2temp(PC),a6
	bsr	mt_playit
	lea	$dff0c0,a5
	lea	mt_aud3temp(PC),a6
	bsr	mt_playit
	lea	$dff0d0,a5
	lea	mt_aud4temp(PC),a6
	bsr	mt_playit
	move.w	#$01f4,d0
mt_rls:	dbf	d0,mt_rls

	move.w	#$8000,d0
	or.w	mt_dmacon,d0
	move.w	d0,$dff096

	lea	mt_aud4temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice3
	move.l	10(a6),$dff0d0
	move.w	#1,$dff0d4
mt_voice3:
	lea	mt_aud3temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice2
	move.l	10(a6),$dff0c0
	move.w	#1,$dff0c4
mt_voice2:
	lea	mt_aud2temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice1
	move.l	10(a6),$dff0b0
	move.w	#1,$dff0b4
mt_voice1:
	lea	mt_aud1temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice0
	move.l	10(a6),$dff0a0
	move.w	#1,$dff0a4
mt_voice0:
	move.l	mt_partnote(PC),d0
	add.l	#$10,d0
	move.l	d0,mt_partnote
	cmp.l	#$400,d0
	bne.s	mt_stop
mt_higher:
	clr.l	mt_partnote
	addq.l	#1,mt_partnrplay
	moveq	#0,d0
	move.w	mt_maxpart(PC),d0
	move.l	mt_partnrplay(PC),d1
	cmp.l	d0,d1
	bne.s	mt_stop
	clr.l	mt_partnrplay
mt_stop:tst.w	mt_status
	beq.s	mt_stop2
	clr.w	mt_status
	bra.s	mt_higher
mt_stop2:
	rts

mt_playit:
	move.l	(a0,d1.l),(a6)
	addq.l	#4,d1
	moveq	#0,d2
	move.b	2(a6),d2
	and.b	#$f0,d2
	lsr.b	#4,d2

	move.b	(a6),d0
	and.b	#$f0,d0
	or.b	d0,d2
	tst.b	d2
	beq.s	mt_nosamplechange

	moveq	#0,d3
	lea	mt_samples(PC),a1
	move.l	d2,d4
	lsl.l	#2,d2
	mulu	#$1e,d4
	move.l	(a1,d2),4(a6)
	move.w	(a3,d4.l),8(a6)
	move.w	2(a3,d4.l),18(a6)
	move.w	4(a3,d4.l),d3
	tst.w	d3
	beq.s	mt_displace
	move.l	4(a6),d2
	add.l	d3,d2
	move.l	d2,4(a6)
	move.l	d2,10(a6)
	move.w	6(a3,d4.l),8(a6)
	move.w	6(a3,d4.l),14(a6)
	move.w	18(a6),8(a5)
	bra.s	mt_nosamplechange

mt_displace:
	move.l	4(a6),d2
	add.l	d3,d2
	move.l	d2,10(a6)
	move.w	6(a3,d4.l),14(a6)
	move.w	18(a6),8(a5)
mt_nosamplechange:
	move.w (a6),d0
	andi.w #$fff,d0			;it's the bug
	tst.w	d0			;of the real
	beq.s	mt_retrout		;source replay
	move.w	(a6),16(a6)
	move.w	20(a6),$dff096
	move.l	4(a6),(a5)
	move.w	8(a6),4(a5)
	move.w	(a6),d0
	andi.w #$fff,d0			;second bug
	move.w d0,6(a5)			;of the source
	move.w	20(a6),d0
	or.w	d0,mt_dmacon

mt_retrout:
	tst.w	(a6)
	beq.s	mt_nonewper
	move.w	(a6),22(a6)

mt_nonewper:
	move.b	2(a6),d0
	and.b	#$0f,d0
	cmp.b	#$0b,d0
	beq.s	mt_posjmp
	cmp.b	#$0c,d0
	beq.s	mt_setvol
	cmp.b	#$0d,d0
	beq.s	mt_break
	cmp.b	#$0e,d0
	beq.s	mt_setfil
	cmp.b	#$0f,d0
	beq.s	mt_setspeed
	rts

mt_posjmp:
	not.w	mt_status
	moveq	#0,d0
	move.b	3(a6),d0
	subq.b	#1,d0
	move.l	d0,mt_partnrplay
	rts

mt_setvol:
	move.b	3(a6),8(a5)
	rts

mt_break:
	not.w	mt_status
	rts

mt_setfil:
	moveq	#0,d0
	move.b	3(a6),d0
	and.b	#1,d0
	rol.b	#1,d0
	and.b	#$fd,$bfe001
	or.b	d0,$bfe001
	rts

mt_setspeed:
	move.b	3(a6),d0
	and.b	#$0f,d0
	beq.s	mt_back
	clr.w	mt_counter
	move.b	d0,mt_cool+3
mt_back:rts

mt_aud1temp:
	blk.w	10,0
	dc.w	1
	blk.w	2,0
mt_aud2temp:
	blk.w	10,0
	dc.w	2
	blk.w	2,0
mt_aud3temp:
	blk.w	10,0
	dc.w	4
	blk.w	2,0
mt_aud4temp:
	blk.w	10,0
	dc.w	8
	blk.w	2,0
mt_partnote:	dc.l	0
mt_partnrplay:	dc.l	0
mt_counter:	dc.w	0
mt_partpoint:	dc.l	0
mt_samples:	dc.l	0
mt_sample1:	blk.l	31,0
mt_maxpart:	dc.w	0
mt_dmacon:	dc.w	0
mt_status:	dc.w	0
mt_forst:	dc.l	0

mt_forst20:	dc.l 472,600,14,470,600
mt_forst23:	dc.l $3b8,$438,$1e,$3b6,$43c
mt_arpeggio:
	dc.w $0358,$0328,$02fa,$02d0,$02a6,$0280,$025c
	dc.w $023a,$021a,$01fc,$01e0,$01c5,$01ac,$0194,$017d
	dc.w $0168,$0153,$0140,$012e,$011d,$010d,$00fe,$00f0
	dc.w $00e2,$00d6,$00ca,$00be,$00b4,$00aa,$00a0,$0097
	dc.w $008f,$0087,$007f,$0078,$0071,$0000,$0000,$0000
mt_rdata:	dc.l mt_data

;===================================================
EVEN				;NOTRE LISTE COPPER
NEWCOPPER:   
	DC.W	$008E,$2881	;DIMENSIONS DE L'ECRAN
	DC.W	$0090,$28D1	;256 LIGNES

	DC.W	$0092,$0038,$0094,$00D0

	;POINTEURS ADRESSE DES PLANS DE L'IMAGE

	SCREENPTRS:
	DC.W $00E0,0
	DC.W $00E2,0  
	DC.W $00E4,0
	DC.W $00E6,0
	DC.W $00E8,0
	DC.W $00EA,0
	DC.W $00EC,0
	DC.W $00EE,0
	DC.W $00F0,0
	DC.W $00F2,0


	;REGISTRE POUR CHOISIR RESOLUTION	

	DC.W	$0100,$5200		;5 PLANS+MODE COULEURS

	;DECALAGE ECRAN - INUTILISE ICI

	DC.W	$0102,$0000

	;PRIORITE DES PLANS ET SPRITES - INUTILISE ICI

	DC.W 	$0104,$0000

	;MODULOS DES PLANS

	DC.W	$0108,$000	;MODULOS PLANS PAIRS
	DC.W 	$010A,$000	;MODULOS PLANS IMPAIRS

	;POINTEURS DES SPRITES - MIS A 0 SI PAS DE SPRITES

	DC.W	$0120,$0000,$0122,$0000
	DC.W	$0124,$0000,$0126,$0000
	DC.W	$0128,$0000,$012A,$0000	;PAS DE SPRITES
	DC.W	$012C,$0000,$012E,$0000
	DC.W	$0130,$0000,$0132,$0000
	DC.W	$0134,$0000,$0136,$0000
	DC.W	$0138,$0000,$013A,$0000
	DC.W	$013C,$0000,$013E,$0000

	;REGISTRES DES COULEURS

	SCREENCOLS:
	DC.W	$0180,$0000	;COULEUR 00
	DC.W	$0182,$020F	;COULEUR 01
	DC.W	$0184,$004F	;COULEUR 02
	DC.W	$0186,$006F	;COULEUR 03
	DC.W	$0188,$008F	;COULEUR 04
	DC.W	$018A,$00F9	;COULEUR 05
	DC.W	$018C,$05F0	;COULEUR 06
	DC.W	$018E,$04E0	;COULEUR 07
	DC.W	$0190,$04D0	;COULEUR 08
	DC.W	$0192,$03C0	;COULEUR 09
	DC.W	$0194,$03B0	;COULEUR 10
	DC.W	$0196,$03A0	;COULEUR 11
	DC.W	$0198,$0290	;COULEUR 12
	DC.W	$019A,$0280	;COULEUR 13
	DC.W	$019C,$0270	;COULEUR 14
	DC.W	$019E,$0260	;COULEUR 15
	DC.W	$01A0,$0460	;COULEUR 16	;LES COULEURS DE 16 A 31 SONT
	DC.W	$01A2,$0561	;COULEUR 17	;AUSSI CELLES DES SPRITES
	DC.W	$01A4,$0661	;COULEUR 18
	DC.W	$01A6,$0650	;COULEUR 19	;LES COULEURS 16 A 31 NE SONT
	DC.W	$01A8,$0541	;COULEUR 20	;PAS UTILISEES DANS LE MODE
	DC.W	$01AA,$0642	;COULEUR 21	;HOLD AND MODIFY (HAM)
	DC.W	$01AC,$0753	;COULEUR 22
	DC.W	$01AE,$0865	;COULEUR 23
	DC.W	$01B0,$0876	;COULEUR 24
	DC.W	$01B2,$0988	;COULEUR 25
	DC.W	$01B4,$0BA9	;COULEUR 26
	DC.W	$01B6,$0BBB	;COULEUR 27
	DC.W	$01B8,$0CCC	;COULEUR 28
	DC.W	$01BA,$0DDD	;COULEUR 29
	DC.W	$01BC,$0EEE	;COULEUR 30
	DC.W	$01BE,$0FFF	;COULEUR 31

	;INSTRUCTIONS POUR AVOIR UN ECRAN PAL (256 LIGNES DE HAUT)

	DC.W $FFDF,$FFFE


DC.L $FFFFFFFE ;FIN LISTE COPPER
EVEN
FINDEMO: