*****************************************
		*					*
		*	   SCOOPEX MINI MENU            *
		*          				*
		*	   CODED BY ELECTRA!		*
		*					*
		*	CALL KRYPT BBS FOR HELP		*
                *         +44 [0] 215 224778            *
		*					*
		*****************************************

	section n,code_c
	opt c-

a 
	move.l	#$dff000,a5
Fun 
	move.w 	$1c(a5),intsave
	move.w 	$02(a5),dmasave
	move.w 	#$7fff,$9a(a5)
	move.w 	#$7fff,$96(a5)
	move.l	#copper,$80(a5)		
	clr.w	$88(a5)
	move.l	$6c.w,oldirq		
	move.l	#IR,$6c.w
	move.w	#$8010,$9a(a5)
	BSR	PRINTTEXT
	BSR	PUT_PIC
	BSR	SET_PLANE
	move.w 	#$C010,$9a(a5)
	move.w 	#$83c0,$96(a5)
wait 
	btst	#7,$bfe001
	bne.s	wait
	move.w 	#$7fff,$9a(a5)
	move.w 	#$7fff,$96(a5)
	move.l	$4.w,a6
	move.l	#gfxname,a1
	clr.l	d0
	jsr	-552(a6)
	move.l	d0,a0
	move.l	38(a0),$80(a5)		
	clr.w	$88(a5)
	move.l	OldIRQ,$6c.w		
	ori.w 	#$c000,intsave
	ori.w 	#$8000,dmasave
	move.w 	intsave,$9a(a5)
	move.w 	dmasave,$96(a5)
	CLR.L	D0
	MOVE.B	CHOICE,0
	rts
IR
	movem.l d0-d7/a0-a6,-(a7)
	BSR.S	GOCODE
	movem.l (a7)+,d0-d7/a0-a6
	MOVE.W 	#$10,$9C(A5)
	RTE
GOCODE
	MOVE.W	#$0010,$9c(a5)
	BSR	JOY_TEST
	BSR	SET_PLANE
	RTS
PUT_PIC
	LEA	BITPLANE1(PC),A1
	LEA	LOGO(PC),A0
	MOVE.L	A0,D0
	MOVE.W	D0,6(A1)
	SWAP	D0
	MOVE.W	D0,2(A1)

	LEA	BITPLANE2(PC),A1
	LEA	LOGO+(80*44)(PC),A0
	MOVE.L	A0,D0
	MOVE.W	D0,6(A1)
	SWAP	D0
	MOVE.W	D0,2(A1)

	LEA	BITPLANE3(PC),A1
	LEA	LOGO+(160*44)(PC),A0
	MOVE.L	A0,D0
	MOVE.W	D0,6(A1)
	SWAP	D0
	MOVE.W	D0,2(A1)

	LEA	BITPLANE4(PC),A1
	LEA	LOGO+(240*44)(PC),A0
	MOVE.L	A0,D0
	MOVE.W	D0,6(A1)
	SWAP	D0
	MOVE.W	D0,2(A1)

	LEA	BITPLANE5(PC),A1
	LEA	LOGO+(320*44)(PC),A0
	MOVE.L	A0,D0
	MOVE.W	D0,6(A1)
	SWAP	D0
	MOVE.W	D0,2(A1)
	RTS
	EVEN
printtext
	CLR.L	D0
	MOVE.L	TEXTPOS(PC),A0
	MOVE.L	TEXTLOC(PC),A1
	MOVE.B	(A0),D0
	CMPI.B	#$FF,D0
	BNE.S	NOEND
	RTS
NOEND
	CMPI.B	#$FC,D0
	BNE.S	NOTLINE
	ADDI.L	#$119,TEXTLOC
	ADDQ.L	#1,TEXTPOS
	BRA.S	PRINTTEXT
NOTLINE
	SUBI.B 	#32,d0
 	LSL	#3,d0
 	move.l 	d0,a2
 	add.l 	#characterset,a2
 	move.b 	(a2),(a1)
 	move.b 	1(a2),40(a1)
 	move.b 	2(a2),80(a1)
 	move.b 	3(a2),120(a1)
 	move.b 	4(a2),160(a1)
 	move.b 	5(a2),200(a1)
 	move.b 	6(a2),240(a1)
 	move.b 	7(a2),280(a1)
	ADDQ.L	#1,TEXTLOC
	ADDQ.L	#1,TEXTPOS
	BRA.S	PRINTTEXT
TEXTLOC
	DC.L	$76000
TEXTPOS
	DC.L	TTEXT
TTEXT
	*	ALL CHARACTERS APART FROM LOWER CASE ARE AVAILABLE!!
	*	LEAVE THE LINE SPACING AS IT IS FOR GOOD RESULTS!
	*	IF YOU ARE WONDERING $FC ACTS AS A RETURN CODE.
	*	ENTER FILENAMES(OR THERE DESCRIPTION) WHERE THE
	* 	NUMBERS ARE BELOW	
	*	FOR EXAMPLE:	1 FIRST OPTION
	*			2 SECOND OPTION
	*			3	ETC..ETC..
	*	ONLY TWENTY OPTIONS ARE AVAILABLE AT THE MOMENT,
	*	IF YOU NEED MORE RING THE KRYPT AND LEAVE A MESSAGE
	*	TO THE SYSOP(INFILTRATOR)......
	* TOP SPACING,DONT CHANGE
	DC.B	'                                       ',$FC
	DC.B	'                                       ',$FC
	DC.B	'                                       ',$FC
	DC.B	'                                       ',$FC
	* CHOICES
	DC.B	'               FILENAME 1              ',$FC
	DC.B	'               FILENAME 2              ',$FC
	DC.B	'               FILENAME 3              ',$FC
	DC.B	'               FILENAME 4              ',$FC
	DC.B	'               FILENAME 5              ',$FC
	DC.B	'               FILENAME 6              ',$FC
	DC.B	'               FILENAME 7              ',$FC
	DC.B	'               FILENAME 8              ',$FC
	DC.B	'               FILENAME 9              ',$FC
	DC.B	'               FILENAME A              ',$FC
	DC.B	'               FILENAME B              ',$FC
	DC.B	'               FILENAME C              ',$FC
	DC.B	'               FILENAME D              ',$FC
	DC.B	'               FILENAME E              ',$FC
	DC.B	'               FILENAME F              ',$FC
	DC.B	'               FILENAME G              ',$FC
	DC.B	'               FILENAME H              ',$FC
	DC.B	'               FILENAME I              ',$FC
	DC.B	'               FILENAME J              ',$FC
	DC.B	'               FILENAME K              ',$FC
	* BOTTOM SPACING,DONT CHANGE
	DC.B	'                                       ',$FC
	DC.B	'                                       ',$FC
	DC.B	'                                       ',$FC
	DC.B	'                                       ',$FC
	*	START OF TEXT AT BOTTOM
	*	DONT USE MORE LINES THAN ARE PRESENT AT THE MOMENT.
	DC.B	'                                       ',$FC
	DC.B	'           SCOOPEX  PRESENTS           ',$FC
 	DC.B	'                                       ',$FC
	DC.B	'          ANOTHER COMPILATION          ',$FC
	DC.B	'                                       ',$FC
	DC.B	'        DISK COMPILED BY MEMBER        ',$FC
	DC.B	'                                       ',$FC
	DC.B	'  GREETINGS GO TO ALL WHO DESERVE THEM ',$FC
	DC.B	'                                       ',$FC
	DC.B	'         USE JOYSTICK TO SELECT        ',$FC
	DC.B	'                                       ',$FC
	DC.B	'         MENU CODED BY  ELECTRA        ',$FC
	DC.B	'                                       ',$FC
	DC.B	'                                       ',$FC
	DC.B	$FF	*DONT REMOVE
	EVEN
	INCLUDE	GFX/CHARS
copper 
	DC.W	$009C,$8010
	DC.W	$008E,$296b
	DC.W	$92,$30
	DC.W	$94,$d8
	DC.W	$108,$0
	DC.W	$10A,$0
S1	DC.W	$0120,0
S2	DC.W	$0122,0
S3	DC.W	$0124,0
S4	DC.W	$0126,0
S5	DC.W	$0128,0
S6	DC.W	$012A,0
	DC.W	$012C,0
	DC.W	$012E,0
	DC.W	$0130,0
	DC.W	$0132,0
	DC.W	$0134,0
	DC.W	$0136,0
	DC.W	$0138,0
	DC.W	$013A,0
	DC.W	$013C,0
	DC.W	$013E,0
	DC.W	$100,$5000
BITPLANE1
	DC.W	$E0,$0
	DC.W	$E2,$0
BITPLANE2
	DC.W	$E4,$0
	DC.W	$E6,$0
BITPLANE3
	DC.W	$E8,$0
	DC.W	$EA,$0
BITPLANE4
	DC.W	$EC,$0
	DC.W	$EE,$0
BITPLANE5
	DC.W	$F0,$0
	DC.W	$F2,$0
	dc.w	$0180,$0000,$0182,$0fbe,$0184,$0f8e,$0186,$0f5d
	dc.w	$0188,$0e0b,$018a,$0b08,$018c,$0807,$018e,$0504
	dc.w	$0190,$0303,$0192,$0fdd,$0194,$0fbb,$0196,$0f88
	dc.w	$0198,$0f00,$019a,$0b00,$019c,$0800,$019e,$0500
	dc.w	$01a0,$0300,$01a2,$fff,$01a4,$0bcf,$01a6,$077f
	dc.w	$01a8,$052f,$01aa,$020a,$01ac,$0106,$01ae,$0004
	dc.w	$01b0,$0cfe,$01b2,$09fd,$01b4,$00fb,$01b6,$00da
	dc.w	$01b8,$00a8,$01ba,$0087,$01bc,$0055,$01be,$0033
	DC.W	$7601,$FFFE
	DC.W	$100,$1000
	DC.W	$E0
PL1	DC.W	$0
	DC.W	$E2
PL2	DC.W	$0	
	DC.W	$92,$34
	DC.W	$94,$CC
	DC.W	$182,$7
	DC.W	$9501,$FFFE
	DC.W	$182,$FF
	DC.W	$9E01,$FFFE
	DC.W	$182,$7
	DC.W	$BE01,$FFFE
	DC.W	$100,0
	DC.W	$C601,$FFFE
	dc.w	$e0,$7
	dc.w	$e2,$8300
	DC.W	$100,$1000
	DC.W	$182,$FFF
	DC.W	$FFFF,$FFFE
	EVEN
JOY_TEST
	CMPI.B	#0,JOYDEL
	BEQ.S	JOY_CONT
	SUBQ.B	#1,JOYDEL
	RTS
JOY_CONT
	MOVE.B	#5,JOYDEL
	MOVE.W	$C(A5),D0
	MOVE.W	D0,D1
	LSR.W	D1
	EOR.W	D0,D1
	BTST	#0,D1
	BNE.S	BACK
	BTST	#8,D1
	BNE.S	FORWARD
	RTS
BACK
	CMPI.W	#$7700,POS+2
	BGT.S	LIMIT
	ADD.W	#320,POS+2
	ADDQ.B	#1,CHOICE
	RTS
FORWARD
	CMPI.W	#$6100,POS+2
	BLT.S	LIMIT
	SUB.W	#320,POS+2
	SUBQ.B	#1,CHOICE
LIMIT
	RTS
CHOICE
	DC.B	0
JOYDEL
	DC.B	0
SET_PLANE
	LEA	POS(PC),A0
	MOVE.W	(A0),PL1
	MOVE.W	2(A0),PL2
	RTS
	EVEN
POS
	DC.W	$0007
	DC.W	$6000
gfxname 
	dc.b	"graphics.library",0
	even
OldIRQ 
	DC.L	0
intsave
	dc.w 	0
dmasave
	dc.w 	0 
LOGO
	INCBIN	GFX/SCOOPEX.RAW