*** Coded by Realidad Binaria
       *** Beyond our imagination there Realidad Binaria is
       *** Moral support and technical aid provided by Optimus Brain, as
       *** the computer itself to code this marvellous utility
       *** What are ya waitin' for ?. Are ya goin' to stick around ?
       *** Ohhh nooo!!!. So come on man, move your ass and go for it!!!

       *** Test this out at once!!!

       *** © Copyright notice. This is a Realidad Binaria® production.

       *** The copyright propietor has licensed this piece of software and
       *** also other material featured in this program for private homr use
       *** only and prohibits any other use, copying, reproduction or perfor-
       *** mance in public, in whole or in part.

       *** This product is manufacturated and distributed by
       *** Realidad Binaria / COOL-X
       *** Therefore you are not allowed to do the said above.
       *** This Code entitles you to call toll free.


          jmp       $30000
          org       $30000
          load      $30000

          move.l    #s,$80
          trap      #0                 ;Exception occurs
          rts

s:        movem.l d0-d7/a0-a6,-(sp)

          lea       $dff000,a5

main:     move.b    $bfec01,d0         ;CIA-B Keyboard register
          not.b     d0
          ror.b     #1,d0
          cmp.b     #$45,d0            ;ESC-key striked ? Yeahh, so quit!
          beq.s     fin
          cmp.b     #$13,d0            ;Checks for 'E' key
          bcc.s     main
          ext.w     d0
          add.w     d0,d0              ;Points out to next frequency
          add.w     d0,d0
          lea       teclas(pc,d0.w),a0 ;Points to Teclas location
          move.w    (a0)+,d0
          move.w    (a0)+,d1
          bsr.s     psono              ;Let's have a walk with BOBI !!!

wait:     move.b    $bfec01,d0         ;Checks if key is released or not to
          btst      #0,d0              ;finish the sound off
          bne.s     wait

          move.w    #$000f,$096(a5)    ;Turn off DMA Channels
          bra.s     main

fin:      move.w    #$000f,$096(a5)    ;Turn off DMA Channels
          movem.l   (sp)+,d0-d7/a0-a6
          rte                          ;Return exception

	*** List of converted frequencies  ***

f700      equ       1278
f900      equ       994
f1100     equ       813
f1300     equ       688
f1500     equ       596
f1700     equ       526
f2500     equ       357
f2600     equ       344

	*** Teclas ***

teclas:
          dc.w      f2500,f2500         2500
          dc.w      f700,f900           1
          dc.w      f700,f1100          2
          dc.w      f900,f1100          3
          dc.w      f700,f1300          4
          dc.w      f900,f1300          5
          dc.w      f1100,f1300         6
          dc.w      f700,f1500          7
          dc.w      f900,f1500          8
          dc.w      f1100,f1500         9
          dc.w      f1300,f1500         0
          dc.w      f1700,f1700         1700
          dc.w      f700,f1700          11
          dc.w      f900,f1700          12
          dc.w      0,0                 Doesn't exist ???
          dc.w      f1100,f1700         KP1
          dc.w      f1300,f1700         KP2
          dc.w      f1500,f1700         ST
          dc.w      f2600,f2600         2600

psono:
* Entry d0-d1 for both channels

          move.w    #$000f,$096(a5)    ;Turn off DMA Sound Channels
          lea       data(pc),a0

          move.l    a0,$0a0(a5)        ;Audio 0 Location (Data Location)
          move.l    a0,$0d0(a5)        ;Audio 1 Location (Data Location)

          move.w    #2,$0a4(a5)        ;Set lenght in words canal 0
          move.w    #2,$0d4(a5)        ;Set lenght in words canal 3

          move.w    #64,$0a8(a5)       ;Set C-0 maximum volume
          move.w    d0,$0a6(a5)        ;Set sample period

          move.w    #64,$0d8(a5)       ;Set C-3 maximum volume
          move.w    d1,$0d6(a5)        ;Set sample period
          move.w    #$00ff,$09e(a5)
          move.w    #$8209,$096(a5)    ;Connects DMA Sound Channel 0 & 3
	rts

data:     dc.b      0,127,0,-127       ;The wave itself
end: