(set @app-name "Flyin\'High Data Disks")
(set @pretend 0)
(set @user-level 2)
(if (= @language "deutsch")
 (
  (set #MSG_WELCOME "Willkommen zur Installation der Daten-Disketten für Flyin\'High.")
  (set #MSG_ASKDIR "Bitte geben Sie das Verzeichnis auf Ihrer Festplatte an, in dem sich Flyin\'High befindet.")
  (set #HELP_ASKDIR "Dieses Verzeichnis muß angegeben werden, damit der Installer weiß, wohin die Daten kopiert werden müssen.")
  (set #MSG_INSERTDISK1 "Bitte legen Sie die 1.Diskette in ein beliebiges Laufwerk ein.")
  (set #MSG_INSERTDISK2 "Bitte legen Sie die 2.Diskette in ein beliebiges Laufwerk ein.")
  (set #MSG_WRONGDIR "In dem angegebenen Verzeichnis konnte keine existierende Installation von Flyin\'High gefunden werden.")
  (set #MSG_JOINING "Füge Archiv zusammen.")
  (set #MSG_UNPACK "Entpacke Archiv. Dieser Vorgang kann etwas Zeit beanspruchen.")
  (set #MSG_COMPLETE "Die Installation der Datendisketten ist abgeschlossen.\nViel Spaß mit Flyin\'High wünscht P.U.R.E.")
 )
 (
  (set #MSG_WELCOME "Welcome the the installation of the data-disks for Flyin\'High.")
  (set #MSG_ASKDIR "Please select the directory on your harddisk, in which Flyin\'High is installed.")
  (set #HELP_ASKDIR "This directory must be selected, that the Installer knows where to copy the data to.")
  (set #MSG_INSERTDISK1 "Please insert Disk 1 in any drive.")
  (set #MSG_INSERTDISK2 "Please insert Disk 2 in any drive.")
  (set #MSG_WRONGDIR "No existing installation of Flyin\'High was found in the selected directory.")
  (set #MSG_JOINING "Joining archive together.")
  (set #MSG_UNPACK "Unpacking archive. This procedure may take some time.")
  (set #MSG_COMPLETE "The installation of the datadisks is now complete.\nP.U.R.E. wishes you a lot of fun with Flyin\'High.")
 )
)
(welcome #MSG_WELCOME)
(set #default-dest (askdir (prompt #MSG_ASKDIR) (default @default-dest) (help #HELP_ASKDIR) (disk)))
(if (NOT(AND (= (exists (tackon #default-dest "Flyin\'High") (noreq)) 1) (= (exists (tackon #default-dest "gfx") (noreq)) 2)))
 (exit #MSG_WRONGDIR (quiet))
 (
  (askdisk (prompt #MSG_INSERTDISK2) (help @askdisk-help) (dest "DataDisk2") (assigns))
  (copyfiles (source "DataDisk2:") (dest #default-dest) (pattern "dd.lha_part?") (files) (optional fail))
  (complete 20)
  (askdisk (prompt #MSG_INSERTDISK1) (help @askdisk-help) (dest "DataDisk1") (assigns))
  (copyfiles (source "DataDisk1:") (dest #default-dest) (pattern "dd.lha_part?") (files) (optional fail))
  (complete 40)
  (working #MSG_JOINING)
  (run ("join \"%s\" \"%s\" as \"%s\""
   (tackon #default-dest "dd.lha_part1")
   (tackon #default-dest "dd.lha_part2")
   (tackon #default-dest "dd.lha")))
  (delete (tackon #default-dest "dd.lha_part1"))
  (delete (tackon #default-dest "dd.lha_part2"))
  (complete 50)
  (working #MSG_UNPACK)
  (run ("DataDisk1:lhex >CON: -fw= \"%s\" x \"%s\"" #default-dest (tackon #default-dest "dd.lha")))
  (delete (tackon #default-dest "dd.lha"))
  (run "avail >NIL: flush")
  (complete 100)
  (exit #MSG_COMPLETE (quiet))
 )
)