; Installationsskript für AmigaKonto V2.2
; erstellt für Installer V1.24, 30.5.94, Autor: Andreas Regul

;   Copyright-Hinweise für Installer:

;     Installer and Installer project icon
;     (c) Copyright 1991-93 Commodore-Amiga, Inc.  All Rights Reserved.
;     Reproduced and distributed under license from Commodore.

;     INSTALLER SOFTWARE IS PROVIDED "AS-IS" AND SUBJECT TO CHANGE;
;     NO WARRANTIES ARE MADE. ALL USE IS AT YOUR OWN RISK. NO LIABILITY
;     OR RESPONSIBILITY IS ASSUMED.

(set @default-dest "SYS:")
(set @user-level 2)
(set @language "deutsch")

(set @abort-button "Installation abbrechen")
(set @special-msg "Ein fataler Fehler ist aufgetreten !\nBitte wiederholen Sie die Installation.")
(set @startup-help ("Für die Installation wählen Sie zunächst ein Anwender-Level, "
                    "je nach Ihrer Kenntnis vom Amiga.\n"))

(set @error-msg (cat "'AmigaKonto' wurde nicht komplett installiert. Bitte wiederholen Sie die Installation, "
                     "um eine lauffähige Version auf Ihrer Festplatte zu erhalten."))

(set sysdir (expandpath "SYS:"))
(set owndevice (expandpath ":"))

; Wurde von der Diskette gebootet ?
(if (= sysdir "AmigaKonto:")
      (
            (message "\nWarnung !!!\n\n"
                     "Es wurde von der AmigaKonto-Diskette gebootet. Für die Festplatten-Installation "
                     "mit diesem Programm ist es notwendig, vorher von Festplatte zu booten.\n\n"
                     "Bitte entfernen Sie die Diskette aus Laufwerk DF0: und setzen Sie Ihren Amiga zurück. "
                     "Danach starten Sie das Installationsprogramm erneut.\n")

            (exit (quiet))
      )
)

; Wurde Diskette umbenannt ?
(if (<> owndevice "AmigaKonto:")
      (
            (message "\nWarnung !!!\n\n"
                     "Die AmigaKonto-Diskette wurde in '" owndevice "' umbenannt.\n\n"
                     "Die Festplatten-Installation kann unter diesen Umständen nicht durchgeführt werden. "
                     "Bitte benennen Sie zunächst die Diskette in ihren ursprünglichen Namen 'AmigaKonto' "
                     "um und starten Sie danach die Installation erneut.\n")

            (exit (quiet))
      )
)

(welcome "Willkommen zur Festplatten-Installation von AmigaKonto.\n")

(complete 0)

(set mydir
            (askdir
               (prompt "Bitte wählen Sie das Laufwerk für 'AmigaKonto'")
               (help "Für 'AmigaKonto' wird ein eigenes Verzeichnis "
                     "auf der Festplatte benötigt. Um dieses Verzeichnis "
                     "anlegen zu können, müssen Sie hier die Festplatte "
                     "angeben, auf der installiert werden soll (z.B. Work:, DH0:, etc).\n\n"
                     "Eine Liste der verfügbaren Laufwerke erhalten Sie nach "
                     "Drücken des Schalters 'Show Drives'.\n"
               )
               (newpath)
               (default @default-dest)
               (disk)
            )
)

(set @default-dest (tackon mydir "AmigaKonto"))
(set icondir (tackon @default-dest "Icons"))
(set exampledir (tackon @default-dest "Beispiel"))

(if (NOT (exists @default-dest))
         (makedir @default-dest
            (prompt "\nVerzeichnis erzeugen\n\n"
                    "Das Verzeichnis '" @default-dest "' wird erzeugt. Bitte 'Proceed' anklicken.")
            (confirm)
            (help "Auf dem von Ihnen ausgewählten Laufwerk wird das Unterverzeichnis "
                  "für 'AmigaKonto' angelegt. Sollten Sie doch einen anderen Pfad als "
                  "'" @default-dest "' verwenden wollen, können Sie das Installationsprogramm "
                  "an dieser Stelle abbrechen. Beim Neustart geben Sie dann den "
                  "von Ihnen gewünschten Pfad an.\n\n"
                  "Als Verzeichnisname wird jedoch in jedem Fall 'AmigaKonto' verwendet.\n")
            (infos)
         )
)

(complete 5)

(if (NOT (exists icondir))
         (makedir icondir
            (infos)
         )
)

(complete 10)

(message "\nProgrammdateien kopieren\n\n"
         "Als nächstes werden die Programmdateien kopiert. Bitte 'Proceed' anklicken, um fortzufahren.")

(set n 0)
(while (set thisfile (select n "AmigaKonto:AmigaKonto" "AmigaKonto:AmigaKonto.info" ""))
         ((set n (+ n 1))
            (copyfiles
               (prompt "Kopiere Datei '"thisfile"'")
               (help "")
               (source thisfile)
               (dest @default-dest)
               (optional force askuser)
            )
         )
)

(complete 60)

(copyfiles
      (prompt "Kopiere Icons")
      (help "")
      (source "AmigaKonto:Icons")
      (dest icondir)
      (optional force askuser)
      (all)
)

(complete 70)

(set osversion (/ (getversion) 65536))

(if (< osversion 36)
        (copyfiles
                (prompt "Kopiere Datei 'AmigaKonto.prefs'")
                (help "")
                (source "AmigaKonto:AmigaKonto.prefs")
                (dest @default-dest)
        )
        (if (exists "ENVARC:")
                (copyfiles
                        (prompt "Kopiere Datei 'AmigaKonto.prefs'")
                        (help "")
                        (source "AmigaKonto:AmigaKonto.prefs")
                        (dest "ENVARC:")
                )
                (copyfiles
                        (prompt "Kopiere Datei 'AmigaKonto.prefs'")
                        (help "")
                        (source "AmigaKonto:AmigaKonto.prefs")
                        (dest @default-dest)
                )
        )
)

(complete 80)

(if   (askbool
            (prompt "\nFrage...\n\nSollen die Beispieldaten kopiert werden ?")
            (help "\nHilfe zur Beispieldaten'\n\n"
                  "Auf der Diskette wird ein Beispielkonto mitgeliefert, "
                  "das Ihnen den Einstieg in das Programm erleichtern kann. "
                  "Auf Wunsch kann dieses Konto mit auf die Festplatte kopiert werden.")
            (choices "Ja" "Nein")
            (default 0)
      )
      (
            (makedir exampledir
                  (infos)
            )
            (copyfiles
                  (prompt "\nKopiere Beispieldaten...")
                  (help "")
                  (source "AmigaKonto:Beispiel")
                  (dest exampledir)
                  (choices "Beispiel-Konto"
                           "Beispiel-Konto.info")
                  (optional force askuser)
            )
      )
)

(complete 90)

(set assign (cat "Assign AmigaKonto: \"" @default-dest "\""))

(startup "AmigaKonto"
         (prompt "\nAssign einrichten\n\n"
                 "Es wird ein Assign in der user-startup benötigt. "
                 "Bitte 'Proceed' anklicken, um dies auszuführen.\n")
         (help "'AmigaKonto' wird über das logische Laufwerk \"AmigaKonto:\" "
               "angesprochen und benötigt deshalb einen Verweis auf "
               "das entsprechende Festplattenverzeichnis. Dieser Verweis "
               "wird beim Amiga in der Datei 'user-startup' durch einen "
               "Assign-Befehl hergestellt. Diese Installation fügt den "
               "benötigten Befehl selbständig ein.\n")
         (command assign)
)

(complete 100)