; LCARS Release 2.2 System Startup
; L.B. Elliott, Feb '95
; This version for Issue 8
; >2.0 Resident commands not with explicit path

NoBorder					; Borderless CLI please
Echo "*e[32m"

C:MakeDir RAM:Env				; Create ENV:
C:MakeDir RAM:T					; Create T:
C:Assign13 ENV: RAM:Env
C:Assign13 T: RAM:T

C:ExecVer					; Get exec version

IF $ExecVer GE 39				; >39 startup
    Echo "Initialising LCARS environment for Amiga Release 3.x..."
    C:SetPatch30 >NIL:
    C:Assign20 LCARS[1]: SYS:LCARS
    C:Assign20 LCARS[2]: "Disk 2:LCARS" DEFER
    C:Assign20 LCARS[3]: "Disk 3:LCARS" DEFER
    C:Assign20 LCARS[4]: "Disk 4:LCARS" DEFER
  
ELSE
    IF $ExecVer NOT GE 36			; <36 startup
    	Echo "Initialising LCARS environment for Amiga Release 1.x..."
    	SetPatch13 >NIL:
    	C:PPLibInit
	C:FF >NIL: -0
	C:Copy S:Startup13 T:			; Assigns
	C:Execute T:Startup13			; Execute (reduces swaps)

    ELSE					; Here must be >=36, <39
    	C:Echo "Initialising LCARS environment for Amiga Release 2.x..."
	C:SetPatch20 >NIL:
    	C:Assign20 LCARS[1]: SYS:LCARS
	C:Assign20 LCARS[2]: "Disk 2:LCARS" DEFER
	C:Assign20 LCARS[3]: "Disk 3:LCARS" DEFER
	C:Assign20 LCARS[4]: "Disk 4:LCARS" DEFER
   ENDIF
ENDIF

C:PPLoadSeg >NIL:				; Patch pp on
C:PPColPatch >NIL: 4				; Turn off decrunch colors
C:AddBuffers DF0: 15
C:SetMap GB

C:MakeDir RAM:LCARS_Data
C:MakeDir RAM:LCARS_Data/MenuFile
C:MakeDir RAM:LCARS_Data/Lists

C:Assign13 LCARS: SYS:LCARS
C:Assign13 LCARS_Data: RAM:LCARS_Data

C:Copy LCARS:MenuFile/ LCARS_Data:MenuFile/ ALL QUIET
C:Copy LCARS:Lists/#? LCARS_Data:Lists/ QUIET

Echo "LCARS Initialised. Activating..."
LCARS:LCARS Contents.MF GL=Startup.GL ML

Echo "*nRebooting in 5 seconds..."
Wait 3 SECS
Reset