.KEY dest
.BRA {
.KET }

;
; Do the PPage installation:
;
; Inputs:
;    dest  Where stuff should go.


IF NOT EXISTS {dest}PPage
   ECHO "     Creating Directory {dest}PPage ..."
   MAKEDIR {dest}PPage
   COPY PPageInstUtil:Misc/Icons/Drawer.info {dest}PPage.info
ENDIF

;
; Install the program itself.
;
ECHO "*N"
INSTUTIL ask -dy "Install the Professional Page program [Y/N]? Y"
IF NOT WARN
   EXECUTE RAM:PPageInstall/DiskMount Program PPage: PPageInstPgm:

   ECHO "*N     Copying Professional Page program ..."
   COPY PPageInstPgm:PPage {dest}PPage/PPage
   COPY PPageInstPgm:PPage.info {dest}PPage/PPage.info
   INSTUTIL reseticon {dest}PPage/PPage


   ;
   ; these libraries are necessary for PPage, make sure that they are there:
   ; (This is near the copying of PPage, to eliminate a disk swap.)
   ;
   IF NOT EXISTS LIBS:mathtrans.library
      ECHO "*N     Copying mathtrans.library"
      COPY PPageInstPgm:libs/mathtrans.library LIBS:
   ENDIF
   IF NOT EXISTS LIBS:diskfont.library
      ECHO "*N     Copying diskfont.library"
      COPY PPageInstPgm:libs/diskfont.library LIBS:
   ENDIF

   ;
   ; While we've got this diskette, grab the new paintjet driver in case
   ; he wants it.
   COPY PPageInstPgm:devs/printers/HP_PaintJet RAM:PPageInstall

   IF NOT EXISTS {dest}PPage/Data
      MAKEDIR {dest}PPage/Data
   ENDIF
   COPY PPageInstUtil:Data {dest}PPage/Data ALL QUIET

   COPY PPageInstUtil:MakeFont {dest}PPage
   COPY PPageInstUtil:MakeFont.info {dest}PPage
   INSTUTIL reseticon {dest}PPage/MakeFont
   COPY PPageInstUtil:PPage_Any_Font {dest}PPage

ENDIF


ECHO "*N"
INSTUTIL ask -dy "Copy Tutorial Files to {dest}PPage [Y/N]? Y"
IF NOT warn

   IF NOT EXISTS {dest}PPage/NewsLetter
      MAKEDIR {dest}PPage/NewsLetter
   ENDIF
   COPY PPageInstUtil:NewsLetter {dest}PPage/NewsLetter ALL QUIET
   COPY PPageInstUtil:NewsLetter.info {dest}PPage
   INSTUTIL reseticon {dest}PPage/NewsLetter

ENDIF   ; copy Tutorial files

ECHO "*N"
INSTUTIL ask -dy "Copy new HP PaintJet printer driver to DEVS:printers [Y/N]? Y"
IF NOT warn
   COPY RAM:PPageInstall/HP_PaintJet DEVS:printers
ENDIF


ECHO "*N"
INSTUTIL ask -dy "Copy PPage Bitmap fonts to FONTS: directory [Y/N]? Y"
IF NOT warn

   FAILAT 21
   ECHO "*N     Copying Bitmap fonts to FONTS:"
   COPY PPageInstUtil:fonts FONTS: ALL QUIET
   IF error
      ECHO "*N      Not enough room on the FONTS: directory*N"
   ENDIF
   FAILAT 10

ELSE

   INSTUTIL ask -dy "Copy PPage Bitmap fonts to {dest}PPage/Fonts [Y/N]? Y"
   IF NOT warn

      ECHO "*N     Copying Bitmap fonts to {dest}PPage/Fonts:"
      IF NOT EXISTS {dest}PPage/Fonts
         MAKEDIR {dest}PPage/Fonts
      ENDIF
      COPY PPageInstUtil:fonts {dest}PPage/Fonts ALL QUIET

      ;
      ; Make a couple of IconX files to switch between PPage and normal fonts.
      ;
      CD RAM:PPageInstall
      ECHO >SelPP.1 "Echo *"Selecting Professional Page fonts: *" NOLINE"
      ECHO >SelPP.2 "Assign FONTS: {dest}PPage/Fonts"
      ECHO >Sel.Done "Echo *"Done.*""
      JOIN SelPP.1 SelPP.2 Sel.Done AS {dest}PPage/PPageFonts
      COPY PPageInstUtil:misc/Icons/PPageFonts.info {dest}PPage/PPageFonts.info

      ECHO >SelAm.1 "Echo *"Selecting Amiga fonts: *" NOLINE"
      ECHO >SelAm.2a "Assign FONTS: " NOLINE

      CD FONTS:
      CD >RAM:PPageInstall/SelAm.2b
      CD RAM:PPageInstall

      JOIN SelAm.1 SelAm.2a SelAm.2b Sel.Done AS {dest}PPage/AmigaFonts
      COPY PPageInstUtil:misc/Icons/AmigaFonts.info {dest}PPage/AmigaFonts.info

   ENDIF

ENDIF   ; copy FONTS

ECHO "*N"
INSTUTIL ask -dy "Copy Compugraphic Fonts to {dest}PPage/CGFonts [Y/N]? Y"
IF NOT warn
   ; Copy the CGFonts stuff
   EXECUTE RAM:PPageInstall/DiskMount "Compugraphic Fonts" CGFonts: PPageInstCG:
   ECHO "*N     Copying Compugraphic Fonts ..."
   IF NOT EXISTS {dest}PPage/CGFonts
      MAKEDIR {dest}PPage/CGFonts
   ENDIF
   COPY PPageInstCG: {dest}PPage/CGFonts ALL QUIET

   ; Post-processing:
   ; - Nuke the Disk.info, which is not needed on the hard drive
   ; - Move CacheEdit up into the main PPage drawer
   DELETE {dest}PPage/CGFonts/Disk.info QUIET
   RENAME {dest}PPage/CGFonts/CacheEdit {dest}PPage/CacheEdit
   RENAME {dest}PPage/CGFonts/CacheEdit.info {dest}PPage/CacheEdit.info
   INSTUTIL reseticon {dest}PPage/CacheEdit

ENDIF   ; copy CG Fonts

ENDSKIP

;
; The Assign commands for startup-sequence
;
CD RAM:PPageInstall
ECHO >AsnPPage     "ASSIGN PPage:     {dest}PPage"
ECHO >AsnUtil      "ASSIGN PPageUtil: {dest}PPage"

If EXISTS {dest}PPage/CGFonts
   ECHO >AsnCFonts "ASSIGN CGFonts:   {dest}PPage/CGFonts"
ELSE
   COPY NIL: to AsnCFonts
ENDIF

IF EXISTS {dest}PPage/CGFonts/CGCache
   ECHO >AsnCCache "ASSIGN CGCache:   {dest}PPage/CGFonts/CGCache"
ELSE
   COPY NIL: to AsnCCache
ENDIF

JOIN AsnPPage AsnUtil AsnCFonts AsnCCache as S:PPage-1.3-Startup