org $30000	;EMPLACEMENT EN MEMOIRE
load $30000	;DE NOTRE PROGRAMME

BEGIN:
JMP START
;=====================================================================
EXECBASE=4
OPENLIBRARY=-408
CLOSELIBRARY=-414
SUPERSTATE=-150
USERSTATE=-156	
FORBID=-132
PERMIT=-138
ADDINTSERVER=-168
REMINTSERVER=-174
Open=-30
Close=-36
Read=-42
Write=-$0030
Delay=-$00c6
;=====================================================================
BLTCON0=$DFF040		
BLTCON1=$DFF042
BLTAFWM=$DFF044
BLTALWM=$DFF046
BLTCPTH=$DFF048
BLTCPTL=$DFF04A
BLTBPTH=$DFF04C
BLTBPTL=$DFF04E
BLTAPTH=$DFF050
BLTAPTL=$DFF052
BLTDPTH=$DFF054
BLTDPTL=$DFF056
BLTSIZE=$DFF058
BLTCMOD=$DFF060
BLTBMOD=$DFF062
BLTAMOD=$DFF064
BLTDMOD=$DFF066
BLTCDAT=$DFF070
BLTBDAT=$DFF072
BLTADAT=$DFF074
DMACONR=$DFF002
;==================================
IMAGE=$45000			;L'IMAGE SE TROUVE A $40000

SCROLL=IMAGE+[40*256*5]		;LE FOND DU SCROLL SE TROUVE JUSTE
				;APRES L'IMAGE
FONT=SCROLL+[50*35*3*3]		;LE DESSIN DES CARACTERES SE TROUVE
				;JUSTE APRES LE FOND DU SCROLL
MT_DATA=FONT+[40*256*3]		;LA MUSIQUE SE TROUVE JUSTE APRES
				;LES CARACTERES
FINDATA: DC.L 0
;==================================
START:  
jsr opendos

MOVEM.L D0-D7/A0-A6,-(A7)	;SAUVE REGISTRES
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR FORBID(A6)    		;SAUTE SOUS PROGRAMME: INTERDIT MULTITACHE
JSR OPENLIB  			;SAUTE SOUS PROGRAMME: OUVERTURE LIBRAIRIES

CLEARSCROLL:			;ON EFFACE LE FOND DU SCROLL POUR EVITER
LEA SCROLL,A1			;D'AVOIR DES BIZARRERIES A L'ECRAN 
MOVE.W #25*35*3*3,D0
CLS:
MOVE.W #0,(A1)+
DBF D0,CLS

MOVE.L #TEXT,PTEXT		;ON MET LE POINTEUR DE LETTRE SUR LE DEBUT
MOVE.W #0,COMPT			;DU TEXTE. ET LE COMPTEUR A 0
MOVE.L #5250,hauteur
move.l #5400,hauteurdavant
move.w #1,choix
move.w #0,choix_line
move.w #0,line

BSR.L INIT_MUSIQUE		;INITIALISATION DE LA MUSIQUE

BSR.L SETCOPPER			;SAUTE SOUS PROGRAMME: MET EN PLACE LISTE COPPER
BSR.L NEWIRQ3			;SAUTE SOUS PROGRAMME: MET EN PLACE ROUTINE D'INTERRRUPTION

WAIT:
CMP.B #$E0,$DFF006		;ATTENDANT 200 IEME LIGNE RASTER
BNE.S WAIT			;SINON RETOURNE A WAIT

BTST	#6,$BFE001		;ATTENDANT PRESSION SUR BOUTON GAUCHE SOURIS
BNE.S	WAIT			;SINON RETOURNE A WAIT
 				;SI OUI  FIN
END: 				;FIN:	
BSR.L STOP_MUSIQUE		;ARRET DE LA MUSIQUE
BSR.L STOPIRQ3        		;SAUTE SOUS PROGRAMME: STOPPE INTERRUPTION
BSR.L CLRCOPPER       		;SAUTE SOUS PROGRAMME: RESTAURE ANCIENNE LISTE COPPER
BSR.L CLOSELIB        		;SAUTE SOUS PROGRAMME: FERME LIBRAIRIES 
MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
JSR PERMIT(A6)      		;AUTORISE MULTITACHE
                      
MOVEM.L (A7)+,D0-D7/A0-A6	;RESTAURE REGISTRES
RTS
;======================
opendos:
move.l execbase,a6
move.l #dosname,a1
move.l #0,d0
jsr openlibrary(a6)
beq error
move.l d0,dosbase

openwin:
move.l dosbase,a6
move.l #fenetre,d1
move.l #1006,d2
jsr open(a6)
beq closedos
move.l d0,winhandle

;===== REQUEST ===========
request:
move.l dosbase,a6	>
move.l winhandle,d1      >
move.l #texte0,d2	  >
move.l #texte0fin,d3	   >
sub.l d2,d3		    >
jsr write(a6)		     >
			      >  DEMANDE TAILLE ZICMU
move.l dosbase,a6	     >
move.l winhandle,d1	    >
move.l #lenzic,d2	   >
move.l #8,d3              >
jsr read(a6)	 	 >
move.b d0,taille	>

move.l #MT_DATA+LENZIC,FINDATA		;FIN DES DATAS APRES LA MUSIQUE

move.l dosbase,a6	>
move.l winhandle,d1      >
move.l #texte9,d2	  >
move.l #texte9fin,d3	   >
sub.l d2,d3		    >
jsr write(a6)		     >
                              > DEMANDE DE TEXTE
move.l dosbase,a6	     >
move.l winhandle,d1	    >
move.l #text,d2 	   >
move.l #999,d3            >
jsr read(a6)	 	 >
move.l d0,taille2	>

move.l #text,d1
move.l taille2,d2
add.l d1,d2
sub.b #1,d2
move.l d2,a0
move.b #' ',(a0)

;=========== OUVRE FICHIER =============
openfile:
move.l dosbase,a6
move.l #nom1,d1
move.l #1005,d2
jsr open(a6)
move.l d0,datahandle
jsr polo1

move.l dosbase,a6
move.l datahandle,d1
move.l #image,d2
move.l #[40*256*5],d3
jsr read(a6)

move.l dosbase,a6
move.l #nom2,d1
move.l #1005,d2
jsr open(a6)
move.l d0,datahandle2
jsr polo2

move.l dosbase,a6
move.l datahandle2,d1
move.l #font,d2
move.l #[40*256*3],d3
jsr read(a6)

move.l dosbase,a6
move.l #nom3,d1
move.l #1005,d2
jsr open(a6)
move.l d0,datahandle3
jsr polo3

move.l dosbase,a6
move.l datahandle3,d1
move.l #mt_data,d2
move.l #lenzic,d3
jsr read(a6)

closewin:
move.l winhandle,d1
move.l dosbase,a6
jsr close(a6)

closedos:
move.l execbase,a6
move.l dosbase,a1
jsr closelibrary(a6)
rts

polo1:
move.l dosbase,a6
move.l winhandle,d1
move.l #texte8,d2
move.l #texte8fin,d3
sub.l d2,d3
jsr write(a6)
rts

polo2:
move.l dosbase,a6
move.l winhandle,d1
move.l #texte7,d2
move.l #texte7fin,d3
sub.l d2,d3
jsr write(a6)
rts

polo3:
move.l dosbase,a6
move.l winhandle,d1
move.l #texte6,d2
move.l #texte6fin,d3
sub.l d2,d3
jsr write(a6)
rts

dosbase: dc.l 0
winhandle: dc.l 0
datahandle: dc.l 0
datahandle2: dc.l 0
datahandle3: dc.l 0

hb: dc.b 0
t: dc.b 0
Lenzic: dc.l 0
taille: dc.b 0
r: dc.b 0
taille2: dc.l 0

dosname: dc.b 'dos.library',0
fenetre: dc.b 'CON:10/10/600/180/ALEX',0
nom1: dc.b 'PIC.RAW',0
nom2: dc.b 'FONT.RAW',0
nom3: dc.b 'MOD.zicmu',0

