;
; $VER: Install InterTalk Pro V33.1 (11.05.93) DK Version
;

;------------------
; Reset complete %
;------------------
(complete 0)

;-------------------------
; Set our path variables.
;-------------------------
(set sourcepath "InterTalk:")
(set @default-dest "SYS:")

;-------------------------------------
; Variables to check for boot-device.
;-------------------------------------
(set sys-space (getdiskspace "SYS:"))
(set appname-space (getdiskspace (cat @app-name ":")))

;=============================================================================
;-----------------
; Danish strings:
;-----------------
(if (= @language "dansk")
(
(set default_lang 4)

(set #mustbootfromhd
(cat "\n\n\nFejl: De skal boote fra Deres harddisk for at installere " @app-name "."
))

(set #installaborted
(cat "Installering af " @app-name " afbrudt."
))

(set #askdestdir
(cat "I hvilken skuffe ønsker De at installere " @app-name " ?"
))

(set #askdesthelp
(cat "De skal her vælge i hvilket directory de ønsker at installere " @app-name
     ". Der vil automatisk blive oprettet en skuffe ved navn " @app-name ", "
     "så de fx. kan installere til WORK:"
))

(set #destdirexists
(cat "\n\n\n\n" @app-name " eksisterer allerede. Skal jeg afbryde installeringen ?"
))

(set #destdirexistshelp
(cat @app-name " skuffen eksisterer allerede på " @default-dest ". De "
     "skal nu afgøre om De vil fortsætte installeringen, hvilket "
     "indebærer at De installerer oveni en tidligere " @app-name ", "
     "eller om De vil afbryde installeringen, og evt. selv slette "
     "den gamle " @app-name ", og så re-installere.\n\n Forslag: De "
     "bør afbryde installeringen, slette " @app-name " skuffen og dens "
     "indhold, og så vende tilbage og re-installere InterTalk her."
))

(set #nowcopying1
(cat "Kopiering af " @app-name " og relaterede filer..."
))

(set #nowcopying1help
(cat "Dette vil kopiere " @app-name " og relaterede filer til destinations skuffen."
     "\n\n" @copyfiles-help
))

(set #nowcopying2
(cat "Kopiering af amigaguide.library..."
))

(set #nowcopying2help
(cat "Dette vil kopiere amigaguide.library til Deres LIBS: skuffe. " @app-name
     " behøver dette bibliotek for at vise amigaguide on-line hjælp dokumenter.\n\n" @copylib-help
))

(set #nowcopying3
(cat "Kopiering af " @app-name " fonte."
))

(set #nowcopying3help
(cat "Dette vil kopiere " @app-name " fonte til Deres FONTS: skuffe. " @app-name
     " behøver disse fonte for at vise tekst på skærmen."
))

(set #nowcopying4
(cat "Kopiering af " @app-name " keymaps til DEVS:KeyMaps."
))

(set #nowcopying4help
(cat "Dette vil kopiere " @app-name " keymaps til Deres DEVS:KeyMaps skuffe."
))

))

;=============================================================================

;---------
; Say HI!
;---------
(welcome)

;-----------------
; Get user-level.
;-----------------
(set @user-level)

;-----------------------
; Recognize OS version.
;-----------------------
(set osver (/ (getversion) 65535))

;---------------------------------
; User *HAS* to boot from his HD!
;---------------------------------
(if (= sys-space appname-space)
(
;-> User booted from disk. This is *NOT* allowed!
   (message #mustbootfromhd)
   (abort   #installaborted)
))

;--------------------------------
; Ask for destination directory.
;--------------------------------
(set @default-dest
   (askdir (prompt #askdestdir)
           (help   #askdesthelp)
           (default @default-dest)
   )
)

;-------------------------------------------------------
; Check that directory InterTalk doesn't exist already.
;-------------------------------------------------------
(set @default-dest (tackon @default-dest "InterTalk"))
(if (exists @default-dest)
   (if (askbool (prompt  #destdirexists)
                (help    #destdirexistshelp)
                (default 1)
       )
      (abort #installaborted)
   )
)

;---------------------------------------------
; Creating directories in destination drawer.
;---------------------------------------------
(makedir @default-dest (infos))

;-------------------------------------
; Copying InterTalk and Config files.
;-------------------------------------
(copyfiles (prompt  #nowcopying1)
           (help    #nowcopying1help)
           (source  sourcepath)
           (dest    @default-dest)
           (choices "InterTalk" "InterTalk.info" "InterTalk.Cfg" "InterTalk.keys"
						  "InterTalk.phone" "InterTalk.guide" "InterTalk.guide.info")
           (confirm "expert")
)

(copyfiles (prompt  #nowcopying3)
           (help    #nowcopying3help)
           (source  sourcepath)
           (dest    "sys:")
           (choices "InterTalk:fonts")
           (confirm "expert")
)

(copyfiles (prompt  #nowcopying4)
           (help    #nowcopying4help)
           (source  sourcepath)
           (dest    "sys:devs")
           (choices "InterTalk:devs/keymaps")
           (confirm "expert")
)

;-----------------------------
; Copying amigaguide.library.
;-----------------------------
(copylib (prompt #nowcopying2)
         (help   #nowcopying2help)
         (source (tackon sourcepath "Libs/amigaguide.library"))
         (dest   "LIBS:")
         (optional)
         (confirm "average")
)

(complete 100)

;------------------------------------------------------------------
; If something goes wrong the onerror below is called to clean-up.
;------------------------------------------------------------------
(onerror
   (delete @default-dest)
)