/* $VER: DMDest2Source.rexx 1.0 (25.3.98) by J. Tierney

  DiskMaster II Dest To Source
  3/25/98  J. Tierney <jtierney@cyberlink-inc.com>

  Purpose:  Change the Dest dir, or open a new window, to either the same dir
           as the Source, or to Source's parent dir.

  Usage:  Rexx DMDest2Source.rexx [<mode>]

          <mode> - 0 - Dest dir = Source dir.  Default.
                   1 - Dest dir = Source's parent dir.
                   2 - Open new window to Source dir.
                   3 - Open new window to Source's parent dir.
*/

OPTIONS RESULTS

/* Dimensions for the new window. */
/* Change these to suit yourself. */
winx = 100  /* X      */
winy = 8    /* Y      */
winw = 260  /* Width  */
winh = 194  /* Height */

ARG mode
IF (mode = '') | (mode < 0) THEN mode = 0
IF mode > 3 THEN mode = 3

/* Get source dir */
'STATUS P'
src = result

/* Get parent dir */
x = LASTPOS('/', src) - 1
IF x = -1 THEN x = LASTPOS(':', src)
prnt = LEFT(src, x)

ok = -1

SELECT
  WHEN mode = 0 THEN DO
    'WINDOW DEST'
    'NEWDIR' src
    END

  WHEN mode = 1 THEN DO
    'WINDOW DEST'
    'NEWDIR' prnt
    END

  WHEN mode = 2 THEN DO
    'OPENWINDOW' winx winy winw winh src
    END

  WHEN mode = 3 THEN DO
    'OPENWINDOW' winx winy winw winh prnt
    END
END

'WINDOW DEST'