;POUR CHARGER LES DATAS TAPEZ:
;
;RI		RETURN
;FONT.RAW	RETURN
;FONT		RETURN RETURN
;
;RI		RETURN
;MODULE		RETURN
;MT_DATA	RETURN RETURN
;
;PUIS TAPEZ
;G BEGIN	RETURN RETURN
;
;SUPPRIMEZ LES LIGNES SUIVANTES SI VOTRE VERSION DU SEKA
;NE COMPORTE PAS LA COMMANDE Y

>EXTERN "FONT.RAW",FONT
>EXTERN "MODULE",MT_DATA

org $30000	;EMPLACEMENT EN MEMOIRE
load $30000	;DE NOTRE PROGRAMME

BEGIN:
JMP START
;=====================================================================
EXECBASE=4
OPENLIBRARY=-408
CLOSELIBRARY=-414
SUPERSTATE=-150
USERSTATE=-156	
FORBID=-132
PERMIT=-138
ADDINTSERVER=-168
REMINTSERVER=-174
Open=-30
Close=-36
Read=-42

;=====================================================================
BLTCON0=$DFF040		
BLTCON1=$DFF042
BLTAFWM=$DFF044
BLTALWM=$DFF046
BLTCPTH=$DFF048
BLTCPTL=$DFF04A
BLTBPTH=$DFF04C
BLTBPTL=$DFF04E
BLTAPTH=$DFF050
BLTAPTL=$DFF052
BLTDPTH=$DFF054
BLTDPTL=$DFF056
BLTSIZE=$DFF058
BLTCMOD=$DFF060
BLTBMOD=$DFF062
BLTAMOD=$DFF064
BLTDMOD=$DFF066
BLTCDAT=$DFF070
BLTBDAT=$DFF072
BLTADAT=$DFF074
DMACONR=$DFF002
;==================================
FOND_EQUA=$32000		;L'IMAGE SE TROUVE A $32000

SCROLL=FOND_EQUA+[40*50]	;LE FOND DU SCROLL SE TROUVE JUSTE
				;APRES L'IMAGE
FONT=SCROLL+[50*35*3]		;LE DESSIN DES CARACTERES SE TROUVE
				;JUSTE APRES LE FOND DU SCROLL
MT_DATA=FONT+[40*256*3]		;LA MUSIQUE SE TROUVE JUSTE APRES
				;LES CARACTERES
FINDATA=MT_DATA+122284		;FIN DES DATAS APRES LA MUSIQUE
				
;==================================
START:    
MOVEM.L D0-D7/A0-A6,-(A7)	;SAUVE REGISTRES
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR FORBID(A6)    		;SAUTE SOUS PROGRAMME: INTERDIT MULTITACHE
JSR OPENLIB  			;SAUTE SOUS PROGRAMME: OUVERTURE LIBRAIRIES

CLEARSCROLL:			;ON EFFACE LE FOND DU SCROLL POUR EVITER
LEA SCROLL,A1			;D'AVOIR DES BIZARRERIES A L'ECRAN 
MOVE.W #25*35*3,D0
CLS:
MOVE.W #0,(A1)+
DBF D0,CLS

MOVE.L #TEXT,PTEXT		;ON MET LE POINTEUR DE LETTRE SUR LE DEBUT
MOVE.W #0,COMPT			;DU TEXTE. ET LE COMPTEUR A 0

BSR.L INIT_MUSIQUE		;INITIALISATION DE LA MUSIQUE

BSR.L SETCOPPER			;SAUTE SOUS PROGRAMME: MET EN PLACE LISTE COPPER
BSR.s NEWIRQ3			;SAUTE SOUS PROGRAMME: MET EN PLACE ROUTINE D'INTERRRUPTION

WAIT:
CMP.B #$40,$DFF006		;ATTENDANT 200 IEME LIGNE RASTER
BNE.S WAIT			;SINON RETOURNE A WAIT

BSR.L 	EQUALIZER		;VA A ROUTINE D'EQUALIZER
BSR.L 	EFFACE_EQUALIZER	;VA ROUTINE D'EFFACEMENT

BTST	#6,$BFE001		;ATTENDANT PRESSION SUR BOUTON GAUCHE SOURIS
BNE.S	WAIT			;SINON RETOURNE A WAIT
 				;SI OUI  FIN
END: 				;FIN:	
BSR.L STOP_MUSIQUE		;ARRET DE LA MUSIQUE
BSR.s STOPIRQ3        		;SAUTE SOUS PROGRAMME: STOPPE INTERRUPTION
BSR.L CLRCOPPER       		;SAUTE SOUS PROGRAMME: RESTAURE ANCIENNE LISTE COPPER
BSR.L CLOSELIB        		;SAUTE SOUS PROGRAMME: FERME LIBRAIRIES 
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR PERMIT(A6)      		;AUTORISE MULTITACHE
                      
MOVEM.L (A7)+,D0-D7/A0-A6	;RESTAURE REGISTRES
RTS
;========================
NEWIRQ3:			;MET EN PLACE NOTRE ROUTINE 
MOVE.L	EXECBASE,A6		;D'INTERRUPTION
lea	irqstr,a1
move.l	#5,d0
jsr	addintserver(a6)
move.l	d0,irq
beq.s	irqerror
rts
irqerror:
rts
;==========================
STOPIRQ3:			;RESTAURE ANCIENNE ROUTINE
movem.l	a0-a6/d0-d7,-(sp)	;D'INTERRUPTION
	tst.l	irq
	beq.s	irqoff1
	move.l	execbase,a6
	lea	irqstr,a1
	move.l	#32,d0
	jsr	remintserver(a6)
irqoff1:movem.l	(sp)+,a0-a6/d0-d7
	rts
irqstr:
	dc.l	0,0
	dc.b	2,-127
	dc.l	0,irqdat,interrupt
irqdat:	dc.l	0,0,0,0
irq:	dc.l	0
;============================
interrupt:			;NOTRE ROUTINE D'INTERRUPTION	
movem.l	a0-a6/d0-d7,-(sp)

BSR.L SCROLLING			;VA A LA ROUTINE DE SCROLLING
BSR.L PLAY_MUSIQUE		;VA A LA ROUTINE POUR JOUER LA MUSIQUE
	
movem.l	(sp)+,a0-a6/d0-d7
rts
;============================
OPENLIB:  			;OUVERTURE DE LA LIBRAIRIE GRAPHIQUE
move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
lea gfxname,a1			;MET NOM DE LA LIBRAIRIE DANS A1
move.l #$0,d0           	;MET 0 DANS D0
jsr openlibrary(a6)		;OUVRE LIBRAIRIE
tst d0				;TESTE D0
beq.s error			;SI = A 0   VA A ERROR = SORTIE
move.l d0,gfxbase       	;SI NON, MET ADRESSE D0 DANS GFXBASE
add.l #$32,d0			;AJOUTE $32 A CETTE ADRESSE
move.l d0,coppertr      	;MET D0=ADRESSE ACTUELLE LISTE COPPER
rts				;DANS COPPERTR
even
gfxname: dc.b 'graphics.library',0 	;NOM DE LA LIBRAIRIE
even
gfxbase: dc.l 0				;POINTEUR POUR LA GRAPHICS LIBRARY
coppertr: dc.l 0			;POINTEUR POUR ADRESSE LISTE COPPER
;====================
CLOSELIB: 			;FERMETURE LIBRAIRIE
move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
move.l gfxbase,a1		;MET NOM DE LA LIBRAIRIE DANS A1
jsr closelibrary(a6)		;FERME LIBRAIRIE
rts
;====================
ERROR:				;SI ERREUR
illegal				;SORTIE
rts
;====================
SETCOPPER:			;MET EN PLACE NOTRE LISTE COPPER
move.l coppertr,a0		;MET ADRESSE ACTUEL COPPER DANS A0
move.l (a0),oldcopper		;MET CONTENU DANS OLDCOPPER
move.l #newcopper,(a0)		;MET NOTRE LISTE COPPER DANS A0
move.w #$81c0,$dff096		;ACTIVE LISTE COPPER
rts		
oldcopper: dc.l 0
;====================
CLRCOPPER:			;RESTAURE ANCIENNE LISTE COPPER
move.l coppertr,a0		;MET ANCIENNE ADRESSE DANS A0
move.l oldcopper,(a0)		;MET CONTENU DANS A0
move.w #$80a0,$dff096		;REACTIVE ANCIENNE COPPER
rts
;====================
WAIT_BLITTER:			;ROUTINE POUR ATTENDRE QUE LE BLITTER
BTST #14,DMACONR		;EST FINI SON PRECEDENT TRAVAIL
BNE.S WAIT_BLITTER
RTS
;===================
SCROLLING:			;ROUTINE DU SCROLLING
BSR.L SEARCH_CHAR		;AFFICHE UN NOUVEAU CARACTERE
BSR.L SCROLLTEXT		;SCROLLE LE FOND DU SCROLL
RTS
;===================	
SCROLLTEXT:			
LEA SCROLL,A0 			;ON POINTE A0 SUR LE FOND DU SCROLL
	
BSR.L WAIT_BLITTER		;ON ATTEND QUE LE BLITTER EST FINI SON 
				;PRECEDENT TRAVAIL

LEA SCROLL-2,A1			;ON POINTE A1 SUR 16 PIXELS AVANT 
				;LE FOND DU SCROLL. 2 = 16 PIXELS

MOVE.L A0,BLTAPTH		;MET ADRESSE DE A0 DANS SOURCE BLITTER A
MOVE.L A1,BLTDPTH		;MET ADRESSE DE A1 DANS DESTINATION BLITTER D
MOVE.W #0,BLTAMOD  		;MET 0 DANS MODULO SOURCE A
MOVE.W #0,BLTDMOD		;MET 0 DANS MODULO DESTINATION D
MOVE.L #$FFFFFFFF,BLTAFWM	;MASQUE DU 1ER ET DU DERNIER MOT
MOVE.L #$C9F00000,BLTCON0    	;MET MIMTERN ET DECALAGE DANS BLTCON0
				;$C = $F - $4 = 16 - 4 = 12
				;4 PIXELS DE DECALAGE VERS LA GAUCHE

				;$9 -> POUR 1 SOURCE BLITTER
				;$F0 -> MINTERM POUR COPIE DIRECTE
				;$0000 -> MIS A 0 CAR SOURCE B INITULISE	

MOVE.W #[35*64*3]+25,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
				;TAILLE = [HAUTEUR * 64]+[LARGEUR/2]
RTS
;============
SEARCH_CHAR:
ADD.W #1,COMPT			;AJOUTE 1 AU COMPTEUR
CMP.W #8,COMPT           	;COMPARE A 8 CAR 8 * 4 PIXELS DE DECALAGE
				;EGALE A 32 SOIT LA LARGEUR D'UNe LETTRE
BNE.L SEARCHAR3			;SI PAS EGAL A 8 ON SORT
MOVE.W #0,COMPT			;SI OUI ON REMET COMPTEUR A 0
				;ET ON CONTINU

MOVE.L PTEXT,A0          	;MET POINTEUR TEXTE DANS A0
CLR.L D0			;ON EFFACE CONTENU DE D0
MOVE.B (A0),D0			;MET LE CONTENU DU POINTEUR TEXTE DANS D0
LEA COMPTEUR_CHAR,A1		;EN POINTE A1 SUR LA TABLE DES LETTRES
CLR.L D1			;ON EFFACE CONTENU DE D1
MOVE.B #-1,D1			;ON MET -1 DANS D1

SEARCHAR1:

ADD.B #1,D1     		;ON AJOUTE 1 A D1         
CMP.B (A1)+,D0			;ON COMPARE LES LETTRES DE LA TABLE
				;AVEC CELLE CONTENU DANS D0
BNE SEARCHAR1			;SI PAS LA MEME ON RECOMMENCE AVEC LA
				;LETTRE SIUVANTE DANS LA TABLE
				;SI C'EST LA MEME ON CONTINU
MULU #4,D1              	;ON MULTIPLIE D1 PAR 4
LEA TABLE_CHAR,A0       	;ON POINTE A0 SUR LE DEBUT DE LA TABLE
				;D'ADRESSE DES IMAGES DES LETTRES
MOVE.L (A0,D1),A2       	;ET ON MET L'ADRESSE DE LA LETTRE DANS A2

LEA SCROLL,A3			;ON POINTE A3 SUR LA POSITION SCROLL+46
ADD.L #46,A3        		;SOIT A 46*8 = 368 PIXELS A DROITE DU 
				;COIN SUPERIEUR DROIT DU FOND DE SCROLL
				;SOIT DANS LA PARTIE INVISIBLE DU SCROLL	

BSR.L WAIT_BLITTER        	;ON ATTENDS LE BLITTER	
MOVE.L A2,BLTAPTH       	;ON MET ADRESSE DE A2 DANS SOURCE BLITTER A
MOVE.L A3,BLTDPTH       	;ON MET ADRESSE DE A3 DANS DESTINATION BLITTER D

MOVE.W #40-4,BLTAMOD  		;ON MET 40-4 DANS MODULO SOURCE A
				;CAR NOTRE LETTRE FAIT 32 PIXELS DE LARGE SOIT
				;4 MOTS (4*8=32) ET L'IMAGE QUI LA CONTIENT
				;FAIT 320 PIXELS DE LARGE SOIT 40 MOTS
	
MOVE.W #50-4,BLTDMOD   	        ;ON MET 50-4 DANS MODULO DESTINATION D
				;CAR LE FOND DE SCROLL FAIT 400 PIXELS DE LARGE
				;SOIT 50 MOTS

MOVE.L #$09F00000,BLTCON0	;$0 -> PAS DE DECALAGE DE LA SOURCE A
				;$9 -> POUR 1 SOURCE BLITTER A
				;$F0 -> MINTERM POUR COPIE DIRECTE

MOVE.W #[35*3*64]+2,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
				;TAILLE = [HAUTEUR * 64]+[LARGEUR/2]

ADD.L #1,PTEXT          	;ON AJOUTE 1 AU POINTEUR DE TEXTE
MOVE.L PTEXT,A0			;ON MET POINTEUR DE TEXTE DANS A0
TST.B (A0)              	;SI PAS EGAL A 0
BNE SEARCHAR3			;ON VA A SEARCHAR3
MOVE.L #TEXT,PTEXT		;SINON ON REMET POINTEUR DE TEXTE AU DEBUT
				;DU TEXTE A SCROLLER

SEARCHAR3:
RTS

EVEN
COMPT: DC.W 0			;COMPTEUR 
PTEXT: DC.L 0			;POINTEUR DE TEXTE
;=================================================================
COMPTEUR_CHAR: DC.B ' ABCDEFGHI'	;TABLE DES CARACTERES
	       DC.B 'JKLMNOPQRS'	;TELS QU'ILS SONT DISPOSES
	       DC.B 'TUVWXYZ.,:'	;DANS NOTRE IMAGE	
	       DC.B '()@#!?-*^/'
	       DC.B '0123456789%'
         
EVEN
FONT1=FONT		;ADRESSES DES LETTRES PAR LIGNES
FONT2=FONT+[3*35*40] 
FONT3=FONT+[6*35*40]
FONT4=FONT+[9*35*40]
FONT5=FONT+[12*35*40]
EVEN 
TABLE_CHAR: 		;ADRESSES DES LETTRES

