OPT C-

	SECTION PROG,CODE_C


BEGIN:
	JMP START
;=====================================================================
EXECBASE=4
OPENLIBRARY=-408
CLOSELIBRARY=-414
SUPERSTATE=-150
USERSTATE=-156	
FORBID=-132
PERMIT=-138
ADDINTSERVER=-168
REMINTSERVER=-174
Open=-30
Close=-36
Read=-42

;=====================================================================
BLTCON0=$DFF040		
BLTCON1=$DFF042
BLTAFWM=$DFF044
BLTALWM=$DFF046
BLTCPTH=$DFF048
BLTCPTL=$DFF04A
BLTBPTH=$DFF04C
BLTBPTL=$DFF04E
BLTAPTH=$DFF050
BLTAPTL=$DFF052
BLTDPTH=$DFF054
BLTDPTL=$DFF056
BLTSIZE=$DFF058
BLTCMOD=$DFF060
BLTBMOD=$DFF062
BLTAMOD=$DFF064
BLTDMOD=$DFF066
BLTCDAT=$DFF070
BLTBDAT=$DFF072
BLTADAT=$DFF074
DMACONR=$DFF002
;==================================
SCROLL:		DCB.B 50*35*3,0	

FONT:		INCBIN	ASM2-DISK3:FUTURE-COMPOSER/FONT.RAW

IMAGE:		INCBIN	ASM2-DISK3:FUTURE-COMPOSER/PIC.RAW

MODULE: 	INCBIN	ASM2-DISK3:FUTURE-COMPOSER/MOD.DISC3
			
;==================================
START:    
	MOVEM.L D0-D7/A0-A6,-(A7)	;SAUVE REGISTRES
	MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
	JSR FORBID(A6)    		;SAUTE SOUS PROGRAMME: INTERDIT MULTITACHE
	JSR OPENLIB  			;SAUTE SOUS PROGRAMME: OUVERTURE LIBRAIRIES
	
	JSR PLACE_ADRESSES

CLEARSCROLL:				;ON EFFACE LE FOND DU SCROLL POUR EVITER
	LEA SCROLL,A1			;D'AVOIR DES BIZARRERIES A L'ECRAN 
	MOVE.W #25*35*3,D0
CLS:
	MOVE.W #0,(A1)+
	DBF D0,CLS
	
	MOVE.L #TEXT,PTEXT		;ON MET LE POINTEUR DE LETTRE SUR LE DEBUT
	MOVE.W #0,COMPT			;DU TEXTE. ET LE COMPTEUR A 0
	
	BSR.W INIT_MUSIQUE		;INITIALISATION DE LA MUSIQUE
	
	BSR.W SETCOPPER			;SAUTE SOUS PROGRAMME: MET EN PLACE LISTE COPPER
	BSR.s NEWIRQ3			;SAUTE SOUS PROGRAMME: MET EN PLACE ROUTINE D'INTERRRUPTION

WAIT:
	CMP.B #$E0,$DFF006		;ATTENDANT 200 IEME LIGNE RASTER
	BNE.S WAIT			;SINON RETOURNE A WAIT
	
	BTST	#6,$BFE001		;ATTENDANT PRESSION SUR BOUTON GAUCHE SOURIS
	BNE.S	WAIT			;SINON RETOURNE A WAIT
	 				;SI OUI  FIN
END: 					;FIN:	
	BSR.W STOP_MUSIQUE		;ARRET DE LA MUSIQUE
	BSR.s STOPIRQ3        		;SAUTE SOUS PROGRAMME: STOPPE INTERRUPTION
	BSR.W CLRCOPPER       		;SAUTE SOUS PROGRAMME: RESTAURE ANCIENNE LISTE COPPER
	BSR.W CLOSELIB        		;SAUTE SOUS PROGRAMME: FERME LIBRAIRIES 
	MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
	JSR PERMIT(A6)      		;AUTORISE MULTITACHE
	                      
	MOVEM.L (A7)+,D0-D7/A0-A6	;RESTAURE REGISTRES
	RTS
;========================
NEWIRQ3:				;MET EN PLACE NOTRE ROUTINE 
	MOVE.L	EXECBASE,A6		;D'INTERRUPTION
	lea	irqstr,a1
	move.l	#5,d0
	jsr	addintserver(a6)
	move.l	d0,irq
	beq.s	irqerror
	rts
irqerror:
	rts
;==========================
STOPIRQ3:				;RESTAURE ANCIENNE ROUTINE
	movem.l	a0-a6/d0-d7,-(sp)	;D'INTERRUPTION
	tst.l	irq
	beq.s	irqoff1
	move.l	execbase,a6
	lea	irqstr,a1
	move.l	#32,d0
	jsr	remintserver(a6)
irqoff1:movem.l	(sp)+,a0-a6/d0-d7
	rts
irqstr:
	dc.l	0,0
	dc.b	2,-127
	dc.l	0,irqdat,interrupt
irqdat:	dc.l	0,0,0,0
irq:	dc.l	0
;============================
interrupt:				;NOTRE ROUTINE D'INTERRUPTION	
	movem.l	a0-a6/d0-d7,-(sp)
	
	BSR.W SCROLLING			;VA A LA ROUTINE DE SCROLLING
	BSR.W PLAY_MUSIQUE		;VA A LA ROUTINE POUR JOUER LA MUSIQUE
	
	movem.l	(sp)+,a0-a6/d0-d7
	rts
;============================
OPENLIB:  				;OUVERTURE DE LA LIBRAIRIE GRAPHIQUE
	move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
	lea gfxname,a1			;MET NOM DE LA LIBRAIRIE DANS A1
	move.l #$0,d0           	;MET 0 DANS D0
	jsr openlibrary(a6)		;OUVRE LIBRAIRIE
	tst d0				;TESTE D0
	beq.s error			;SI = A 0   VA A ERROR = SORTIE
	move.l d0,gfxbase       	;SI NON, MET ADRESSE D0 DANS GFXBASE
	add.l #$32,d0			;AJOUTE $32 A CETTE ADRESSE
	move.l d0,coppertr      	;MET D0=ADRESSE ACTUELLE LISTE COPPER
	rts				;DANS COPPERTR
	even
gfxname: dc.b 'graphics.library',0 	;NOM DE LA LIBRAIRIE
	even
gfxbase: dc.l 0				;POINTEUR POUR LA GRAPHICS LIBRARY
coppertr: dc.l 0			;POINTEUR POUR ADRESSE LISTE COPPER
;====================
CLOSELIB: 				;FERMETURE LIBRAIRIE
	move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
	move.l gfxbase,a1		;MET NOM DE LA LIBRAIRIE DANS A1
	jsr closelibrary(a6)		;FERME LIBRAIRIE
	rts
;====================
ERROR:					;SI ERREUR
	illegal				;SORTIE
	rts
;====================
SETCOPPER:				;MET EN PLACE NOTRE LISTE COPPER
	move.l coppertr,a0		;MET ADRESSE ACTUEL COPPER DANS A0
	move.l (a0),oldcopper		;MET CONTENU DANS OLDCOPPER
	move.l #newcopper,(a0)		;MET NOTRE LISTE COPPER DANS A0
	move.w #$81c0,$dff096		;ACTIVE LISTE COPPER
	rts		
oldcopper: dc.l 0
;====================
CLRCOPPER:				;RESTAURE ANCIENNE LISTE COPPER
	move.l coppertr,a0		;MET ANCIENNE ADRESSE DANS A0
	move.l oldcopper,(a0)		;MET CONTENU DANS A0
	move.w #$80a0,$dff096		;REACTIVE ANCIENNE COPPER
	rts
;====================
PLACE_ADRESSES:

				;CHARGE ADRESSE DE L'IMAGE DANS LA COPPER LIST
	MOVE.L #IMAGE,D0 	;MET ADRESSE DE L'IMAGE DANS D0 (MOT LONG =
				;PAR EXEMPLE $0005 0000 = D0
	MOVE.W D0,IMAGE_LO1	;MET $0000 DANS LO1
	SWAP D0			;INVERSE D0 = $0000 0005
	MOVE.W D0,IMAGE_HI1	;MET $0005 DANS HI1
	SWAP D0			;INVERSE D0 = $0005 0000
	ADD.L #256*40,D0	;AJOUTE LA LONGUEUR D'UN PLAN DANS D0
				;ET RECOMMENCE POUR LE PLAN SUIVANT
	MOVE.W D0,IMAGE_LO2
	SWAP D0
	MOVE.W D0,IMAGE_HI2
	SWAP D0
	ADD.L #256*40,D0
	
	MOVE.W D0,IMAGE_LO3
	SWAP D0
	MOVE.W D0,IMAGE_HI3     
	SWAP D0
	ADD.L #256*40,D0

	MOVE.W D0,IMAGE_LO4
	SWAP D0
	MOVE.W D0,IMAGE_HI4
	SWAP D0     
	ADD.L #256*40,D0

	MOVE.W D0,IMAGE_LO5
	SWAP D0
	MOVE.W D0,IMAGE_HI5     



	MOVE.L #SCROLL,D0 		;IDEM POUR SCROLL
				
	MOVE.W D0,SCROLL_LO1		
	SWAP D0			
	MOVE.W D0,SCROLL_HI1		
	SWAP D0			
	ADD.L #50,D0	
				
	MOVE.W D0,SCROLL_LO2
	SWAP D0
	MOVE.W D0,SCROLL_HI2
	SWAP D0
	ADD.L #50,D0
	
	MOVE.W D0,SCROLL_LO3
	SWAP D0
	MOVE.W D0,SCROLL_HI3     

	RTS
;====================
WAIT_BLITTER:				;ROUTINE POUR ATTENDRE QUE LE BLITTER
	BTST #14,DMACONR		;EST FINI SON PRECEDENT TRAVAIL
	BNE.S WAIT_BLITTER
	RTS
;===================
SCROLLING:				;ROUTINE DU SCROLLING
	BSR.W SEARCH_CHAR		;AFFICHE UN NOUVEAU CARACTERE
	BSR.W SCROLLTEXT		;SCROLLE LE FOND DU SCROLL
	RTS
;===================	
SCROLLTEXT:			
	LEA SCROLL,A0 			;ON POINTE A0 SUR LE FOND DU SCROLL
		
	BSR.W WAIT_BLITTER		;ON ATTEND QUE LE BLITTER EST FINI SON 
					;PRECEDENT TRAVAIL
	
	LEA SCROLL-2,A1			;ON POINTE A1 SUR 16 PIXELS AVANT 
					;LE FOND DU SCROLL. 2 = 16 PIXELS
	
	MOVE.L A0,BLTAPTH		;MET ADRESSE DE A0 DANS SOURCE BLITTER A
	MOVE.L A1,BLTDPTH		;MET ADRESSE DE A1 DANS DESTINATION BLITTER D
	MOVE.W #0,BLTAMOD  		;MET 0 DANS MODULO SOURCE A
	MOVE.W #0,BLTDMOD		;MET 0 DANS MODULO DESTINATION D
	MOVE.L #$FFFFFFFF,BLTAFWM	;MASQUE DU 1ER ET DU DERNIER MOT
	MOVE.L #$C9F00000,BLTCON0    	;MET MIMTERN ET DECALAGE DANS BLTCON0
					;$C = $F - $4 = 16 - 4 = 12
					;4 PIXELS DE DECALAGE VERS LA GAUCHE
	
					;$9 -> POUR 1 SOURCE BLITTER
					;$F0 -> MINTERM POUR COPIE DIRECTE
					;$0000 -> MIS A 0 CAR SOURCE B INITULISE	
	
	MOVE.W #(35*64*3)+25,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
					;TAILLE = (HAUTEUR * 64)+(LARGEUR/2)
	RTS
;============
SEARCH_CHAR:
	ADD.W #1,COMPT			;AJOUTE 1 AU COMPTEUR
	CMP.W #8,COMPT           	;COMPARE A 8 CAR 8 * 4 PIXELS DE DECALAGE
					;EGALE A 32 SOIT LA LARGEUR D'UNe LETTRE
	BNE.W SEARCHAR3			;SI PAS EGAL A 8 ON SORT
	MOVE.W #0,COMPT			;SI OUI ON REMET COMPTEUR A 0
					;ET ON CONTINU
	
	MOVE.L PTEXT,A0          	;MET POINTEUR TEXTE DANS A0
	CLR.L D0			;ON EFFACE CONTENU DE D0
	MOVE.B (A0),D0			;MET LE CONTENU DU POINTEUR TEXTE DANS D0
	LEA COMPTEUR_CHAR,A1		;EN POINTE A1 SUR LA TABLE DES LETTRES
	CLR.L D1			;ON EFFACE CONTENU DE D1
	MOVE.B #-1,D1			;ON MET -1 DANS D1

SEARCHAR1:
	
	ADD.B #1,D1     		;ON AJOUTE 1 A D1         
	CMP.B (A1)+,D0			;ON COMPARE LES LETTRES DE LA TABLE
					;AVEC CELLE CONTENU DANS D0
	BNE SEARCHAR1			;SI PAS LA MEME ON RECOMMENCE AVEC LA
					;LETTRE SIUVANTE DANS LA TABLE
					;SI C'EST LA MEME ON CONTINU
	MULU #4,D1              	;ON MULTIPLIE D1 PAR 4
	LEA TABLE_CHAR,A0       	;ON POINTE A0 SUR LE DEBUT DE LA TABLE
					;D'ADRESSE DES IMAGES DES LETTRES
	MOVE.L (A0,D1),A2       	;ET ON MET L'ADRESSE DE LA LETTRE DANS A2
	
	LEA SCROLL,A3			;ON POINTE A3 SUR LA POSITION SCROLL+46
	ADD.L #46,A3        		;SOIT A 46*8 = 368 PIXELS A DROITE DU 
					;COIN SUPERIEUR DROIT DU FOND DE SCROLL
					;SOIT DANS LA PARTIE INVISIBLE DU SCROLL	
	
	BSR.W WAIT_BLITTER        	;ON ATTENDS LE BLITTER	
	MOVE.L A2,BLTAPTH       	;ON MET ADRESSE DE A2 DANS SOURCE BLITTER A
	MOVE.L A3,BLTDPTH       	;ON MET ADRESSE DE A3 DANS DESTINATION BLITTER D
	
	MOVE.W #40-4,BLTAMOD  		;ON MET 40-4 DANS MODULO SOURCE A
					;CAR NOTRE LETTRE FAIT 32 PIXELS DE LARGE SOIT
					;4 MOTS (4*8=32) ET L'IMAGE QUI LA CONTIENT
					;FAIT 320 PIXELS DE LARGE SOIT 40 MOTS
		
	MOVE.W #50-4,BLTDMOD   	        ;ON MET 50-4 DANS MODULO DESTINATION D
					;CAR LE FOND DE SCROLL FAIT 400 PIXELS DE LARGE
					;SOIT 50 MOTS
	
	MOVE.L #$09F00000,BLTCON0	;$0 -> PAS DE DECALAGE DE LA SOURCE A
					;$9 -> POUR 1 SOURCE BLITTER A
					;$F0 -> MINTERM POUR COPIE DIRECTE
	
	MOVE.W #(35*3*64)+2,BLTSIZE	;MET TAILLE A SCROLLER DANS BLTSIZE
					;TAILLE = (HAUTEUR * 64)+(LARGEUR/2)
	
	ADD.L #1,PTEXT          	;ON AJOUTE 1 AU POINTEUR DE TEXTE
	MOVE.L PTEXT,A0			;ON MET POINTEUR DE TEXTE DANS A0
	TST.B (A0)              	;SI PAS EGAL A 0
	BNE SEARCHAR3			;ON VA A SEARCHAR3
	MOVE.L #TEXT,PTEXT		;SINON ON REMET POINTEUR DE TEXTE AU DEBUT
					;DU TEXTE A SCROLLER

SEARCHAR3:
	RTS
	
	EVEN
COMPT: DC.W 0			;COMPTEUR 
PTEXT: DC.L 0			;POINTEUR DE TEXTE
;=================================================================


COMPTEUR_CHAR: 
		DC.B ' ABCDEFGHI'	;TABLE DES CARACTERES
		DC.B 'JKLMNOPQRS'	;TELS QU'ILS SONT DISPOSES
		DC.B 'TUVWXYZ.,:'	;DANS NOTRE IMAGE	
		DC.B '()@#!?-*^/'
		DC.B '0123456789%'
         
	EVEN
FONT1=FONT		;ADRESSES DES LETTRES PAR LIGNES
FONT2=FONT+(3*35*40) 
FONT3=FONT+(6*35*40)
FONT4=FONT+(9*35*40)
FONT5=FONT+(12*35*40)
	EVEN 
TABLE_CHAR: 		;ADRESSES DES LETTRES

	DC.L FONT1,FONT1+4,FONT1+8,FONT1+12,FONT1+16,FONT1+20
	DC.L FONT1+24,FONT1+28,FONT1+32,FONT1+36
	DC.L FONT2,FONT2+4,FONT2+8,FONT2+12,FONT2+16,FONT2+20
	DC.L FONT2+24,FONT2+28,FONT2+32,FONT2+36
	DC.L FONT3,FONT3+4,FONT3+8,FONT3+12,FONT3+16,FONT3+20
	DC.L FONT3+24,FONT3+28,FONT3+32,FONT3+36
	DC.L FONT4,FONT4+4,FONT4+8,FONT4+12,FONT4+16,FONT4+20
	DC.L FONT4+24,FONT4+28,FONT4+32,FONT4+36
	DC.L FONT5,FONT5+4,FONT5+8,FONT5+12,FONT5+16,FONT5+20
	DC.L FONT5+24,FONT5+28,FONT5+32,FONT5+36
	EVEN
	
	EVEN		;TEXTE A SCROLLER

TEXT: 
	DC.B '             '
	DC.B 'VOICI L EXEMPLE DE REPLAY ROUTINE DU FUTURE COMPOSER '
	DC.B 'CET UTILITAIRE MUSICAL EST TRES APPRECIE NON PAS POUR SES '
	DC.B 'PERFORMANCES  MAIS POUR SON EXTREME RAPIDITE ET LA TAILLE TRES '
	DC.B 'REDUITE DE SES MODULES '
	dc.b '    ',0
fin:
;====================
	EVEN
STOP_MUSIQUE:
	clr.w onoff
	clr.l $dff0a6
	clr.l $dff0b6
	clr.l $dff0c6
	clr.l $dff0d6
	move.w #$000f,$dff096
	bclr #1,$bfe001
	rts

INIT_MUSIQUE:
	move.w #1,onoff
	bset #1,$bfe001
	lea MODULE,a0
	lea 180(a0),a1
	move.l a1,SEQpoint
	move.l a0,a1
	add.l 8(a0),a1
	move.l a1,PATpoint
	move.l a0,a1
	add.l 16(a0),a1
	move.l a1,FRQpoint
	move.l a0,a1
	add.l 24(a0),a1
	move.l a1,VOLpoint
	move.l 4(a0),d0
	divu #13,d0
	
	lea 40(a0),a1
	lea SOUNDINFO+4(pc),a2
	moveq #10-1,d1
initloop:
	move.w (a1)+,(a2)+
	move.l (a1)+,(a2)+
	adda.w #10,a2
	dbf d1,initloop
	move.l a0,d1
	add.l 32(a0),d1
	lea SOUNDINFO(pc),a3
	move.l d1,(a3)+
	moveq #9-1,d3
	moveq #0,d2
initloop1:
	move.w (a3),d2
	add.l d2,d1
	add.l d2,d1
	addq.l #2,d1
	adda.w #12,a3
	move.l d1,(a3)+
	dbf d3,initloop1
	
	lea 100(a0),a1
	lea SOUNDINFO+(10*16)(pc),a2
	move.l a0,a3
	add.l 36(a0),a3
	
	moveq #80-1,d1
	moveq #0,d2
initloop2:
	move.l a3,(a2)+
	move.b (a1)+,d2
	move.w d2,(a2)+
	clr.w (a2)+
	move.w d2,(a2)+
	addq.w #6,a2
	add.w d2,a3
	add.w d2,a3
	dbf d1,initloop2
	
	move.l SEQpoint(pc),a0
	moveq #0,d2
	move.b 12(a0),d2		;Get replay speed
	bne.s speedok
	move.b #3,d2			;Set default speed
speedok:
	move.w d2,respcnt		;Init repspeed counter
	move.w d2,repspd
INIT2:
	clr.w audtemp
	move.w #$000f,$dff096		;Disable audio DMA
	move.w #$0780,$dff09a		;Disable audio IRQ
	moveq #0,d7
	mulu #13,d0
	moveq #4-1,d6			;Number of soundchannels-1
	lea V1data(pc),a0		;Point to 1st voice data area
	lea silent(pc),a1
	lea Chandata(pc),a2
initloop3:
	move.l a1,10(a0)
	move.l a1,18(a0)
	clr.w 4(a0)
	move.w #$000d,6(a0)
	clr.w 8(a0)
	clr.l 14(a0)
	move.b #$01,23(a0)
	move.b #$01,24(a0)
	clr.b 25(a0)
	clr.l 26(a0)
	clr.w 30(a0)
	clr.l 38(a0)
	clr.w 42(a0)
	clr.l 44(a0)
	clr.l 48(a0)
	clr.w 56(a0)
	moveq #$00,d3
	move.w (a2)+,d1
	move.w (a2),d3
	divu #$0003,d3
	moveq #0,d4
	bset d3,d4
	move.w d4,32(a0)
	move.w (a2)+,d3
	andi.l #$00ff,d3
	andi.l #$00ff,d1
	lea $dff0a0,a6
	add.w d1,a6
	move.l #$0000,(a6)
	move.w #$0100,4(a6)
	move.w #$0000,6(a6)
	move.w #$0000,8(a6)
	move.l a6,60(a0)
	move.l SEQpoint(pc),(a0)
	move.l SEQpoint(pc),52(a0)
	add.l d0,52(a0)
	add.l d3,52(a0)
	add.l d7,(a0)
	add.l d3,(a0)
	move.l (a0),a3
	move.b (a3),d1
	andi.l #$00ff,d1
	lsl.w #6,d1
	move.l PATpoint(pc),a4
	adda.w d1,a4
	move.l a4,34(a0)
	move.b 1(a3),44(a0)
	move.b 2(a3),22(a0)
	lea $4a(a0),a0		;Point to next voice's data area
	dbf d6,initloop3
	rts
	
	
PLAY_MUSIQUE:
	lea audtemp(pc),a5
	tst.w 8(a5)
	bne.s music_on
	rts

music_on:
	subq.w #1,4(a5)			;Decrease replayspeed counter
	bne.s nonewnote
	move.w 6(a5),4(a5)		;Restore replayspeed counter
	moveq #0,d5
	moveq #6,d6
	lea V1data(pc),a0		;Point to voice1 data area
	bsr.W new_note
	lea V2data(pc),a0		;Point to voice2 data area
	bsr.W new_note
	lea V3data(pc),a0		;Point to voice3 data area
	bsr.W new_note
	lea V4data(pc),a0		;Point to voice4 data area
	bsr.W new_note
nonewnote:
	clr.w (a5)
	lea $dff000,a6
	lea V1data(pc),a0
	bsr.W effects
	move.l d0,$a6(a6)
	lea V2data(pc),a0
	bsr.W effects
	move.l d0,$b6(a6)
	lea V3data(pc),a0
	bsr.W effects
	move.l d0,$c6(a6)
	lea V4data(pc),a0
	bsr.W effects
	move.l d0,$d6(a6)
	lea V1data(pc),a0
	move.l 68+(0*74)(a0),a1		;Get samplepointer
	adda.w 64+(0*74)(a0),a1		;add repeat_start
	move.l 68+(1*74)(a0),a2
	adda.w 64+(1*74)(a0),a2
	move.l 68+(2*74)(a0),a3
	adda.w 64+(2*74)(a0),a3
	move.l 68+(3*74)(a0),a4
	adda.w 64+(3*74)(a0),a4
	move.w 66+(0*74)(a0),d1		;Get repeat_length
	move.w 66+(1*74)(a0),d2
	move.w 66+(2*74)(a0),d3
	move.w 66+(3*74)(a0),d4
	moveq #2,d0
	moveq #0,d5
	move.w (a5),d7
	ori.w #$8000,d7			;Set/clr bit = 1
	move.w d7,$dff096		;Enable audio DMA
chan1:
	lea V1data+72(pc),a0
	move.w (a0),d7
	beq.s chan2
	subq.w #1,(a0)
	cmp.w d0,d7
	bne.s chan2
	move.w d5,(a0)
	move.l a1,$a0(a6)		;Set samplestart
	move.w d1,$a4(a6)		;Set samplelength
chan2:
	lea V2data+72(pc),a0
	move.w (a0),d7
	beq.s chan3
	subq.w #1,(a0)
	cmp.w d0,d7
	bne.s chan3
	move.w d5,(a0)
	move.l a2,$b0(a6)
	move.w d2,$b4(a6)
chan3:
	lea V3data+72(pc),a0
	move.w (a0),d7
	beq.s chan4
	subq.w #1,(a0)
	cmp.w d0,d7
	bne.s chan4
	move.w d5,(a0)
	move.l a3,$c0(a6)
	move.w d3,$c4(a6)
chan4:
	lea V4data+72(pc),a0
	move.w (a0),d7
	beq.s endplay
	subq.w #1,(a0)
	cmp.w d0,d7
	bne.s endplay
	move.w d5,(a0)
	move.l a4,$d0(a6)
	move.w d4,$d4(a6)
endplay:
	rts

NEW_NOTE:
	move.l 34(a0),a1
	adda.w 40(a0),a1
	cmp.b #$49,(a1)		;Check "END" mark in pattern
	beq.s patend
	cmp.w #64,40(a0)		;Have all the notes been played?
	bne.W samepat
patend:
	move.w d5,40(a0)
	move.l (a0),a2
	adda.w 6(a0),a2		;Point to next sequence row
	cmpa.l 52(a0),a2	;Is it the end?
	bne.s notend
	move.w d5,6(a0)		;yes!
	move.l (a0),a2		;Point to first sequence
notend:
	lea spdtemp(pc),a3
	moveq #1,d1
	addq.b #1,(a3)
	cmpi.b #5,(a3)
	bne.s nonewspd
	move.b d1,(a3)
	move.b 12(a2),d1	;Get new replay speed
	beq.s nonewspd
	move.w d1,2(a3)		;store in counter
	move.w d1,4(a3)
nonewspd:
	move.b (a2)+,d1		;Pattern to play
	move.b (a2)+,44(a0)	;Transpose value
	move.b (a2)+,22(a0)	;Soundtranspose value
	lsl.w d6,d1
	move.l PATpoint(pc),a1	;Get pattern pointer
	add.w d1,a1
	move.l a1,34(a0)
	addi.w #$000d,6(a0)
samepat:
	move.b 1(a1),d1		;Get info byte
	move.b (a1)+,d0		;Get note
	bne.s ww1
	andi.w #%11000000,d1
	beq.s noport
	bra.s ww11
ww1:
	move.w d5,56(a0)
ww11:
	move.b d5,47(a0)
	btst #7,d1
	beq.s noport
	move.b 2(a1),47(a0)	
noport:
	andi.w #$007f,d0
	beq.W nextnote
	move.b d0,8(a0)
	move.b (a1),d1
	move.b d1,9(a0)
	move.w 32(a0),d3
	or.w d3,(a5)
	move.w d3,$dff096
	andi.w #$003f,d1	;Max 64 instruments
	add.b 22(a0),d1		;add Soundtranspose
	move.l VOLpoint(pc),a2
	lsl.w d6,d1
	adda.w d1,a2
	move.w d5,16(a0)
	move.b (a2),23(a0)
	move.b (a2)+,24(a0)
	moveq #0,d1
	move.b (a2)+,d1
	move.b (a2)+,27(a0)
	move.b #$40,46(a0)
	move.b (a2),28(a0)
	move.b (a2)+,29(a0)
	move.b (a2)+,30(a0)
	move.l a2,10(a0)
	move.l FRQpoint(pc),a2
	lsl.w d6,d1
	adda.w d1,a2
	move.l a2,18(a0)
	move.w d5,50(a0)
	move.b d5,25(a0)
	move.b d5,26(a0)
nextnote:
	addq.w #2,40(a0)
	rts

EFFECTS:
	moveq #0,d7
testsustain:
	tst.b 26(a0)		;Is sustain counter = 0
	beq.s sustzero
	subq.b #1,26(a0)	;if no, decrease counter
	bra.W VOLUfx
sustzero:		;Next part of effect sequence
	move.l 18(a0),a1	;can be executed now.
	adda.w 50(a0),a1
testeffects:
	cmpi.b #$e1,(a1)	;E1 = end of FREQseq sequence
	beq.W VOLUfx
	move.b (a1),d0
	cmpi.b #$e0,d0		;E0 = loop to other part of sequence
	bne.s testnewsound
	move.b 1(a1),d1		;loop to start of sequence + 1(a1)
	andi.w #$003f,d1
	move.w d1,50(a0)
	move.l 18(a0),a1
	adda.w d1,a1
	move.b (a1),d0
testnewsound:
	cmpi.b #$e2,d0		;E2 = set waveform
	bne.s testE4
	move.w 32(a0),d1
	or.w d1,(a5)
	move.w d1,$dff096
	moveq #0,d0
	move.b 1(a1),d0
	lea SOUNDINFO(pc),a4
	lsl.w #4,d0
	adda.w d0,a4
	move.l 60(a0),a3
	move.l (a4)+,d1
	move.l d1,(a3)
	move.l d1,68(a0)
	move.w (a4)+,4(a3)
	move.l (a4),64(a0)
	move.w #$0003,72(a0)
	move.w d7,16(a0)
	move.b #$01,23(a0)
	addq.w #2,50(a0)
	bra.W transpose
testE4:
	cmpi.b #$e4,d0
	bne.s testE9
	moveq #0,d0
	move.b 1(a1),d0
	lea SOUNDINFO(pc),a4
	lsl.w #4,d0
	adda.w d0,a4
	move.l 60(a0),a3
	move.l (a4)+,d1
	move.l d1,(a3)
	move.l d1,68(a0)
	move.w (a4)+,4(a3)
	move.l (a4),64(a0)
	move.w #$0003,72(a0)
	addq.w #2,50(a0)
	bra.W transpose
testE9:
	cmpi.b #$e9,d0
	bne testpatjmp
	move.w 32(a0),d1
	or.w d1,(a5)
	move.w d1,$dff096
	moveq #0,d0
	move.b 1(a1),d0
	lea SOUNDINFO(pc),a4
	lsl.w #4,d0
	adda.w d0,a4
	move.l (a4),a2
	cmpi.l #"SSMP",(a2)+
	bne.s nossmp
	lea 320(a2),a4
	moveq #0,d1
	move.b 2(a1),d1
	lsl.w #4,d1
	add.w d1,a2
	add.l (a2),a4
	move.l 60(a0),a3
	move.l a4,(a3)
	move.l 4(a2),4(a3)
	move.l a4,68(a0)
	move.l 6(a2),64(a0)
	move.w d7,16(a0)
	move.b #1,23(a0)
	move.w #3,72(a0)
nossmp:
	addq.w #3,50(a0)
	bra.s transpose
testpatjmp:
	cmpi.b #$e7,d0
	bne.s testpitchbend
	moveq #0,d0
	move.b 1(a1),d0
	lsl.w d6,d0
	move.l FRQpoint(pc),a1
	adda.w d0,a1
	move.l a1,18(a0)
	move.w d7,50(a0)
	bra.W testeffects
testpitchbend:
	cmpi.b #$ea,d0
	bne.s testnewsustain
	move.b 1(a1),4(a0)
	move.b 2(a1),5(a0)
	addq.w #3,50(a0)
	bra.s transpose
testnewsustain:
	cmpi.b #$e8,d0
	bne.s testnewvib
	move.b 1(a1),26(a0)
	addq.w #2,50(a0)
	bra.W testsustain
testnewvib:
	cmpi.b #$e3,(a1)+
	bne.s transpose
	addq.w #3,50(a0)
	move.b (a1)+,27(a0)
	move.b (a1),28(a0)
transpose:
	move.l 18(a0),a1
	adda.w 50(a0),a1
	move.b (a1),43(a0)
	addq.w #1,50(a0)

VOLUfx:
	tst.b 25(a0)
	beq.s volsustzero
	subq.b #1,25(a0)
	bra.W calcperiod
volsustzero:
	tst.b 15(a0)
	bne.s do_VOLbend
	subq.b #1,23(a0)
	bne.s calcperiod
	move.b 24(a0),23(a0)
volu_cmd:
	move.l 10(a0),a1
	adda.w 16(a0),a1
	move.b (a1),d0
testvoluend:
	cmpi.b #$e1,d0
	beq.s calcperiod
	cmpi.b #$ea,d0
	bne.s testVOLsustain
	move.b 1(a1),14(a0)
	move.b 2(a1),15(a0)
	addq.w #3,16(a0)
	bra.s do_VOLbend
testVOLsustain:
	cmpi.b #$e8,d0
	bne.s testVOLloop
	addq.w #2,16(a0)
	move.b 1(a1),25(a0)
	bra.s calcperiod
testVOLloop:
	cmpi.b #$e0,d0
	bne.s setvolume
	move.b 1(a1),d0
	andi.w #$003f,d0
	subq.b #5,d0
	move.w d0,16(a0)
	bra.s volu_cmd
do_VOLbend:
	not.b 38(a0)
	beq.s calcperiod
	subq.b #1,15(a0)
	move.b 14(a0),d1
	add.b d1,45(a0)
	bpl.s calcperiod
	moveq #0,d1
	move.b d1,15(a0)
	move.b d1,45(a0)
	bra.s calcperiod
setvolume:
	move.b (a1),45(a0)
	addq.w #1,16(a0)
	calcperiod:
	move.b 43(a0),d0
	bmi.s lockednote
	add.b 8(a0),d0
	add.b 44(a0),d0
lockednote:
	moveq #$7f,d1
	and.l d1,d0
	lea PERIODS(pc),a1
	add.w d0,d0
	move.w d0,d1
	adda.w d0,a1
	move.w (a1),d0
	
	move.b 46(a0),d7
	tst.b 30(a0)		;Vibrato_delay = zero ?
	beq.s vibrator
	subq.b #1,30(a0)
	bra.s novibrato
vibrator:
	moveq #5,d2
	move.b d1,d5
	move.b 28(a0),d4
	add.b d4,d4
	move.b 29(a0),d1
	tst.b d7
	bpl.s vib1
	btst #0,d7
	bne.s vib4
vib1:
	btst d2,d7
	bne.s vib2
	sub.b 27(a0),d1
	bcc.s vib3
	bset d2,d7
	moveq #0,d1
	bra.s vib3
vib2:
	add.b 27(a0),d1
	cmp.b d4,d1
	bcs.s vib3
	bclr d2,d7
	move.b d4,d1
vib3:
	move.b d1,29(a0)
vib4:
	lsr.b #1,d4
	sub.b d4,d1
	bcc.s vib5
	subi.w #$0100,d1
vib5:
	addi.b #$a0,d5
	bcs.s vib7
vib6:
	add.w d1,d1
	addi.b #$18,d5
	bcc.s vib6
vib7:
	add.w d1,d0
novibrato:
	eori.b #$01,d7
	move.b d7,46(a0)

; DO THE PORTAMENTO THING
	not.b 39(a0)
	beq.s pitchbend
	moveq #0,d1
	move.b 47(a0),d1	;get portavalue
	beq.s pitchbend		;0=no portamento
	cmpi.b #$1f,d1
	bls.s portaup
portadown: 
	andi.w #$1f,d1
	neg.w d1
portaup:
	sub.w d1,56(a0)
pitchbend:
	not.b 42(a0)
	beq.s addporta
	tst.b 5(a0)
	beq.s addporta
	subq.b #1,5(a0)
	moveq #0,d1
	move.b 4(a0),d1
	bpl.s pitchup
	ext.w d1
pitchup:
	sub.w d1,56(a0)
addporta:
	add.w 56(a0),d0
	cmpi.w #$0070,d0
	bhi.s nn1
	move.w #$0071,d0
nn1:
	cmpi.w #$0d60,d0
	bls.s nn2
	move.w #$0d60,d0
nn2:
	swap d0
	move.b 45(a0),d0
	rts



V1data:  dcb.b 64,0	;Voice 1 data area
offset1: dcb.b 02,0	;Is added to start of sound
ssize1:  dcb.b 02,0	;Length of sound
start1:  dcb.b 06,0	;Start of sound

V2data:  dcb.b 64,0	;Voice 2 data area
offset2: dcb.b 02,0
ssize2:  dcb.b 02,0
start2:  dcb.b 06,0

V3data:  dcb.b 64,0	;Voice 3 data area
offset3: dcb.b 02,0
ssize3:  dcb.b 02,0
start3:  dcb.b 06,0

V4data:  dcb.b 64,0	;Voice 4 data area
offset4: dcb.b 02,0
ssize4:  dcb.b 02,0
start4:  dcb.b 06,0

audtemp: dc.w 0		;DMACON
spdtemp: dc.w 0
respcnt: dc.w 0		;Replay speed counter 
repspd:  dc.w 0		;Replay speed counter temp
onoff:   dc.w 0		;Music on/off flag.

Chandata: dc.l $00000000,$00100003,$00200006,$00300009
SEQpoint: dc.l 0
PATpoint: dc.l 0
FRQpoint: dc.l 0
VOLpoint: dc.l 0


SILENT: dc.w $0100,$0000,$0000,$00e1

PERIODS:dc.w $06b0,$0650,$05f4,$05a0,$054c,$0500,$04b8,$0474
	dc.w $0434,$03f8,$03c0,$038a,$0358,$0328,$02fa,$02d0
	dc.w $02a6,$0280,$025c,$023a,$021a,$01fc,$01e0,$01c5
	dc.w $01ac,$0194,$017d,$0168,$0153,$0140,$012e,$011d
	dc.w $010d,$00fe,$00f0,$00e2,$00d6,$00ca,$00be,$00b4
	dc.w $00aa,$00a0,$0097,$008f,$0087,$007f,$0078,$0071
	dc.w $0071,$0071,$0071,$0071,$0071,$0071,$0071,$0071
	dc.w $0071,$0071,$0071,$0071,$0d60,$0ca0,$0be8,$0b40
	dc.w $0a98,$0a00,$0970,$08e8,$0868,$07f0,$0780,$0714
	dc.w $1ac0,$1940,$17d0,$1680,$1530,$1400,$12e0,$11d0
	dc.w $10d0,$0fe0,$0f00,$0e28,$06b0,$0650,$05f4,$05a0
	dc.w $054c,$0500,$04b8,$0474,$0434,$03f8,$03c0,$038a
	dc.w $0358,$0328,$02fa,$02d0,$02a6,$0280,$025c,$023a
	dc.w $021a,$01fc,$01e0,$01c5,$01ac,$0194,$017d,$0168
	dc.w $0153,$0140,$012e,$011d,$010d,$00fe,$00f0,$00e2
	dc.w $00d6,$00ca,$00be,$00b4,$00aa,$00a0,$0097,$008f
	dc.w $0087,$007f,$0078,$0071

SOUNDINFO:
;Start.l , Length.w , Repeat start.w , Repeat-length.w , dcb.b 6,0 

	dcb.b 10*16,0	;Reserved for samples
	dcb.b 80*16,0	;Reserved for waveforms

;====================
	EVEN			;NOTRE LISTE COPPER
NEWCOPPER:   
	DC.W	$008E,$1281	;DIMENSIONS DE L'ECRAN
	DC.W	$0090,$35D1	;256 LIGNES + 35 LIGNES = 291 LIGNES

	DC.W	$0092,$0038,$0094,$00D0

	;POINTEURS ADRESSE DES PLANS DE L'IMAGE

		DC.W 	$00E0
IMAGE_HI1:	DC.W	0
		DC.W	$00E2
IMAGE_LO1:	DC.W	0   
		DC.W	$00E4
IMAGE_HI2:	DC.W	0   
		DC.W	$00E6
IMAGE_LO2:	DC.W	0   
		DC.W	$00E8
IMAGE_HI3:	DC.W	0   
		DC.W	$00EA
IMAGE_LO3:	DC.W	0   
		DC.W	$00EC
IMAGE_HI4:	DC.W	0   
		DC.W	$00EE
IMAGE_LO4:	DC.W	0   
		DC.W	$00F0
IMAGE_HI5:	DC.W	0
		DC.W	$00F2
IMAGE_LO5:	DC.W	0

	;REGISTRE POUR CHOISIR RESOLUTION	

	DC.W	$0100,$5200		;5 PLANS+MODE COULEURS

	;8;BIT 15 HIRES		:0	HAUTE RESOLUTION  	NON = 0 
;5	;4;BIT 14 BPU2		:1      NBRE DE PLANS     	1   SI 1 = +4 PLANS
	;2;BIT 13 BPU1		:0	      5			0   SI 1 = +2 PLANS
	;1;BIT 12 BPU0		:1				1   SI 1 = +1 PLANS

	;8;BIT 11 HOMOD		:0	MODE HAM 		NON = 0
;2	;4;BIT 10 DBPLF		:0	DUAL PLAYFIELD		NON = 0
	;2;BIT 09 COLOR		:1	COULEURS  		OUI = 1
	;1;BIT 08 GAUD		:0

	;8;BIT 07 INUTILISE	:0				0
;0	;4;BIT 06 INUTILISE	:0				0
	;2;BIT 05 INUTILISE	:0				0
	;1;BIT 04 INUTILISE	:0				0

	;8;BIT 03 LPEN		:0	CRAYON OPTIQUE		NON = 0
;0	;4;BIT 02 LACE		:0	MODE INTERLACE		NON = 0
	;2;BIT 01 ERSY		:0	SYNCHRO EXTERNE		NON = 0
	;1;BIT 00 INUTILISE	:0				0
	

	;DECALAGE ECRAN - INUTILISE ICI

	DC.W	$0102,$0000

	;PRIORITE DES PLANS ET SPRITES - INUTILISE ICI

	DC.W 	$0104,$0000

	;MODULOS DES PLANS

	DC.W	$0108,$000	;MODULOS PLANS PAIRS
	DC.W 	$010A,$000	;MODULOS PLANS IMPAIRS

	;POINTEURS DES SPRITES - MIS A 0 SI PAS DE SPRITES

	DC.W	$0120,$0000,$0122,$0000
	DC.W	$0124,$0000,$0126,$0000
	DC.W	$0128,$0000,$012A,$0000	;PAS DE SPRITES
	DC.W	$012C,$0000,$012E,$0000
	DC.W	$0130,$0000,$0132,$0000
	DC.W	$0134,$0000,$0136,$0000
	DC.W	$0138,$0000,$013A,$0000
	DC.W	$013C,$0000,$013E,$0000

	;REGISTRES DES COULEURS

	DC.W	$0180,$0000	;COULEUR 00
	DC.W	$0182,$0FFF	;COULEUR 01
	DC.W	$0184,$0BDD	;COULEUR 02
	DC.W	$0186,$0899	;COULEUR 03
	DC.W	$0188,$0455	;COULEUR 04
	DC.W	$018A,$0333	;COULEUR 05
	DC.W	$018C,$0222	;COULEUR 06
	DC.W	$018E,$0111	;COULEUR 07
	DC.W	$0190,$0EEF	;COULEUR 08
	DC.W	$0192,$0CCF	;COULEUR 09
	DC.W	$0194,$099F	;COULEUR 10
	DC.W	$0196,$055F	;COULEUR 11
	DC.W	$0198,$000F	;COULEUR 12
	DC.W	$019A,$000A	;COULEUR 13
	DC.W	$019C,$0006	;COULEUR 14
	DC.W	$019E,$0003	;COULEUR 15
	DC.W	$01A0,$0DEF	;COULEUR 16	;LES COULEURS DE 16 A 31 SONT
	DC.W	$01A2,$0BEF	;COULEUR 17	;AUSSI CELLES DES SPRITES
	DC.W	$01A4,$0ADF	;COULEUR 18
	DC.W	$01A6,$07BD	;COULEUR 19	;LES COULEURS 16 A 31 NE SONT
	DC.W	$01A8,$058A	;COULEUR 20	;PAS UTILISEES DANS LE MODE
	DC.W	$01AA,$0357	;COULEUR 21	;HOLD AND MODIFY (HAM)
	DC.W	$01AC,$0234	;COULEUR 22
	DC.W	$01AE,$0011	;COULEUR 23
	DC.W	$01B0,$0FD0	;COULEUR 24
	DC.W	$01B2,$0FA0	;COULEUR 25
	DC.W	$01B4,$0E80	;COULEUR 26
	DC.W	$01B6,$0C60	;COULEUR 27
	DC.W	$01B8,$0A30	;COULEUR 28
	DC.W	$01BA,$0720	;COULEUR 29
	DC.W	$01BC,$0510	;COULEUR 30
	DC.W	$01BE,$0300	;COULEUR 31

	;INSTRUCTIONS POUR AVOIR UN ECRAN PAL (256 LIGNES DE HAUT)

	DC.W $FFDF,$FFFE

	DC.W $1101,$FFFE
	
	DC.W $0100,0		;MET RESOLUTION NULLE
	
	DC.W $0180,$0000	;REGISTRES DES COULEURS
	DC.W $0182,$0a50	;POUR LE SCROLL
	DC.W $0184,$0dc0
	DC.W $0186,$0606
	DC.W $0188,$0818
	DC.W $018a,$0a2a
	DC.W $018c,$0d3d
	DC.W $018e,$0f5f
	
	DC.W	$0092,$0030	;PASSAGE EN OVERSCAN
	DC.W	$0094,$00D8
	
	
	DC.W $1201,$FFFE
	
	DC.W $0100,$3200	;RESOLUTION 3 PLANS = 8 COULEURS

	DC.W $10A,110-4		;MODULO = 10 + 50 + 50 - 4
				;-4 POUR PASSAGE EN OVERSCAN
	DC.W $108,110-4		;MODULO POUR FORMAT RAW BLITTER

	;POINTEURS DE PLANS DU FOND DE SCROLL

		DC.W $00E0
SCROLL_HI1:	DC.W 0	
		DC.W $00E2
SCROLL_LO1:	DC.W 0
		DC.W $00E4
SCROLL_HI2:	DC.W 0
		DC.W $00E6
SCROLL_LO2:	DC.W 0
		DC.W $00E8
SCROLL_HI3:	DC.W 0  
		DC.W $00EA
SCROLL_LO3:	DC.W 0

	DC.L $FFFFFFFE ;FIN LISTE COPPER
	EVEN
FINDEMO: