* AUTEUR: J.ETIENNE
* SUJET: ZOOM BITMAP AVEC LE BLT
* ASSEMBLEUR: DEVPACK 2.14
* MODIFICATIONS PAR FUNX/PHOENIX
* DEVPAC 3.02

	OPT	C-	* opt case off

BEGIN:
	JMP START
;=====================================================================
EXECBASE=4
OPENLIBRARY=-408
CLOSELIBRARY=-414
SUPERSTATE=-150
USERSTATE=-156	
FORBID=-132
PERMIT=-138
ADDINTSERVER=-168
REMINTSERVER=-174
Open=-30
Close=-36
Read=-42

;=====================================================================
BLTCON0=$DFF040		
BLTCON1=$DFF042
BLTAFWM=$DFF044
BLTALWM=$DFF046
BLTCPTH=$DFF048
BLTCPTL=$DFF04A
BLTBPTH=$DFF04C
BLTBPTL=$DFF04E
BLTAPTH=$DFF050
BLTAPTL=$DFF052
BLTDPTH=$DFF054
BLTDPTL=$DFF056
BLTSIZE=$DFF058
BLTCMOD=$DFF060
BLTBMOD=$DFF062
BLTAMOD=$DFF064
BLTDMOD=$DFF066
BLTCDAT=$DFF070
BLTBDAT=$DFF072
BLTADAT=$DFF074
DMACONR=$DFF002
;=================
BPL_X		=	320
BPL_Y		=	256
BPL_DEPTH	=	4
BPL_WIDTH	=	BPL_X/8
BPL_SIZE	=	BPL_WIDTH*BPL_Y
;=================
WAIT_BLT:	MACRO
	
	BTST	#14,DMACONR
LOOP_WAIT_BLT\@:
	BTST	#14,DMACONR
	BNE.S	LOOP_WAIT_BLT\@
	ENDM

;=================
START:    
	MOVEM.L D0-D7/A0-A6,-(A7)	;SAUVE REGISTRES
	MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
	JSR FORBID(A6)    		;SAUTE SOUS PROGRAMME: INTERDIT MULTITACHE
	JSR OPENLIB  			;SAUTE SOUS PROGRAMME: OUVERTURE LIBRAIRIES
	
	BSR MET_ADRESSES		;MET ADRESSE IMAGE DANS NOUVELLE LISTE COPPER
	
	BSR INIT_MUSIQUE		;INITIALISATION DE LA MUSIQUE
	
	BSR ZOOM			;VA A ROUTINE DE ZOOM
	
	BSR SETCOPPER			;SAUTE SOUS PROGRAMME: MET EN PLACE LISTE COPPER
	BSR NEWIRQ3			;SAUTE SOUS PROGRAMME: MET EN PLACE ROUTINE D'INTERRRUPTION

WAIT:
	CMP.B #$E0,$DFF006		;ATTENDANT 200 IEME LIGNE RASTER
	BNE.S WAIT			;SINON RETOURNE A WAIT
	
	BSR ZOOM			;VA A ROUTINE DE ZOOM
	
	BTST	#6,$BFE001		;ATTENDANT PRESSION SUR BOUTON GAUCHE SOURIS
	BNE.S	WAIT			;SINON RETOURNE A WAIT
	 				;SI OUI  FIN
END: 				;FIN:	
	BSR STOP_MUSIQUE		;ARRET DE LA MUSIQUE
	BSR STOPIRQ3        		;SAUTE SOUS PROGRAMME: STOPPE INTERRUPTION
	BSR CLRCOPPER       		;SAUTE SOUS PROGRAMME: RESTAURE ANCIENNE LISTE COPPER
	BSR CLOSELIB        		;SAUTE SOUS PROGRAMME: FERME LIBRAIRIES 
	MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
	JSR PERMIT(A6)      		;AUTORISE MULTITACHE
	                      
	MOVEM.L (A7)+,D0-D7/A0-A6	;RESTAURE REGISTRES
	RTS
;========================
NEWIRQ3:			;MET EN PLACE NOTRE ROUTINE 
	MOVE.L	EXECBASE,A6		;D'INTERRUPTION
	lea	irqstr,a1
	move.l	#5,d0
	jsr	addintserver(a6)
	move.l	d0,irq
	beq.s	irqerror
	rts
irqerror:
	rts
;==========================
STOPIRQ3:			;RESTAURE ANCIENNE ROUTINE
	movem.l	a0-a6/d0-d7,-(sp)	;D'INTERRUPTION
	tst.l	irq
	beq.s	irqoff1
	move.l	execbase,a6
	lea	irqstr,a1
	move.l	#32,d0
	jsr	remintserver(a6)
irqoff1:movem.l	(sp)+,a0-a6/d0-d7
	rts
irqstr:
	dc.l	0,0
	dc.b	2,-127
	dc.l	0,irqdat,interrupt
irqdat:	dc.l	0,0,0,0
irq:	dc.l	0
;============================
interrupt:			;NOTRE ROUTINE D'INTERRUPTION	
	movem.l	a0-a6/d0-d7,-(sp)
	
	BSR PLAY_MUSIQUE		;VA A LA ROUTINE POUR JOUER LA MUSIQUE
	
	movem.l	(sp)+,a0-a6/d0-d7
rts
;============================
OPENLIB:  			;OUVERTURE DE LA LIBRAIRIE GRAPHIQUE
	move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
	lea gfxname,a1			;MET NOM DE LA LIBRAIRIE DANS A1
	move.l #$0,d0           	;MET 0 DANS D0
	jsr openlibrary(a6)		;OUVRE LIBRAIRIE
	tst d0				;TESTE D0
	beq.s error			;SI = A 0   VA A ERROR = SORTIE
	move.l d0,gfxbase       	;SI NON, MET ADRESSE D0 DANS GFXBASE
	add.l #$32,d0			;AJOUTE $32 A CETTE ADRESSE
	move.l d0,coppertr      	;MET D0=ADRESSE ACTUELLE LISTE COPPER
	rts				;DANS COPPERTR
	even
gfxname: dc.b 'graphics.library',0 	;NOM DE LA LIBRAIRIE
	even
gfxbase: dc.l 0				;POINTEUR POUR LA GRAPHICS LIBRARY
coppertr: dc.l 0			;POINTEUR POUR ADRESSE LISTE COPPER
;====================
CLOSELIB: 			;FERMETURE LIBRAIRIE
	move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
	move.l gfxbase,a1		;MET NOM DE LA LIBRAIRIE DANS A1
	jsr closelibrary(a6)		;FERME LIBRAIRIE
	rts
;====================
ERROR:				;SI ERREUR
	illegal				;SORTIE
	rts
;====================
SETCOPPER:			;MET EN PLACE NOTRE LISTE COPPER
	move.l coppertr,a0	;MET ADRESSE ACTUEL COPPER DANS A0
	move.l (a0),oldcopper	;MET CONTENU DANS OLDCOPPER
	move.l #newcopper,(a0)	;MET NOTRE LISTE COPPER DANS A0
	move.w #$81c0+%1000000000,$dff096		;ACTIVE LISTE COPPER
	rts		
oldcopper: dc.l 0
;====================
CLRCOPPER:			;RESTAURE ANCIENNE LISTE COPPER
	move.l coppertr,a0	;MET ANCIENNE ADRESSE DANS A0
	move.l oldcopper,(a0)	;MET CONTENU DANS A0
	move.w #$80a0,$dff096	;REACTIVE ANCIENNE COPPER
	rts
;====================
MET_ADRESSES:			;CHARGE ADRESSE DE L'IMAGE DANS LA COPPER LIST
	MOVE.L #PHY_SCR_ADR,D0	;MET ADRESSE DE L'IMAGE DANS D0 (MOT LONG =
				;PAR EXEMPLE $0005 0000 = D0
	MOVE.W D0,LO1		;MET $0000 DANS LO1
	SWAP D0			;INVERSE D0 = $0000 0005
	MOVE.W D0,HI1		;MET $0005 DANS HI1
	SWAP D0			;INVERSE D0 = $0005 0000
	ADD.L #40,D0		;AJOUTE LA LONGUEUR D'UN PLAN DANS D0
				;ET RECOMMENCE POUR LE PLAN SUIVANT
	MOVE.W D0,LO2
	SWAP D0
	MOVE.W D0,HI2
	SWAP D0
	ADD.L #40,D0
	
	MOVE.W D0,LO3
	SWAP D0
	MOVE.W D0,HI3
	SWAP D0
	ADD.L #40,D0
	
	MOVE.W D0,LO4
	SWAP D0
	MOVE.W D0,HI4
	
	RTS
;====================
ZOOM: 
				;INIT COOR DU RECTANGLE SOURCE
	MOVE.L	#000*$10000,OX1
	;MOVE.L	#000*$10000,OY1
	;MOVE.L	#319*$10000,OX2
	MOVE.L	#255*$10000,OY2
				;INIT COOR DU RECTANGLE CIBLE
	MOVE.L	#000*$10000,DX1
	MOVE.L	#000*$10000,DY1
	MOVE.L	#319*$10000,DX2
	MOVE.L	#255*$10000,DY2
				;FAIT LE ZOOM VERTICAL PUIS HORIZONTAL
	BSR	ZOOM_VERTICAL
	BSR	ZOOM_HORIZONTAL

	MOVE.L	VALEUR,D1
	SUB.L D1,OY1 
	ADD.L D1,OX2
	CMP.L #140*$10000,OY1
	BLE OK 
	NEG VALEUR
	OK:

	CMP.L #0*$10000,OY1
	BNE OK2
	NEG VALEUR
	OK2:

	RTS
	
VALEUR:	DC.L	4*-$10000
		
;============================
ZOOM_HORIZONTAL: 

	MOVEQ	#0,D0 
	MOVE.W	DX2,D0
	SUB.W	DX1,D0
	MOVEQ	#0,D1
	MOVE.W	OX2,D1
	SUB.W	OX1,D1
	SWAP	D1
	BSR	DIV_32_BITS

	MOVE.L	D0,COEF_HORIZONTAL


	MOVE.L	DX1,CUR_OX	
	MOVE.L	DX1,CUR_DX
	
LOOP_EACH_LINE:

	MOVE.W	CUR_OX,D0
	MOVE.W	DY1,D1
	MOVE.W	DY2,D2
	MOVE.W	CUR_DX,D3
	MOVE.W	DY1,D4
	
	BSR	COPY_VERTICAL_LINE
	
	MOVE.L	COEF_HORIZONTAL,D0
	ADD.L	D0,CUR_OX
	ADDQ.W	#1,CUR_DX

	MOVE.W	CUR_DX,D0
	CMP.W	DX2,D0
	BLT.S	LOOP_EACH_LINE
	
	RTS

;====================================
COPY_VERTICAL_LINE:

	; IN: D0 = CUR_OX    = COOR ORIGINE
	;     D1 = OY1       = COOR ORIGINE
	;     D2 = OY2       = COOR ORIGINE
	;     D3 = CUR_DX    = COOR DESTINATION
	;     D4 = DY1       = COOR DESTINATION

	SUB.W	D1,D2			; D2 = LARGEUR	

	MOVE.L	#LOG_SCR_ADR,A0
	MULU	#BPL_WIDTH*BPL_DEPTH,D1
	ADD.L	D1,A0

	MOVEQ	#$F,D1
	AND.W	D0,D1			;D1 = SHIFT OF SOURCE
	MOVEQ	#$F,D6
	AND.W	D3,D6			;D6 = SHIFT OF TARGET
	SUB.W	D1,D6			;D6 = SHIFT FOR BLT
	
	MOVE.L	#PHY_SCR_ADR,A1
	MULU	#BPL_WIDTH*BPL_DEPTH,D4
	ADD.L	D4,A1
	AND.W	#$FFF0,D3
	LSR.W	#3,D3
	LEA	(A1,D3.W),A1		;A1 = TARGET ADR

	TST.W	D6
	BGE.S	SHIFT_GE_0
	ADD.W	#16,D6
	LEA	-BPL_WIDTH*BPL_DEPTH(A1),A1
	ADDQ.W	#1,D2
SHIFT_GE_0:

	MOVE.W	#$8000,D5
	LSR.W	D1,D5

	AND.W	#$FFF0,D0
	LSR.W	#3,D0
	LEA	(A0,D0.W),A0		;A0 = SOURCE ADR

	
	LSL.W	#6,D2
	OR.W	#1,D2			;D2 = BLTSIZE

	ROR.W	#4,D6
	AND.W	#$F000,D6
	MOVE.W	D6,D1
	OR.W	#$07CA,D1


	WAIT_BLT
	MOVE.W	#BPL_WIDTH*BPL_DEPTH-2,BLTBMOD
	MOVE.W	#BPL_WIDTH*BPL_DEPTH-2,BLTCMOD
	MOVE.W	#BPL_WIDTH*BPL_DEPTH-2,BLTDMOD
	MOVE.L	#-1,BLTAFWM
	MOVEQ	#BPL_DEPTH-1,D7
LOOP_EACH_BPL:	
	WAIT_BLT
	MOVE.W	D5,BLTADAT
	MOVE.W	D1,BLTCON0
	MOVE.W	D6,BLTCON1

	MOVE.L	A0,BLTBPTH
	MOVE.L	A1,BLTCPTH
	MOVE.L	A1,BLTDPTH
	MOVE.W 	D2,BLTSIZE
	LEA	BPL_WIDTH(A0),A0
	LEA	BPL_WIDTH(A1),A1
	DBF	D7,LOOP_EACH_BPL	
		
	RTS

;===============================
ZOOM_VERTICAL: 

	MOVEQ	#0,D0 
	MOVE.W	DY2,D0
	SUB.W	DY1,D0
	MOVEQ	#0,D1
	MOVE.W	OY2,D1
	SUB.W	OY1,D1
	SWAP	D1
	BSR	DIV_32_BITS
	MOVE.L	D0,COEF_VERTICAL

	MOVE.L	OY1,CUR_OY	
	MOVE.L	DY1,CUR_DY	
LOOP_EACH_LINEX:

	MOVE.W	OX1,D0
	MOVE.W	CUR_OY,D1
	MOVE.W	OX2,D2
	MOVE.W	DX1,D3
	MOVE.W	CUR_DY,D4
	
	BSR	COPY_HORIZONTAL_LINE

	MOVE.L	COEF_VERTICAL,D0
	ADD.L	D0,CUR_OY
	ADDQ.W	#1,CUR_DY
	
	MOVE.W	CUR_DY,D0
	CMP.W	DY2,D0
	BLT.S	LOOP_EACH_LINEX
	
	RTS

;================================
COPY_HORIZONTAL_LINE:

	; IN: D0 = OX1       = COOR ORIGINE
	;     D1 = CUR_OY    = COOR ORIGINE
	;     D2 = OX2       = COOR ORIGINE
	;     D3 = DX1       = COOR DESTINATION
	;     D4 = CUR_DY    = COOR DESTINATION


	MOVE.L	#FIRST_SCR_ADR,A0
	MULU	#BPL_WIDTH*BPL_DEPTH,D1
	ADD.L	D1,A0

	AND.W	#$FFF0,D0
	AND.W	#$FFF0,D2
	LSR.W	#3,D0
	LSR.W	#3,D2
	
	LEA	(A0,D0.W),A0

	MOVE.L	#LOG_SCR_ADR,A1
	SUBQ.W	#1,D4
	MULU	#BPL_WIDTH*BPL_DEPTH,D4
	ADD.L	D4,A1

	AND.W	#$FFF0,D3
	LSR.W	#3,D3
	LEA	(A1,D3.W),A1
	
	SUB.W	D0,D2
	ADDQ.W	#2,D2			;D2 = LARGEUR DE LA LIGNE EN OCTET
	
	MOVE.W	#BPL_WIDTH,D1
	SUB.W	D2,D1			;D1 = MODULO
	
	LSR.W	#1,D2
	OR.W	#BPL_DEPTH<<6,D2	;D2 = BLTSIZE

	WAIT_BLT
	MOVE.L	#-1,BLTAFWM
	MOVE.L	#$09F00000,BLTCON0
	MOVE.W	D1,BLTAMOD
	MOVE.W	D1,BLTDMOD
	MOVE.L	A0,BLTAPTH
	MOVE.L	A1,BLTDPTH
	MOVE.W 	D2,BLTSIZE
		
	RTS

;==========================
DIV_32_BITS:

	; ROUTINE DE DIVISION D'UN CHIFFRE 32 BITS PART UN CHIFFRE 16 BIT AVEC UN
	; RESULTAT 32 BITS. ELLE EST DIRECTEMENT TIRE DE MISE EN OEUVRE DU 68000
	; DE SYBEX (TRES BON LIVRE SOIT DIT EN PASSANT).
	; IN: D0 = X   CHIFFRE 16 BITS
	;     D1 = YZ  CHIFFRE 32 BITS
	; OUT: D0 = RESULTAT 32 BITS
	; D0-D3 SONT DETRUIT

	MOVEQ	#0,D3
	DIVU	D0,D1
	BVC.S	RESULT 
	MOVE.L	D1,D2
	CLR.W	D1
	SWAP	D1
	DIVU	D0,D1
	MOVE.W	D1,D3
	MOVE.W	D2,D1
	DIVU	D0,D1
RESULT:	MOVE.L	D1,D0
	SWAP	D1
	MOVE.W	D3,D1
	SWAP	D1
	MOVE.L	D1,D0
	RTS

;==============================

COEF_VERTICAL:		DS.L	1  
COEF_HORIZONTAL:	DS.L	1

CUR_OX:		DS.L	1
CUR_OY:		DS.L	1
CUR_DX:		DS.L	1
CUR_DY:		DS.L	1

OX1:	DC.L	0
OY1:	DC.L	0
OX2:	DC.L	319*$10000
OY2:	DC.L	255*$10000

DX1:	DS.L	1
DY1:	DS.L	1
DX2:	DS.L	1
DY2:	DS.L	1

;====================
	EVEN
;CETTE ROUTINE PERMET DE JOUER TOUS LES MODULES DE SOUNDTRACKERS
;DE LA VERSION 1.0 A LA VERSION 2.6  AINSI QUE CERTAINS MODULES
;NOISETRACKER.

INIT_MUSIQUE:			;INITIALISATION DE LA MUSIQUE
mt_init:move.l	mt_rdata(pc),a0
	cmp.l	#"M.K.",$438(a0)
	bne	mt_st20
	lea	mt_forst23(pc),a2
	move.l	a2,mt_forst
	bra	ok1st23
mt_st20:
	lea	mt_forst20(pc),a2
	move.l	a2,mt_forst
ok1st23:	
	add.l	(a2),a0
	moveq	#$7f,d0
	moveq	#0,d1
mt_init1:
	move.l	d1,d2
	subq.w	#1,d0
mt_init2:
	move.b	(a0)+,d1
	cmp.b	d2,d1
	bgt.s	mt_init1
	dbf	d0,mt_init2
	addq.b	#1,d2

mt_init3:
	move.l	mt_rdata(pc),a0
	lea	mt_sample1(pc),a1
	asl.l	#8,d2
	asl.l	#2,d2
	add.l	4(a2),d2
	add.l	a0,d2
	move.l	8(a2),d0
mt_init4:
	move.l	d2,(a1)+
	moveq	#0,d1
	move.w	42(a0),d1
	asl.l	#1,d1
	add.l	d1,d2
	add.l	#$1e,a0
	dbf	d0,mt_init4

	lea	mt_sample1(PC),a0
	moveq	#0,d0
mt_clear:
	move.l	(a0,d0.w),a1
	clr.l	(a1)
	addq.w	#4,d0
	cmp.w	#$7c,d0
	bne.s	mt_clear

	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	clr.l	mt_partnrplay
	clr.l	mt_partnote
	clr.l	mt_partpoint
	move.l	mt_rdata(pc),a1
	add.l	12(a2),a1
	move.b	(a1),mt_maxpart+1
	rts

STOP_MUSIQUE:			;ARRET DE LA MUSIQUE
mt_end:	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	move.w	#$f,$dff096
	rts

PLAY_MUSIQUE:			;JOUE LA MUSIQUE
mt_music:
	addq.w	#1,mt_counter
mt_cool:cmp.w	#6,mt_counter
	bne.s	mt_notsix
	clr.w	mt_counter
	bra	mt_rout2

mt_notsix:
	lea	mt_aud1temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp1
	lea	$dff0a0,a5		
	BSR	mt_arprout
mt_arp1:lea	mt_aud2temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp2
	lea	$dff0b0,a5
	BSR	mt_arprout
mt_arp2:lea	mt_aud3temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp3
	lea	$dff0c0,a5
	BSR	mt_arprout
mt_arp3:lea	mt_aud4temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp4
	lea	$dff0d0,a5
	bra.s	mt_arprout
mt_arp4:rts

mt_arprout:
	move.b	2(a6),d0
	and.b	#$0f,d0
	tst.b	d0
	beq	mt_arpegrt
	cmp.b	#$01,d0
	beq.s	mt_portup
	cmp.b	#$02,d0
	beq.s	mt_portdwn
	cmp.b	#$0a,d0
	beq.s	mt_volslide
	rts

mt_portup:
	moveq	#0,d0
	move.b	3(a6),d0
	sub.w	d0,22(a6)
	cmp.w	#$71,22(a6)
	bpl.s	mt_ok1
	move.w	#$71,22(a6)
mt_ok1:	move.w	22(a6),6(a5)
	rts

mt_portdwn:
	moveq	#0,d0
	move.b	3(a6),d0
	add.w	d0,22(a6)
	cmp.w	#$538,22(a6)
	bmi.s	mt_ok2
	move.w	#$538,22(a6)
mt_ok2:	move.w	22(a6),6(a5)
	rts

mt_volslide:
	moveq	#0,d0
	move.b	3(a6),d0
	lsr.b	#4,d0
	tst.b	d0
	beq.s	mt_voldwn
	add.w	d0,18(a6)
	cmp.w	#64,18(a6)
	bmi.s	mt_ok3
	move.w	#64,18(a6)
mt_ok3:	move.w	18(a6),8(a5)
	rts
mt_voldwn:
	moveq	#0,d0
	move.b	3(a6),d0
	and.b	#$0f,d0
	sub.w	d0,18(a6)
	bpl.s	mt_ok4
	clr.w	18(a6)
mt_ok4:	move.w	18(a6),8(a5)
	rts

mt_arpegrt:
	move.w	mt_counter(PC),d0
	cmp.w	#1,d0
	beq.s	mt_loop2
	cmp.w	#2,d0
	beq.s	mt_loop3
	cmp.w	#3,d0
	beq.s	mt_loop4
	cmp.w	#4,d0
	beq.s	mt_loop2
	cmp.w	#5,d0
	beq.s	mt_loop3
	rts

mt_loop2:
	moveq	#0,d0
	move.b	3(a6),d0
	lsr.b	#4,d0
	bra.s	mt_cont
mt_loop3:
	moveq	#$00,d0
	move.b	3(a6),d0
	and.b	#$0f,d0
	bra.s	mt_cont
mt_loop4:
	move.w	16(a6),d2
	bra.s	mt_endpart
mt_cont:
	add.w	d0,d0
	moveq	#0,d1
	move.w	16(a6),d1
	lea	mt_arpeggio(PC),a0
mt_loop5:
	move.w	(a0,d0),d2
	cmp.w	(a0),d1
	beq.s	mt_endpart
	addq.l	#2,a0
	bra.s	mt_loop5
mt_endpart:
	move.w	d2,6(a5)
	rts

mt_rout2:
	move.l	mt_rdata(pc),a0
	move.l	a0,a3
	add.l	#$0c,a3
	move.l	a0,a2
	move.l	mt_forst,a4
	add.l	(a4),a2
	add.l	16(a4),a0
	move.l	mt_partnrplay(PC),d0
	moveq	#0,d1
	move.b	(a2,d0),d1
	asl.l	#8,d1
	asl.l	#2,d1
	add.l	mt_partnote(PC),d1
	move.l	d1,mt_partpoint
	clr.w	mt_dmacon

	lea	$dff0a0,a5
	lea	mt_aud1temp(PC),a6
	bsr	mt_playit
	lea	$dff0b0,a5
	lea	mt_aud2temp(PC),a6
	bsr	mt_playit
	lea	$dff0c0,a5
	lea	mt_aud3temp(PC),a6
	bsr	mt_playit
	lea	$dff0d0,a5
	lea	mt_aud4temp(PC),a6
	bsr	mt_playit
	move.w	#$01f4,d0
mt_rls:	dbf	d0,mt_rls

	move.w	#$8000,d0
	or.w	mt_dmacon,d0
	move.w	d0,$dff096

	lea	mt_aud4temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice3
	move.l	10(a6),$dff0d0
	move.w	#1,$dff0d4
mt_voice3:
	lea	mt_aud3temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice2
	move.l	10(a6),$dff0c0
	move.w	#1,$dff0c4
mt_voice2:
	lea	mt_aud2temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice1
	move.l	10(a6),$dff0b0
	move.w	#1,$dff0b4
mt_voice1:
	lea	mt_aud1temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice0
	move.l	10(a6),$dff0a0
	move.w	#1,$dff0a4
mt_voice0:
	move.l	mt_partnote(PC),d0
	add.l	#$10,d0
	move.l	d0,mt_partnote
	cmp.l	#$400,d0
	bne.s	mt_stop
mt_higher:
	clr.l	mt_partnote
	addq.l	#1,mt_partnrplay
	moveq	#0,d0
	move.w	mt_maxpart(PC),d0
	move.l	mt_partnrplay(PC),d1
	cmp.l	d0,d1
	bne.s	mt_stop
	clr.l	mt_partnrplay
mt_stop:tst.w	mt_status
	beq.s	mt_stop2
	clr.w	mt_status
	bra.s	mt_higher
mt_stop2:
	rts

mt_playit:
	move.l	(a0,d1.l),(a6)
	addq.l	#4,d1
	moveq	#0,d2
	move.b	2(a6),d2
	and.b	#$f0,d2
	lsr.b	#4,d2

	move.b	(a6),d0
	and.b	#$f0,d0
	or.b	d0,d2
	tst.b	d2
	beq.s	mt_nosamplechange

	moveq	#0,d3
	lea	mt_samples(PC),a1
	move.l	d2,d4
	lsl.l	#2,d2
	mulu	#$1e,d4
	move.l	(a1,d2),4(a6)
	move.w	(a3,d4.l),8(a6)
	move.w	2(a3,d4.l),18(a6)
	move.w	4(a3,d4.l),d3
	tst.w	d3
	beq.s	mt_displace
	move.l	4(a6),d2
	add.l	d3,d2
	move.l	d2,4(a6)
	move.l	d2,10(a6)
	move.w	6(a3,d4.l),8(a6)
	move.w	6(a3,d4.l),14(a6)
	move.w	18(a6),8(a5)
	bra.s	mt_nosamplechange

mt_displace:
	move.l	4(a6),d2
	add.l	d3,d2
	move.l	d2,10(a6)
	move.w	6(a3,d4.l),14(a6)
	move.w	18(a6),8(a5)
mt_nosamplechange:
	move.w (a6),d0
	andi.w #$fff,d0			;it's the bug
	tst.w	d0			;of the real
	beq.s	mt_retrout		;source replay
	move.w	(a6),16(a6)
	move.w	20(a6),$dff096
	move.l	4(a6),(a5)
	move.w	8(a6),4(a5)
	move.w	(a6),d0
	andi.w #$fff,d0			;second bug
	move.w d0,6(a5)			;of the source
	move.w	20(a6),d0
	or.w	d0,mt_dmacon

mt_retrout:
	tst.w	(a6)
	beq.s	mt_nonewper
	move.w	(a6),22(a6)

mt_nonewper:
	move.b	2(a6),d0
	and.b	#$0f,d0
	cmp.b	#$0b,d0
	beq.s	mt_posjmp
	cmp.b	#$0c,d0
	beq.s	mt_setvol
	cmp.b	#$0d,d0
	beq.s	mt_break
	cmp.b	#$0e,d0
	beq.s	mt_setfil
	cmp.b	#$0f,d0
	beq.s	mt_setspeed
	rts

mt_posjmp:
	not.w	mt_status
	moveq	#0,d0
	move.b	3(a6),d0
	subq.b	#1,d0
	move.l	d0,mt_partnrplay
	rts

mt_setvol:
	move.b	3(a6),8(a5)
	rts

mt_break:
	not.w	mt_status
	rts

mt_setfil:
	moveq	#0,d0
	move.b	3(a6),d0
	and.b	#1,d0
	rol.b	#1,d0
	and.b	#$fd,$bfe001
	or.b	d0,$bfe001
	rts

mt_setspeed:
	move.b	3(a6),d0
	and.b	#$0f,d0
	beq.s	mt_back
	clr.w	mt_counter
	move.b	d0,mt_cool+3
mt_back:rts

mt_aud1temp:
	DS.w	10
	dc.w	1
	DS.w	2
mt_aud2temp:
	DS.w	10
	dc.w	2
	DS.w	2
mt_aud3temp:
	DS.w	10
	dc.w	4
	DS.w	2
mt_aud4temp:
	DS.w	10
	dc.w	8
	DS.w	2
mt_partnote:	dc.l	0
mt_partnrplay:	dc.l	0
mt_counter:	dc.w	0
mt_partpoint:	dc.l	0
mt_samples:	dc.l	0
mt_sample1:	DS.l	31
mt_maxpart:	dc.w	0
mt_dmacon:	dc.w	0
mt_status:	dc.w	0
mt_forst:	dc.l	0

mt_forst20:	dc.l 472,600,14,470,600
mt_forst23:	dc.l $3b8,$438,$1e,$3b6,$43c
mt_arpeggio:
	dc.w $0358,$0328,$02fa,$02d0,$02a6,$0280,$025c
	dc.w $023a,$021a,$01fc,$01e0,$01c5,$01ac,$0194,$017d
	dc.w $0168,$0153,$0140,$012e,$011d,$010d,$00fe,$00f0
	dc.w $00e2,$00d6,$00ca,$00be,$00b4,$00aa,$00a0,$0097
	dc.w $008f,$0087,$007f,$0078,$0071,$0000,$0000,$0000
mt_rdata:	dc.l mt_data

;====================
	EVEN				;NOTRE LISTE COPPER
	
	SECTION COPPER,CODE_C
	
NEWCOPPER:   
	DC.W	$008E,$2A81,$0090,$2AD1	;DIMENSIONS DE L'ECRAN
	DC.W	$0092,$0038,$0094,$00D0

	;POINTEURS ADRESSE DES PLANS DE L'IMAGE

	DC.W $00E0
HI1:	DC.W 0				;PLAN 1		
	DC.W $00E2
LO1:	DC.W 0 
	DC.W $00E4
HI2:	DC.W 0				;PLAN 2
	DC.W $00E6
LO2:	DC.W 0
	DC.W $00E8
HI3:	DC.W 0				;PLAN 3
	DC.W $00EA
LO3:	DC.W 0
	DC.W $00EC
HI4:	DC.W 0				;PLAN 4
	DC.W $00EE
LO4:	DC.W 0 

	;REGISTRE POUR CHOISIR RESOLUTION	

	DC.W	$0100,$4200		;5 PLANS+MODE COULEURS

	;DECALAGE ECRAN - INUTILISE ICI

	DC.W	$0102,$0000

	;PRIORITE DES PLANS ET SPRITES - INUTILISE ICI

	DC.W 	$0104,$0000

	;MODULOS DES PLANS

	DC.W	$0108,3*40	;MODULOS PLANS PAIRS
	DC.W 	$010A,3*40	;MODULOS PLANS IMPAIRS

	;POINTEURS DES SPRITES - MIS A 0 SI PAS DE SPRITES

	DC.W	$0120,$0000,$0122,$0000
	DC.W	$0124,$0000,$0126,$0000
	DC.W	$0128,$0000,$012A,$0000	;PAS DE SPRITES
	DC.W	$012C,$0000,$012E,$0000
	DC.W	$0130,$0000,$0132,$0000
	DC.W	$0134,$0000,$0136,$0000
	DC.W	$0138,$0000,$013A,$0000
	DC.W	$013C,$0000,$013E,$0000

	;REGISTRES DES COULEURS

	DC.W	$0180,$0000,$0182,$0111,$0184,$0222,$0186,$0333
	DC.W	$0188,$0444,$018A,$0555,$018C,$0666,$018E,$0777
	DC.W	$0190,$0888,$0192,$0999,$0194,$0AAA,$0196,$0BBB
	DC.W	$0198,$0CCC,$019A,$0DDD,$019C,$0EEE,$019E,$0FFF

	;INSTRUCTIONS POUR AVOIR UN ECRAN PAL (256 LIGNES DE HAUT)

	DC.W $FFDF,$FFFE

	DC.L $FFFFFFFE

	EVEN
;================================

	SECTION	ZONE_CHIP,CODE_C
	
MT_DATA:	INCBIN MODULE

FIRST_SCR_ADR:	INCBIN PIC_RAW

PHY_SCR_ADR:		DS.L	BPL_WIDTH*BPL_Y*BPL_DEPTH/4

LOG_SCR_ADR:		DS.L	BPL_WIDTH*BPL_Y*BPL_DEPTH/4
	END