; $VER: VLabInstall 1.0 (23.2.92)

;---- Kickstart prüfen

Version exec.library 37
If WARN
  Echo "*E[7m                                            *E[0m"
  Echo "*E[7m      VLab benötigt Amiga-OS-2.0 v37 !      *E[0m"
  Echo "*E[7m                                            *E[0m"
  Skip Abbruch
Endif

Echo "*Ec*N       VLab  Installation*N*N"

;---- prüfen, ob die VLAB-Diskette da ist

Assign >NIL: "VLAB:" EXISTS
If WARN
  Echo "*E[7m Diskette 'VLAB' nicht gefunden! *E[0m"
  Skip Abbruch
Endif

;----

Set Ver `Version VLab:VLab/VLab`
Failat 21 ; wegen CD

;---- Prüfen, ob von Diskette gebootet wurde

CD >NIL: SYS:
Set x "`CD`"
If "$x" EQ "VLab:"
  Echo "*E[7m Zur Installation bitte von der Festplatte booten! *E[0m"
  Skip Abbruch
Endif

;---- Ziel-Verzeichnis holen

Lab GetName
Unset Dest
Echo "Bitte das Ziel-Verzeichnis auf der Festplatte"
Echo "angeben (z.B. DH0:Anwender): " NOLINE
Set >NIL: Dest ?

If "${Dest}" EQ "*${Dest}"
  Echo "*E[7m Wohin ??? *E[0m"
  Skip BACK GetName
Endif

If `Echo "${Dest}" LEN 4` EQ "VLAB"
  Echo "*E[7m Das Verzeichnis 'VLab' wird automatisch erzeugt, *E[0m"
  Echo "*E[7m bitte nicht im Pfad angeben!                     *E[0m"
  Skip BACK GetName
Endif

Cd >NIL: ${Dest}
If FAIL
  Echo "*E[7m Das Verzeichnis '${Dest}' existiert nicht! *E[0m"
  Skip GetName BACK
Endif
Echo " "

;---- Prüfen ob nicht VLab-Datei dort ist

If EXISTS VLab
  Cd VLab
  If WARN
    Echo "*E[7m Im Verzeichnis '${Dest}' existiert eine Datei 'VLab'. *E[0m"
    Echo "*E[7m Installation nicht möglich!                           *E[0m"
    Skip Abbruch
  Endif
  Cd /
Endif

;---- Prüfen, ob neuere Version

If EXISTS VLab/VLab
  Set OldVer "`Version VLab/VLab`"
  Echo "Im Zielverzeichnis '${Dest}' existiert bereits ${OldVer}!"
  Echo "Soll diese Version mit ${Ver} überschrieben werden?"
  Ask "(y=Ja, n=Nein) [n]:"
  If NOT WARN
    Skip Ende
  Endif
Endif

Echo "Kopiere ${Ver} nach '${Dest}'..." NOLINE
Copy VLab:Vlab.info "" QUIET CLONE
If NOT EXISTS VLab
  MakeDir VLab
Endif
Copy VLab:Vlab/~(HDInstall#?) VLab ALL QUIET CLONE

Echo "*NKopiere VLab.Prefs und VLab-Standard-Icons nach 'ENVARC:VLab'..." NOLINE
Copy VLab:Prefs/Env-Archive/VLab ENVARC:VLab ALL CLONE QUIET

Echo "*NKopiere VLab.Prefs und VLab-Standard-Icons nach 'ENV:VLab'..." NOLINE
Copy VLab:Prefs/Env-Archive/VLab ENV:VLab ALL CLONE QUIET

Echo "*NKopiere Palette-Presets nach 'SYS:Prefs/Presets/VLab'..." NOLINE
Copy VLab:Prefs/Presets/Vlab#? SYS:Prefs/Presets ALL QUIET CLONE

Echo " "

;----
Lab Ende

Echo "*N*NInstallation beendet..."

;---- Abbruch

Lab Abbruch
Wait 3 SECS
Echo " "
EndCli