.KEY dest
.BRA {
.KET }

; Install_Font - Install CGFonts onto a hard drive.
;
; Inputs:
;    dest   Directory to install Font into
;

ASSIGN CGFInstOrig: ""            ; Save initial directory

; Start with a fresh copy, to avoid any screwups
IF EXISTS RAM:CGFInstall
   DELETE RAM:CGFInstall/#? quiet
ELSE
   MAKEDIR RAM:CGFInstall
ENDIF

CD ram:CGFInstall   ; Search it without adding it to path
C:COPY C:Copy    RAM:CGFInstall
Copy   C:Assign  RAM:CGFInstall
Copy   C:Echo    RAM:CGFInstall
Copy   C:If      RAM:CGFInstall
Copy   C:Else    RAM:CGFInstall
Copy   C:Endif   RAM:CGFInstall
Copy   C:Makedir RAM:CGFInstall
Copy   C:Failat  RAM:CGFInstall

COPY CGFonts_1:InstUtil     RAM:CGFInstall

;
; Make sure that the destination exists and is a directory
;
IF NOT EXISTS {dest$CGFonts:}
   ECHO "*N ****** Couldn't find drawer {dest$CGFonts:} *******N"
   SKIP wrapup
ENDIF

INSTUTIL isdir {dest$CGFonts:}
IF WARN
   ECHO "*N ****** {dest$CGFonts:} is not a drawer! *******N"
   SKIP wrapup
ENDIF

INSTUTIL ask -dy "Install Triumvirate onto {dest$CGFonts:} [Y/N]? Y"
IF warn
   ECHO "*N Installation aborted!*N"
   SKIP wrapup
ENDIF

;
; finally do the actual installation:
;
FAILAT 21
ECHO "*N --------------------------------------------------------------------"
ECHO "*N    Copying Triumvirate to {dest$CGFonts:} ..."
ECHO "*N --------------------------------------------------------------------"
COPY CGFonts_1:Triumvirate to {dest$CGFonts:} quiet
IF ERROR
   SKIP wrapup
ENDIF
;
; make sue that there is a PS subdirectory on CGFonts:
;
IF {dest$CGFonts:} EQ "CGFonts:"
   IF NOT EXISTS CGFonts:PS
      MAKEDIR CGFonts:PS
   ENDIF
ENDIF

ECHO "*N --------------------------------------------------------------------"
ECHO "*N*N Installation of Triumvirate complete."
ECHO "*N ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*N"

;
; Clean up
;
LAB wrapup

CD CGFInstOrig:
DELETE >NIL: RAM:CGFInstall all quiet
Assign CGFInstOrig:

CGFonts_1:InstUtil ask "Press RETURN."