OPT	C-	* opt case off

        SECTION datas,code_c

BEGIN:
	JMP START
;=====================================================================
EXECBASE=4
OPENLIBRARY=-408
CLOSELIBRARY=-414
SUPERSTATE=-150
USERSTATE=-156	
FORBID=-132
PERMIT=-138
ADDINTSERVER=-168
REMINTSERVER=-174
Open=-30
Close=-36
Read=-42

;=====================================================================
BLTCON0=$DFF040		
BLTCON1=$DFF042
BLTAFWM=$DFF044
BLTALWM=$DFF046
BLTCPTH=$DFF048
BLTCPTL=$DFF04A
BLTBPTH=$DFF04C
BLTBPTL=$DFF04E
BLTAPTH=$DFF050
BLTAPTL=$DFF052
BLTDPTH=$DFF054
BLTDPTL=$DFF056
BLTSIZE=$DFF058
BLTCMOD=$DFF060
BLTBMOD=$DFF062
BLTAMOD=$DFF064
BLTDMOD=$DFF066
BLTCDAT=$DFF070
BLTBDAT=$DFF072
BLTADAT=$DFF074
DMACONR=$DFF002

COP1LCH=$DFF080
COPJMP1=$DFF088

;=================

;=================
START:    
	MOVEM.L D0-D7/A0-A6,-(A7)	;SAUVE REGISTRES
	MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
	JSR FORBID(A6)    		;SAUTE SOUS PROGRAMME: INTERDIT MULTITACHE
	JSR OPENLIB  			;SAUTE SOUS PROGRAMME: OUVERTURE LIBRAIRIES

	BSR INIT_MUSIQUE		;INITIALISATION DE LA MUSIQUE

	BSR SETCOPPER			;SAUTE SOUS PROGRAMME: MET EN PLACE LISTE COPPER
	BSR NEWIRQ3			;SAUTE SOUS PROGRAMME: MET EN PLACE ROUTINE D'INTERRRUPTION

	BRA PLASMA

END: 				;FIN:	
	BSR STOP_MUSIQUE		;ARRET DE LA MUSIQUE
	BSR STOPIRQ3        		;SAUTE SOUS PROGRAMME: STOPPE INTERRUPTION
	BSR CLRCOPPER       		;SAUTE SOUS PROGRAMME: RESTAURE ANCIENNE LISTE COPPER
	BSR CLOSELIB        		;SAUTE SOUS PROGRAMME: FERME LIBRAIRIES 
	MOVE.L EXECBASE,A6		;CHARGE ADRESSE EXECBASE DANS A6
	JSR PERMIT(A6)      		;AUTORISE MULTITACHE
	                      
	MOVEM.L (A7)+,D0-D7/A0-A6	;RESTAURE REGISTRES
	RTS
;========================
NEWIRQ3:			;MET EN PLACE NOTRE ROUTINE 
	MOVE.L	EXECBASE,A6	;D'INTERRUPTION
	lea	irqstr,a1
	move.l	#5,d0
	jsr	addintserver(a6)
	move.l	d0,irq
	beq.s	irqerror
	rts
irqerror:
	rts
;==========================
STOPIRQ3:				;RESTAURE ANCIENNE ROUTINE
	movem.l	a0-a6/d0-d7,-(sp)	;D'INTERRUPTION
	tst.l	irq
	beq.s	irqoff1
	move.l	execbase,a6
	lea	irqstr,a1
	move.l	#32,d0
	jsr	remintserver(a6)
irqoff1:movem.l	(sp)+,a0-a6/d0-d7
	rts
irqstr:
	dc.l	0,0
	dc.b	2,-127
	dc.l	0,irqdat,interrupt
irqdat:	dc.l	0,0,0,0
irq:	dc.l	0
;============================
interrupt:			;NOTRE ROUTINE D'INTERRUPTION	
	movem.l	a0-a6/d0-d7,-(sp)

	BSR PLAY_MUSIQUE		;VA A LA ROUTINE POUR JOUER LA MUSIQUE

;------------INTERUPTIONS---------------
ITCOPPER:				;POUR LE DOUBLE-BUFFERING
	MOVE.L	#NEWCOPPER2,COP1LCH
	MOVE.L	#PT_COP2+2,ATROIS
        BTST	#0,ECR
        BEQ.S	LANCE
	MOVE.L	#NEWCOPPER1,COP1LCH
	MOVE.L	#PT_COP1+2,ATROIS
LANCE:	
	CLR.W	COPJMP1			;COPPERLIST à AFFICHER
	
	movem.l	(sp)+,a0-a6/d0-d7
rts
;============================
OPENLIB:  				;OUVERTURE DE LA LIBRAIRIE GRAPHIQUE
	move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
	lea gfxname,a1			;MET NOM DE LA LIBRAIRIE DANS A1
	move.l #$0,d0           	;MET 0 DANS D0
	jsr openlibrary(a6)		;OUVRE LIBRAIRIE
	tst d0				;TESTE D0
	beq.s error			;SI = A 0   VA A ERROR = SORTIE
	move.l d0,gfxbase       	;SI NON, MET ADRESSE D0 DANS GFXBASE
	add.l #$32,d0			;AJOUTE $32 A CETTE ADRESSE
	move.l d0,coppertr      	;MET D0=ADRESSE ACTUELLE LISTE COPPER
	rts				;DANS COPPERTR
	even
gfxname: dc.b 'graphics.library',0 	;NOM DE LA LIBRAIRIE
	even
gfxbase: dc.l 0				;POINTEUR POUR LA GRAPHICS LIBRARY
coppertr: dc.l 0			;POINTEUR POUR ADRESSE LISTE COPPER
;====================
CLOSELIB: 				;FERMETURE LIBRAIRIE
	move.l execbase,a6      	;MET ADRESSE EXECBASE DANS A6
	move.l gfxbase,a1		;MET NOM DE LA LIBRAIRIE DANS A1
	jsr closelibrary(a6)		;FERME LIBRAIRIE
	rts
;====================
ERROR:					;SI ERREUR
	illegal				;SORTIE
	rts
;====================
SETCOPPER:				;MET EN PLACE NOTRE LISTE COPPER
	move.w #$0080,$dff096
	move.l coppertr,a0		;MET ADRESSE ACTUEL COPPER DANS A0
	move.l (a0),oldcopper		;MET CONTENU DANS OLDCOPPER
	move.w #$87c0,$dff096		;ACTIVE LISTE COPPER
	rts		
oldcopper: dc.l 0
;====================
CLRCOPPER:				;RESTAURE ANCIENNE LISTE COPPER
	move.w #$0080,$dff096
	move.l coppertr,a0		;MET ANCIENNE ADRESSE DANS A0
	move.l oldcopper,(a0)		;MET CONTENU DANS A0
	move.w #$80a0,$dff096		;REACTIVE ANCIENNE COPPER
	rts
;====================

ECR:	DC.W	0

ATROIS:	DC.L	PT_COP1+2

NBMOVE=47

HAUT=200

;======================
WAITBLIT:	
	BTST	#14,$DFF002
	BNE	WAITBLIT
	RTS
;====================

PLASMA:
	
	BSR WAITBLIT

				;INITIALISATION
	MOVE.L	#-1,BLTAFWM	;DU BLITTER
	CLR	BLTCON1
	CLR.L	BLTCMOD
	CLR.W	BLTAMOD		;MODULOS :
	MOVE.W	#190,BLTDMOD	;(NBMOVE+1)*4-2
	
	MOVE.L	#PLAN,D0	;ADRESSE PLAN1
	LEA	PLAN_A,A0	;COPPER_LIST1
	LEA	PLAN_B,A1	;COPPER_LIST2
	MOVE	D0,2(A0)	;MOT DE POID
	MOVE	D0,2(A1)	;FAIBLE
	SWAP	D0
	MOVE	D0,6(A0)	;MOT DE POID
	MOVE	D0,6(A1)	;FORT

LOOP:

WAIT:	CMP.B	#$F0,$DFF006
	BNE.S	WAIT
	
	BTST	#10,$DFF016	;BOUTON DROIT
	BNE.S	CHGMIN
	ADD.B	#1,MINTERM
CHGMIN:

	
	MOVE	#0,$DFF180
	BTST	#6,$BFE001	;BOUTON GAUCHE?
	BEQ	END		;SI OUI BYE!

	BCHG	#0,ECR
	MOVE.L	ATROIS(PC),A3	;A3=COP_LIST1 OU 2

**  CHANGE LE MASQUE DES 'WAIT'  **

	BSR WAITBLIT

	MOVEQ	#0,D6
	MOVE	Z(PC),D6
	ADDQ	#2,D6
	AND	#MDECAL,D6
	MOVE	D6,Z
	ADD.L	#DECAL,D6
	MOVE	#$9F0,BLTCON0
	MOVE.L	D6,BLTAPTH
	MOVE.L	A3,BLTDPTH
	MOVE.W	#200*64+1,BLTSIZE

**  CHANGE LE MINTERM  **

	LEA	4(A3),A3
	MOVE	BLTCON(PC),D6

**  VARIATION DES COURBES SINUSSOïDALES  **

	LEA	T1(PC),A4
	MOVE	VA(PC),D3
	ADDQ	#2,D3
	AND	#MT1,D3
	MOVE	D3,VA
	MOVE	VB(PC),D4
	SUBQ	#2,D4
	AND	#MT1,D4
	MOVE	D4,VB
	MOVE	D3,D5

**  COPIE DES SOURCES DE COULEURS DANS LA 
**  COPPERLIST DE TRAVAIL

	BSR WAITBLIT

	MOVE	D6,BLTCON0
	MOVEQ	#NBMOVE-1,D7
BCL:	MOVEQ	#0,D0
	MOVEQ	#0,D1
	MOVEQ	#0,D2
	MOVE	(A4,D3),D0
	ADDQ.W	#4,D3
	AND	#MT1,D3
	ADD.L	#FX_ROUGE,D0
	MOVE	(A4,D4),D1
	ADDQ.W	#8,D4
	AND	#MT1,D4
	ADD.L	#FX_VERT,D1
	MOVE	(A4,D5),D2
	SUBQ.W	#6,D5
	AND	#MT1,D5
	ADD.L	#FX_BLEU,D2

	MOVE.L	D0,BLTCPTH
	MOVE.L	D1,BLTBPTH
	MOVE.L	D2,BLTAPTH
	MOVE.L	A3,BLTDPTH
	MOVE.W	#HAUT*64+1,BLTSIZE
	LEA	4(A3),A3
	DBF	D7,BCL

	BRA	LOOP


;**********************************
Z:		DC.W	0
VA:		DC.W	0
VB:		DC.W	0
BLTCON:		DC.B	$0F
MINTERM:	DC.B	$01
	EVEN

MT1=256*2-1		;MODULO DE LA TABLE DE SINUS

T1:

	DC.W $0C8,$0CC,$0D1,$0D6,$0DB,$0E0,$0E5,$0EA,$0EF,$0F3,$0F8,$0FD
	DC.W $102,$106,$10B,$10F,$114,$119,$11D,$121,$126,$12A,$12E,$132
	DC.W $137,$13B,$13F,$143,$146,$14A,$14E,$151,$155,$158,$15C,$15F
	dc.w $162,$165,$168,$16B,$16E,$170,$173,$176,$178,$17A,$17C,$17E
	dc.w $180,$182,$184,$185,$187,$188,$18A,$18B,$18C,$18D,$18D,$18E
	dc.w $18F,$18F,$18F,$18F,$190,$18F,$18F,$18F,$18F,$18E,$18D,$18D
	dc.w $18C,$18B,$18A,$188,$187,$185,$184,$182,$180,$17E,$17C,$17A
	dc.w $178,$176,$173,$170,$16E,$16B,$168,$165,$162,$15F,$15C,$158
	dc.w $155,$151,$14E,$14A,$146,$143,$13F,$13B,$137,$132,$12E,$12A
	dc.w $126,$121,$11D,$119,$114,$10F,$10B,$106,$102,$0FD,$0F8,$0F3
	dc.w $0EF,$0EA,$0E5,$0E0,$0DB,$0D6,$0D1,$0CC,$0C8,$0C3,$0BE,$0B9
	dc.w $0B4,$0AF,$0AA,$0A5,$0A0,$09C,$097,$092,$08D,$089,$084,$080
	dc.w $07B,$076,$072,$06E,$069,$065,$061,$05D,$058,$054,$050,$04C
	dc.w $049,$045,$041,$03E,$03A,$037,$033,$030,$02D,$02A,$027,$024
	dc.w $021,$01F,$01C,$019,$017,$015,$013,$011,$00F,$00D,$00B,$00A
	dc.w $008,$007,$005,$004,$003,$002,$002,$001,$000,$000,$000,$000
	dc.w $000,$000,$000,$000,$000,$001,$002,$002,$003,$004,$005,$007
	dc.w $008,$00A,$00B,$00D,$00F,$011,$013,$015,$017,$019,$01C,$01F
	dc.w $021,$024,$027,$02A,$02D,$030,$033,$037,$03A,$03E,$041,$045
	dc.w $049,$04C,$050,$054,$058,$05D,$061,$065,$069,$06E,$072,$076
	dc.w $07B,$080,$084,$089,$08D,$092,$097,$09C,$0A0,$0A5,$0AA,$0AF
	dc.w $0B4,$0B9,$0BE,$0C3


MDECAL=64*2-1		;MODULO DE LA TABLE DE 'WAIT'

DECAL:	


	DC.w $FFF0,$FFF0,$FFF2,$FFF4,$FFF4,$FFF6,$FFF6
	dc.w $FFF8,$FFF8,$FFFA,$FFFA,$FFFC,$FFFC,$FFFC
	dc.w $FFFC,$FFFC,$FFFE,$FFFC,$FFFC,$FFFC,$FFFC
	dc.w $FFFC,$FFFA,$FFFA,$FFF8,$FFF8,$FFF6,$FFF6
	dc.w $FFF4,$FFF4,$FFF2,$FFF0,$FFF0,$FFEE,$FFEC
	dc.w $FFEA,$FFEA,$FFE8,$FFE8,$FFE6,$FFE6,$FFE4
	dc.w $FFE4,$FFE2,$FFE2,$FFE2,$FFE2,$FFE2,$FFE2
	dc.w $FFE2,$FFE2,$FFE2,$FFE2,$FFE2,$FFE4,$FFE4
	dc.w $FFE6,$FFE6,$FFE8,$FFE8,$FFEA,$FFEA,$FFEC
	dc.w $FFEE

	dc.w $FFF0,$FFF0,$FFF2,$FFF4,$FFF4,$FFF6,$FFF6
	dc.w $FFF8,$FFF8,$FFFA,$FFFA,$FFFC,$FFFC,$FFFC
	dc.w $FFFC,$FFFC,$FFFE,$FFFC,$FFFC,$FFFC,$FFFC
	dc.w $FFFC,$FFFA,$FFFA,$FFF8,$FFF8,$FFF6,$FFF6
	dc.w $FFF4,$FFF4,$FFF2,$FFF0,$FFF0,$FFEE,$FFEC
	dc.w $FFEA,$FFEA,$FFE8,$FFE8,$FFE6,$FFE6,$FFE4
	dc.w $FFE4,$FFE2,$FFE2,$FFE2,$FFE2,$FFE2,$FFE2
	dc.w $FFE2,$FFE2,$FFE2,$FFE2,$FFE2,$FFE4,$FFE4
	dc.w $FFE6,$FFE6,$FFE8,$FFE8,$FFEA,$FFEA,$FFEC
	dc.w $FFEE

	dc.w $FFF0,$FFF0,$FFF2,$FFF4,$FFF4,$FFF6,$FFF6
	dc.w $FFF8,$FFF8,$FFFA,$FFFA,$FFFC,$FFFC,$FFFC
	dc.w $FFFC,$FFFC,$FFFE,$FFFC,$FFFC,$FFFC,$FFFC
	dc.w $FFFC,$FFFA,$FFFA,$FFF8,$FFF8,$FFF6,$FFF6
	dc.w $FFF4,$FFF4,$FFF2,$FFF0,$FFF0,$FFEE,$FFEC
	dc.w $FFEA,$FFEA,$FFE8,$FFE8,$FFE6,$FFE6,$FFE4
	dc.w $FFE4,$FFE2,$FFE2,$FFE2,$FFE2,$FFE2,$FFE2
	dc.w $FFE2,$FFE2,$FFE2,$FFE2,$FFE2,$FFE4,$FFE4
	dc.w $FFE6,$FFE6,$FFE8,$FFE8,$FFEA,$FFEA,$FFEC
	dc.w $FFEE

	dc.w $FFF0,$FFF0,$FFF2,$FFF4,$FFF4,$FFF6,$FFF6
	dc.w $FFF8,$FFF8,$FFFA,$FFFA,$FFFC,$FFFC,$FFFC
	dc.w $FFFC,$FFFC,$FFFE,$FFFC,$FFFC,$FFFC,$FFFC
	dc.w $FFFC,$FFFA,$FFFA,$FFF8,$FFF8,$FFF6,$FFF6
	dc.w $FFF4,$FFF4,$FFF2,$FFF0,$FFF0,$FFEE,$FFEC
	dc.w $FFEA,$FFEA,$FFE8,$FFE8,$FFE6,$FFE6,$FFE4
	dc.w $FFE4,$FFE2,$FFE2,$FFE2,$FFE2,$FFE2,$FFE2
	dc.w $FFE2,$FFE2,$FFE2,$FFE2,$FFE2,$FFE4,$FFE4
	dc.w $FFE6,$FFE6,$FFE8,$FFE8,$FFEA,$FFEA,$FFEC
	dc.w $FFEE

	dc.w $FFF0,$FFF0,$FFF2,$FFF4,$FFF4,$FFF6,$FFF6
	dc.w $FFF8,$FFF8,$FFFA,$FFFA,$FFFC,$FFFC,$FFFC
	dc.w $FFFC,$FFFC,$FFFE,$FFFC,$FFFC,$FFFC,$FFFC
	dc.w $FFFC,$FFFA,$FFFA,$FFF8,$FFF8,$FFF6,$FFF6
	dc.w $FFF4,$FFF4,$FFF2,$FFF0,$FFF0,$FFEE,$FFEC
	dc.w $FFEA,$FFEA,$FFE8,$FFE8,$FFE6,$FFE6,$FFE4
	dc.w $FFE4,$FFE2,$FFE2,$FFE2,$FFE2,$FFE2,$FFE2
	dc.w $FFE2,$FFE2,$FFE2,$FFE2,$FFE2,$FFE4,$FFE4
	dc.w $FFE6,$FFE6,$FFE8,$FFE8,$FFEA,$FFEA,$FFEC
	dc.w $FFEE



;====================
;CETTE ROUTINE PERMET DE JOUER TOUS LES MODULES DE SOUNDTRACKERS
;DE LA VERSION 1.0 A LA VERSION 2.6  AINSI QUE CERTAINS MODULES
;NOISETRACKER.

INIT_MUSIQUE:			;INITIALISATION DE LA MUSIQUE
mt_init:move.l	mt_rdata(pc),a0
	cmp.l	#"M.K.",$438(a0)
	bne	mt_st20
	lea	mt_forst23(pc),a2
	move.l	a2,mt_forst
	bra	ok1st23
mt_st20:
	lea	mt_forst20(pc),a2
	move.l	a2,mt_forst
ok1st23:	
	add.l	(a2),a0
	moveq	#$7f,d0
	moveq	#0,d1
mt_init1:
	move.l	d1,d2
	subq.w	#1,d0
mt_init2:
	move.b	(a0)+,d1
	cmp.b	d2,d1
	bgt.s	mt_init1
	dbf	d0,mt_init2
	addq.b	#1,d2

mt_init3:
	move.l	mt_rdata(pc),a0
	lea	mt_sample1(pc),a1
	asl.l	#8,d2
	asl.l	#2,d2
	add.l	4(a2),d2
	add.l	a0,d2
	move.l	8(a2),d0
mt_init4:
	move.l	d2,(a1)+
	moveq	#0,d1
	move.w	42(a0),d1
	asl.l	#1,d1
	add.l	d1,d2
	add.l	#$1e,a0
	dbf	d0,mt_init4

	lea	mt_sample1(PC),a0
	moveq	#0,d0
mt_clear:
	move.l	(a0,d0.w),a1
	clr.l	(a1)
	addq.w	#4,d0
	cmp.w	#$7c,d0
	bne.s	mt_clear

	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	clr.l	mt_partnrplay
	clr.l	mt_partnote
	clr.l	mt_partpoint
	move.l	mt_rdata(pc),a1
	add.l	12(a2),a1
	move.b	(a1),mt_maxpart+1
	rts

STOP_MUSIQUE:			;ARRET DE LA MUSIQUE
mt_end:	clr.w	$dff0a8
	clr.w	$dff0b8
	clr.w	$dff0c8
	clr.w	$dff0d8
	move.w	#$f,$dff096
	rts

PLAY_MUSIQUE:			;JOUE LA MUSIQUE
mt_music:
	addq.w	#1,mt_counter
mt_cool:cmp.w	#6,mt_counter
	bne.s	mt_notsix
	clr.w	mt_counter
	bra	mt_rout2

mt_notsix:
	lea	mt_aud1temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp1
	lea	$dff0a0,a5		
	BSR	mt_arprout
mt_arp1:lea	mt_aud2temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp2
	lea	$dff0b0,a5
	BSR	mt_arprout
mt_arp2:lea	mt_aud3temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp3
	lea	$dff0c0,a5
	BSR	mt_arprout
mt_arp3:lea	mt_aud4temp(PC),a6
	tst.b	3(a6)
	beq.s	mt_arp4
	lea	$dff0d0,a5
	bra.s	mt_arprout
mt_arp4:rts

mt_arprout:
	move.b	2(a6),d0
	and.b	#$0f,d0
	tst.b	d0
	beq	mt_arpegrt
	cmp.b	#$01,d0
	beq.s	mt_portup
	cmp.b	#$02,d0
	beq.s	mt_portdwn
	cmp.b	#$0a,d0
	beq.s	mt_volslide
	rts

mt_portup:
	moveq	#0,d0
	move.b	3(a6),d0
	sub.w	d0,22(a6)
	cmp.w	#$71,22(a6)
	bpl.s	mt_ok1
	move.w	#$71,22(a6)
mt_ok1:	move.w	22(a6),6(a5)
	rts

mt_portdwn:
	moveq	#0,d0
	move.b	3(a6),d0
	add.w	d0,22(a6)
	cmp.w	#$538,22(a6)
	bmi.s	mt_ok2
	move.w	#$538,22(a6)
mt_ok2:	move.w	22(a6),6(a5)
	rts

mt_volslide:
	moveq	#0,d0
	move.b	3(a6),d0
	lsr.b	#4,d0
	tst.b	d0
	beq.s	mt_voldwn
	add.w	d0,18(a6)
	cmp.w	#64,18(a6)
	bmi.s	mt_ok3
	move.w	#64,18(a6)
mt_ok3:	move.w	18(a6),8(a5)
	rts
mt_voldwn:
	moveq	#0,d0
	move.b	3(a6),d0
	and.b	#$0f,d0
	sub.w	d0,18(a6)
	bpl.s	mt_ok4
	clr.w	18(a6)
mt_ok4:	move.w	18(a6),8(a5)
	rts

mt_arpegrt:
	move.w	mt_counter(PC),d0
	cmp.w	#1,d0
	beq.s	mt_loop2
	cmp.w	#2,d0
	beq.s	mt_loop3
	cmp.w	#3,d0
	beq.s	mt_loop4
	cmp.w	#4,d0
	beq.s	mt_loop2
	cmp.w	#5,d0
	beq.s	mt_loop3
	rts

mt_loop2:
	moveq	#0,d0
	move.b	3(a6),d0
	lsr.b	#4,d0
	bra.s	mt_cont
mt_loop3:
	moveq	#$00,d0
	move.b	3(a6),d0
	and.b	#$0f,d0
	bra.s	mt_cont
mt_loop4:
	move.w	16(a6),d2
	bra.s	mt_endpart
mt_cont:
	add.w	d0,d0
	moveq	#0,d1
	move.w	16(a6),d1
	lea	mt_arpeggio(PC),a0
mt_loop5:
	move.w	(a0,d0),d2
	cmp.w	(a0),d1
	beq.s	mt_endpart
	addq.l	#2,a0
	bra.s	mt_loop5
mt_endpart:
	move.w	d2,6(a5)
	rts

mt_rout2:
	move.l	mt_rdata(pc),a0
	move.l	a0,a3
	add.l	#$0c,a3
	move.l	a0,a2
	move.l	mt_forst,a4
	add.l	(a4),a2
	add.l	16(a4),a0
	move.l	mt_partnrplay(PC),d0
	moveq	#0,d1
	move.b	(a2,d0),d1
	asl.l	#8,d1
	asl.l	#2,d1
	add.l	mt_partnote(PC),d1
	move.l	d1,mt_partpoint
	clr.w	mt_dmacon

	lea	$dff0a0,a5
	lea	mt_aud1temp(PC),a6
	bsr	mt_playit
	lea	$dff0b0,a5
	lea	mt_aud2temp(PC),a6
	bsr	mt_playit
	lea	$dff0c0,a5
	lea	mt_aud3temp(PC),a6
	bsr	mt_playit
	lea	$dff0d0,a5
	lea	mt_aud4temp(PC),a6
	bsr	mt_playit
	move.w	#$01f4,d0
mt_rls:	dbf	d0,mt_rls

	move.w	#$8000,d0
	or.w	mt_dmacon,d0
	move.w	d0,$dff096

	lea	mt_aud4temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice3
	move.l	10(a6),$dff0d0
	move.w	#1,$dff0d4
mt_voice3:
	lea	mt_aud3temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice2
	move.l	10(a6),$dff0c0
	move.w	#1,$dff0c4
mt_voice2:
	lea	mt_aud2temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice1
	move.l	10(a6),$dff0b0
	move.w	#1,$dff0b4
mt_voice1:
	lea	mt_aud1temp(PC),a6
	cmp.w	#1,14(a6)
	bne.s	mt_voice0
	move.l	10(a6),$dff0a0
	move.w	#1,$dff0a4
mt_voice0:
	move.l	mt_partnote(PC),d0
	add.l	#$10,d0
	move.l	d0,mt_partnote
	cmp.l	#$400,d0
	bne.s	mt_stop
mt_higher:
	clr.l	mt_partnote
	addq.l	#1,mt_partnrplay
	moveq	#0,d0
	move.w	mt_maxpart(PC),d0
	move.l	mt_partnrplay(PC),d1
	cmp.l	d0,d1
	bne.s	mt_stop
	clr.l	mt_partnrplay
mt_stop:tst.w	mt_status
	beq.s	mt_stop2
	clr.w	mt_status
	bra.s	mt_higher
mt_stop2:
	rts

mt_playit:
	move.l	(a0,d1.l),(a6)
	addq.l	#4,d1
	moveq	#0,d2
	move.b	2(a6),d2
	and.b	#$f0,d2
	lsr.b	#4,d2

	move.b	(a6),d0
	and.b	#$f0,d0
	or.b	d0,d2
	tst.b	d2
	beq.s	mt_nosamplechange

	moveq	#0,d3
	lea	mt_samples(PC),a1
	move.l	d2,d4
	lsl.l	#2,d2
	mulu	#$1e,d4
	move.l	(a1,d2),4(a6)
	move.w	(a3,d4.l),8(a6)
	move.w	2(a3,d4.l),18(a6)
	move.w	4(a3,d4.l),d3
	tst.w	d3
	beq.s	mt_displace
	move.l	4(a6),d2
	add.l	d3,d2
	move.l	d2,4(a6)
	move.l	d2,10(a6)
	move.w	6(a3,d4.l),8(a6)
	move.w	6(a3,d4.l),14(a6)
	move.w	18(a6),8(a5)
	bra.s	mt_nosamplechange

mt_displace:
	move.l	4(a6),d2
	add.l	d3,d2
	move.l	d2,10(a6)
	move.w	6(a3,d4.l),14(a6)
	move.w	18(a6),8(a5)
mt_nosamplechange:
	move.w (a6),d0
	andi.w #$fff,d0			;it's the bug
	tst.w	d0			;of the real
	beq.s	mt_retrout		;source replay
	move.w	(a6),16(a6)
	move.w	20(a6),$dff096
	move.l	4(a6),(a5)
	move.w	8(a6),4(a5)
	move.w	(a6),d0
	andi.w #$fff,d0			;second bug
	move.w d0,6(a5)			;of the source
	move.w	20(a6),d0
	or.w	d0,mt_dmacon

mt_retrout:
	tst.w	(a6)
	beq.s	mt_nonewper
	move.w	(a6),22(a6)

mt_nonewper:
	move.b	2(a6),d0
	and.b	#$0f,d0
	cmp.b	#$0b,d0
	beq.s	mt_posjmp
	cmp.b	#$0c,d0
	beq.s	mt_setvol
	cmp.b	#$0d,d0
	beq.s	mt_break
	cmp.b	#$0e,d0
	beq.s	mt_setfil
	cmp.b	#$0f,d0
	beq.s	mt_setspeed
	rts

mt_posjmp:
	not.w	mt_status
	moveq	#0,d0
	move.b	3(a6),d0
	subq.b	#1,d0
	move.l	d0,mt_partnrplay
	rts

mt_setvol:
	move.b	3(a6),8(a5)
	rts

mt_break:
	not.w	mt_status
	rts

mt_setfil:
	moveq	#0,d0
	move.b	3(a6),d0
	and.b	#1,d0
	rol.b	#1,d0
	and.b	#$fd,$bfe001
	or.b	d0,$bfe001
	rts

mt_setspeed:
	move.b	3(a6),d0
	and.b	#$0f,d0
	beq.s	mt_back
	clr.w	mt_counter
	move.b	d0,mt_cool+3
mt_back:rts

mt_aud1temp:
	DS.w	10
	dc.w	1
	DS.w	2
mt_aud2temp:
	DS.w	10
	dc.w	2
	DS.w	2
mt_aud3temp:
	DS.w	10
	dc.w	4
	DS.w	2
mt_aud4temp:
	DS.w	10
	dc.w	8
	DS.w	2
mt_partnote:	dc.l	0
mt_partnrplay:	dc.l	0
mt_counter:	dc.w	0
mt_partpoint:	dc.l	0
mt_samples:	dc.l	0
mt_sample1:	DS.l	31
mt_maxpart:	dc.w	0
mt_dmacon:	dc.w	0
mt_status:	dc.w	0
mt_forst:	dc.l	0

mt_forst20:	dc.l 472,600,14,470,600
mt_forst23:	dc.l $3b8,$438,$1e,$3b6,$43c
mt_arpeggio:
	dc.w $0358,$0328,$02fa,$02d0,$02a6,$0280,$025c
	dc.w $023a,$021a,$01fc,$01e0,$01c5,$01ac,$0194,$017d
	dc.w $0168,$0153,$0140,$012e,$011d,$010d,$00fe,$00f0
	dc.w $00e2,$00d6,$00ca,$00be,$00b4,$00aa,$00a0,$0097
	dc.w $008f,$0087,$007f,$0078,$0071,$0000,$0000,$0000
mt_rdata:	dc.l mt_data

;====================

	EVEN				;NOTRE LISTE COPPER
	
NEWCOPPER1:
   
	DC.W	$008E,$3781
	DC.W	$0090,$FFC1	;DIMENSIONS DE L'ECRAN
	DC.W	$0092,$0038
	DC.W	$0094,$00D0

	;POINTEURS ADRESSE DES PLANS DE L'IMAGE

PLAN_A:
	DC.W $00E2
	DC.W 0				;PLAN 1		
	DC.W $00E0
	DC.W 0 

	;REGISTRE POUR CHOISIR RESOLUTION	

	DC.W	$0100,$1200		;1 PLANS+MODE COULEURS

	;DECALAGE ECRAN - INUTILISE ICI

	DC.W	$0102,$0000

	;PRIORITE DES PLANS ET SPRITES - INUTILISE ICI

	DC.W 	$0104,$0000

	;MODULOS DES PLANS

	DC.W	$0108,-40	;MODULOS PLANS PAIRS
	DC.W 	$010A,-40	;MODULOS PLANS IMPAIRS

	;POINTEURS DES SPRITES - MIS A 0 SI PAS DE SPRITES

	DC.W	$0120,$0000,$0122,$0000
	DC.W	$0124,$0000,$0126,$0000
	DC.W	$0128,$0000,$012A,$0000	;PAS DE SPRITES
	DC.W	$012C,$0000,$012E,$0000
	DC.W	$0130,$0000,$0132,$0000
	DC.W	$0134,$0000,$0136,$0000
	DC.W	$0138,$0000,$013A,$0000
	DC.W	$013C,$0000,$013E,$0000

	;REGISTRES DES COULEURS

	DC.W	$0180,$0000	;COULEUR 00
	DC.W	$0182,$0ffc	;COULEUR 01

PT_COP1:
A SET $373F
	REPT	HAUT
	DC.W	A,$FFFE		WAIT
	DCB.L	47,$01820000	MOVE
A SET A+$100
	ENDR
	DC.W	$0182,$0000

	DC.L $FFFFFFFE
;--------------------------------------------
NEWCOPPER2:
   
	DC.W	$008E,$3781
	DC.W	$0090,$FFC1	;DIMENSIONS DE L'ECRAN
	DC.W	$0092,$0038
	DC.W	$0094,$00D0

	;POINTEURS ADRESSE DES PLANS DE L'IMAGE

PLAN_B:
	DC.W $00E2
	DC.W 0				;PLAN 1		
	DC.W $00E0
	DC.W 0 

	;REGISTRE POUR CHOISIR RESOLUTION	

	DC.W	$0100,$1200		;1 PLANS+MODE COULEURS

	;DECALAGE ECRAN - INUTILISE ICI

	DC.W	$0102,$0000

	;PRIORITE DES PLANS ET SPRITES - INUTILISE ICI

	DC.W 	$0104,$0000

	;MODULOS DES PLANS

	DC.W	$0108,-40	;MODULOS PLANS PAIRS
	DC.W 	$010A,-40	;MODULOS PLANS IMPAIRS

	;POINTEURS DES SPRITES - MIS A 0 SI PAS DE SPRITES

	DC.W	$0120,$0000,$0122,$0000
	DC.W	$0124,$0000,$0126,$0000
	DC.W	$0128,$0000,$012A,$0000	;PAS DE SPRITES
	DC.W	$012C,$0000,$012E,$0000
	DC.W	$0130,$0000,$0132,$0000
	DC.W	$0134,$0000,$0136,$0000
	DC.W	$0138,$0000,$013A,$0000
	DC.W	$013C,$0000,$013E,$0000

	;REGISTRES DES COULEURS

	DC.W	$0180,$0000	;COULEUR 00
	DC.W	$0182,$0ffc	;COULEUR 01

PT_COP2:
A SET $373F
	REPT	HAUT
	DC.W	A,$FFFE		WAIT
	DCB.L	47,$01820000	MOVE
A SET A+$100
	ENDR
	DC.W	$0182,$0000

	DC.L $FFFFFFFE

;--------------------------------------------

**	BARRES DE COULEURS	**

FX_ROUGE:
	DS.W	100
R SET 0
	REPT	15
R SET R+$100
	DCB.W	8,R
	ENDR
	REPT	15
R SET R-$100
	DCB.W	8,R
	ENDR

FX_VERT:
	DS.W	100
V SET 0
	REPT	15
V SET V+$10
	DCB.W	8,V
	ENDR
	REPT	15
V SET V-$10
	DCB.W	8,V
	ENDR

FX_BLEU:
	DS.W	100
B SET 0
	REPT	15
B SET B+$1
	DCB.W	8,B
	ENDR
	REPT	15
B SET B-$1
	DCB.W	8,B
	ENDR
	DS.W	100

**	1 PLAN EN UNE SEULE LIGNE GRACE AU
**	MODULO BTPL1 :  BPL1MOD
PLAN:	DCB.B	40,$FF
	

	EVEN

MT_DATA:	INCBIN MODULE

	END