texte0: dc.b 'Entrez la taille de votre muzic: '
texte0fin:
texte8: dc.b 10,'Je charge le graphisme...',10
texte8fin:
texte7: dc.b 10,'Je charge les fontes...',10
texte7fin:
texte6: dc.b 10,'Je charge la zicmu...',10
texte6fin:
texte9: dc.b 'Caracteres de commande des lettres: ',10,' ABCDEFGHI',10,'JKLMNOPQRS',10,'TUVWXYZ.,:',10,'()à#!?-*^/',10,'0123456789',10,10,'Entrez votre texte (999 caractères maximum): '
texte9fin:

;========================
NEWIRQ3:			;MET EN PLACE NOTRE ROUTINE 
move.l EXECBASE,A6		;D'INTERRUPTION
lea	irqstr,a1
move.l	#5,d0
jsr	addintserver(a6)
move.l	d0,irq
beq.s	irqerror
rts
irqerror:
rts
;==========================
STOPIRQ3:			;RESTAURE ANCIENNE ROUTINE
movem.l	a0-a6/d0-d7,-(sp)	;D'INTERRUPTION
	tst.l	irq
	beq.s	irqoff1
	move.l	execbase,a6
	lea	irqstr,a1
	move.l	#32,d0
	jsr	remintserver(a6)
irqoff1:movem.l	(sp)+,a0-a6/d0-d7
	rts
irqstr:
	dc.l	0,0
	dc.b	2,-127
	dc.l	0,irqdat,interrupt
irqdat:	dc.l	0,0,0,0
irq:	dc.l	0
;============================
interrupt:			;NOTRE ROUTINE D'INTERRUPTION	
movem.l	a0-a6/d0-d7,-(sp)

stop:
btst #10,$dff016
beq ok_stop
bsr.l init_colorscroll
bsr.l hbscroll
ok_stop:
BSR.L PLAY_MUSIQUE		;VA A LA ROUTINE POUR JOUER LA MUSIQUE

movem.l	(sp)+,a0-a6/d0-d7
rts
;============================
OPENLIB:  			;OUVERTURE DE LA LIBRAIRIE GRAPHIQUE
move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
lea gfxname,a1			;MET NOM DE LA LIBRAIRIE DANS A1
move.l #$0,d0           	;MET 0 DANS D0
jsr openlibrary(a6)		;OUVRE LIBRAIRIE
tst d0				;TESTE D0
beq.s error			;SI = A 0   VA A ERROR = SORTIE
move.l d0,gfxbase       	;SI NON, MET ADRESSE D0 DANS GFXBASE
add.l #$32,d0			;AJOUTE $32 A CETTE ADRESSE
move.l d0,coppertr      	;MET D0=ADRESSE ACTUELLE LISTE COPPER
rts				;DANS COPPERTR
even
gfxname: dc.b 'graphics.library',0 	;NOM DE LA LIBRAIRIE
even
gfxbase: dc.l 0				;POINTEUR POUR LA GRAPHICS LIBRARY
coppertr: dc.l 0			;POINTEUR POUR ADRESSE LISTE COPPER
;====================
CLOSELIB: 			;FERMETURE LIBRAIRIE
move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
move.l gfxbase,a1		;MET NOM DE LA LIBRAIRIE DANS A1
jsr closelibrary(a6)		;FERME LIBRAIRIE
rts
;====================
ERROR:				;SI ERREUR
illegal				;SORTIE
rts
;====================
SETCOPPER:			;MET EN PLACE NOTRE LISTE COPPER
move.l coppertr,a0		;MET ADRESSE ACTUEL COPPER DANS A0
move.l (a0),oldcopper		;MET CONTENU DANS OLDCOPPER
move.l #newcopper2,(a0)		;MET NOTRE LISTE COPPER DANS A0
move.w #$81c0,$dff096		;ACTIVE LISTE COPPER
rts		
oldcopper: dc.l 0
;====================
CLRCOPPER:			;RESTAURE ANCIENNE LISTE COPPER
move.l coppertr,a0		;MET ANCIENNE ADRESSE DANS A0
move.l oldcopper,(a0)		;MET CONTENU DANS A0
move.w #$80a0,$dff096		;REACTIVE ANCIENNE COPPER
rts
;====================
WAIT_BLITTER:			;ROUTINE POUR ATTENDRE QUE LE BLITTER
BTST #14,DMACONR		;EST FINI SON PRECEDENT TRAVAIL
BNE.S WAIT_BLITTER
RTS
;====================
HBSCROLL:
cmp.w #0,choix_line
bne ok_choix_line
add.w #2,line

ok_choix_line:
sub.w #1,line

cmp.w #35*2-11,line
bne ok_colors_plus1
move.w #1,choix_line
ok_colors_plus1:

cmp.w #0,line
bne ok_colors_mois1
move.w #0,choix_line
ok_colors_mois1:

move.w #0,compt_colors
move.w #0,choix_colors
move.w #$444,colors
lea colorscroll,a1
move.w line,d1

met_line:
cmp.w #0,d1
bne fait_line
jmp init_line
fait_line:
move.l (a1)+,d0
move.l (a1)+,d0
sub.w #1,d1
jmp met_line

init_line:
add.w #1,compt_colors
move.w colors,(a1)+

cmp.w #0,choix_colors
bne ok_choi_line
add.w #$444,colors
ok_choi_line:
sub.w #$222,colors

cmp.w #$eee,colors
bne ok_line_plus
move.w #1,choix_colors
ok_line_plus:

move.l (a1)+,d0
move.w (a1)+,d0

cmp.w #12,compt_colors
bne init_line

BSR.L SCROLLING			;VA A LA ROUTINE DE SCROLLING

move.l hauteurdavant,a1
add.l #scroll,a1
cmp.w #1,choix
bne ok_line
add.l #150*34,a1
ok_line:
move.w #25*2,d0
cls_line:
move.w #0,(a1)+
dbf d0,cls_line

move.l hauteur,hauteurdavant
cmp.w #0,choix
bne ok_choix
add.l #300,hauteur
ok_choix:
sub.l #150,hauteur

cmp.l #5400,hauteur
bne ok_hauteur
move.l #5100,hauteur
move.w #1,choix
ok_hauteur:
cmp.l #-150,hauteur
bne ok_hauteur2
move.l #150,hauteur
move.w #0,choix
ok_hauteur2:
rts
;===================
SCROLLING:			;ROUTINE DU SCROLLING
BSR.L SEARCH_CHAR		;AFFICHE UN NOUVEAU CARACTERE
BSR.L SCROLLTEXT		;SCROLLE LE FOND DU SCROLL
RTS
;===================	
SCROLLTEXT:			
LEA SCROLL,A0 			;ON POINTE A0 SUR LE FOND DU SCROLL
add.l hauteurdavant,a0
	
BSR.L WAIT_BLITTER		;ON ATTEND QUE LE BLITTER EST FINI SON 
				;PRECEDENT TRAVAIL

LEA SCROLL-2,A1			;ON POINTE A1 SUR 16 PIXELS AVANT 
add.l hauteur,a1
				;LE FOND DU SCROLL. 2 = 16 PIXELS
move.l #$c9f00000,d0
cmp.w #0,choix
bne ok_
add.l #2,d0
add.l #50*35*3,a0
add.l #50*35*3+2,a1
sub.l #$80000000,d0
ok_:

MOVE.L A0,BLTAPTH		;MET ADRESSE DE A0 DANS SOURCE BLITTER A
MOVE.L A1,BLTDPTH		;MET ADRESSE DE A1 DANS DESTINATION BLITTER D
MOVE.W #0,BLTAMOD  		;MET 0 DANS MODULO SOURCE A
MOVE.W #0,BLTDMOD		;MET 0 DANS MODULO DESTINATION D
MOVE.L #$FFFFFFFF,BLTAFWM	;MASQUE DU 1ER ET DU DERNIER MOT
move.l d0,BLTCON0	    	;MET MIMTERN ET DECALAGE DANS BLTCON0
				;$C = $F - $4 = 16 - 4 = 12
				;4 PIXELS DE DECALAGE VERS LA GAUCHE

				;$9 -> POUR 1 SOURCE BLITTER
				;$F0 -> MINTERM POUR COPIE DIRECTE
				;$0000 -> MIS A 0 CAR SOURCE B INITULISE	

MOVE.W #[35*64*3]+25,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
				;TAILLE = [HAUTEUR * 64]+[LARGEUR/2]
RTS
;============
SEARCH_CHAR:
ADD.W #1,COMPT			;AJOUTE 1 AU COMPTEUR
CMP.W #8,COMPT           	;COMPARE A 8 CAR 8 * 4 PIXELS DE DECALAGE
				;EGALE A 32 SOIT LA LARGEUR D'UNe LETTRE
BNE.L SEARCHAR3			;SI PAS EGAL A 8 ON SORT
MOVE.W #0,COMPT			;SI OUI ON REMET COMPTEUR A 0
				;ET ON CONTINU

MOVE.L PTEXT,A0          	;MET POINTEUR TEXTE DANS A0
CLR.L D0			;ON EFFACE CONTENU DE D0
MOVE.B (A0),D0			;MET LE CONTENU DU POINTEUR TEXTE DANS D0
LEA COMPTEUR_CHAR,A1		;EN POINTE A1 SUR LA TABLE DES LETTRES
CLR.L D1			;ON EFFACE CONTENU DE D1
MOVE.B #-1,D1			;ON MET -1 DANS D1

SEARCHAR1:

ADD.B #1,D1     		;ON AJOUTE 1 A D1         
CMP.B (A1)+,D0			;ON COMPARE LES LETTRES DE LA TABLE
				;AVEC CELLE CONTENU DANS D0
BNE SEARCHAR1			;SI PAS LA MEME ON RECOMMENCE AVEC LA
				;LETTRE SIUVANTE DANS LA TABLE
				;SI C'EST LA MEME ON CONTINU
MULU #4,D1              	;ON MULTIPLIE D1 PAR 4
LEA TABLE_CHAR,A0       	;ON POINTE A0 SUR LE DEBUT DE LA TABLE
				;D'ADRESSE DES IMAGES DES LETTRES
MOVE.L (A0,D1),A2       	;ET ON MET L'ADRESSE DE LA LETTRE DANS A2

LEA SCROLL,A3			;ON POINTE A3 SUR LA POSITION SCROLL+46
ADD.L #46,A3        		;SOIT A 46*8 = 368 PIXELS A DROITE DU 
add.l hauteurdavant,a3		;COIN SUPERIEUR DROIT DU FOND DE SCROLL
				;SOIT DANS LA PARTIE INVISIBLE DU SCROLL	

BSR.L WAIT_BLITTER        	;ON ATTENDS LE BLITTER	
MOVE.L A2,BLTAPTH       	;ON MET ADRESSE DE A2 DANS SOURCE BLITTER A
MOVE.L A3,BLTDPTH       	;ON MET ADRESSE DE A3 DANS DESTINATION BLITTER D

MOVE.W #40-4,BLTAMOD  		;ON MET 40-4 DANS MODULO SOURCE A
				;CAR NOTRE LETTRE FAIT 32 PIXELS DE LARGE SOIT
				;4 MOTS (4*8=32) ET L'IMAGE QUI LA CONTIENT
				;FAIT 320 PIXELS DE LARGE SOIT 40 MOTS
	
MOVE.W #50-4,BLTDMOD   	        ;ON MET 50-4 DANS MODULO DESTINATION D
				;CAR LE FOND DE SCROLL FAIT 400 PIXELS DE LARGE
				;SOIT 50 MOTS

MOVE.L #$09F00000,BLTCON0	;$0 -> PAS DE DECALAGE DE LA SOURCE A
				;$9 -> POUR 1 SOURCE BLITTER A
				;$F0 -> MINTERM POUR COPIE DIRECTE

MOVE.W #[35*3*64]+2,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
				;TAILLE = [HAUTEUR * 64]+[LARGEUR/2]

ADD.L #1,PTEXT          	;ON AJOUTE 1 AU POINTEUR DE TEXTE
MOVE.L PTEXT,A0			;ON MET POINTEUR DE TEXTE DANS A0
TST.B (A0)              	;SI PAS EGAL A 0
BNE SEARCHAR3			;ON VA A SEARCHAR3
MOVE.L #TEXT,PTEXT		;SINON ON REMET POINTEUR DE TEXTE AU DEBUT
				;DU TEXTE A SCROLLER

SEARCHAR3:
RTS

EVEN
choix: dc.w 0
hauteurdavant: dc.l 0
hauteur: dc.l 0
COMPT: DC.W 0			;COMPTEUR 
choix_colors: dc.w 0
choix_line: dc.w 0
compt_colors: dc.w 0
compt_line: dc.w 0
colors: dc.w 0
line: dc.w 0
PTEXT: DC.L 0			;POINTEUR DE TEXTE
;=================================================================
even
init_colorscroll:
move.w #0,choix_colors
move.w #0,colors
move.w #0,compt_colors
lea colorscroll,a1

init_colors:
add.w #1,compt_colors
move.w colors,(a1)+

cmp.w #0,choix_colors
bne ok_choix_colors
add.w #2,colors
ok_choix_colors:
sub.w #1,colors

cmp.w #$f,colors
bne ok_colors_plus
move.w #1,choix_colors
ok_colors_plus:

cmp.w #0,colors
bne ok_colors_mois
move.w #0,choix_colors
ok_colors_mois:

move.l (a1)+,d0
move.w (a1)+,d0

cmp.w #71,compt_colors
bne init_colors
rts
;===================
COMPTEUR_CHAR: DC.B ' ABCDEFGHI'	;TABLE DES CARACTERES
	       DC.B 'JKLMNOPQRS'	;TELS QU'ILS SONT DISPOSES
	       DC.B 'TUVWXYZ.,:'	;DANS NOTRE IMAGE	
	       DC.B '()@#!?-*^/'
	       DC.B '0123456789%'
         
EVEN
FONT1=FONT		;ADRESSES DES LETTRES PAR LIGNES
FONT2=FONT+[3*35*40] 
FONT3=FONT+[6*35*40]
FONT4=FONT+[9*35*40]
FONT5=FONT+[12*35*40]
EVEN 
TABLE_CHAR: 		;ADRESSES DES LETTRES

DC.L FONT1,FONT1+4,FONT1+8,FONT1+12,FONT1+16,FONT1+20
DC.L FONT1+24,FONT1+28,FONT1+32,FONT1+36
DC.L FONT2,FONT2+4,FONT2+8,FONT2+12,FONT2+16,FONT2+20
DC.L FONT2+24,FONT2+28,FONT2+32,FONT2+36
DC.L FONT3,FONT3+4,FONT3+8,FONT3+12,FONT3+16,FONT3+20
DC.L FONT3+24,FONT3+28,FONT3+32,FONT3+36
DC.L FONT4,FONT4+4,FONT4+8,FONT4+12,FONT4+16,FONT4+20
DC.L FONT4+24,FONT4+28,FONT4+32,FONT4+36
DC.L FONT5,FONT5+4,FONT5+8,FONT5+12,FONT5+16,FONT5+20
DC.L FONT5+24,FONT5+28,FONT5+32,FONT5+36
EVEN

EVEN		;TEXTE A SCROLLER

TEXT: blk.b 1000,0

fin:
;====================
EVEN
;CETTE ROUTINE PERMET DE JOUER TOUS LES MODULES DE SOUNDTRACKERS
;DE LA VERSION 1.0 A LA VERSION 2.6  AINSI QUE CERTAINS MODULES
;NOISETRACKER.

INIT_MUSIQUE:			;INITIALISATION DE LA MUSIQUE
mt_init:move.l	mt_rdata(pc),a0
	cmp.l	#"M.K.",$438(a0)
	bne	mt_st20
	lea	mt_forst23(pc),a2
	move.l	a2,mt_forst
	bra	ok1st23
mt_st20:
	lea	mt_forst20(pc),a2
	move.l	a2,mt_forst
ok1st23:	
	add.l	(a2),a0
	moveq	#$7f,d0
	moveq	#0,d1
mt_init1:
	move.l	d1,d2
	subq.w	#1,d0
mt_init2:
	move.b	(a0)+,d1
	cmp.b	d2,d1
	bgt.s	mt_init1
	dbf	d0,mt_init2
	addq.b	#1,d2

mt_init3:
	move.l	mt_rdata(pc),a0
	lea	mt_sample1(pc),a1
	asl.l	#8,d2
	asl.l	#2,d2
	add.l	4(a2),d2
	add.l	a0,d2
	move.l	8(a2),d0
mt_init4:
	move.l	d2,(a1)+
	moveq	#0,d1
	move.w	42(a0),d1
	asl.l	#1,d1
	add.l	d1,d2
	add.l	#$1e,a0
	dbf	d0,mt_init4

	lea	mt_sample1(PC),a0
	moveq	#0,d0
mt_clear:
	move.l	(a0,d0.w),a1
	clr.l	(a1)
	addq.w	#4,d0
	cmp.w	#$7c,d0
	bne.s	mt_clear

	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	clr.l	mt_partnrplay
	clr.l	mt_partnote
	clr.l	mt_partpoint
	move.l	mt_rdata(pc),a1
	add.l	12(a2),a1
	move.b	(a1),mt_maxpart+1
	rts

STOP_MUSIQUE:			;ARRET DE LA MUSIQUE
mt_end:	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	move.w	#$f,$dff096
	rts

PLAY_MUSIQUE:			;JOUE LA MUSIQUE
mt_music:
	addq.w	#1,mt_counter
mt_cool:cmp.w	#6,mt_counter
	bne.s	mt_notsix
	clr.w	mt_counter
	bra	mt_rout2

mt_notsix:
	lea	mt_aud1temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp1
	lea	$dff0a0,a5		
	bsr.s	mt_arprout
mt_arp1:lea	mt_aud2temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp2
	lea	$dff0b0,a5
	bsr.s	mt_arprout
mt_arp2:lea	mt_aud3temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp3
	lea	$dff0c0,a5
	bsr.s	mt_arprout
mt_arp3:lea	mt_aud4temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp4
	lea	$dff0d0,a5
	bra.s	mt_arprout
mt_arp4:rts

mt_arprout:
	move.b	2(a6),d0
	and.b	#$0f,d0
	tst.b	d0
	beq	mt_arpegrt
	cmp.b	#$01,d0
	beq.s	mt_portup
	cmp.b	#$02,d0
	beq.s	mt_portdwn
	cmp.b	#$0a,d0
	beq.s	mt_volslide
	rts

mt_portup:
	moveq	#0,d0
	move.b	3(a6),d0
	sub.w	d0,22(a6)
	cmp.w	#$71,22(a6)
	bpl.s	mt_ok1
	move.w	#$71,22(a6)
mt_ok1:	move.w	22(a6),6(a5)
	rts

mt_portdwn:
	moveq	#0,d0
	move.b	3(a6),d0
	add.w	d0,22(a6)
	cmp.w	#$538,22(a6)
	bmi.s	mt_ok2
	move.w	#$538,22(a6)
mt_ok2:	move.w	22(a6),6(a5)
	rts

mt_volslide:
	moveq	#0,d0
	move.b	3(a6),d0
	lsr.b	#4,d0
	tst.b	d0
	beq.s	mt_voldwn
	add.w	d0,18(a6)
	cmp.w	#64,18(a6)
	bmi.s	mt_ok3
	move.w	#64,18(a6)
mt_ok3:	move.w	18(a6),8(a5)
	rts
mt_voldwn:
	moveq	#0,d0
	move.b	3(a6),d0
	and.b	#$0f,d0
	sub.w	d0,18(a6)
	bpl.s	mt_ok4
	clr.w	18(a6)
mt_ok4:	move.w	18(a6),8(a5)
	rts

mt_arpegrt:
	move.w	mt_counter(PC),d0
	cmp.w	#1,d0
	beq.s	mt_loop2
	cmp.w	#2,d0
	beq.s	mt_loop3
	cmp.w	#3,d0
	beq.s	mt_loop4
	cmp.w	#4,d0
	beq.s	mt_loop2
	cmp.w	#5,d0
	beq.s	mt_loop3
	rts

mt_loop2:
	moveq	#0,d0
	move.b	3(a6),d0
	lsr.b	#4,d0
	bra.s	mt_cont
mt_loop3:
	moveq	#$00,d0
	move.b	3(a6),d0
	and.b	#$0f,d0
	bra.s	mt_cont
mt_loop4:
	move.w	16(a6),d2
	bra.s	mt_endpart
mt_cont:
	add.w	d0,d0
	moveq	#0,d1
	move.w	16(a6),d1
	lea	mt_arpeggio(PC),a0
mt_loop5:
	move.w	(a0,d0),d2
	cmp.w	(a0),d1
	beq.s	mt_endpart
	addq.l	#2,a0
	bra.s	mt_loop5
mt_endpart:
	move.w	d2,6(a5)
	rts

mt_rout2:
	move.l	mt_rdata(pc),a0
	move.l	a0,a3
	add.l	#$0c,a3
	move.l	a0,a2
	move.l	mt_forst,a4
	add.l	(a4),a2
	add.l	16(a4),a0
	move.l	mt_partnrplay(PC),d0
	moveq	#0,d1
	move.b	(a2,d0),d1
	asl.l	#8,d1
	asl.l	#2,d1
	add.l	mt_partnote(PC),d1
	move.l	d1,mt_partpoint
	clr.w	mt_dmacon

	lea	$dff0a0,a5
	lea	mt_aud1temp(PC),a6
	bsr	mt_playit
	lea	$dff0b0,a5
	lea	mt_aud2temp(PC),a6
	bsr	mt_playit
	lea	$dff0c0,a5
	lea	mt_aud3temp(PC),a6
	bsr	mt_playit
	lea	$dff0d0,a5
	lea	mt_aud4temp(PC),a6
	bsr	mt_playit
	move.w	#$01f4,d0
mt_rls:	dbf	d0,mt_rls

	move.w	#$8000,d0
	or.w	mt_dmacon,d0
	move.w	d0,$dff096

	lea	mt_aud4temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice3
	move.l	10(a6),$dff0d0
	move.w	#1,$dff0d4
mt_voice3:
	lea	mt_aud3temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice2
	move.l	10(a6),$dff0c0
	move.w	#1,$dff0c4
mt_voice2:
	lea	mt_aud2temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice1
	move.l	10(a6),$dff0b0
	move.w	#1,$dff0b4
mt_voice1:
	lea	mt_aud1temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice0
	move.l	10(a6),$dff0a0
	move.w	#1,$dff0a4
mt_voice0:
	move.l	mt_partnote(PC),d0
	add.l	#$10,d0
	move.l	d0,mt_partnote
	cmp.l	#$400,d0
	bne.s	mt_stop
mt_higher:
	clr.l	mt_partnote
	addq.l	#1,mt_partnrplay
	moveq	#0,d0
	move.w	mt_maxpart(PC),d0
	move.l	mt_partnrplay(PC),d1
	cmp.l	d0,d1
	bne.s	mt_stop
	clr.l	mt_partnrplay
mt_stop:tst.w	mt_status
	beq.s	mt_stop2
	clr.w	mt_status
	bra.s	mt_higher
mt_stop2:
	rts

mt_playit:
	move.l	(a0,d1.l),(a6)
	addq.l	#4,d1
	moveq	#0,d2
	move.b	2(a6),d2
	and.b	#$f0,d2
	lsr.b	#4,d2

	move.b	(a6),d0
	and.b	#$f0,d0
	or.b	d0,d2
	tst.b	d2
	beq.s	mt_nosamplechange

	moveq	#0,d3
	lea	mt_samples(PC),a1
	move.l	d2,d4
	lsl.l	#2,d2
	mulu	#$1e,d4
	move.l	(a1,d2),4(a6)
	move.w	(a3,d4.l),8(a6)
	move.w	2(a3,d4.l),18(a6)
	move.w	4(a3,d4.l),d3
	tst.w	d3
	beq.s	mt_displace
	move.l	4(a6),d2
	add.l	d3,d2
	move.l	d2,4(a6)
	move.l	d2,10(a6)
	move.w	6(a3,d4.l),8(a6)
	move.w	6(a3,d4.l),14(a6)
	move.w	18(a6),8(a5)
	bra.s	mt_nosamplechange

mt_displace:
	move.l	4(a6),d2
	add.l	d3,d2
	move.l	d2,10(a6)
	move.w	6(a3,d4.l),14(a6)
	move.w	18(a6),8(a5)
mt_nosamplechange:
	move.w (a6),d0
	andi.w #$fff,d0			;it's the bug
	tst.w	d0			;of the real
	beq.s	mt_retrout		;source replay
	move.w	(a6),16(a6)
	move.w	20(a6),$dff096
	move.l	4(a6),(a5)
	move.w	8(a6),4(a5)
	move.w	(a6),d0
	andi.w #$fff,d0			;second bug
	move.w d0,6(a5)			;of the source
	move.w	20(a6),d0
	or.w	d0,mt_dmacon

mt_retrout:
	tst.w	(a6)
	beq.s	mt_nonewper
	move.w	(a6),22(a6)

mt_nonewper:
	move.b	2(a6),d0
	and.b	#$0f,d0
	cmp.b	#$0b,d0
	beq.s	mt_posjmp
	cmp.b	#$0c,d0
	beq.s	mt_setvol
	cmp.b	#$0d,d0
	beq.s	mt_break
	cmp.b	#$0e,d0
	beq.s	mt_setfil
	cmp.b	#$0f,d0
	beq.s	mt_setspeed
	rts

mt_posjmp:
	not.w	mt_status
	moveq	#0,d0
	move.b	3(a6),d0
	subq.b	#1,d0
	move.l	d0,mt_partnrplay
	rts

mt_setvol:
	move.b	3(a6),8(a5)
	rts

mt_break:
	not.w	mt_status
	rts

mt_setfil:
	moveq	#0,d0
	move.b	3(a6),d0
	and.b	#1,d0
	rol.b	#1,d0
	and.b	#$fd,$bfe001
	or.b	d0,$bfe001
	rts

mt_setspeed:
	move.b	3(a6),d0
	and.b	#$0f,d0
	beq.s	mt_back
	clr.w	mt_counter
	move.b	d0,mt_cool+3
mt_back:rts

mt_aud1temp:
	blk.w	10,0
	dc.w	1
	blk.w	2,0
mt_aud2temp:
	blk.w	10,0
	dc.w	2
	blk.w	2,0
mt_aud3temp:
	blk.w	10,0
	dc.w	4
	blk.w	2,0
mt_aud4temp:
	blk.w	10,0
	dc.w	8
	blk.w	2,0
mt_partnote:	dc.l	0
mt_partnrplay:	dc.l	0
mt_counter:	dc.w	0
mt_partpoint:	dc.l	0
mt_samples:	dc.l	0
mt_sample1:	blk.l	31,0
mt_maxpart:	dc.w	0
mt_dmacon:	dc.w	0
mt_status:	dc.w	0
mt_forst:	dc.l	0

mt_forst20:	dc.l 472,600,14,470,600
mt_forst23:	dc.l $3b8,$438,$1e,$3b6,$43c
mt_arpeggio:
	dc.w $0358,$0328,$02fa,$02d0,$02a6,$0280,$025c
	dc.w $023a,$021a,$01fc,$01e0,$01c5,$01ac,$0194,$017d
	dc.w $0168,$0153,$0140,$012e,$011d,$010d,$00fe,$00f0
	dc.w $00e2,$00d6,$00ca,$00be,$00b4,$00aa,$00a0,$0097
	dc.w $008f,$0087,$007f,$0078,$0071,$0000,$0000,$0000
mt_rdata:	dc.l mt_data
;====================
even
;====================
EVEN				;NOTRE LISTE COPPER
NEWCOPPER2:   
	DC.W	$008E,$1d81	;DIMENSIONS DE L'ECRAN
	DC.W	$0090,$36d1	;256 LIGNES + 35 LIGNES = 291 LIGNES


dc.w $102,0,$104,0
dc.w $108,106,$10a,106
dc.w $120,0,$122,0
dc.w $124,0,$126,0
dc.w $128,0,$12a,0
dc.w $12c,0,$12e,0
dc.w $130,0,$132,0
dc.w $134,0,$136,0
dc.w $138,0,$13a,0
dc.w $13c,0,$13e,0
dc.w $180,0,$182,$a50
dc.w $184,$dc0,$186,$606
dc.w $188,$818,$18a,$a2a
dc.w $18c,$d3d,$18e,$f5f
dc.w $100,$5200
	DC.W	$0092,$0038,$0094,$00D0

	;POINTEURS ADRESSE DES PLANS DE L'IMAGE

	DC.W $00E0,IMAGE+[40*256*0]/65536
	DC.W $00E2,IMAGE+[40*256*0] & 65535   
	DC.W $00E4,IMAGE+[40*256*1]/65536
	DC.W $00E6,IMAGE+[40*256*1] & 65535
	DC.W $00E8,IMAGE+[40*256*2]/65536
	DC.W $00EA,IMAGE+[40*256*2] & 65535
	DC.W $00EC,IMAGE+[40*256*3]/65536
	DC.W $00EE,IMAGE+[40*256*3] & 65535
	DC.W $00F0,IMAGE+[40*256*4]/65536
	DC.W $00F2,IMAGE+[40*256*4] & 65535


	;MODULOS DES PLANS

	DC.W	$0108,$000	;MODULOS PLANS PAIRS
	DC.W 	$010A,$000	;MODULOS PLANS IMPAIRS


	;REGISTRES DES COULEURS

	DC.W	$0180,$0000	;COULEUR 00
	DC.W	$0182,$0FFF	;COULEUR 01
	DC.W	$0184,$0BDD	;COULEUR 02
	DC.W	$0186,$0899	;COULEUR 03
	DC.W	$0188,$0455	;COULEUR 04
	DC.W	$018A,$0333	;COULEUR 05
	DC.W	$018C,$0222	;COULEUR 06
	DC.W	$018E,$0111	;COULEUR 07
	DC.W	$0190,$0EEF	;COULEUR 08
	DC.W	$0192,$0CCF	;COULEUR 09
	DC.W	$0194,$099F	;COULEUR 10
	DC.W	$0196,$055F	;COULEUR 11
	DC.W	$0198,$000F	;COULEUR 12
	DC.W	$019A,$000A	;COULEUR 13
	DC.W	$019C,$0006	;COULEUR 14
	DC.W	$019E,$0003	;COULEUR 15
	DC.W	$01A0,$0DEF	;COULEUR 16	;LES COULEURS DE 16 A 31 SONT
	DC.W	$01A2,$0BEF	;COULEUR 17	;AUSSI CELLES DES SPRITES
	DC.W	$01A4,$0ADF	;COULEUR 18
	DC.W	$01A6,$07BD	;COULEUR 19	;LES COULEURS 16 A 31 NE SONT
	DC.W	$01A8,$058A	;COULEUR 20	;PAS UTILISEES DANS LE MODE
	DC.W	$01AA,$0357	;COULEUR 21	;HOLD AND MODIFY (HAM)
	DC.W	$01AC,$0234	;COULEUR 22
	DC.W	$01AE,$0011	;COULEUR 23
	DC.W	$01B0,$0FD0	;COULEUR 24
	DC.W	$01B2,$0FA0	;COULEUR 25
	DC.W	$01B4,$0E80	;COULEUR 26
	DC.W	$01B6,$0C60	;COULEUR 27
	DC.W	$01B8,$0A30	;COULEUR 28
	DC.W	$01BA,$0720	;COULEUR 29
	DC.W	$01BC,$0510	;COULEUR 30
	DC.W	$01BE,$0300	;COULEUR 31

DC.W $cc01,$FFFE

DC.W $0100,0		;MET RESOLUTION NULLE

	;REGISTRES DES COULEURS
DC.W $0182,$0a50	;POUR LE SCROLL
DC.W $0184,$0dc0
DC.W $0186,$0606
DC.W $0188,$0818
DC.W $018a,$0a2a
DC.W $018c,$0d3d
DC.W $018e,$0f5f

DC.W	$0092,$0030	;PASSAGE EN OVERSCAN
DC.W	$0094,$00D8


DC.W $cd01,$FFFE

		DC.W $0100,$3200	;RESOLUTION 3 PLANS = 8 COULEURS

		DC.W $10A,110-4		;MODULO = 10 + 50 + 50 - 4
					;-4 POUR PASSAGE EN OVERSCAN
		DC.W $108,110-4		;MODULO POUR FORMAT RAW BLITTER

		;POINTEURS DE PLANS DU FOND DE SCROLL

		DC.W $00E0,SCROLL+0/65535
		DC.W $00E2,SCROLL+0 & 65535
		DC.W $00E4,SCROLL+[50]/65536
		DC.W $00E6,SCROLL+[50] & 65535
		DC.W $00E8,SCROLL+[100]/65536  
		DC.W $00EA,SCROLL+[100] & 65535
DC.W $180
colorscroll:dc.w 0
dc.w $cd01,$fffe
DC.W $180
dc.w 0
dc.w $ce01,$fffe
DC.W $180
dc.w 0
dc.w $cf01,$fffe
DC.W $180
dc.w 0
dc.w $d001,$fffe
DC.W $180
dc.w 0
dc.w $d101,$fffe
DC.W $180
dc.w 0
dc.w $d201,$fffe
DC.W $180
dc.w 0
dc.w $d301,$fffe
DC.W $180
dc.w 0
dc.w $d401,$fffe
DC.W $180
dc.w 0
dc.w $d501,$fffe
DC.W $180
dc.w 0
dc.w $d601,$fffe
DC.W $180
dc.w 0
dc.w $d701,$fffe
DC.W $180
dc.w 0
dc.w $d801,$fffe
DC.W $180
dc.w 0
dc.w $d901,$fffe
DC.W $180
dc.w 0
dc.w $da01,$fffe
DC.W $180
dc.w 0
dc.w $db01,$fffe
DC.W $180
dc.w 0
dc.w $dc01,$fffe
DC.W $180
dc.w 0
dc.w $dd01,$fffe
DC.W $180
dc.w 0
dc.w $de01,$fffe
DC.W $180
dc.w 0
dc.w $df01,$fffe
DC.W $180
dc.w 0
dc.w $e001,$fffe
DC.W $180
dc.w 0
dc.w $e101,$fffe
DC.W $180
dc.w 0
dc.w $e201,$fffe
DC.W $180
dc.w 0
dc.w $e301,$fffe
DC.W $180
dc.w 0
dc.w $e401,$fffe
DC.W $180
dc.w 0
dc.w $e501,$fffe
DC.W $180
dc.w 0
dc.w $e601,$fffe
DC.W $180
dc.w 0
dc.w $e701,$fffe
DC.W $180
dc.w 0
dc.w $e801,$fffe
DC.W $180
dc.w 0
dc.w $e901,$fffe
DC.W $180
dc.w 0
dc.w $ea01,$fffe
DC.W $180
dc.w 0
dc.w $eb01,$fffe
DC.W $180
dc.w 0
dc.w $ec01,$fffe
DC.W $180
dc.w 0
dc.w $ed01,$fffe
DC.W $180
dc.w 0
dc.w $ee01,$fffe
DC.W $180
dc.w 0
dc.w $ef01,$fffe
DC.W $180
dc.w 0
dc.w $f001,$fffe
DC.W $180
dc.w 0
dc.w $f101,$fffe
DC.W $180
dc.w 0
dc.w $f201,$fffe
DC.W $180
dc.w 0
dc.w $f301,$fffe
DC.W $180
dc.w 0
dc.w $f401,$fffe
DC.W $180
dc.w 0
dc.w $f501,$fffe
DC.W $180
dc.w 0
dc.w $f601,$fffe
DC.W $180
dc.w 0
dc.w $f701,$fffe
DC.W $180
dc.w 0
dc.w $f801,$fffe
DC.W $180
dc.w 0
dc.w $f901,$fffe
DC.W $180
dc.w 0
dc.w $fa01,$fffe
DC.W $180
dc.w 0
dc.w $fb01,$fffe
DC.W $180
dc.w 0
dc.w $fc01,$fffe
DC.W $180
dc.w 0
dc.w $fd01,$fffe
DC.W $180
dc.w 0
dc.w $fe01,$fffe
DC.W $180
dc.w 0
dc.w $ff01,$fffe
DC.W $180
dc.w 0
dc.w $ffdf,$fffe
DC.W $180
dc.w 0
dc.w $0101,$fffe
DC.W $180
dc.w 0
dc.w $0201,$fffe
DC.W $180
dc.w 0
dc.w $0301,$fffe
DC.W $180
dc.w 0
dc.w $0401,$fffe
DC.W $180
dc.w 0
dc.w $0501,$fffe
DC.W $180
dc.w 0
dc.w $0601,$fffe
DC.W $180
dc.w 0
dc.w $0701,$fffe
DC.W $180
dc.w 0
dc.w $0801,$fffe
DC.W $180
dc.w 0
dc.w $0901,$fffe
DC.W $180
dc.w 0
dc.w $0a01,$fffe
DC.W $180
dc.w 0
dc.w $0b01,$fffe
DC.W $180
dc.w 0
dc.w $0c01,$fffe
DC.W $180
dc.w 0
dc.w $0d01,$fffe
DC.W $180
dc.w 0
dc.w $0e01,$fffe
DC.W $180
dc.w 0
dc.w $0f01,$fffe
DC.W $180
dc.w 0
dc.w $1001,$fffe
DC.W $180
dc.w 0
dc.w $1101,$fffe
DC.W $180
dc.w 0
dc.w $1201,$fffe
DC.W $180
dc.w 0
dc.w $1301,$fffe
DC.W $180
dc.w $0
dc.w $1401,$fffe
DC.W $180
dc.w $0
dc.w $102,$00
		DC.W $00E0,SCROLL+[50*210]/65535
		DC.W $00E2,SCROLL+[50*210] & 65535
		DC.W $00E4,SCROLL+[50*211]/65536
		DC.W $00E6,SCROLL+[50*211] & 65535
		DC.W $00E8,SCROLL+[50*212]/65536  
		DC.W $00EA,SCROLL+[50*212] & 65535
dc.w $1501,$fffe
DC.W $180
dc.w $0
dc.w $102,$00
		DC.W $00E0,SCROLL+[50*207]/65535
		DC.W $00E2,SCROLL+[50*207] & 65535
		DC.W $00E4,SCROLL+[50*208]/65536
		DC.W $00E6,SCROLL+[50*208] & 65535
		DC.W $00E8,SCROLL+[50*209]/65536  
		DC.W $00EA,SCROLL+[50*209] & 65535
dc.w $1601,$fffe
DC.W $180
dc.w $100
dc.w $102,$11
		DC.W $00E0,SCROLL+[50*204]/65535
		DC.W $00E2,SCROLL+[50*204] & 65535
		DC.W $00E4,SCROLL+[50*205]/65536
		DC.W $00E6,SCROLL+[50*205] & 65535
		DC.W $00E8,SCROLL+[50*206]/65536  
		DC.W $00EA,SCROLL+[50*206] & 65535
dc.w $1701,$fffe
DC.W $180
dc.w $100
dc.w $102,$11
		DC.W $00E0,SCROLL+[50*201]/65535
		DC.W $00E2,SCROLL+[50*201] & 65535
		DC.W $00E4,SCROLL+[50*202]/65536
		DC.W $00E6,SCROLL+[50*202] & 65535
		DC.W $00E8,SCROLL+[50*203]/65536  
		DC.W $00EA,SCROLL+[50*203] & 65535
dc.w $1801,$fffe
DC.W $180
dc.w $200
dc.w $102,$22
		DC.W $00E0,SCROLL+[50*198]/65535
		DC.W $00E2,SCROLL+[50*198] & 65535
		DC.W $00E4,SCROLL+[50*199]/65536
		DC.W $00E6,SCROLL+[50*199] & 65535
		DC.W $00E8,SCROLL+[50*200]/65536  
		DC.W $00EA,SCROLL+[50*200] & 65535
dc.w $1901,$fffe
DC.W $180
dc.w $200
dc.w $102,$22
		DC.W $00E0,SCROLL+[50*195]/65535
		DC.W $00E2,SCROLL+[50*195] & 65535
		DC.W $00E4,SCROLL+[50*196]/65536
		DC.W $00E6,SCROLL+[50*196] & 65535
		DC.W $00E8,SCROLL+[50*197]/65536  
		DC.W $00EA,SCROLL+[50*197] & 65535
dc.w $1a01,$fffe
DC.W $180
dc.w $300
dc.w $102,$33
		DC.W $00E0,SCROLL+[50*192]/65535
		DC.W $00E2,SCROLL+[50*192] & 65535
		DC.W $00E4,SCROLL+[50*193]/65536
		DC.W $00E6,SCROLL+[50*193] & 65535
		DC.W $00E8,SCROLL+[50*194]/65536  
		DC.W $00EA,SCROLL+[50*194] & 65535
dc.w $1b01,$fffe
DC.W $180
dc.w $300
dc.w $102,$33
		DC.W $00E0,SCROLL+[50*189]/65535
		DC.W $00E2,SCROLL+[50*189] & 65535
		DC.W $00E4,SCROLL+[50*190]/65536
		DC.W $00E6,SCROLL+[50*190] & 65535
		DC.W $00E8,SCROLL+[50*191]/65536  
		DC.W $00EA,SCROLL+[50*191] & 65535
dc.w $1c01,$fffe
DC.W $180
dc.w $400
dc.w $102,$44
		DC.W $00E0,SCROLL+[50*186]/65535
		DC.W $00E2,SCROLL+[50*186] & 65535
		DC.W $00E4,SCROLL+[50*187]/65536
		DC.W $00E6,SCROLL+[50*187] & 65535
		DC.W $00E8,SCROLL+[50*188]/65536  
		DC.W $00EA,SCROLL+[50*188] & 65535
dc.w $1d01,$fffe
DC.W $180
dc.w $400
dc.w $102,$44
		DC.W $00E0,SCROLL+[50*183]/65535
		DC.W $00E2,SCROLL+[50*183] & 65535
		DC.W $00E4,SCROLL+[50*184]/65536
		DC.W $00E6,SCROLL+[50*184] & 65535
		DC.W $00E8,SCROLL+[50*185]/65536  
		DC.W $00EA,SCROLL+[50*185] & 65535
dc.w $1e01,$fffe
DC.W $180
dc.w $500
dc.w $102,$55
		DC.W $00E0,SCROLL+[50*180]/65535
		DC.W $00E2,SCROLL+[50*180] & 65535
		DC.W $00E4,SCROLL+[50*181]/65536
		DC.W $00E6,SCROLL+[50*181] & 65535
		DC.W $00E8,SCROLL+[50*182]/65536  
		DC.W $00EA,SCROLL+[50*182] & 65535
dc.w $1f01,$fffe
DC.W $180
dc.w $500
dc.w $102,$55
		DC.W $00E0,SCROLL+[50*177]/65535
		DC.W $00E2,SCROLL+[50*177] & 65535
		DC.W $00E4,SCROLL+[50*178]/65536
		DC.W $00E6,SCROLL+[50*178] & 65535
		DC.W $00E8,SCROLL+[50*179]/65536  
		DC.W $00EA,SCROLL+[50*179] & 65535
dc.w $2001,$fffe
DC.W $180
dc.w $600
dc.w $102,$66
		DC.W $00E0,SCROLL+[50*174]/65535
		DC.W $00E2,SCROLL+[50*174] & 65535
		DC.W $00E4,SCROLL+[50*175]/65536
		DC.W $00E6,SCROLL+[50*175] & 65535
		DC.W $00E8,SCROLL+[50*176]/65536  
		DC.W $00EA,SCROLL+[50*176] & 65535
dc.w $2101,$fffe
DC.W $180
dc.w $600
dc.w $102,$66
		DC.W $00E0,SCROLL+[50*171]/65535
		DC.W $00E2,SCROLL+[50*171] & 65535
		DC.W $00E4,SCROLL+[50*172]/65536
		DC.W $00E6,SCROLL+[50*172] & 65535
		DC.W $00E8,SCROLL+[50*173]/65536  
		DC.W $00EA,SCROLL+[50*173] & 65535
dc.w $2201,$fffe
DC.W $180
dc.w $700
dc.w $102,$77
		DC.W $00E0,SCROLL+[50*168]/65535
		DC.W $00E2,SCROLL+[50*168] & 65535
		DC.W $00E4,SCROLL+[50*169]/65536
		DC.W $00E6,SCROLL+[50*169] & 65535
		DC.W $00E8,SCROLL+[50*170]/65536  
		DC.W $00EA,SCROLL+[50*170] & 65535
dc.w $2301,$fffe
DC.W $180
dc.w $700
dc.w $102,$77
		DC.W $00E0,SCROLL+[50*165]/65535
		DC.W $00E2,SCROLL+[50*165] & 65535
		DC.W $00E4,SCROLL+[50*166]/65536
		DC.W $00E6,SCROLL+[50*166] & 65535
		DC.W $00E8,SCROLL+[50*167]/65536  
		DC.W $00EA,SCROLL+[50*167] & 65535
dc.w $2401,$fffe
DC.W $180
dc.w $800
dc.w $102,$88
		DC.W $00E0,SCROLL+[50*162]/65535
		DC.W $00E2,SCROLL+[50*162] & 65535
		DC.W $00E4,SCROLL+[50*163]/65536
		DC.W $00E6,SCROLL+[50*163] & 65535
		DC.W $00E8,SCROLL+[50*164]/65536  
		DC.W $00EA,SCROLL+[50*164] & 65535
dc.w $2501,$fffe
DC.W $180
dc.w $800
dc.w $102,$88
		DC.W $00E0,SCROLL+[50*159]/65535
		DC.W $00E2,SCROLL+[50*159] & 65535
		DC.W $00E4,SCROLL+[50*160]/65536
		DC.W $00E6,SCROLL+[50*160] & 65535
		DC.W $00E8,SCROLL+[50*161]/65536  
		DC.W $00EA,SCROLL+[50*161] & 65535
dc.w $2601,$fffe
DC.W $180
dc.w $900
dc.w $102,$99
		DC.W $00E0,SCROLL+[50*156]/65535
		DC.W $00E2,SCROLL+[50*156] & 65535
		DC.W $00E4,SCROLL+[50*157]/65536
		DC.W $00E6,SCROLL+[50*157] & 65535
		DC.W $00E8,SCROLL+[50*158]/65536  
		DC.W $00EA,SCROLL+[50*158] & 65535
dc.w $2701,$fffe
DC.W $180
dc.w $900
dc.w $102,$99
		DC.W $00E0,SCROLL+[50*153]/65535
		DC.W $00E2,SCROLL+[50*153] & 65535
		DC.W $00E4,SCROLL+[50*154]/65536
		DC.W $00E6,SCROLL+[50*154] & 65535
		DC.W $00E8,SCROLL+[50*155]/65536  
		DC.W $00EA,SCROLL+[50*155] & 65535
dc.w $2801,$fffe
DC.W $180
dc.w $a00
dc.w $102,$aa
		DC.W $00E0,SCROLL+[50*150]/65535
		DC.W $00E2,SCROLL+[50*150] & 65535
		DC.W $00E4,SCROLL+[50*151]/65536
		DC.W $00E6,SCROLL+[50*151] & 65535
		DC.W $00E8,SCROLL+[50*152]/65536  
		DC.W $00EA,SCROLL+[50*152] & 65535
dc.w $2901,$fffe
DC.W $180
dc.w $a00
dc.w $102,$aa
		DC.W $00E0,SCROLL+[50*147]/65535
		DC.W $00E2,SCROLL+[50*147] & 65535
		DC.W $00E4,SCROLL+[50*148]/65536
		DC.W $00E6,SCROLL+[50*148] & 65535
		DC.W $00E8,SCROLL+[50*149]/65536  
		DC.W $00EA,SCROLL+[50*149] & 65535
dc.w $2a01,$fffe
DC.W $180
dc.w $b00
dc.w $102,$bb
		DC.W $00E0,SCROLL+[50*144]/65535
		DC.W $00E2,SCROLL+[50*144] & 65535
		DC.W $00E4,SCROLL+[50*145]/65536
		DC.W $00E6,SCROLL+[50*145] & 65535
		DC.W $00E8,SCROLL+[50*146]/65536  
		DC.W $00EA,SCROLL+[50*146] & 65535
dc.w $2b01,$fffe
DC.W $180
dc.w $b00
dc.w $102,$bb
		DC.W $00E0,SCROLL+[50*141]/65535
		DC.W $00E2,SCROLL+[50*141] & 65535
		DC.W $00E4,SCROLL+[50*142]/65536
		DC.W $00E6,SCROLL+[50*142] & 65535
		DC.W $00E8,SCROLL+[50*143]/65536  
		DC.W $00EA,SCROLL+[50*143] & 65535
dc.w $2c01,$fffe
DC.W $180
dc.w $c00
dc.w $102,$cc
		DC.W $00E0,SCROLL+[50*138]/65535
		DC.W $00E2,SCROLL+[50*138] & 65535
		DC.W $00E4,SCROLL+[50*139]/65536
		DC.W $00E6,SCROLL+[50*139] & 65535
		DC.W $00E8,SCROLL+[50*140]/65536  
		DC.W $00EA,SCROLL+[50*140] & 65535
dc.w $2d01,$fffe
DC.W $180
dc.w $c00
dc.w $102,$cc
		DC.W $00E0,SCROLL+[50*135]/65535
		DC.W $00E2,SCROLL+[50*135] & 65535
		DC.W $00E4,SCROLL+[50*136]/65536
		DC.W $00E6,SCROLL+[50*136] & 65535
		DC.W $00E8,SCROLL+[50*137]/65536  
		DC.W $00EA,SCROLL+[50*137] & 65535
dc.w $2e01,$fffe
DC.W $180
dc.w $d00
dc.w $102,$dd
		DC.W $00E0,SCROLL+[50*132]/65535
		DC.W $00E2,SCROLL+[50*132] & 65535
		DC.W $00E4,SCROLL+[50*133]/65536
		DC.W $00E6,SCROLL+[50*133] & 65535
		DC.W $00E8,SCROLL+[50*134]/65536  
		DC.W $00EA,SCROLL+[50*134] & 65535
dc.w $2f01,$fffe
DC.W $180
dc.w $d00
dc.w $102,$dd
		DC.W $00E0,SCROLL+[50*129]/65535
		DC.W $00E2,SCROLL+[50*129] & 65535
		DC.W $00E4,SCROLL+[50*130]/65536
		DC.W $00E6,SCROLL+[50*130] & 65535
		DC.W $00E8,SCROLL+[50*131]/65536  
		DC.W $00EA,SCROLL+[50*131] & 65535
dc.w $3001,$fffe
DC.W $180
dc.w $e00
dc.w $102,$ee
		DC.W $00E0,SCROLL+[50*126]/65535
		DC.W $00E2,SCROLL+[50*126] & 65535
		DC.W $00E4,SCROLL+[50*127]/65536
		DC.W $00E6,SCROLL+[50*127] & 65535
		DC.W $00E8,SCROLL+[50*128]/65536  
		DC.W $00EA,SCROLL+[50*128] & 65535
dc.w $3101,$fffe
DC.W $180
dc.w $e00
dc.w $102,$ee
		DC.W $00E0,SCROLL+[50*123]/65535
		DC.W $00E2,SCROLL+[50*123] & 65535
		DC.W $00E4,SCROLL+[50*124]/65536
		DC.W $00E6,SCROLL+[50*124] & 65535
		DC.W $00E8,SCROLL+[50*125]/65536  
		DC.W $00EA,SCROLL+[50*125] & 65535
dc.w $3201,$fffe
DC.W $180
dc.w $f00
dc.w $102,$ff
		DC.W $00E0,SCROLL+[50*120]/65535
		DC.W $00E2,SCROLL+[50*120] & 65535
		DC.W $00E4,SCROLL+[50*121]/65536
		DC.W $00E6,SCROLL+[50*121] & 65535
		DC.W $00E8,SCROLL+[50*122]/65536  
		DC.W $00EA,SCROLL+[50*122] & 65535
dc.w $3301,$fffe
DC.W $180
dc.w $f00
dc.w $102,$ff
		DC.W $00E0,SCROLL+[50*117]/65535
		DC.W $00E2,SCROLL+[50*117] & 65535
		DC.W $00E4,SCROLL+[50*118]/65536
		DC.W $00E6,SCROLL+[50*118] & 65535
		DC.W $00E8,SCROLL+[50*119]/65536  
		DC.W $00EA,SCROLL+[50*119] & 65535
dc.w $3401,$fffe
DC.W $180
dc.w $f00
dc.w $102,$ff
		DC.W $00E0,SCROLL+[50*114]/65535
		DC.W $00E2,SCROLL+[50*114] & 65535
		DC.W $00E4,SCROLL+[50*115]/65536
		DC.W $00E6,SCROLL+[50*115] & 65535
		DC.W $00E8,SCROLL+[50*116]/65536  
		DC.W $00EA,SCROLL+[50*116] & 65535
dc.w $3501,$fffe
DC.W $180
dc.w $f00
dc.w $102,$ff
		DC.W $00E0,SCROLL+[50*111]/65535
		DC.W $00E2,SCROLL+[50*111] & 65535
		DC.W $00E4,SCROLL+[50*112]/65536
		DC.W $00E6,SCROLL+[50*112] & 65535
		DC.W $00E8,SCROLL+[50*113]/65536  
		DC.W $00EA,SCROLL+[50*113] & 65535
dc.w $3601,$fffe
DC.W $180
dc.w $f00
dc.w $102,$ff
		DC.W $00E0,SCROLL+[50*108]/65535
		DC.W $00E2,SCROLL+[50*108] & 65535
		DC.W $00E4,SCROLL+[50*109]/65536
		DC.W $00E6,SCROLL+[50*109] & 65535
		DC.W $00E8,SCROLL+[50*110]/65536  
		DC.W $00EA,SCROLL+[50*110] & 65535

DC.L $FFFFFFFE ;FIN LISTE COPPER
EVEN
FINDEMO: