;POUR CHARGER LES DATAS TAPEZ:
;RI		RETURN
;PIC_RAW	RETURN
;IMAGE		RETURN RETURN
;
;RI		RETURN
;LOADPIC_RAW	RETURN
;PICLOAD	RETURN RETURN
;
;RI		RETURN
;DECRUNPIC_RAW	RETURN
;PICDECRUN	RETURN RETURN
;
;RI		RETURN
;FONT.RAW	RETURN
;FONT		RETURN RETURN
;
;RI		RETURN
;MOD.AM		RETURN
;MT_DATA	RETURN RETURN
;
;RI		RETURN
;MOD.AM.NT	RETURN
;MT_DATA2	RETURN RETURN
;
;PUIS TAPEZ
;G BEGIN	RETURN RETURN
;
;SUPPRIMEZ LES LIGNES SUIVANTES SI VOTRE VERSION DU SEKA
;NE COMPORTE PAS LA COMMANDE Y

>EXTERN "PIC_RAW",IMAGE
>EXTERN "LOADPIC_RAW",PICLOAD
>EXTERN "DECRUNPIC_RAW",PICDECRUN
>EXTERN "FONT.RAW",FONT
>EXTERN "MOD.AM",MT_DATA
>EXTERN "MOD.AM.NT",MT_DATA2

org $10000	;EMPLACEMENT EN MEMOIRE
load $10000	;DE NOTRE PROGRAMME

BEGIN:
JMP START
;=====================================================================
EXECBASE=4
OPENLIBRARY=-408
CLOSELIBRARY=-414
SUPERSTATE=-150
USERSTATE=-156	
FORBID=-132
PERMIT=-138
ADDINTSERVER=-168
REMINTSERVER=-174
OPEN=-30
CLOSE=-36
READ=-42
FINDTASK=-294
ADDPORT=-354
REMPORT=-360
OPENDEV=-444
CLOSEDEV=-450
DOIO=-456
;=====================================================================
BLTCON0=$DFF040		
BLTCON1=$DFF042
BLTAFWM=$DFF044
BLTALWM=$DFF046
BLTCPTH=$DFF048
BLTCPTL=$DFF04A
BLTBPTH=$DFF04C
BLTBPTL=$DFF04E
BLTAPTH=$DFF050
BLTAPTL=$DFF052
BLTDPTH=$DFF054
BLTDPTL=$DFF056
BLTSIZE=$DFF058
BLTCMOD=$DFF060
BLTBMOD=$DFF062
BLTAMOD=$DFF064
BLTDMOD=$DFF066
BLTCDAT=$DFF070
BLTBDAT=$DFF072
BLTADAT=$DFF074
DMACONR=$DFF002
;==================================
IMAGE=$15000			;L'IMAGE SE TROUVE A $40000
				;320 PIXELS SUR 200 EN 3 PLANS
PICLOAD=IMAGE+[40*200*3]	;IMAGE DU LOADING
				;320 PIXELS SUR 45 EN 3 PLANS
PICDECRUN=PICLOAD+[40*45*3]	;IMAGE DU DECRUNCH
				;320 PIXELS SUR 45 EN 3 PLANS
VIDE=PICDECRUN+[40*45*3]	;EMPLACEMENT VIDE	

SCROLL=VIDE+[40*45*3]		;LE FOND DU SCROLL SE TROUVE JUSTE
				;APRES L'IMAGE
FONT=SCROLL+[50*35*3]		;LE DESSIN DES CARACTERES SE TROUVE
				;JUSTE APRES LE FOND DU SCROLL
MT_DATA=FONT+[40*176*3]		;LA MUSIQUE SE TROUVE JUSTE APRES
				;LES CARACTERES
MT_DATA2=MT_DATA+8252		;LE FICHIER INFO SE TROUVE JUSTE APRES
				;LA MUSIQUE
FINDATA=MT_DATA2+4104		;FIN DES DATAS APRES LA MUSIQUE

DESTINATION_A=$2F000		;ADRESSE DE CHARGEMENT DES DEMOS
	
DESTINATION_B=$30000		;ADRESSE DE SAUT POUR EXECUTION DES DEMOS			
			
;==================================
START:    

CLEARSCROLL:			;ON EFFACE LE FOND DU SCROLL POUR EVITER
LEA SCROLL,A1			;D'AVOIR DES BIZARRERIES A L'ECRAN 
MOVE.W #25*35*3,D0
CLS:
MOVE.W #0,(A1)+
DBF D0,CLS

LEA VIDE,A1
MOVE.W #20*45*3,D0
CLSV:
MOVE.W #0,(A1)+
DBF D0,CLSV


BSR.L INITSPRITES		;INITILISATION DES SPRITES

MOVE.L #TEXT,PTEXT		;ON MET LE POINTEUR DE LETTRE SUR LE DEBUT
MOVE.W #0,COMPT			;DU TEXTE. ET LE COMPTEUR A 0

BSR.L INIT_MUSIQUE		;INITIALISATION DE LA MUSIQUE

RUN:				;LABEL DE SAUT APRES EXECUTION DES DEMOS
				;PLACE APRES INITILISATION DE LA MUSIQUE
				;ET DU TEXTE

LEA VIDE,A2			;EFFACE EMPLACEMENT DES IMAGES
BSR.L PICTRACK			;LOADING ET DECRUNCHING


MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR FORBID(A6)    		;SAUTE SOUS PROGRAMME: INTERDIT MULTITACHE
JSR OPENLIB  			;SAUTE SOUS PROGRAMME: OUVERTURE LIBRAIRIES

BSR.L SETCOPPER			;SAUTE SOUS PROGRAMME: MET EN PLACE LISTE COPPER
BSR.L NEWIRQ3			;SAUTE SOUS PROGRAMME: MET EN PLACE ROUTINE D'INTERRRUPTION

CLR.B $BFEC01			;EFFACE BUFFER CLAVIER
CLR.B $BFE001			;STOPPE LE DRIVE
WAIT:
CMP.B #$E0,$DFF006		;ATTENDANT 200 IEME LIGNE RASTER
BNE.S WAIT			;SINON RETOURNE A WAIT

CMP.B #$5F,$BFEC01		;TESTE TOUCHE F1       
BNE L2				;SINON VA TESTER TOUCHE SUIVANTE
LEA PICLOAD,A2			;POINTE A2 SUR IMAGE LOADING
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
MOVE.L #DEMO01,FILE		;MET NOM DU FICHIER DANS FILE
JSR LOADING			;VA A ROUTINE DE LOADING
LEA PICDECRUN,A2		;POINTE A2 SUR IMAGE DECRUNCH
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
JSR EXECUTE			;VA A ROUTINE DE DECRUNCH
				;ET EXECUTE DEMO                 
				
L2:				
CMP.B #$5D,$BFEC01  		;TESTE TOUCHE F2
BNE L3				;SINON VA TESTER TOUCHE SUIVANTE
LEA PICLOAD,A2			;POINTE A2 SUR IMAGE LOADING
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
MOVE.L #DEMO02,FILE		;MET NOM DU FICHIER DANS FILE
JSR LOADING			;VA A ROUTINE DE LOADING
LEA PICDECRUN,A2		;POINTE A2 SUR IMAGE DECRUNCH
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
JSR EXECUTE			;VA A ROUTINE DE DECRUNCH
				;ET EXECUTE DEMO                 
L3:				
CMP.B #$5B,$BFEC01		;TESTE TOUCHE F3
BNE L4				;SINON VA TESTER TOUCHE SUIVANTE
LEA PICLOAD,A2			;POINTE A2 SUR IMAGE LOADING
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
MOVE.L #DEMO03,FILE		;MET NOM DU FICHIER DANS FILE
JSR LOADING			;VA A ROUTINE DE LOADING
LEA PICDECRUN,A2		;POINTE A2 SUR IMAGE DECRUNCH
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
JSR EXECUTE			;VA A ROUTINE DE DECRUNCH
				;ET EXECUTE DEMO                 
L4:				
CMP.B #$59,$BFEC01		;TESTE TOUCHE F4
BNE L5				;SINON VA TESTER TOUCHE SUIVANTE
LEA PICLOAD,A2			;POINTE A2 SUR IMAGE LOADING
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
MOVE.L #DEMO04,FILE		;MET NOM DU FICHIER DANS FILE
JSR LOADING			;VA A ROUTINE DE LOADING
LEA PICDECRUN,A2		;POINTE A2 SUR IMAGE DECRUNCH
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
JSR EXECUTE			;VA A ROUTINE DE DECRUNCH
				;ET EXECUTE DEMO                 
L5:				
CMP.B #$57,$BFEC01		;TESTE TOUCHE F5
BNE L6				;SINON VA TESTER TOUCHE SUIVANTE
LEA PICLOAD,A2			;POINTE A2 SUR IMAGE LOADING
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
MOVE.L #DEMO05,FILE		;MET NOM DU FICHIER DANS FILE
JSR LOADING			;VA A ROUTINE DE LOADING
LEA PICDECRUN,A2		;POINTE A2 SUR IMAGE DECRUNCH
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
JSR EXECUTE			;VA A ROUTINE DE DECRUNCH
				;ET EXECUTE DEMO                 
L6:				
CMP.B #$55,$BFEC01		;TESTE TOUCHE F6
BNE L7				;SINON VA TESTER TOUCHE SUIVANTE
LEA PICLOAD,A2			;POINTE A2 SUR IMAGE LOADING
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
MOVE.L #DEMO06,FILE		;MET NOM DU FICHIER DANS FILE
JSR LOADING			;VA A ROUTINE DE LOADING
LEA PICDECRUN,A2		;POINTE A2 SUR IMAGE DECRUNCH
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
JSR EXECUTE			;VA A ROUTINE DE DECRUNCH
				;ET EXECUTE DEMO                 
L7:				
CMP.B #$53,$BFEC01		;TESTE TOUCHE F7
BNE L8				;SINON VA TESTER TOUCHE SUIVANTE
LEA PICLOAD,A2			;POINTE A2 SUR IMAGE LOADING
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
MOVE.L #DEMO07,FILE		;MET NOM DU FICHIER DANS FILE
JSR LOADING			;VA A ROUTINE DE LOADING
LEA PICDECRUN,A2		;POINTE A2 SUR IMAGE DECRUNCH
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
JSR EXECUTE			;VA A ROUTINE DE DECRUNCH
				;ET EXECUTE DEMO                 
L8:				
CMP.B #$51,$BFEC01		;TESTE TOUCHE F8
BNE L9				;SINON VA TESTER TOUCHE SUIVANTE
LEA PICLOAD,A2			;POINTE A2 SUR IMAGE LOADING
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
MOVE.L #DEMO08,FILE		;MET NOM DU FICHIER DANS FILE
JSR LOADING			;VA A ROUTINE DE LOADING
LEA PICDECRUN,A2		;POINTE A2 SUR IMAGE DECRUNCH
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
JSR EXECUTE			;VA A ROUTINE DE DECRUNCH
				;ET EXECUTE DEMO                 
L9:				
CMP.B #$4F,$BFEC01		;TESTE TOUCHE F9
BNE L10				;SINON VA TESTER TOUCHE SUIVANTE
LEA PICLOAD,A2			;POINTE A2 SUR IMAGE LOADING
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
MOVE.L #DEMO09,FILE		;MET NOM DU FICHIER DANS FILE
JSR LOADING			;VA A ROUTINE DE LOADING
LEA PICDECRUN,A2		;POINTE A2 SUR IMAGE DECRUNCH
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
JSR EXECUTE			;VA A ROUTINE DE DECRUNCH
				;ET EXECUTE DEMO                 
L10:				
CMP.B #$4D,$BFEC01		;TESTE TOUCHE F10
BNE L11				;SINON VA TESTER TOUCHE SUIVANTE
LEA PICLOAD,A2			;POINTE A2 SUR IMAGE LOADING
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
MOVE.L #DEMO10,FILE		;MET NOM DU FICHIER DANS FILE
JSR LOADING			;VA A ROUTINE DE LOADING
LEA PICDECRUN,A2		;POINTE A2 SUR IMAGE DECRUNCH
JSR PICTRACK			;VA A ROUTINE D'AFFICHAGE
JSR EXECUTE			;VA A ROUTINE DE DECRUNCH
L11:				;ET EXECUTE DEMO                 
				
				;CECI EST A SUPPRIMER DANS LA VERSION FINALE
;BTST	#6,$BFE001		;ATTENDANT PRESSION SUR BOUTON GAUCHE SOURIS
;BNE.L	WAIT			;SINON RETOURNE A WAIT
 				;SI OUI  FIN

JMP WAIT			;POUR VERSION FINALE = PAS DE SORTIE DU LOADER


END: 				;FIN:	
BSR.L STOP_MUSIQUE		;ARRET DE LA MUSIQUE
BSR.s STOPIRQ3        		;SAUTE SOUS PROGRAMME: STOPPE INTERRUPTION
BSR.L CLRCOPPER       		;SAUTE SOUS PROGRAMME: RESTAURE ANCIENNE LISTE COPPER
BSR.L CLOSELIB        		;SAUTE SOUS PROGRAMME: FERME LIBRAIRIES 
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR PERMIT(A6)      		;AUTORISE MULTITACHE
                      
RTS
;========================
NEWIRQ3:			;MET EN PLACE NOTRE ROUTINE 
MOVE.L	EXECBASE,A6		;D'INTERRUPTION
lea	irqstr,a1
move.l	#5,d0
jsr	addintserver(a6)
move.l	d0,irq
beq.s	irqerror
rts
irqerror:
rts
;==========================
STOPIRQ3:			;RESTAURE ANCIENNE ROUTINE
movem.l	a0-a6/d0-d7,-(sp)	;D'INTERRUPTION
	tst.l	irq
	beq.s	irqoff1
	move.l	execbase,a6
	lea	irqstr,a1
	move.l	#32,d0
	jsr	remintserver(a6)
irqoff1:movem.l	(sp)+,a0-a6/d0-d7
	rts
irqstr:
	dc.l	0,0
	dc.b	2,-127
	dc.l	0,irqdat,interrupt
irqdat:	dc.l	0,0,0,0
irq:	dc.l	0
;============================
interrupt:			;NOTRE ROUTINE D'INTERRUPTION	
movem.l	a0-a6/d0-d7,-(sp)

BSR.L STARMOV
BSR.L SCROLLING			;VA A LA ROUTINE DE SCROLLING
BSR.L PLAY_MUSIQUE		;VA A LA ROUTINE POUR JOUER LA MUSIQUE

movem.l	(sp)+,a0-a6/d0-d7
rts
;============================
OPENLIB:  			;OUVERTURE DE LA LIBRAIRIE GRAPHIQUE
move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
lea gfxname,a1			;MET NOM DE LA LIBRAIRIE DANS A1
move.l #$0,d0           	;MET 0 DANS D0
jsr openlibrary(a6)		;OUVRE LIBRAIRIE
tst d0				;TESTE D0
beq.L error			;SI = A 0   VA A ERROR = SORTIE
move.l d0,gfxbase       	;SI NON, MET ADRESSE D0 DANS GFXBASE
add.l #$32,d0			;AJOUTE $32 A CETTE ADRESSE
move.l d0,coppertr      	;MET D0=ADRESSE ACTUELLE LISTE COPPER
rts				;DANS COPPERTR
even
gfxname: dc.b 'graphics.library',0 	;NOM DE LA LIBRAIRIE
even
gfxbase: dc.l 0				;POINTEUR POUR LA GRAPHICS LIBRARY
coppertr: dc.l 0			;POINTEUR POUR ADRESSE LISTE COPPER
even
;====================
CLOSELIB: 			;FERMETURE LIBRAIRIE
move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
move.l gfxbase,a1		;MET NOM DE LA LIBRAIRIE DANS A1
jsr closelibrary(a6)		;FERME LIBRAIRIE
rts
;====================
ERROR:				;SI ERREUR
illegal				;SORTIE
rts
;====================
SETCOPPER:			;MET EN PLACE NOTRE LISTE COPPER
move.l coppertr,a0		;MET ADRESSE ACTUEL COPPER DANS A0
move.l (a0),oldcopper		;MET CONTENU DANS OLDCOPPER
move.l #newcopper,(a0)		;MET NOTRE LISTE COPPER DANS A0
move.w #$81c0,$dff096		;ACTIVE LISTE COPPER
rts		
oldcopper: dc.l 0
;====================
CLRCOPPER:			;RESTAURE ANCIENNE LISTE COPPER
move.l coppertr,a0		;MET ANCIENNE ADRESSE DANS A0
move.l oldcopper,(a0)		;MET CONTENU DANS A0
move.w #$80a0,$dff096		;REACTIVE ANCIENNE COPPER
rts
;====================
PICTRACK:

	
BSR.L WAIT_BLITTER		;ON ATTEND QUE LE BLITTER EST FINI SON 
				;PRECEDENT TRAVAIL

LEA IMAGE+[150*40*3],A1		;ON POINTE A1 SUR IMAGE 

MOVE.L A2,BLTAPTH		;MET ADRESSE DE A0 DANS SOURCE BLITTER A
MOVE.L A1,BLTDPTH		;MET ADRESSE DE A1 DANS DESTINATION BLITTER D
MOVE.W #0,BLTAMOD  		;MET 0 DANS MODULO SOURCE A
MOVE.W #0,BLTDMOD		;MET 0 DANS MODULO DESTINATION D
MOVE.L #$FFFFFFFF,BLTAFWM	;MASQUE DU 1ER ET DU DERNIER MOT
MOVE.L #$09F00000,BLTCON0    	;MET MIMTERN ET DECALAGE DANS BLTCON0
				;$9 -> POUR 1 SOURCE BLITTER
				;$F0 -> MINTERM POUR COPIE DIRECTE
				;$0000 -> MIS A 0 CAR SOURCE B INITULISEE	

MOVE.W #[45*64*3]+20,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
				;TAILLE = [HAUTEUR * 64]+[LARGEUR/2]
RTS
;====================
EXECUTE:
MOVE.L	#DESTINATION_A,A0	; ADRESSE DE CHARGEMENT
MOVE.L	#DESTINATION_B,A5		; ADRESSE DE SAUT POUR DEMO
MOVE.L	#$70004E75,$CE(A0)	; MOVEQ #$00,D0 /  RTS
MOVE.L  #$00DFF1C0,$C0(A0)	; PAS DE FLASH ($01C0 REGISTRE INUTILISE)
JSR	(A0)			; EFFECTUE LE DECRUNCH
MOVE.L	A5,-(SP)		; SAUVE ADRESSE SAUT DANS PILE
JSR	END			; FIN DU LOADER
MOVE.L	(SP)+,A5    		; REPLACE ADRESSE SAUT DANS A5
MOVE.L #RUN,A0			; MET ADRESSE DE RETOUR DANS A0
MOVE.L A0,-(SP)			; SAUVE ADRESSE RETOUR DANS PILE
JSR	(A5)			; EXECUTE DEMO
MOVE.L (SP)+,A0			; REPLACE ADRESSE RETOUR DANS A0
JMP  (A0)			; EFFECTUE RETOUR
RTS
;====================
EVEN
FileHD:		DC.L 0
DosBase:	DC.L 0
DosName:	DC.B 'dos.library',0

DEMO01: 	DC.B 'DEMO01',0
DEMO02: 	DC.B 'DEMO02',0 	
DEMO03: 	DC.B 'DEMO03',0 	
DEMO04: 	DC.B 'DEMO04',0 	
DEMO05: 	DC.B 'DEMO05',0 	
DEMO06: 	DC.B 'DEMO06',0 	
DEMO07: 	DC.B 'DEMO07',0 	
DEMO08: 	DC.B 'DEMO08',0 	
DEMO09: 	DC.B 'DEMO09',0 	
DEMO10: 	DC.B 'DEMO10',0 	


EVEN
File: DC.L 0
EVEN
;====================
LOADING:			;ROUTINE DE CHARGEMENT DE FICHIER
move.l ExecBase,a6		;OUVRE LIBRAIRIE DOS
lea DosName,a1
jsr OpenLibrary(a6)
move.l d0,DosBase
move.l d0,a6

move.l #1005,d2			;OUVRE FICHIER
move.l File,d1
jsr Open(a6)
move.l d0,FileHD

move.l d0,d1			;LECTURE DU FICHIER
move.l #DESTINATION_A,d2	;ADRESSE DE LOAD
move.l #$fffff,d3		;LONGUEUR   $FFFFF = FICHIER COMPLET
JSR Read(a6)
	
move.l FileHD,d1		;FERMETURE DU FICHIER
jsr Close(a6)

move.l ExecBase,a6		;FERMETURE LIBRAIRIE DOS
move.l DosBase,a1
jsr CloseLibrary(a6)

RTS
;====================
WAIT_BLITTER:			;ROUTINE POUR ATTENDRE QUE LE BLITTER
BTST #14,DMACONR		;EST FINI SON PRECEDENT TRAVAIL
BNE.S WAIT_BLITTER
RTS
;===================
SCROLLING:			;ROUTINE DU SCROLLING
BSR.L SEARCH_CHAR		;AFFICHE UN NOUVEAU CARACTERE
BSR.L SCROLLTEXT		;SCROLLE LE FOND DU SCROLL
RTS
;===================	
SCROLLTEXT:			
LEA SCROLL,A0 			;ON POINTE A0 SUR LE FOND DU SCROLL
	
BSR.L WAIT_BLITTER		;ON ATTEND QUE LE BLITTER EST FINI SON 
				;PRECEDENT TRAVAIL

LEA SCROLL-2,A1			;ON POINTE A1 SUR 16 PIXELS AVANT 
				;LE FOND DU SCROLL. 2 = 16 PIXELS

MOVE.L A0,BLTAPTH		;MET ADRESSE DE A0 DANS SOURCE BLITTER A
MOVE.L A1,BLTDPTH		;MET ADRESSE DE A1 DANS DESTINATION BLITTER D
MOVE.W #0,BLTAMOD  		;MET 0 DANS MODULO SOURCE A
MOVE.W #0,BLTDMOD		;MET 0 DANS MODULO DESTINATION D
MOVE.L #$FFFFFFFF,BLTAFWM	;MASQUE DU 1ER ET DU DERNIER MOT
MOVE.L #$C9F00000,BLTCON0    	;MET MIMTERN ET DECALAGE DANS BLTCON0
				;$C = $F - $4 = 16 - 4 = 12
				;4 PIXELS DE DECALAGE VERS LA GAUCHE

				;$9 -> POUR 1 SOURCE BLITTER
				;$F0 -> MINTERM POUR COPIE DIRECTE
				;$0000 -> MIS A 0 CAR SOURCE B INITULISE	

MOVE.W #[35*64*3]+25,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
				;TAILLE = [HAUTEUR * 64]+[LARGEUR/2]
RTS
;============
SEARCH_CHAR:
ADD.W #1,COMPT			;AJOUTE 1 AU COMPTEUR
CMP.W #8,COMPT           	;COMPARE A 8 CAR 8 * 4 PIXELS DE DECALAGE
				;EGALE A 32 SOIT LA LARGEUR D'UNe LETTRE
BNE.L SEARCHAR3			;SI PAS EGAL A 8 ON SORT
MOVE.W #0,COMPT			;SI OUI ON REMET COMPTEUR A 0
				;ET ON CONTINU

MOVE.L PTEXT,A0          	;MET POINTEUR TEXTE DANS A0
CLR.L D0			;ON EFFACE CONTENU DE D0
MOVE.B (A0),D0			;MET LE CONTENU DU POINTEUR TEXTE DANS D0
LEA COMPTEUR_CHAR,A1		;EN POINTE A1 SUR LA TABLE DES LETTRES
CLR.L D1			;ON EFFACE CONTENU DE D1
MOVE.B #-1,D1			;ON MET -1 DANS D1

SEARCHAR1:

ADD.B #1,D1     		;ON AJOUTE 1 A D1         
CMP.B (A1)+,D0			;ON COMPARE LES LETTRES DE LA TABLE
				;AVEC CELLE CONTENU DANS D0
BNE SEARCHAR1			;SI PAS LA MEME ON RECOMMENCE AVEC LA
				;LETTRE SIUVANTE DANS LA TABLE
				;SI C'EST LA MEME ON CONTINU
MULU #4,D1              	;ON MULTIPLIE D1 PAR 4
LEA TABLE_CHAR,A0       	;ON POINTE A0 SUR LE DEBUT DE LA TABLE
				;D'ADRESSE DES IMAGES DES LETTRES
MOVE.L (A0,D1),A2       	;ET ON MET L'ADRESSE DE LA LETTRE DANS A2

LEA SCROLL,A3			;ON POINTE A3 SUR LA POSITION SCROLL+46
ADD.L #46,A3        		;SOIT A 46*8 = 368 PIXELS A DROITE DU 
				;COIN SUPERIEUR DROIT DU FOND DE SCROLL
				;SOIT DANS LA PARTIE INVISIBLE DU SCROLL	

BSR.L WAIT_BLITTER        	;ON ATTENDS LE BLITTER	
MOVE.L A2,BLTAPTH       	;ON MET ADRESSE DE A2 DANS SOURCE BLITTER A
MOVE.L A3,BLTDPTH       	;ON MET ADRESSE DE A3 DANS DESTINATION BLITTER D

MOVE.W #40-4,BLTAMOD  		;ON MET 40-4 DANS MODULO SOURCE A
				;CAR NOTRE LETTRE FAIT 32 PIXELS DE LARGE SOIT
				;4 MOTS (4*8=32) ET L'IMAGE QUI LA CONTIENT
				;FAIT 320 PIXELS DE LARGE SOIT 40 MOTS
	
MOVE.W #50-4,BLTDMOD   	        ;ON MET 50-4 DANS MODULO DESTINATION D
				;CAR LE FOND DE SCROLL FAIT 400 PIXELS DE LARGE
				;SOIT 50 MOTS

MOVE.L #$09F00000,BLTCON0	;$0 -> PAS DE DECALAGE DE LA SOURCE A
				;$9 -> POUR 1 SOURCE BLITTER A
				;$F0 -> MINTERM POUR COPIE DIRECTE

MOVE.W #[35*3*64]+2,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
				;TAILLE = [HAUTEUR * 64]+[LARGEUR/2]

ADD.L #1,PTEXT          	;ON AJOUTE 1 AU POINTEUR DE TEXTE
MOVE.L PTEXT,A0			;ON MET POINTEUR DE TEXTE DANS A0
TST.B (A0)              	;SI PAS EGAL A 0
BNE SEARCHAR3			;ON VA A SEARCHAR3
MOVE.L #TEXT,PTEXT		;SINON ON REMET POINTEUR DE TEXTE AU DEBUT
				;DU TEXTE A SCROLLER

SEARCHAR3:
RTS

EVEN
COMPT: DC.W 0			;COMPTEUR 
PTEXT: DC.L 0			;POINTEUR DE TEXTE
;=================================================================
COMPTEUR_CHAR: DC.B ' ABCDEFGHI'	;TABLE DES CARACTERES
	       DC.B 'JKLMNOPQRS'	;TELS QU'ILS SONT DISPOSES
	       DC.B 'TUVWXYZ.,:'	;DANS NOTRE IMAGE	
	       DC.B '()@#!?-*^/'
	       DC.B '0123456789%'
         
EVEN
FONT1=FONT		;ADRESSES DES LETTRES PAR LIGNES
FONT2=FONT+[3*35*40] 
FONT3=FONT+[6*35*40]
FONT4=FONT+[9*35*40]
FONT5=FONT+[12*35*40]
EVEN 
TABLE_CHAR: 		;ADRESSES DES LETTRES

DC.L FONT1,FONT1+4,FONT1+8,FONT1+12,FONT1+16,FONT1+20
DC.L FONT1+24,FONT1+28,FONT1+32,FONT1+36
DC.L FONT2,FONT2+4,FONT2+8,FONT2+12,FONT2+16,FONT2+20
DC.L FONT2+24,FONT2+28,FONT2+32,FONT2+36
DC.L FONT3,FONT3+4,FONT3+8,FONT3+12,FONT3+16,FONT3+20
DC.L FONT3+24,FONT3+28,FONT3+32,FONT3+36
DC.L FONT4,FONT4+4,FONT4+8,FONT4+12,FONT4+16,FONT4+20
DC.L FONT4+24,FONT4+28,FONT4+32,FONT4+36
DC.L FONT5,FONT5+4,FONT5+8,FONT5+12,FONT5+16,FONT5+20
DC.L FONT5+24,FONT5+28,FONT5+32,FONT5+36
EVEN

EVEN		;TEXTE A SCROLLER

TEXT: DC.B '             '
DC.B 'VOICI UN EXEMPLE DE LOADER DE MEGADEMO UTILISANT UN CHARGEMENT '
DC.B 'DE FICHIERS SOUS INTERRUPTION SOUS AMIGA DOS             '
DC.B 'APPUYEZ SUR LES TOUCHES F1 A F10 POUR CHARGER LES DIFFERENTES DEMOS'
dc.b '    ',0
fin:
even
;====================
INITSPRITES:
					
	LEA 	SPRITE0,A0	;POINTE A0 SUR STRUCTURE SPRITE 0
	LEA	SPRITE1,A1	;POINTE A1 SUR STRUCTURE SPRITE 1
	MOVE.L 	#$36004600,D0	;$36 = SPRITE DEBUTE EN LIGNE $36
				;$46 = FIN DU SPRITE EN LIGNE $46	
	MOVEQ 	#11,D1		;11 SPRITES DANS LE SENS VERTICAL	
SPR01LP:	SWAP	D0	;POSITION X ALEATOIRE
	MOVE.B 	$DFF007,D2
	EOR.B 	D2,D0
	SWAP 	D0		;MOTS DE CONTROLE OK

	MOVE.L D0,(A0)+		;MET LES 2 MOTS DE CONTROLE DANS STRUCTURE SPRITE 0
	ADD.L #$80,D0		;AJOUTE $80 AU SPRITE 1 = SPRITE 16 COULEURS
				;VOIR COURS ASM 3
	MOVE.L D0,(A1)+		;MET MOTS DE CONTROLE DANS STUCTURE SPRITE 1
	MOVE.L #$000003C0,(A0)+	;PREMIER MOT DE DONNEES = DESSIN DU SPRITE 0
	MOVE.L #$03800E50,(A0)+
	MOVE.L #$0E4032C8,(A0)+
	MOVE.L #$17487EE4,(A0)+
	MOVE.L #$1E6464C2,(A0)+
	MOVE.L #$7F20CB24,(A0)+
	MOVE.L #$3B5266E1,(A0)+
	MOVE.L #$0A421211,(A0)+
	MOVE.L #$164C30A0,(A0)+
	MOVE.L #$5D5679D1,(A0)+
	MOVE.L #$3F748FB4,(A0)+
	MOVE.L #$7CB82D5A,(A0)+
	MOVE.L #$237C4D00,(A0)+
	MOVE.L #$0CD01008,(A0)+
	MOVE.L #$0B601098,(A0)+
	MOVE.L #$02000460,(A0)+	;16 LIGNES DE HAUT

	MOVE.L #$03C003C0,(A1)+	;PREMIER MOT DE DONNEES DU SPRITE 1
	MOVE.L #$0DD00FF0,(A1)+
	MOVE.L #$3F083DF8,(A1)+
	MOVE.L #$632C7DFC,(A1)+
	MOVE.L #$652E7FFE,(A1)+
	MOVE.L #$A8CCFFFE,(A1)+
	MOVE.L #$019FFFFF,(A1)+
	MOVE.L #$7DFFFFFF,(A1)+
	MOVE.L #$C9ECFFFF,(A1)+
	MOVE.L #$96AFFFFF,(A1)+
	MOVE.L #$F0CAFFFE,(A1)+
	MOVE.L #$53867FFE,(A1)+
	MOVE.L #$7EFC7FFC,(A1)+
	MOVE.L #$1FF83FFC,(A1)+
	MOVE.L #$1FF81FF8,(A1)+
	MOVE.L #$066007E0,(A1)+	;16 LIGNES DE HAUT

	SUB.L #$80,D0		;SOUSTRAIT $80 (SPRITE 16 COULEURS)	
	ADD.L #$11001100,D0	;AJOUTE HAUTEUR + 1 AUX 2 MOTS DE CONTROLES
	DBRA D1,SPR01LP		;ET RECOMMENCE

	MOVE.L #SPRITE0,D0	;PLACE ADRESSE STRUCTURE SPRITE 0
	MOVE.W D0,SP0L		;DANS POINTEURS SPRITES
	SWAP D0			;DE LA COPPER LIST               
	MOVE.W D0,SP0H

	MOVE.L #SPRITE1,D0	;PLACE ADRESSE STRUCTURE SPRITE 0
	MOVE.W D0,SP1L		;DANS POINTEURS SPRITES
	SWAP D0			;DE LA COPPER LIST               
	MOVE.W D0,SP1H

;--------------------------
	LEA 	SPRITE2,A0	;IDEM POUR LES PAIRES DE SPRITES SUIVANTES
	LEA	SPRITE3,A1	;SEULS LE NOMBRE DE SPRITES,LA HAUTEUR	
	MOVE.L 	#$36003E00,D0	;ET LES DONNEES CHANGENT	
	MOVEQ 	#21,D1			
SPR23LP:	SWAP	D0
	MOVE.B 	$DFF007,D2
	EOR.B 	D2,D0
	SWAP 	D0

	MOVE.L D0,(A0)+
	ADD.L #$80,D0
	MOVE.L D0,(A1)+
	MOVE.L #$18003400,(A0)+	;1
	MOVE.L #$34009D00,(A0)+
	MOVE.L #$AB007800,(A0)+
	MOVE.L #$A200BC80,(A0)+
	MOVE.L #$55006C00,(A0)+
	MOVE.L #$95807A00,(A0)+
	MOVE.L #$EE002600,(A0)+
	MOVE.L #$08002000,(A0)+
	MOVE.L #$2C003C00,(A1)+	;1
	MOVE.L #$D300EF00,(A1)+
	MOVE.L #$A700FF00,(A1)+
	MOVE.L #$5380FF80,(A1)+
	MOVE.L #$CB00FF80,(A1)+
	MOVE.L #$CC80FF80,(A1)+
	MOVE.L #$D900FF00,(A1)+
	MOVE.L #$3C00FF00,(A1)+

	SUB.L #$80,D0
	ADD.L #$09000900,D0	
	DBRA D1,SPR23LP	

	MOVE.L #SPRITE2,D0
	MOVE.W D0,SP2L
	SWAP D0
	MOVE.W D0,SP2H

	MOVE.L #SPRITE3,D0
	MOVE.W D0,SP3L
	SWAP D0
	MOVE.W D0,SP3H
	
;--------------------------
	LEA 	SPRITE4,A0
	LEA	SPRITE5,A1	
	MOVE.L 	#$36003A00,D0		
	MOVEQ 	#36,D1			
SPR45LP:	SWAP	D0
	MOVE.B 	$DFF007,D2
	EOR.B 	D2,D0
	SWAP 	D0

	MOVE.L D0,(A0)+
	ADD.L #$80,D0
	MOVE.L D0,(A1)+
	MOVE.L #$40006000,(A0)+	;1
	MOVE.L #$1000C000,(A0)+
	MOVE.L #$F0002000,(A0)+
	MOVE.L #$20002000,(A0)+
	MOVE.L #$20006000,(A1)+	;1
	MOVE.L #$3000F000,(A1)+
	MOVE.L #$1000F000,(A1)+
	MOVE.L #$40006000,(A1)+

	SUB.L #$80,D0
	ADD.L #$05000500,D0	
	DBRA D1,SPR45LP	

	MOVE.L #SPRITE4,D0
	MOVE.W D0,SP4L
	SWAP D0
	MOVE.W D0,SP4H

	MOVE.L #SPRITE5,D0
	MOVE.W D0,SP5L
	SWAP D0
	MOVE.W D0,SP5H
	
;-------------------------
	LEA 	SPRITE6,A0
	LEA	SPRITE7,A1	
	MOVE.L 	#$36003800,D0		
	MOVEQ 	#66,D1			
SPR67LP:	SWAP	D0
	MOVE.B 	$DFF007,D2
	EOR.B 	D2,D0
	SWAP 	D0

	MOVE.L D0,(A0)+
	ADD.L #$80,D0
	MOVE.L D0,(A1)+
	MOVE.L #$40006000,(A0)+	;1
	MOVE.L #$1000C000,(A0)+
	MOVE.L #$20006000,(A1)+	;1
	MOVE.L #$3000F000,(A1)+

	SUB.L #$80,D0
	ADD.L #$03000300,D0	
	DBRA D1,SPR67LP	

	MOVE.L #SPRITE6,D0
	MOVE.W D0,SP6L
	SWAP D0
	MOVE.W D0,SP6H

	MOVE.L #SPRITE7,D0
	MOVE.W D0,SP7L
	SWAP D0
	MOVE.W D0,SP7H
	

RTS

;====================
STARMOV:	

MOVE01:
LEA SPRITE0,A0		;DEPLACE LES SPRITES 0 ET 1 
LEA SPRITE1,A1		;A UNE VITESSE DE 2*4 PIXELS
MOVEQ #11,D0		;VOIR COURS ASM 3
PLUS01:
SUBQ.B #$04,1(A1)
SUBQ.B #$04,1(A0)
CMP.B #$10,1(A0)
Bhi.S OKPLUS01
MOVE.B #$F0,1(A0)
MOVE.B #$F0,1(A1)
OKPLUS01:
ADD.W #68,A0
ADD.W #68,A1
DBF D0,PLUS01

MOVE23:
LEA SPRITE2,A0
LEA SPRITE3,A1
MOVEQ #21,D0
PLUS23:
SUBQ.B #$03,1(A1)	;VITESSE 2*3 PIXELS
SUBQ.B #$03,1(A0)
CMP.B #$10,1(A0)
Bhi.S OKPLUS23
MOVE.B #$F0,1(A0)
MOVE.B #$F0,1(A1)
OKPLUS23:
ADD.W #36,A0
ADD.W #36,A1
DBF D0,PLUS23

MOVE45:
LEA SPRITE4,A0
LEA SPRITE5,A1
MOVEQ #36,D0
PLUS45:
SUBQ.B #$02,1(A1)	;VITESSE 2*2 PIXELS
SUBQ.B #$02,1(A0)
CMP.B #$10,1(A0)
Bhi.S OKPLUS45
MOVE.B #$F0,1(A0)
MOVE.B #$F0,1(A1)
OKPLUS45:
ADD.W #20,A0
ADD.W #20,A1
DBF D0,PLUS45

MOVE67:
LEA SPRITE6,A0
LEA SPRITE7,A1
MOVEQ #66,D0
PLUS67:
SUBQ.B #$01,1(A1)	;VITESSE 2*1 PIXELS
SUBQ.B #$01,1(A0)
CMP.B #$10,1(A0)
Bhi.S OKPLUS67
MOVE.B #$F0,1(A0)
MOVE.B #$F0,1(A1)
OKPLUS67:
ADD.W #12,A0
ADD.W #12,A1
DBF D0,PLUS67

RTS
;====================
EVEN
INIT_MUSIQUE:

mt_init:lea	mt_data,a0
	lea	$3b8(a0),a1
	moveq	#$7f,d0
	moveq	#0,d2
	moveq	#0,d1
mt_lop2:move.b	(a1)+,d1
	cmp.b	d2,d1
	ble.s	mt_lop
	move.l	d1,d2
mt_lop:	dbf	d0,mt_lop2
	addq.b	#1,d2

	asl.l	#8,d2
	asl.l	#2,d2
	lea	4(a1,d2.l),a2
	lea	mt_samplestarts(pc),a1
	add.w	#42,a0
	moveq	#$1e,d0
mt_lop3:clr.l	(a2)
	move.l	a2,(a1)+
	moveq	#0,d1
	move.w	(a0),d1
	clr.b	2(a0)
	asl.l	#1,d1
	add.l	d1,a2
	add.l	#30,a0
	dbf	d0,mt_lop3

	or.b	#2,$bfe001
	move.b	#6,mt_speed
	moveq	#0,d0
	lea	$dff000,a0
	move.w	d0,$a8(a0)
	move.w	d0,$b8(a0)
	move.w	d0,$c8(a0)
	move.w	d0,$d8(a0)
	clr.b	mt_songpos
	clr.b	mt_counter
	clr.w	mt_pattpos
	rts

STOP_MUSIQUE:

mt_end:	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	move.w	#$f,$dff096
	rts

PLAY_MUSIQUE:

mt_music:
	lea	mt_data,a0
	addq.b	#1,mt_counter
	move.b	mt_counter(pc),d0
	cmp.b	mt_speed(pc),d0
	blt	mt_nonew
	clr.b	mt_counter

	lea	mt_data,a0
	lea	$c(a0),a3
	lea	$3b8(a0),a2
	lea	$43c(a0),a0

	moveq	#0,d0
	moveq	#0,d1
	move.b	mt_songpos(pc),d0
	move.b	(a2,d0.w),d1
	lsl.w	#8,d1
	lsl.w	#2,d1
	add.w	mt_pattpos(pc),d1
	clr.w	mt_dmacon

	lea	$dff0a0,a5
	lea	mt_voice1(pc),a4
	bsr	mt_playvoice
	addq.l	#4,d1
	lea	$dff0b0,a5
	lea	mt_voice2(pc),a4
	bsr	mt_playvoice
	addq.l	#4,d1
	lea	$dff0c0,a5
	lea	mt_voice3(pc),a4
	bsr	mt_playvoice
	addq.l	#4,d1
	lea	$dff0d0,a5
	lea	mt_voice4(pc),a4
	bsr	mt_playvoice

	bsr	mt_wait
	move.w	mt_dmacon(pc),d0
	or.w	#$8000,d0
	move.w	d0,$dff096
	bsr	mt_wait
mt_nodma:
	lea	$dff000,a3
	lea	mt_voice1(pc),a4
	move.l	$a(a4),$a0(a3)
	move.w	$e(a4),$a4(a3)
	tst.w	30(a4)
	bne.s	mt_nov1
	move.w	$12(a4),$a8(a3)
mt_nov1:lea	mt_voice2(pc),a4
	move.l	$a(a4),$b0(a3)
	move.w	$e(a4),$b4(a3)
	tst.w	30(a4)
	bne.s	mt_nov2
	move.w	$12(a4),$b8(a3)
mt_nov2:lea	mt_voice3(pc),a4
	move.l	$a(a4),$c0(a3)
	move.w	$e(a4),$c4(a3)
	tst.w	30(a4)
	bne.s	mt_nov3
	move.w	$12(a4),$c8(a3)
mt_nov3:lea	mt_voice4(pc),a4
	move.l	$a(a4),$d0(a3)
	tst.w	30(a4)
	bne.s	mt_nov4
	move.w	$e(a4),$d4(a3)
	move.w	$12(a4),$d8(a3)

mt_nov4:add.w	#$10,mt_pattpos
	cmp.w	#$400,mt_pattpos
	bne.s	mt_exit
mt_next:clr.w	mt_pattpos
	clr.b	mt_break
	lea	mt_data,a0
	addq.b	#1,mt_songpos
	and.b	#$7f,mt_songpos
	move.b	$3b6(a0),d0
	cmp.b	mt_songpos(pc),d0
	bne.s	mt_exit
	move.b	$3b7(a0),mt_songpos
mt_exit:tst.b	mt_break
	bne.s	mt_next
	bra	mt_amhandler

mt_wait:moveq	#4,d3		
mt_wai2:move.b	$dff006,d2	
mt_wai3:cmp.b	$dff006,d2	
	beq.s	mt_wai3
	dbf	d3,mt_wai2	
	moveq	#8,d2
mt_wai4:dbf	d2,mt_wai4

mt_nonew:
	lea	mt_voice1(pc),a4
	lea	$dff0a0,a5
	bsr	mt_com
	lea	mt_voice2(pc),a4
	lea	$dff0b0,a5
	bsr	mt_com
	lea	mt_voice3(pc),a4
	lea	$dff0c0,a5
	bsr	mt_com
	lea	mt_voice4(pc),a4
	lea	$dff0d0,a5
	bsr	mt_com
	bra.s	mt_exit

mt_mulu:
	dc.w	0,$1e,$3c,$5a,$78,$96,$b4,$d2,$f0,$10e,$12c,$14a
	dc.w	$168,$186,$1a4,$1c2,$1e0,$1fe,$21c,$23a,$258,$276
	dc.w	$294,$2b2,$2d0,$2ee,$30c,$32a,$348,$366,$384,$3a2

mt_playvoice:
	move.l	(a0,d1.l),(a4)
	moveq	#0,d2
	move.b	2(a4),d2
	lsr.b	#4,d2
	move.b	(a4),d0
	and.b	#$f0,d0
	or.b	d0,d2
	beq	mt_oldinstr

	lea	mt_samplestarts-4(pc),a1
	move.w	d2,34(a4)
	move.w	d2,d0
	mulu	#120,d0
	add.l	#mt_data2+24,d0
	move.l	a0,-(sp)
	move.l	d0,a0
	clr.w	30(a4)
	cmp.w	#"AM",(a0)
	bne.s	mt_noa9
	move.w	6(a0),d0
	lsr.w	#2,d0
	st	30(a4)
mt_noa9:move.l	(sp)+,a0

	asl.w	#2,d2
	move.l	(a1,d2.l),4(a4)
	lsr.w	#2,d2
	mulu	#30,d2
	move.w	(a3,d2.w),8(a4)
	tst.w	30(a4)
	beq.s	mt_noa8
	move.w	d0,$12(a4)
	bra.s	mt_noa7
mt_noa8:move.w	2(a3,d2.w),$12(a4)
mt_noa7:moveq	#0,d3
	move.w	4(a3,d2.w),d3
	tst.w	d3
	beq.s	mt_noloop
	move.l	4(a4),d0
	asl.w	#1,d3
	add.l	d3,d0
	move.l	d0,$a(a4)
	move.w	4(a3,d2.w),d0
	add.w	6(a3,d2.w),d0
	move.w	d0,8(a4)
	bra.s	mt_hejaSverige
mt_noloop:
	move.l	4(a4),d0
	add.l	d3,d0
	move.l	d0,$a(a4)
mt_hejaSverige:
	move.w	6(a3,d2.w),$e(a4)

mt_oldinstr:
	move.w	(a4),d0
	and.w	#$fff,d0
	beq	mt_com2
	tst.w	30(a4)
	bne.s	mt_rambo
	tst.w	8(a4)
	beq	mt_stopsound
	tst.b	$12(a4)
	bne	mt_stopsound
	move.b	2(a4),d0
	and.b	#$f,d0
	cmp.b	#5,d0
	beq	mt_setport
	cmp.b	#3,d0
	beq	mt_setport

mt_rambo:
	move.w	(a4),$10(a4)
	and.w	#$fff,$10(a4)
	move.w	$1a(a4),$dff096
	clr.b	$19(a4)

	tst.w	30(a4)
	beq.s	mt_noaminst
	move.l	a0,-(sp)
	move.w	34(a4),d0
	mulu	#120,d0
	add.l	#mt_data2+24,d0
	move.l	d0,a0
	moveq	#0,d0
	move.w	26(a0),d0
	lsl.w	#5,d0
	add.l	#mt_amwaveforms,d0
	move.l	d0,(a5)
	move.w	#16,4(a5)
	move.l	d0,$a(a4)
	move.w	#16,$e(a4)
	move.w	6(a0),32(a4)
	move.l	#1,36(a4)
	move.w	34(a0),d0
	move.w	d1,-(sp)
	move.w	$10(a4),d1
	lsl.w	d0,d1
	move.w	d1,$10(a4)
	move.w	d1,6(a5)
	move.w	(sp)+,d1
	move.l	(sp)+,a0
	bra.s	mt_juck

mt_noaminst:
	move.l	4(a4),(a5)
	move.w	8(a4),4(a5)
	move.w	$10(a4),6(a5)

mt_juck:move.w	$1a(a4),d0
	or.w	d0,mt_dmacon
	bra	mt_com2

mt_stopsound:
	move.w	$1a(a4),$dff096
	bra	mt_com2

mt_setport:
	move.w	(a4),d2
	and.w	#$fff,d2
	move.w	d2,$16(a4)
	move.w	$10(a4),d0
	clr.b	$14(a4)
	cmp.w	d0,d2
	beq.s	mt_clrport
	bge	mt_com2
	move.b	#1,$14(a4)
	bra	mt_com2
mt_clrport:
	clr.w	$16(a4)
	rts

mt_port:move.b	3(a4),d0
	beq.s	mt_port2
	move.b	d0,$15(a4)
	clr.b	3(a4)
mt_port2:
	tst.w	$16(a4)
	beq.s	mt_rts
	moveq	#0,d0
	move.b	$15(a4),d0
	tst.b	$14(a4)
	bne.s	mt_sub
	add.w	d0,$10(a4)
	move.w	$16(a4),d0
	cmp.w	$10(a4),d0
	bgt.s	mt_portok
	move.w	$16(a4),$10(a4)
	clr.w	$16(a4)
mt_portok:
	move.w	$10(a4),6(a5)
mt_rts:	rts

mt_sub:	sub.w	d0,$10(a4)
	move.w	$16(a4),d0
	cmp.w	$10(a4),d0
	blt.s	mt_portok
	move.w	$16(a4),$10(a4)
	clr.w	$16(a4)
	move.w	$10(a4),6(a5)
	rts

mt_sin:	dc.b	0,$18,$31,$4a,$61,$78,$8d,$a1,$b4,$c5,$d4,$e0,$eb,$f4
	dc.b	$fa,$fd
	dc.b	$ff,$fd,$fa,$f4,$eb,$e0,$d4,$c5,$b4,$a1,$8d,$78,$61
	dc.b	$4a,$31,$18

mt_vib:	move.b	$3(a4),d0
	beq.s	mt_vib2
	move.b	d0,$18(a4)

mt_vib2:move.b	$19(a4),d0
	lsr.w	#2,d0
	and.w	#$1f,d0
	moveq	#0,d2
	move.b	mt_sin(pc,d0.w),d2
	move.b	$18(a4),d0
	and.w	#$f,d0
	mulu	d0,d2
	lsr.w	#7,d2
	move.w	$10(a4),d0
	tst.b	$19(a4)
	bmi.s	mt_vibsub
	add.w	d2,d0
	bra.s	mt_vib3
mt_vibsub:
	sub.w	d2,d0
mt_vib3:move.w	d0,6(a5)
	move.b	$18(a4),d0
	lsr.w	#2,d0
	and.w	#$3c,d0
	add.b	d0,$19(a4)
	rts

mt_arplist:
	dc.b	0,1,2,0,1,2,0,1,2,0,1,2,0
	dc.b	1,2,0,1,2,0,1,2,0,1,2,0,1,2,0,1,2,0,1

mt_arp:	moveq	#0,d0
	move.b	mt_counter(pc),d0
	move.b	mt_arplist(pc,d0.w),d0
	beq.s	mt_arp0
	cmp.b	#2,d0
	beq.s	mt_arp2
mt_arp1:moveq	#0,d0
	move.b	3(a4),d0
	lsr.b	#4,d0
	bra.s	mt_arpdo
mt_arp2:moveq	#0,d0
	move.b	3(a4),d0
	and.b	#$f,d0
mt_arpdo:
	asl.w	#1,d0
	move.w	$10(a4),d1
	and.w	#$fff,d1
	lea	mt_periods(pc),a0
	moveq	#$24,d2
mt_arp3:cmp.w	(a0)+,d1
	bge.s	mt_arpfound
	dbf	d2,mt_arp3
mt_arp0:move.w	$10(a4),6(a5)
	rts
mt_arpfound:
	move.w	-2(a0,d0.w),6(a5)
	rts

mt_normper:
	move.w	$10(a4),6(a5)
	rts

mt_com:	move.w	2(a4),d0
	and.w	#$fff,d0
	beq.s	mt_normper
	move.b	2(a4),d0
	and.b	#$f,d0
	tst.b	d0
	beq.s	mt_arp
	cmp.b	#1,d0
	beq.s	mt_portup
	cmp.b	#2,d0
	beq.s	mt_portdown
	cmp.b	#3,d0
	beq	mt_port
	cmp.b	#4,d0
	beq	mt_vib
	cmp.b	#5,d0
	beq.s	mt_volport
	cmp.b	#6,d0
	beq.s	mt_volvib
	move.w	$10(a4),6(a5)
	cmp.b	#$a,d0
	beq.s	mt_volslide
	rts

mt_portup:
	moveq	#0,d0
	move.b	3(a4),d0
	sub.w	d0,$10(a4)
	move.w	$10(a4),d0
	cmp.w	#$71,d0
	bpl.s	mt_portup2
	move.w	#$71,$10(a4)
mt_portup2:
	move.w	$10(a4),6(a5)
	rts

mt_portdown:
	moveq	#0,d0
	move.b	3(a4),d0
	add.w	d0,$10(a4)
	move.w	$10(a4),d0
	cmp.w	#$358,d0
	bmi.s	mt_portdown2
	move.w	#$358,$10(a4)
mt_portdown2:
	move.w	$10(a4),6(a5)
	rts

mt_volvib:
	 bsr	mt_vib2
	 bra.s	mt_volslide
mt_volport:
	 bsr	mt_port2

mt_volslide:
	moveq	#0,d0
	move.b	3(a4),d0
	lsr.b	#4,d0
	beq.s	mt_vol3
	add.b	d0,$13(a4)
	cmp.b	#$40,$13(a4)
	bmi.s	mt_vol2
	move.b	#$40,$13(a4)
mt_vol2:moveq	#0,d0
	move.b	$13(a4),d0
	move.w	d0,8(a5)
	rts

mt_vol3:move.b	3(a4),d0
	and.b	#$f,d0
	sub.b	d0,$13(a4)
	bpl.s	mt_vol4
	clr.b	$13(a4)
mt_vol4:moveq	#0,d0
	move.b	$13(a4),d0
	move.w	d0,8(a5)
	rts

mt_com2:move.b	$2(a4),d0
	and.b	#$f,d0
	cmp.b	#$e,d0
	beq.s	mt_filter
	cmp.b	#$d,d0
	beq.s	mt_pattbreak
	cmp.b	#$b,d0
	beq.s	mt_songjmp
	cmp.b	#$c,d0
	beq.s	mt_setvol
	cmp.b	#$f,d0
	beq.s	mt_setspeed
	rts

mt_filter:
	move.b	3(a4),d0
	and.b	#1,d0
	asl.b	#1,d0
	and.b	#$fd,$bfe001
	or.b	d0,$bfe001
	rts

mt_pattbreak:
	move.b	#1,mt_break
	rts

mt_songjmp:
	move.b	#1,mt_break
	move.b	3(a4),d0
	subq.b	#1,d0
	move.b	d0,mt_songpos
	rts

mt_setvol:
	cmp.b	#$40,3(a4)
	bls.s	mt_sv2
	move.b	#$40,3(a4)
mt_sv2:	moveq	#0,d0
	move.b	3(a4),d0
	move.b	d0,$13(a4)
	move.w	d0,8(a5)
	rts

mt_setspeed:
	moveq	#0,d0
	move.b	3(a4),d0
	cmp.b	#$1f,d0
	bls.s	mt_sp2
	moveq	#$1f,d0
mt_sp2:	tst.w	d0
	bne.s	mt_sp3
	moveq	#1,d0
mt_sp3:	move.b	d0,mt_speed
	rts

mt_amhandler:
	moveq	#3,d7
	lea	mt_voice1,a6
	lea	$dff0a0,a5
mt_amloop:
	tst.w	30(a6)
	beq	mt_anrp
	move.w	34(a6),d0
	mulu	#120,d0
	add.l	#mt_data2+24,d0
	move.l	d0,a0
	tst.w	38(a6)
	beq	mt_anrp
	cmp.w	#1,38(a6)
	bne.s	mt_anat
	move.w	32(a6),d0
	cmp.w	8(a0),d0
	beq.s	mt_aaeq
	cmp.w	8(a0),d0
	blt.s	mt_aaad
	move.w	10(a0),d0
	sub.w	d0,32(a6)
	move.w	32(a6),d0
	cmp.w	8(a0),d0
	bgt	mt_anxt
	move.w	8(a0),32(a6)
mt_aaeq:move.w	#2,38(a6)
	bra	mt_anxt
mt_aaad:move.w	10(a0),d0
	add.w	d0,32(a6)
	move.w	32(a6),d0
	cmp.w	8(a0),d0
	blt	mt_anxt
	move.w	8(a0),32(a6)
	bra.s	mt_aaeq
mt_anat:cmp.w	#2,38(a6)
	bne.s	mt_ana2
	move.w	32(a6),d0
	cmp.w	12(a0),d0
	beq.s	mt_a2eq
	cmp.w	12(a0),d0
	blt.s	mt_a2ad
	move.w	14(a0),d0
	sub.w	d0,32(a6)
	move.w	32(a6),d0
	cmp.w	12(a0),d0
	bgt	mt_anxt
	move.w	12(a0),32(a6)
mt_a2eq:move.w	#3,38(a6)
	bra	mt_anxt
mt_a2ad:move.w	14(a0),d0
	add.w	d0,32(a6)
	move.w	32(a6),d0
	cmp.w	12(a0),d0
	blt	mt_anxt
	move.w	12(a0),32(a6)
	bra.s	mt_a2eq
mt_ana2:cmp.w	#3,38(a6)
	bne.s	mt_andc
	move.w	32(a6),d0
	cmp.w	16(a0),d0
	beq.s	mt_adeq
	cmp.w	16(a0),d0
	blt.s	mt_adad
	move.w	18(a0),d0
	sub.w	d0,32(a6)
	move.w	32(a6),d0
	cmp.w	16(a0),d0
	bgt.s	mt_anxt
	move.w	16(a0),32(a6)
mt_adeq:move.w	#4,38(a6)
	move.w	20(a0),40(a6)
	bra.s	mt_anxt
mt_adad:move.w	18(a0),d0
	add.w	d0,32(a6)
	move.w	32(a6),d0
	cmp.w	16(a0),d0
	blt.s	mt_anxt
	move.w	16(a0),32(a6)
	bra.s	mt_adeq
mt_andc:cmp.w	#4,38(a6)
	bne.s	mt_anst
	subq.w	#1,40(a6)
	bpl.s	mt_anxt
	move.w	#5,38(a6)
	bra.s	mt_anxt
mt_anst:move.w	24(a0),d0
	sub.w	d0,32(a6)
	bpl.s	mt_anxt
	clr.l	30(a6)
	clr.w	38(a6)
	move.w	26(a6),$dff096
mt_anxt:move.w	32(a6),d0
	lsr.w	#2,d0
	move.w	d0,8(a5)
	move.w	28(a0),d0
	add.w	d0,16(a6)
	move.w	30(a0),d1
	beq.s	mt_nvib
	move.w	36(a6),d2
	moveq	#0,d3
	cmp.w	#360,d2
	blt.s	mt_vibq
	sub.w	#360,d2
	moveq	#1,d3
mt_vibq:lea	mt_amsinus,a2
	muls	(a2,d2.w),d1
	asr.w	#7,d1
	tst.w	d3
	beq.s	mt_nvib
	neg.w	d1
mt_nvib:add.w	16(a6),d1
	move.w	d1,6(a5)
	move.w	32(a0),d0
	add.w	d0,d0
	add.w	d0,36(a6)
	cmp.w	#720,36(a6)
	blt.s	mt_anrp
	sub.w	#720,36(a6)
mt_anrp:lea	$10(a5),a5
	lea	42(a6),a6
	dbra	d7,mt_amloop

	lea	mt_noisewave,a0
	move.w	#$7327,d0
	moveq	#31,d1
mt_nlop:move.b	d0,(a0)+
	add.b	$dff007,d0
	eor.w	#124,d0
	rol.w	#3,d0
	dbra	d1,mt_nlop
	rts

mt_amwaveforms:
	dc.b	0,25,49,71,90,106,117,125
	dc.b	127,125,117,106,90,71,49,25
	dc.b	0,-25,-49,-71,-90,-106,-117
	dc.b	-125,-127,-125,-117,-106
	dc.b	-90,-71,-49,-25
	dc.b	-128,-120,-112,-104,-96,-88,-80,-72,-64,-56,-48
	dc.b	-40,-32,-24,-16,-8,0,8,16,24,32,40,48,56,64,72,80
	dc.b	88,96,104,112,120
	blk.b	16,-128
	blk.b	16,127
mt_noisewave:
	blk.b	32,0

mt_amsinus:
	dc.w	0,2,4,6,8,$b,$d,$f,$11,$14,$16,$18,$1a,$1c,$1e,$21
	dc.w	$23,$25,$27,$29,$2b,$2d,$2f,$32,$34,$36,$38,$3a,$3c,$3e
	dc.w	$3f,$41,$43,$45,$47,$49,$4b,$4d,$4e,$50,$52,$53,$55,$57
	dc.w	$58,$5a,$5c,$5d,$5f,$60,$62,$63,$64,$66,$67,$68,$6a,$6b
	dc.w	$6c,$6d,$6e,$6f,$71,$72,$73,$74,$74,$75,$76,$77,$78,$79
	dc.w	$79,$7a,$7b,$7b,$7c,$7c,$7d,$7d,$7e,$7e,$7e,$7f,$7f,$7f
	dc.w	$7f,$7f,$7f,$7f,$80,$7f,$7f,$7f,$7f,$7f,$7f,$7f,$7e,$7e
	dc.w	$7e,$7d,$7d,$7c,$7c,$7b,$7b,$7a,$79,$79,$78,$77,$76,$75
	dc.w	$74,$73,$72,$71,$6f,$6e,$6d,$6c,$6b,$6a,$68,$67,$66,$64
	dc.w	$63,$62,$60,$5f,$5d,$5c,$5a,$58,$57,$55,$53,$52,$50,$4e
	dc.w	$4d,$4b,$49,$47,$45,$43,$41,$40,$3e,$3c,$3a,$38,$36,$34
	dc.w	$32,$2f,$2d,$2b,$29,$27,$25,$23,$21,$1e,$1c,$1a,$18,$16
	dc.w	$14,$11,$f,$d,$b,$8,$6,$4,$2,0
	
mt_periods:
	dc.w	$358,$328,$2fa,$2d0,$2a6,$280,$25c,$23a,$21a,$1fc,$1e0
	dc.w	$1c5,$1ac,$194,$17d,$168,$153,$140,$12e,$11d,$10d,$fe
	dc.w	$f0,$e2,$d6,$ca,$be,$b4,$aa,$a0,$97,$8f,$87
	dc.w	$7f,$78,$71,0

mt_speed:	dc.b	6
mt_counter:	dc.b	0
mt_pattpos:	dc.w	0
mt_songpos:	dc.b	0
mt_break:	dc.b	0
mt_dmacon:	dc.w	0
mt_samplestarts:blk.l	$1f,0
mt_voice1:	blk.w	13,0
		dc.w	1
		blk.w	7,0
mt_voice2:	blk.w	13,0
		dc.w	2
		blk.w	7,0
mt_voice3:	blk.w	13,0
		dc.w	4
		blk.w	7,0
mt_voice4:	blk.w	13,0
		dc.w	8
		blk.w	7,0

;====================
EVEN				;NOTRE LISTE COPPER
NEWCOPPER:   
	DC.W	$008E,$2081	;DIMENSIONS DE L'ECRAN
	DC.W	$0090,$38D1	;256 LIGNES + 35 LIGNES = 291 LIGNES

	DC.W	$0092,$0038,$0094,$00D0

	;POINTEURS ADRESSE DES PLANS DE L'IMAGE

	DC.W $00E0,IMAGE+[40*0]/65536
	DC.W $00E2,IMAGE+[40*0] & 65535   
	DC.W $00E4,IMAGE+[40*1]/65536
	DC.W $00E6,IMAGE+[40*1] & 65535
	DC.W $00E8,IMAGE+[40*2]/65536
	DC.W $00EA,IMAGE+[40*2] & 65535

	;REGISTRE POUR CHOISIR RESOLUTION	

	DC.W	$0100,$0000		;3 PLANS + MODE COULEURS

	;DECALAGE ECRAN - INUTILISE ICI

	DC.W	$0102,$0000

	;PRIORITE DES PLANS ET SPRITES - INUTILISE ICI

	DC.W 	$0104,$0000

	;MODULOS DES PLANS

	DC.W	$0108,80	;MODULOS PLANS PAIRS
	DC.W 	$010A,80	;MODULOS PLANS IMPAIRS

	;POINTEURS DES SPRITES

	DC.W	$120
SP0H:	DC.W	0,$122
SP0L:	DC.W	0,$124
SP1H:	DC.W	0,$126
SP1L:	DC.W	0,$128
SP2H:	DC.W	0,$12A
SP2L:	DC.W	0,$12C
SP3H:	DC.W	0,$12E
SP3L:	DC.W	0,$130
SP4H:	DC.W	0,$132
SP4L:	DC.W	0,$134
SP5H:	DC.W	0,$136
SP5L:	DC.W	0,$138
SP6H:	DC.W	0,$13A
SP6L:	DC.W	0,$13C
SP7H:	DC.W	0,$13E
SP7L:	DC.W	0

	;REGISTRES DES COULEURS

	DC.W	$0180,$0000	;COULEUR 00
	DC.W	$0182,$0fed	;COULEUR 01
	DC.W	$0184,$0ff0	;COULEUR 02
	DC.W	$0186,$0fb0	;COULEUR 03
	DC.W	$0188,$0f90	;COULEUR 04
	DC.W	$018A,$0f40	;COULEUR 05
	DC.W	$018C,$0d20	;COULEUR 06
	DC.W	$018E,$0b10	;COULEUR 07

	DC.W	$0190,$0EEF	;COULEUR 08
	DC.W	$0192,$0CCF	;COULEUR 09
	DC.W	$0194,$099F	;COULEUR 10
	DC.W	$0196,$055F	;COULEUR 11
	DC.W	$0198,$000F	;COULEUR 12
	DC.W	$019A,$000A	;COULEUR 13
	DC.W	$019C,$0006	;COULEUR 14
	DC.W	$019E,$0003	;COULEUR 15

	DC.W	$01A0,$0000	;COULEUR 16	;LES COULEURS DE 16 A 31 SONT
	DC.W	$01A2,$0015	;COULEUR 17	;AUSSI CELLES DES SPRITES
	DC.W	$01A4,$0135	;COULEUR 18
	DC.W	$01A6,$0246	;COULEUR 19	;LES COULEURS 16 A 31 NE SONT
	DC.W	$01A8,$0468	;COULEUR 20	;PAS UTILISEES DANS LE MODE
	DC.W	$01AA,$068a	;COULEUR 21	;HOLD AND MODIFY (HAM)
	DC.W	$01AC,$08ac	;COULEUR 22
	DC.W	$01AE,$0ace	;COULEUR 23
	DC.W	$01B0,$0310	;COULEUR 24
	DC.W	$01B2,$0da2	;COULEUR 25
	DC.W	$01B4,$0c70	;COULEUR 26
	DC.W	$01B6,$0b50	;COULEUR 27
	DC.W	$01B8,$0a40	;COULEUR 28
	DC.W	$01BA,$0830	;COULEUR 29
	DC.W	$01BC,$0520	;COULEUR 30
	DC.W	$01BE,$0def	;COULEUR 31

	DC.W	$3801,$fffe
	dc.w	$0100,$3200,$180,$111		;3 PLANS + MODE COULEURS


	;INSTRUCTIONS POUR AVOIR UN ECRAN PAL (256 LIGNES DE HAUT)

DC.W $FFDF,$FFFE

DC.W $0100,0		;MET RESOLUTION NULLE

DC.W $0180,$0000	;REGISTRES DES COULEURS
DC.W $0182,$0a50	;POUR LE SCROLL
DC.W $0184,$0dc0
DC.W $0186,$0606
DC.W $0188,$0818
DC.W $018a,$0a2a
DC.W $018c,$0d3d
DC.W $018e,$0f5f

DC.W	$0092,$0030	;PASSAGE EN OVERSCAN
DC.W	$0094,$00D8


DC.W $0501,$FFFE

		DC.W $0100,$3200	;RESOLUTION 3 PLANS = 8 COULEURS

		DC.W $10A,110-4		;MODULO = 10 + 50 + 50 - 4
					;-4 POUR PASSAGE EN OVERSCAN
		DC.W $108,110-4		;MODULO POUR FORMAT RAW BLITTER

		;POINTEURS DE PLANS DU FOND DE SCROLL

		DC.W $00E0,SCROLL+[50*0]/65536	
		DC.W $00E2,SCROLL+[50*0] & 65535
		DC.W $00E4,SCROLL+[50*1]/65536
		DC.W $00E6,SCROLL+[50*1] & 65535
		DC.W $00E8,SCROLL+[50*2]/65536  
		DC.W $00EA,SCROLL+[50*2] & 65535

DC.W $2801,$FFFE,$100,0

DC.L $FFFFFFFE ;FIN LISTE COPPER
EVEN
;RESERVATION DE MEMOIRE POUR STRUCTURES SPRITES
sprite0:	blk.l 17*20
sprite1:	blk.l 17*20
sprite2: 	blk.l 17*20
sprite3: 	blk.l 17*20
sprite4:	blk.l 17*20
sprite5:	blk.l 17*20
sprite6:	blk.l 17*20
sprite7:	blk.l 17*20
EVEN
FINDEMO: