; Installationsskript für AmiAtlas V1.0
; erstellt für Installer V1.24, 19.3.94, Autor: Andreas Regul

;   Copyright-Hinweise für Installer:

;     Installer and Installer project icon
;     (c) Copyright 1991-93 Commodore-Amiga, Inc. All Rights Reserved.
;     Reproduced and distributed under license from Commodore.

;     INSTALLER SOFTWARE IS PROVIDED "AS-IS" AND SUBJECT TO CHANGE;
;     NO WARRANTIES ARE MADE. ALL USE IS AT YOUR OWN RISK. NO LIABILITY
;     OR RESPONSIBILITY IS ASSUMED.

(set @user-level 2)
(set @language "deutsch")
(set @abort-button "Installation abbrechen")
(set @special-msg "Ein fataler Fehler ist aufgetreten !\nBitte wiederholen Sie die Installation.")
(set @error-msg (cat "'AmiAtlas' wurde nicht komplett installiert. Bitte wiederholen Sie die Installation, "
                     "um eine lauffähige Version auf Ihrer Festplatte zu erhalten."))

(set sysdir (expandpath "SYS:"))

; Wurde von der Diskette gebootet ?
(if (= sysdir "AmiAtlas")
      (
            (message "Warnung !!!\n\n"
                     "Es wurde von der AmiAtlas-Diskette gebootet. Für die Festplatten-Installation "
                     "mit diesem Programm ist es notwendig, vorher von Festplatte zu booten.\n\n"
                     "Bitte entfernen Sie die Diskette aus Laufwerk DF0: und setzen Sie Ihren Amiga zurück. "
                     "Danach starten Sie das Installationsprogramm erneut.\n")

            (exit (quiet))
      )
)

(complete 0)

(welcome "Willkommen zur Festplatten-Installation von 'AmiAtlas'.\n")

(set mydir
      (askdir
            (prompt "Bitte wählen Sie das Laufwerk für 'AmiAtlas'")
            (help "Für 'AmiAtlas' wird ein eigenes Verzeichnis "
                  "auf der Festplatte benötigt. Um dieses Verzeichnis "
                  "anlegen zu können, müssen Sie hier die Festplatte "
                  "angeben, auf der installiert werden soll (z.B. Work:, DH0:, etc).\n"
            )
            (newpath)
            (default @default-dest)
            (disk)
      )
)

(set @default-dest (tackon mydir "AmiAtlas"))
(set mapdir (tackon @default-dest "germany"))
(set icondir (tackon @default-dest "Icons"))

(if (NOT (exists @default-dest))
      (makedir @default-dest
            (prompt "\nVerzeichnis erzeugen\n\n"
                    "Bitte klicken Sie 'Proceed' an, um für 'AmiAtlas' das Verzeichnis '"
                    @default-dest "' zu erzeugen.\n\n"
                    "Mit 'Abort Install' wird die Installation an dieser Stelle abgebrochen. "
                    "'AmiAtlas' befindet sich dann nur unvollständig auf der Festplatte, "
                    "und es ist eine neue Installation notwendig.")
            (confirm)
            (help "\nHilfe zu 'Verzeichnis erzeugen'\n\n"
                  "Auf dem von Ihnen ausgewählten Laufwerk wird das Unterverzeichnis "
                  "für 'AmiAtlas' angelegt. Sollten Sie doch einen anderen Pfad als "
                  "'" @default-dest "' verwenden wollen, können Sie das Installationsprogramm "
                  "an dieser Stelle abbrechen. Beim Neustart geben Sie dann den von Ihnen "
                  "gewünschten Pfad an.\n\n"
                  "Als Verzeichnisname wird jedoch in jedem Fall 'AmiAtlas' verwendet.\n")
            (infos)
      )
)

(complete 4)

(message "\nProgrammdateien kopieren\n\n"
         "Bitte klicken Sie 'Proceed' an, um die Programmdateien von 'AmiAtlas' "
         "zu installieren.\n\n"
         "Mit 'Abort Install' wird die Installation an dieser Stelle abgebrochen. "
         "'AmiAtlas' befindet sich dann nur unvollständig auf der Festplatte, "
         "und es ist eine neue Installation notwendig.")

(copyfiles
      (prompt "Kopiere Programmdateien.")
      (help "")
      (source "" )
      (dest @default-dest)
      (choices "AmiAtlas"
               "AmiAtlas.info")
      (optional force askuser)
)

(complete 30)

(set osversion (/ (getversion) 65536))

(if (< osversion 36)
        (copyfiles
                (prompt "Kopiere Datei 'AmiAtlas.prefs'")
                (help "")
                (source "AmiAtlas:AmiAtlas.prefs")
                (dest @default-dest)
        )
        (if (exists "ENVARC:")
                (copyfiles
                        (prompt "Kopiere Datei 'AmiAtlas.prefs'")
                        (help "")
                        (source "AmiAtlas:AmiAtlas.prefs")
                        (dest "ENVARC:")
                )
                (copyfiles
                        (prompt "Kopiere Datei 'AmiAtlas.prefs'")
                        (help "")
                        (source "AmiAtlas:AmiAtlas.prefs")
                        (dest @default-dest)
                )
        )
)

(complete 35)

(if (< osversion 36)
        (copylib
                (prompt "Kopiere Datei 'reqtools.library'")
                (help "")
                (source "AmiAtlas:support/libs1.3/reqtools.library")
                (dest "LIBS:")
        )
        (copylib
                (prompt "Kopiere Datei 'AmiAtlas.prefs'")
                (help "")
                (source "AmiAtlas:support/libs2.0/reqtools.library")
                (dest "LIBS:")
        )
)

(complete 40)

(message "\nDeutschland-Karte kopieren\n\n"
         "Bitte klicken Sie 'Proceed' an, um die Kartendaten von Deutschland zu kopieren.\n\n"
         "Mit 'Abort Install' wird die Installation an dieser Stelle abgebrochen. "
         "'AmiAtlas' befindet sich dann nur unvollständig auf der Festplatte, "
         "und es ist eine neue Installation notwendig.")

(if (NOT (exists mapdir))
      (makedir mapdir
            (infos)
      )
)

(complete 45)

(copyfiles
      (prompt "Kopiere Deutschland-Karte")
      (help "")
      (source "AmiAtlas:germany")
      (dest mapdir)
      (optional force askuser)
      (all)
)

(complete 80)

(if (NOT (exists "FONTS:helvetica.font"))
      (
            (makedir "FONTS:helvetica"
               (prompt "Das Verzeichnis 'FONTS:helvetica' wird erzeugt.")
               (confirm)
               (help "Im FONTS-Verzeichnis Ihrer Festplatte fehlen noch Zeichensätze, "
                     "die von 'AmiAtlas' verwendet werden. Diese werden jetzt kopiert.\n\n")
            )
            (copyfiles
                  (prompt "Kopiere Zeichensatz")
                  (help "")
                  (source "AmiAtlas:font/helvetica")
                  (dest "FONTS:helvetica")
                  (optional force askuser)
                  (all)
            )
            (copyfiles
                  (prompt "Kopiere Datei 'AmiAtlas:font/helvetica.font'")
                  (help "")
                  (source "AmiAtlas:font/helvetica.font")
                  (dest "FONTS:")
                  (optional force askuser)
            )
      )
)

(complete 90)

(set assigncmd (cat "Assign AmiAtlas: \"" @default-dest "\""))

(startup "AmiAtlas"
         (prompt "\nAssign für 'AmiAtlas'\n\n"
                 "Es wird ein Assign in der Datei 'user-startup' benötigt. "
                 "Bitte 'Proceed' anklicken, um diese Ergänzung automatisch "
                 "durchführen zu lassen.")
         (help "\nHilfe zu Assign\n\n"
               "'AmiAtlas' wird über das logische Laufwerk \"AmiAtlas:\" "
               "angesprochen und benötigt deshalb einen Verweis auf "
               "das entsprechende Festplattenverzeichnis. Dieser Verweis "
               "wird beim Amiga in der Datei 'user-startup' durch einen "
               "Assign-Befehl hergestellt. Die Installation fügt den "
               "benötigten Befehl selbständig ein.")
         (command assigncmd)
)

(complete 100)

(message "\nInstallation beendet\n\n"
         "'AmiAtlas' befindet sich nun im Verzeichnis:\n'" @default-dest "'\n\n"
         "Bitte booten Sie Ihren Amiga erneut.")

(exit (quiet))