DC.L FONT1,FONT1+4,FONT1+8,FONT1+12,FONT1+16,FONT1+20
DC.L FONT1+24,FONT1+28,FONT1+32,FONT1+36
DC.L FONT2,FONT2+4,FONT2+8,FONT2+12,FONT2+16,FONT2+20
DC.L FONT2+24,FONT2+28,FONT2+32,FONT2+36
DC.L FONT3,FONT3+4,FONT3+8,FONT3+12,FONT3+16,FONT3+20
DC.L FONT3+24,FONT3+28,FONT3+32,FONT3+36
DC.L FONT4,FONT4+4,FONT4+8,FONT4+12,FONT4+16,FONT4+20
DC.L FONT4+24,FONT4+28,FONT4+32,FONT4+36
DC.L FONT5,FONT5+4,FONT5+8,FONT5+12,FONT5+16,FONT5+20
DC.L FONT5+24,FONT5+28,FONT5+32,FONT5+36
EVEN

EVEN		;TEXTE A SCROLLER

TEXT: DC.B '             '
DC.B 'COMME VOUS AVEZ ETE NOMBREUX A ME LE DEMANDER  VOICI UNE ROUTINE '
DC.B 'TRES SIMPLE QUI VOUS PERMET D AFFICHER DES EQUALIZERS IDENTIQUES '
DC.B 'A CEUX PRESENTS DANS LES VERSIONS DE NOISETRACKERS ET AUTRES PRO'
DC.B 'TRACKERS.   CETTE ROUTINE N EST VALABLE QUE POUR LES REPLAY-ROUTINES '
DC.B 'DE NOISETRACKER  PROTRACKER  SOUNDTRACKER ET STARTREKKER. '
DC.B 'L AFFICHAGE NECESSITE UN ECRAN DE 1 PLAN DE DE 320 PIXELS DE '
DC.B 'LARGE SUR AU MOINS 40 PIXELS DE HAUT.  '

dc.b '    ',0
fin:
;====================
UPGRAND = 	56
UPPETIT = 	14
VITESSE =	1
HAUTEUR =	40
EVEN
;====================
EQSUB:				;ROUTINE APPELEE A PARTIR
	MOVE 	(A0),D0		;DE LA REPLAY ROUTINE
	BNE.S 	EQSUB2
	RTS
EQSUB2:	
	CLR 	(A0)
	LEA 	MT_ARPEGGIO,A1
	MOVEQ 	#0,D1
NOMATCH:
	MOVE 	(A1)+,D2		
	CMP 	D2,D0		
	BGT.S 	MATCH			
	ADD.B 	#1,D1			
	BRA.S 	NOMATCH
;-------------------------
MATCH:	
	LEA 	EQTAB(PC),A1
	ADD.L 	D1,A1
	ADD.B 	#UPGRAND,(A1)
	ADD.B 	#UPPETIT,-1(A1)
	ADD.B 	#UPPETIT,1(A1)
NOPLUS:	
	MOVE.B 	(A1),D0
	CMP.B 	#HAUTEUR,D0
	BLS.S 	LESS50
	MOVE.B 	#HAUTEUR,(A1)
LESS50:	
	MOVE.B 	-1(A1),D0
	CMP.B 	#HAUTEUR-2,D0
	BLS.S 	LESS41
	MOVE.B 	#HAUTEUR-2,-1(A1)
LESS41:	
	MOVE.B 	1(A1),D0
	CMP.B 	#HAUTEUR-2,D0
	BLS.S 	LESS42
	MOVE.B 	#HAUTEUR-2,1(A1)
LESS42:	
	RTS
;--------------------------------
EQUALIZER:			;ROUTINE D'EQUALIZER
	LEA 	EQ1P,A0		
	BSR.S 	EQSUB
	LEA 	EQ2P,A0
	BSR.S 	EQSUB
	LEA 	EQ3P,A0
	BSR.S 	EQSUB
	LEA 	EQ4P,A0
	BSR.S 	EQSUB

	MOVEQ 	#39,D0			;DESSINE BARRES
	LEA 	EQTAB,A1		
	LEA 	FOND_EQUA,A2
MAINLP:	
	MOVEQ 	#0,D1
	MOVE.B 	(A1),D1			
NONOISE:
	MOVE.L 	D1,D4		
	NEG 	D1
	ADD 	#HAUTEUR,D1		
	MULU 	#40,D1			;40 = LARGEUR IMAGE	
FILLBAR:MOVE.B 	#$FE,0(A2,D1)		;$FE = %1111111111111110= MOTIF BARRE
	ADD 	#40,D1			;40 = LARGEUR IMAGE
	DBRA 	D4,FILLBAR
	MOVE.B 	(A1),D3
	SUB.B 	#VITESSE,(A1)		;VITESSE DE RETOMBEE
	BPL.S 	IZOK		
	MOVE.B 	#0,(A1)
IZOK:	ADDQ.L 	#1,A2
	ADDQ.L 	#1,A1
	DBF 	D0,MAINLP
	RTS
;--------------------
EQTAB: 	BLK.B 	80,2
;--------------------
EFFACE_EQUALIZER:
 
	LEA 	FOND_EQUA,A0
	MOVE.W 	#[[40*40]/2]-1,D0
EFFACE_EQ:
	MOVE.W #0,(A0)+
	DBF 	D0,EFFACE_EQ
	RTS
;================================
EVEN
;CETTE ROUTINE PERMET DE JOUER TOUS LES MODULES DE SOUNDTRACKERS
;DE LA VERSION 1.0 A LA VERSION 2.6  AINSI QUE CERTAINS MODULES
;NOISETRACKER.

INIT_MUSIQUE:			;INITIALISATION DE LA MUSIQUE
mt_init:move.l	mt_rdata(pc),a0
	cmp.l	#"M.K.",$438(a0)
	bne	mt_st20
	lea	mt_forst23(pc),a2
	move.l	a2,mt_forst
	bra	ok1st23
mt_st20:
	lea	mt_forst20(pc),a2
	move.l	a2,mt_forst
ok1st23:	
	add.l	(a2),a0
	moveq	#$7f,d0
	moveq	#0,d1
mt_init1:
	move.l	d1,d2
	subq.w	#1,d0
mt_init2:
	move.b	(a0)+,d1
	cmp.b	d2,d1
	bgt.s	mt_init1
	dbf	d0,mt_init2
	addq.b	#1,d2

mt_init3:
	move.l	mt_rdata(pc),a0
	lea	mt_sample1(pc),a1
	asl.l	#8,d2
	asl.l	#2,d2
	add.l	4(a2),d2
	add.l	a0,d2
	move.l	8(a2),d0
mt_init4:
	move.l	d2,(a1)+
	moveq	#0,d1
	move.w	42(a0),d1
	asl.l	#1,d1
	add.l	d1,d2
	add.l	#$1e,a0
	dbf	d0,mt_init4

	lea	mt_sample1(PC),a0
	moveq	#0,d0
mt_clear:
	move.l	(a0,d0.w),a1
	clr.l	(a1)
	addq.w	#4,d0
	cmp.w	#$7c,d0
	bne.s	mt_clear

	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	clr.l	mt_partnrplay
	clr.l	mt_partnote
	clr.l	mt_partpoint
	move.l	mt_rdata(pc),a1
	add.l	12(a2),a1
	move.b	(a1),mt_maxpart+1
	rts

STOP_MUSIQUE:			;ARRET DE LA MUSIQUE
mt_end:	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	move.w	#$f,$dff096
	rts

PLAY_MUSIQUE:			;JOUE LA MUSIQUE
mt_music:
	addq.w	#1,mt_counter
mt_cool:cmp.w	#6,mt_counter
	bne.s	mt_notsix
	clr.w	mt_counter
	bra	mt_rout2

mt_notsix:
	lea	mt_aud1temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp1
	lea	$dff0a0,a5		
	bsr.s	mt_arprout
mt_arp1:lea	mt_aud2temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp2
	lea	$dff0b0,a5
	bsr.s	mt_arprout
mt_arp2:lea	mt_aud3temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp3
	lea	$dff0c0,a5
	bsr.s	mt_arprout
mt_arp3:lea	mt_aud4temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp4
	lea	$dff0d0,a5
	bra.s	mt_arprout
mt_arp4:rts

mt_arprout:
	move.b	2(a6),d0
	and.b	#$0f,d0
	tst.b	d0
	beq	mt_arpegrt
	cmp.b	#$01,d0
	beq.s	mt_portup
	cmp.b	#$02,d0
	beq.s	mt_portdwn
	cmp.b	#$0a,d0
	beq.s	mt_volslide
	rts

mt_portup:

	BSR.L MT_EQ		;BRANCHEMENT SUR ROUTINE EQUALIZER

	moveq	#0,d0
	move.b	3(a6),d0
	sub.w	d0,22(a6)
	cmp.w	#$71,22(a6)
	bpl.s	mt_ok1
	move.w	#$71,22(a6)
mt_ok1:	move.w	22(a6),6(a5)
	rts

mt_portdwn:

	BSR.L MT_EQ		;BRANCHEMENT SUR ROUTINE EQUALIZER

	moveq	#0,d0
	move.b	3(a6),d0
	add.w	d0,22(a6)
	cmp.w	#$538,22(a6)
	bmi.s	mt_ok2
	move.w	#$538,22(a6)
mt_ok2:	move.w	22(a6),6(a5)
	rts

mt_volslide:
	moveq	#0,d0
	move.b	3(a6),d0
	lsr.b	#4,d0
	tst.b	d0
	beq.s	mt_voldwn
	add.w	d0,18(a6)
	cmp.w	#64,18(a6)
	bmi.s	mt_ok3
	move.w	#64,18(a6)
mt_ok3:	move.w	18(a6),8(a5)
	rts
mt_voldwn:
	moveq	#0,d0
	move.b	3(a6),d0
	and.b	#$0f,d0
	sub.w	d0,18(a6)
	bpl.s	mt_ok4
	clr.w	18(a6)
mt_ok4:	move.w	18(a6),8(a5)
	rts

mt_arpegrt:
	move.w	mt_counter(PC),d0
	cmp.w	#1,d0
	beq.s	mt_loop2
	cmp.w	#2,d0
	beq.s	mt_loop3
	cmp.w	#3,d0
	beq.s	mt_loop4
	cmp.w	#4,d0
	beq.s	mt_loop2
	cmp.w	#5,d0
	beq.s	mt_loop3
	rts

mt_loop2:
	moveq	#0,d0
	move.b	3(a6),d0
	lsr.b	#4,d0
	bra.s	mt_cont
mt_loop3:
	moveq	#$00,d0
	move.b	3(a6),d0
	and.b	#$0f,d0
	bra.s	mt_cont
mt_loop4:
	move.w	16(a6),d2
	bra.s	mt_endpart
mt_cont:
	add.w	d0,d0
	moveq	#0,d1
	move.w	16(a6),d1
	lea	mt_arpeggio(PC),a0
mt_loop5:
	move.w	(a0,d0),d2
	cmp.w	(a0),d1
	beq.s	mt_endpart
	addq.l	#2,a0
	bra.s	mt_loop5
mt_endpart:
	move.w	d2,6(a5)
	rts

mt_rout2:
	move.l	mt_rdata(pc),a0
	move.l	a0,a3
	add.l	#$0c,a3
	move.l	a0,a2
	move.l	mt_forst,a4
	add.l	(a4),a2
	add.l	16(a4),a0
	move.l	mt_partnrplay(PC),d0
	moveq	#0,d1
	move.b	(a2,d0),d1
	asl.l	#8,d1
	asl.l	#2,d1
	add.l	mt_partnote(PC),d1
	move.l	d1,mt_partpoint
	clr.w	mt_dmacon

	lea	$dff0a0,a5
	lea	mt_aud1temp(PC),a6
	bsr	mt_playit
	lea	$dff0b0,a5
	lea	mt_aud2temp(PC),a6
	bsr	mt_playit
	lea	$dff0c0,a5
	lea	mt_aud3temp(PC),a6
	bsr	mt_playit
	lea	$dff0d0,a5
	lea	mt_aud4temp(PC),a6
	bsr	mt_playit
	move.w	#$01f4,d0
mt_rls:	dbf	d0,mt_rls

	move.w	#$8000,d0
	or.w	mt_dmacon,d0
	move.w	d0,$dff096

	lea	mt_aud4temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice3
	move.l	10(a6),$dff0d0
	move.w	#1,$dff0d4
mt_voice3:
	lea	mt_aud3temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice2
	move.l	10(a6),$dff0c0
	move.w	#1,$dff0c4
mt_voice2:
	lea	mt_aud2temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice1
	move.l	10(a6),$dff0b0
	move.w	#1,$dff0b4
mt_voice1:
	lea	mt_aud1temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice0
	move.l	10(a6),$dff0a0
	move.w	#1,$dff0a4
mt_voice0:
	move.l	mt_partnote(PC),d0
	add.l	#$10,d0
	move.l	d0,mt_partnote
	cmp.l	#$400,d0
	bne.s	mt_stop
mt_higher:
	clr.l	mt_partnote
	addq.l	#1,mt_partnrplay
	moveq	#0,d0
	move.w	mt_maxpart(PC),d0
	move.l	mt_partnrplay(PC),d1
	cmp.l	d0,d1
	bne.s	mt_stop
	clr.l	mt_partnrplay
mt_stop:tst.w	mt_status
	beq.s	mt_stop2
	clr.w	mt_status
	bra.s	mt_higher
mt_stop2:
	rts

mt_playit:
	move.l	(a0,d1.l),(a6)
	addq.l	#4,d1
	moveq	#0,d2
	move.b	2(a6),d2
	and.b	#$f0,d2
	lsr.b	#4,d2

	move.b	(a6),d0
	and.b	#$f0,d0
	or.b	d0,d2
	tst.b	d2
	beq.s	mt_nosamplechange

	moveq	#0,d3
	lea	mt_samples(PC),a1
	move.l	d2,d4
	lsl.l	#2,d2
	mulu	#$1e,d4
	move.l	(a1,d2),4(a6)
	move.w	(a3,d4.l),8(a6)
	move.w	2(a3,d4.l),18(a6)
	move.w	4(a3,d4.l),d3
	tst.w	d3
	beq.s	mt_displace
	move.l	4(a6),d2
	add.l	d3,d2
	move.l	d2,4(a6)
	move.l	d2,10(a6)
	move.w	6(a3,d4.l),8(a6)
	move.w	6(a3,d4.l),14(a6)
	move.w	18(a6),8(a5)
	bra.s	mt_nosamplechange

mt_displace:
	move.l	4(a6),d2
	add.l	d3,d2
	move.l	d2,10(a6)
	move.w	6(a3,d4.l),14(a6)
	move.w	18(a6),8(a5)
mt_nosamplechange:
	move.w (a6),d0
	andi.w #$fff,d0			;it's the bug
	tst.w	d0			;of the real
	beq.s	mt_retrout		;source replay
	move.w	(a6),16(a6)
	move.w	20(a6),$dff096
	move.l	4(a6),(a5)
	move.w	8(a6),4(a5)
	move.w	(a6),d0
	andi.w #$fff,d0			;second bug
	move.w d0,6(a5)			;of the source
	move.w	20(a6),d0
	or.w	d0,mt_dmacon

mt_retrout:
	tst.w	(a6)
	beq.s	mt_nonewper
	move.w	(a6),22(a6)

mt_nonewper:

	BSR.L MT_EQ		;BRANCHEMENT SUR ROUTINE EQUALIZER

	move.b	2(a6),d0
	and.b	#$0f,d0
	cmp.b	#$0b,d0
	beq.s	mt_posjmp
	cmp.b	#$0c,d0
	beq.s	mt_setvol
	cmp.b	#$0d,d0
	beq.s	mt_break
	cmp.b	#$0e,d0
	beq.s	mt_setfil
	cmp.b	#$0f,d0
	beq.s	mt_setspeed
	rts

mt_posjmp:
	not.w	mt_status
	moveq	#0,d0
	move.b	3(a6),d0
	subq.b	#1,d0
	move.l	d0,mt_partnrplay
	rts

mt_setvol:
	move.b	3(a6),8(a5)
	rts

mt_break:
	not.w	mt_status
	rts

mt_setfil:
	moveq	#0,d0
	move.b	3(a6),d0
	and.b	#1,d0
	rol.b	#1,d0
	and.b	#$fd,$bfe001
	or.b	d0,$bfe001
	rts

mt_setspeed:
	move.b	3(a6),d0
	and.b	#$0f,d0
	beq.s	mt_back
	clr.w	mt_counter
	move.b	d0,mt_cool+3
mt_back:rts

MT_EQ: 	CMP.L #MT_AUD1TEMP,A6		;ROUTINE DE TEST DES NOTES
	BNE.S MT_NEXT1
	MOVE.W (A6),EQ1P
        RTS
MT_NEXT1: CMP.L #MT_AUD2TEMP,A6
	BNE.S MT_NEXT2
	MOVE.W (A6),EQ2P
	RTS
MT_NEXT2: CMP.L #MT_AUD3TEMP,A6
	BNE.S MT_NEXT3
	MOVE.W (A6),EQ3P
	RTS
MT_NEXT3: 
	MOVE.W (A6),EQ2P
	RTS

mt_aud1temp:
	blk.w	10,0
	dc.w	1
	blk.w	2,0
mt_aud2temp:
	blk.w	10,0
	dc.w	2
	blk.w	2,0
mt_aud3temp:
	blk.w	10,0
	dc.w	4
	blk.w	2,0
mt_aud4temp:
	blk.w	10,0
	dc.w	8
	blk.w	2,0
mt_partnote:	dc.l	0
mt_partnrplay:	dc.l	0
mt_counter:	dc.w	0
mt_partpoint:	dc.l	0
mt_samples:	dc.l	0
mt_sample1:	blk.l	31,0
mt_maxpart:	dc.w	0
mt_dmacon:	dc.w	0
mt_status:	dc.w	0
mt_forst:	dc.l	0

mt_forst20:	dc.l 472,600,14,470,600
mt_forst23:	dc.l $3b8,$438,$1e,$3b6,$43c
mt_arpeggio:
	dc.w $0358,$0328,$02fa,$02d0,$02a6,$0280,$025c
	dc.w $023a,$021a,$01fc,$01e0,$01c5,$01ac,$0194,$017d
	dc.w $0168,$0153,$0140,$012e,$011d,$010d,$00fe,$00f0
	dc.w $00e2,$00d6,$00ca,$00be,$00b4,$00aa,$00a0,$0097
	dc.w $008f,$0087,$007f,$0078,$0071,$0000,$0000,$0000
mt_rdata:	dc.l mt_data

; EQUALIZER
EQ1P: 	DC.W 	381
EQ2P: 	DC.W 	381
EQ3P: 	DC.W 	381
EQ4P: 	DC.W 	381

;====================
EVEN				;NOTRE LISTE COPPER
NEWCOPPER:   
	DC.W	$008E,$3581	;DIMENSIONS DE L'ECRAN
	DC.W	$0090,$35D1	;256 LIGNES + 35 LIGNES = 291 LIGNES

	DC.W	$0092,$0038,$0094,$00D0

	;POINTEURS ADRESSE DES PLANS DE L'IMAGE

	DC.W $00E0,FOND_EQUA+[40*0]/65536
	DC.W $00E2,FOND_EQUA+[40*0] & 65535   


	;REGISTRE POUR CHOISIR RESOLUTION	

	DC.W	$0100,$0200		;0 PLANS+MODE COULEURS

	;DECALAGE ECRAN - INUTILISE ICI

	DC.W	$0102,$0000

	;PRIORITE DES PLANS ET SPRITES - INUTILISE ICI

	DC.W 	$0104,$0000

	;MODULOS DES PLANS

	DC.W	$0108,$000	;MODULOS PLANS PAIRS
	DC.W 	$010A,$000	;MODULOS PLANS IMPAIRS

	;POINTEURS DES SPRITES - MIS A 0 SI PAS DE SPRITES

	DC.W	$0120,$0000,$0122,$0000
	DC.W	$0124,$0000,$0126,$0000
	DC.W	$0128,$0000,$012A,$0000	;PAS DE SPRITES
	DC.W	$012C,$0000,$012E,$0000
	DC.W	$0130,$0000,$0132,$0000
	DC.W	$0134,$0000,$0136,$0000
	DC.W	$0138,$0000,$013A,$0000
	DC.W	$013C,$0000,$013E,$0000

	;REGISTRES DES COULEURS

	DC.W	$0180,$0222	;COULEUR 00
	DC.W	$0182,$0FFF	;COULEUR 01
	DC.W	$0184,$0BDD	;COULEUR 02
	DC.W	$0186,$0899	;COULEUR 03
	DC.W	$0188,$0455	;COULEUR 04
	DC.W	$018A,$0333	;COULEUR 05
	DC.W	$018C,$0222	;COULEUR 06
	DC.W	$018E,$0111	;COULEUR 07
	DC.W	$0190,$0EEF	;COULEUR 08
	DC.W	$0192,$0CCF	;COULEUR 09
	DC.W	$0194,$099F	;COULEUR 10
	DC.W	$0196,$055F	;COULEUR 11
	DC.W	$0198,$000F	;COULEUR 12
	DC.W	$019A,$000A	;COULEUR 13
	DC.W	$019C,$0006	;COULEUR 14
	DC.W	$019E,$0003	;COULEUR 15
	DC.W	$01A0,$0DEF	;COULEUR 16	;LES COULEURS DE 16 A 31 SONT
	DC.W	$01A2,$0BEF	;COULEUR 17	;AUSSI CELLES DES SPRITES
	DC.W	$01A4,$0ADF	;COULEUR 18
	DC.W	$01A6,$07BD	;COULEUR 19	;LES COULEURS 16 A 31 NE SONT
	DC.W	$01A8,$058A	;COULEUR 20	;PAS UTILISEES DANS LE MODE
	DC.W	$01AA,$0357	;COULEUR 21	;HOLD AND MODIFY (HAM)
	DC.W	$01AC,$0234	;COULEUR 22
	DC.W	$01AE,$0011	;COULEUR 23
	DC.W	$01B0,$0FD0	;COULEUR 24
	DC.W	$01B2,$0FA0	;COULEUR 25
	DC.W	$01B4,$0E80	;COULEUR 26
	DC.W	$01B6,$0C60	;COULEUR 27
	DC.W	$01B8,$0A30	;COULEUR 28
	DC.W	$01BA,$0720	;COULEUR 29
	DC.W	$01BC,$0510	;COULEUR 30
	DC.W	$01BE,$0300	;COULEUR 31

;MET RESOLUTION A 1 PLAN

DC.W $5601,$FFFE,$0100,$1200,$0180,$0000

DC.W		 $182,$000		;PETIT EFFET COPPER DE COULEUR
DC.W $5701,$FFFE,$182,$001		;POUR RENDRE LES BARRES PLUS AGREABLES
DC.W $5801,$FFFE,$182,$002
DC.W $5901,$FFFE,$182,$003
DC.W $5A01,$FFFE,$182,$004
DC.W $5B01,$FFFE,$182,$005
DC.W $5C01,$FFFE,$182,$006
DC.W $5D01,$FFFE,$182,$007
DC.W $5E01,$FFFE,$182,$008
DC.W $5F01,$FFFE,$182,$009
DC.W $6001,$FFFE,$182,$00a
DC.W $6101,$FFFE,$182,$00b
DC.W $6201,$FFFE,$182,$00c
DC.W $6301,$FFFE,$182,$00d
DC.W $6401,$FFFE,$182,$00e
DC.W $6501,$FFFE,$182,$00f
DC.W $6601,$FFFE,$182,$01f
DC.W $6701,$FFFE,$182,$02f
DC.W $6801,$FFFE,$182,$03f
DC.W $6901,$FFFE,$182,$04f
DC.W $6A01,$FFFE,$182,$05f
DC.W $6B01,$FFFE,$182,$06f
DC.W $6C01,$FFFE,$182,$07f
DC.W $6D01,$FFFE,$182,$08f
DC.W $6E01,$FFFE,$182,$09f
DC.W $6F01,$FFFE,$182,$0Af
DC.W $7001,$FFFE,$182,$0Bf
DC.W $7101,$FFFE,$182,$0Cf
DC.W $7201,$FFFE,$182,$0Df
DC.W $7301,$FFFE,$182,$0Ef
DC.W $7401,$FFFE,$182,$0Ff
DC.W $7501,$FFFE,$182,$1Ff
DC.W $7601,$FFFE,$182,$2Ff
DC.W $7701,$FFFE,$182,$3Ff
DC.W $7801,$FFFE,$182,$FFF

;MET RESOLUTION A 0
DC.W $7F01,$FFFE,$100,0,$180,$222



	;INSTRUCTIONS POUR AVOIR UN ECRAN PAL (256 LIGNES DE HAUT)

	DC.W $FFDF,$FFFE

DC.W $0101,$FFFE

DC.W $0100,0		;MET RESOLUTION NULLE

DC.W $0180,$0000	;REGISTRES DES COULEURS
DC.W $0182,$0a50	;POUR LE SCROLL
DC.W $0184,$0dc0
DC.W $0186,$0606
DC.W $0188,$0818
DC.W $018a,$0a2a
DC.W $018c,$0d3d
DC.W $018e,$0f5f

DC.W	$0092,$0030	;PASSAGE EN OVERSCAN
DC.W	$0094,$00D8


DC.W $0201,$FFFE

		DC.W $0100,$3200	;RESOLUTION 3 PLANS = 8 COULEURS

		DC.W $10A,110-4		;MODULO = 10 + 50 + 50 - 4
					;-4 POUR PASSAGE EN OVERSCAN
		DC.W $108,110-4		;MODULO POUR FORMAT RAW BLITTER

		;POINTEURS DE PLANS DU FOND DE SCROLL

		DC.W $00E0,SCROLL+[50*0]/65536	
		DC.W $00E2,SCROLL+[50*0] & 65535
		DC.W $00E4,SCROLL+[50*1]/65536
		DC.W $00E6,SCROLL+[50*1] & 65535
		DC.W $00E8,SCROLL+[50*2]/65536  
		DC.W $00EA,SCROLL+[50*2] & 65535

dc.w	$0201+[$100*35],$fffe,$100,0,$180,$222

DC.L $FFFFFFFE ;FIN LISTE COPPER
EVEN
FINDEMO: