;----------------------------------------------------;
  ;BASIC-Extension Zzz                       SMmagic'88;
  ;----------------------------------------------------;
  ;Syntax: Zzz WINDOW(7),OnOff                         ;
  ;OnOff  even or 0   :    Mouse is slepping           ;
  ;OnOff  odd     (1) :    Mouse is normal             ;
  ;----------------------------------------------------;
ZZZ:     MOVEM.L D0-A6,-(SP) ;Reserve register
         MOVE.L 4,A6         ;Get Base address of Exec
         LEA INTNAME,A1      ;Address of Library-Names
         MOVEQ #0,D0         ;Version is same
         JSR -552(A6)        ;OpenLibrary
         TST.L D0            ;No, what's happening?
         BEQ.S ENDE          ;No? then end
         MOVE.L D0,A6        ;IntuitionBase loaded
         MOVE.L 64(SP),A0    ;get WindowBase
         MOVE.L 68(SP),D0    ;get OnOff-Flag
         BTST #0,D0          ;Bit 0 test
         BEQ.S SLEEP         ;Even number? Good night
         JSR -60(A6)         ;ClearPointer called
         BRA.S EXIT          ;and end
SLEEP:   LEA MOUSE,A1         ;Addess the Pointer data
         MOVEQ #22,D0        ;Height in d0
         MOVEQ #16,D1        ;Width in d1
         MOVEQ #0,D2         ;xoffset clear
         MOVE.L D2,D3        ;yoffset clear
         JSR -270(A6)        ;SetPointer called
EXIT:    MOVE.L A6,A1        ;IntuitionBase to a1
         MOVE.L 4,A6         ;ExecBase
         JSR -414(A6)        ;CloseLibrary call
ENDE:    MOVEM.L (SP)+,D0-A6 ;Register from Stack
         RTS                 ;return to BASIC-Program
INTNAME: DC.B "intuition.library",0 ;Library-Name
MOUSE:   DC.L 0,$3000300,$7A007A0,$1FF01FF0,$3FF03FF0
         DC.L $30F83FF8,$3DFC3FFC,$7BFC7FFC,$30FE3FFE
         DC.L $3F863FFE,$1FEF1FFF,$3FDE3FFE,$1F861FFE
         DC.L $FFC0FFC,$3F803F8,$E000E0,$3800380,$7E007E0
         DC.L $3400340,0,$600060,$700070,$200020,0
         END                 ;End the data
;One typical call in BASIC:
;ZZZ WINDOW(7),0     'sleeping
;ZZZ WINDOW(7),1     'normal