;****************************************************************
; Bravo Romeo Delta Install Script
; $VER: 1.0 (14 September 1996) ©1996 FRANKENSTEIN SOFTWARE
;
; Original    by Jack Rollan ---- 14 September 1996
;
; Written for use with Commodore's Installer V1.24
;****************************************************************

;****************************************************************
; Some useful variables
;****************************************************************
  
 ; set up a error cleanup routine
  
(onerror
 (makeassign "Bravo_Romeo_Delta" (safe))
)


(complete 0)
  
 ; just in case the installation was restarted

(makeassign "Bravo_Romeo_Delta" (safe))  ; start fresh
  
 ; see if this is really an update
  
(@execute-dir "c:")
  
(set is_update 0)
(set Bravo_Romeo_Delta_dest (getassign "Bravo_Romeo_Delta" "a"))
  

 ; if update, be sure they want program in same place
  
(if Bravo_Romeo_Delta_dest
 (if (askbool
   (prompt "Your current copy of Bravo Romeo Delta \n appears to be located in the drawer \n named \""
     Bravo_Romeo_Delta_dest
     "\". \n Do you want the update installed in that drawer?"
   )
   (help
    "The installer has determined that you may already have a "
    "copy of Bravo Romeo Delta installed on your system. If "
    "this is wrong, select NO as an answer. Otherwise, select YES."
  )
  (default 1)
 )
  
  (set is_update 1)  ; if user wants in same place
  
  (set Bravo_Romeo_Delta_dest   ; if user wants in different place
   (tackon
    (askdir
     (prompt "A In which disk or drawer should Bravo Romeo Delta be installed?")
     (help @askdir-help)
     (default @default-dest)
    )
    "Bravo_Romeo_Delta"
   )
  )
 )
  
  
; else if not an update, get a location for program
;
 (set Bravo_Romeo_Delta_dest
  (tackon
   (askdir
    (prompt "B In which disk or drawer should \n  Bravo Romeo Delta be installed?")
    (help @askdir-help)
    (default @default-dest)
   )
   "Bravo_Romeo_Delta"
  )
 )
)

(makedir Bravo_Romeo_Delta_dest (infos))
  
 ; reinitialize assigns

(if (not @pretend)
 (makeassign "Bravo_Romeo_Delta" Bravo_Romeo_Delta_dest)
)
  
 ; now lock on to disks volumes
  
  
   
  ;COPY DISKETTE
(askdisk
 (prompt "Please insert the master program disk \n labeled \"Bravo_Romeo_Delta\"."
         "\n (files will be copied).")
 (help "The Bravo Romeo Delta program and other \n options will be copied "
   "from the \"Bravo_Romeo_Delta\" \n into your system.")
  (dest  "Bravo_Romeo_Delta")
)
  
  
  
(copyfiles
 (prompt "Files will be copied.")
  (help "The Bravo Romeo Delta program and other \n options will be copied "
   "from the \"Bravo_Romeo_Delta\" \n into your system.")
   (source "Bravo_Romeo_Delta:")
   (dest Bravo_Romeo_Delta_dest)
   (all)
   (confirm)
)

(complete 99)

 ; modify S:User-Startup

(startup "Bravo Romeo Delta ©1996"
 (prompt
  "Some instructions need to be added to the \"S:user-startup\" "
  "so that your system will be properly configured to use Bravo Romeo Delta.")
 (help "Do this or Bravo Romeo Delta won't work!!")
 (command "ASSIGN Bravo_Romeo_Delta: \""Bravo_Romeo_Delta_dest "\"\n"
  
 )
)


(complete 100)
  
(exit)