,ouchflag-d(a5)
		cmp.w	#9,ouchflag-d(a5)
		bpl.s	.c04
		addq.w	#1,ouchflag-d(a5)
.c04


		bra	.show
		
.tab		dc.w	16,15,14,13,12,11,10,9,8,7,6,5,4,3,2,1,0,0,0,0,0,0,0,0
;------------------------------------------------
wheelanim	wheelanim_m #160*224
;------------------------------------------------
;------------------------------------------------
maskblitxy	maskblitxy_m
;------------------------------------------------
maskblit	maskblit_m
;------------------------------------------------
d		;data-start
;------------------------------------------------
normblit	normblit_m
;------------------------------------------------
falling_down3	falling_down3_m
;------------------------------------------------
falling_down2	falling_down2_m
;------------------------------------------------
falling_down	falling_down_m
;------------------------------------------------
falling_down4	falling_down4_m
;-----------------------------------------------
teststomp	teststomp_m
;------------------------------------------------
teststand	teststand_m
;------------------------------------------------
;------------------------------------------------
move1		clr.l	nmdata(a0)
		bsr	maskblit
		rts
		
;------------------------------------------------
move2		cmp.w	#10,enterflag2-d(a5)
		bmi.s	.end2

		move.l	absmanxpos-d(a5),d0
		add.w	#80,d0
		cmp.w	nmxpos(a0),d0
		bmi.s	.end
		sub.w	#32,d0
		cmp.w	nmxpos(a0),d0
		bpl.s	.end

		move.l	absmanypos-d(a5),d0
		add.w	#16,d0
		cmp.w	nmypos(a0),d0
		bmi.s	.end
		sub.w	#64,d0
		cmp.w	nmypos(a0),d0
		bpl.s	.end

		move.l	nmanimpos(a0),d0
		and.l	#$fffffffc,d0
		add.l	#nrmbobs,d0
		move.l	d0,nmdata(a0)
		
		moveq	#0,d5
		bsr	normblit
		cmp.l	#16,nmanimpos(a0)
		bpl.s	.end
		addq.l	#1,nmanimpos(a0)
.end		rts
.end2		clr.l	nmanimpos(a0)
		rts
;------------------------------------------------
move3		move.w	#1,nmobj(a0)
		move.l	#nrmbobs+36,nmdata(a0)
		moveq	#0,d5
		bsr	normblit
		tst.w	mancoll-d(a5)
		beq.s	.ret
		clr.w	mancoll-d(a5)
		moveq	#1,d1
		move.w	d1,touchflag-d(a5)
		move.w	d1,touchtext-d(a5)
		move.w	d1,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret		rts
;------------------------------------------------
move4		tst.w	textflag-d(a5)
		bne	maskblitxy
		movem.l	d0/d1/a1/a2,-(a7)
		tst.w	nmanimcount+2(a0)
		bne	.front
		tst.w	nmxdir(a0)
		bne	.right
.left		moveq	#0,d0
		move.w	nmxpos(a0),d0
		subq.w	#6,d0
		lsr.w	#4,d0
		add.w	d0,d0
		subq.w	#8,d0
		move.w	nmypos(a0),d1
		lsr.w	#4,d1
		addq.w	#4,d1
		mulu	#_levwidth,d1
		add.l	d1,d0
		move.l	_xmem,a1
		add.l	ldatofs-d(a5),a1
		lea	blocktab-d(a5),a2
		move.w	-2(a1,d0.l),d1
		move.w	d1,d0
		and.w	#$fc00,d0
		cmp.w	#$e800,d0
		beq.s	.lc1
		and.w	#$3ff,d1
		cmp.b	#1,(a2,d1.w)
		beq.s	.lc1
		
.lturn		move.w	#1,nmxdir(a0)
		move.w	#7,nmanimcount+2(a0)
		bra	.front
.lc1		and.w	#$fff0,nmypos(a0)
		clr.l	nmyspeed(a0)
		lea	.ltab(pc),a2
		
		eor.w	#1,nmanimcount(a0)
		move.w	nmanimcount(a0),d0
		sub.w	d0,nmxpos(a0)
		bra	.end
		
.right		moveq	#0,d0
		move.w	nmxpos(a0),d0
		addq.w	#3,d0
		lsr.w	#4,d0
		add.w	d0,d0
		subq.w	#2,d0
		move.w	nmypos(a0),d1
		lsr.w	#4,d1
		addq.w	#4,d1
		mulu	#_levwidth,d1
		add.l	d1,d0
		move.l	_xmem,a1
		add.l	ldatofs-d(a5),a1
		lea	blocktab-d(a5),a2
		move.w	2(a1,d0.l),d1
		move.w	d1,d0
		and.w	#$fc00,d0
		cmp.w	#$e800,d0
		beq.s	.rc1
		and.w	#$3ff,d1
		cmp.b	#1,(a2,d1.w)
		beq.s	.rc1
		
.rturn		clr.w	nmxdir(a0)
		move.w	#7,nmanimcount+2(a0)
		bra	.front
.rc1		and.w	#$fff0,nmypos(a0)
		clr.l	nmyspeed(a0)
		lea	.rtab(pc),a2
		
		eor.w	#1,nmanimcount(a0)
		move.w	nmanimcount(a0),d0
		add.w	d0,nmxpos(a0)

.end		move.w	nmanimpos(a0),d0
		lsr.w	#1,d0
		and.w	#$fffc,d0
		move.l	(a2,d0.w),nmdata(a0)
		addq.w	#2,nmanimpos(a0)
		cmp.w	#48,nmanimpos(a0)
		bmi.s	.ret
		clr.w	nmanimpos(a0)
.ret		movem.l	(a7)+,d0/d1/a1/a2
		bsr	maskblitxy
		tst.w	mancoll-d(a5)
		beq.s	.ret2
		clr.w	mancoll-d(a5)
		moveq	#2,d1
		move.w	#1,speakflag-d(a5)
		move.w	#1,speakmenu-d(a5)
		move.w	#spfatmanq-spe,speakqadr-d(a5)
		move.w	#spfatmana-spe,speakaadr-d(a5)
		move.w	#1,touchflag-d(a5)
		move.w	d1,touchtext-d(a5)
		move.w	d1,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret2		rts

.front		subq.w	#1,nmanimcount+2(a0)
		move.l	#64*160+24,nmdata(a0)
		bra.s	.ret
		
.ltab		dc.l	4,8,12,16,20,24
.rtab		dc.l	28,32,36,64*160+28,64*160+32,64*160+36

;------------------------------------------------
move5		tst.w	textflag-d(a5)
		bne	maskblitxy
		move.l	#64*160+4,nmdata(a0)
		move.w	nmstartypos(a0),d0
		addq.w	#8,d0
		move.w	d0,nmypos(a0)
		bsr	maskblit

		tst.w	mancoll-d(a5)
		beq.s	.ret2
		clr.w	mancoll-d(a5)
		move.w	#13,mantextcol-d(a5)
		move.w	#1,speakflag-d(a5)
		move.w	#1,speakmenu-d(a5)
		move.w	#spfatmanq-spe,speakqadr-d(a5)
		move.w	#spfatmana-spe,speakaadr-d(a5)
		move.w	nmxpos(a0),nmspeakxpos+2-d(a5)
		move.w	nmypos(a0),nmspeakypos+2-d(a5)
		move.w	#1,touchflag-d(a5)
		moveq	#3,d1
		move.w	d1,touchtext-d(a5)
		move.w	d1,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret2		rts
;------------------------------------------------
move6		tst.w	textflag-d(a5)
		bne	maskblitxy
		move.l	#64*160+8,nmdata(a0)
		move.w	nmstartypos(a0),d0
		addq.w	#8,d0
		move.w	d0,nmypos(a0)
		bsr	maskblit

		tst.w	mancoll-d(a5)
		beq.s	.ret2
		clr.w	mancoll-d(a5)
		moveq	#4,d1
		move.w	#1,speakflag-d(a5)
		move.w	#1,touchflag-d(a5)
		move.w	d1,touchtext-d(a5)
		move.w	d1,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret2		rts
;------------------------------------------------
move7		tst.w	textflag-d(a5)
		bne	maskblitxy
		move.l	#120*160,nmdata(a0)
		bsr	maskblit

		tst.w	mancoll-d(a5)
		beq.s	.ret2
		clr.w	mancoll-d(a5)
		moveq	#5,d1
		move.w	#1,speakflag-d(a5)
		move.w	#1,touchflag-d(a5)
		move.w	d1,touchtext-d(a5)
		move.w	d1,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret2		rts
;------------------------------------------------
move8		moveq	#6,d1			; Banane
		moveq	#11,d2
		move.l	#67*160+18,d0
		bra	objrout		
;------------------------------------------------
move9		moveq	#7,d1			; Melone
		moveq	#11,d2
		move.l	#67*160+16,d0
		bra	objrout		
;------------------------------------------------
move10		move.w	nmanimpos(a0),d0
		and.w	#$fffc,d0
		lsr.w	#1,d0
		ext.l	d0
		add.l	#128*160+28,d0
		move.l	d0,nmdata(a0)
		addq.w	#1,nmanimpos(a0)
		and.w	#15,nmanimpos(a0)
		bsr	maskblit
		rts
;------------------------------------------------
move11		move.l	#88*160+16,nmdata(a0)
		bsr	maskblit
		tst.w	mancoll-d(a5)
		beq.s	.ret
		clr.w	mancoll-d(a5)
		move.w	#2,mantextcol-d(a5)
		move.w	#1,speakflag-d(a5)
		move.w	#1,speakmenu-d(a5)
		move.w	#spboozerq-spe,speakqadr-d(a5)
		move.w	#spboozera-spe,speakaadr-d(a5)
		move.w	nmxpos(a0),nmspeakxpos+2-d(a5)
		move.w	nmypos(a0),nmspeakypos+2-d(a5)
		moveq	#8,d1
		move.w	#1,touchflag-d(a5)
		move.w	d1,touchtext-d(a5)
		move.w	d1,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret		rts
;------------------------------------------------
move12		tst.w	textflag-d(a5)
		bne	maskblitxy
		move.l	a1,-(a7)
		lea	.animtab(pc),a1
		move.w	nmanimpos(a0),d0
		lsr.w	#1,d0
		and.w	#$fffe,d0
		move.w	(a1,d0.w),d0
		lea	.animadr(pc),a1
		move.l	(a1,d0.w),nmdata(a0)
		addq.w	#1,nmanimpos(a0)
		cmp.w	#384,nmanimpos(a0)
		bmi.s	.c1
		clr.w	nmanimpos(a0)
.c1		move.w	nmstartypos(a0),d0
		addq.w	#7,d0
		move.w	d0,nmypos(a0)
		move.l	(a7)+,a1
		bsr	maskblit
		
		tst.w	mancoll-d(a5)
		beq.s	.ret2
		clr.w	mancoll-d(a5)
		moveq	#9,d1
		move.w	#1,touchflag-d(a5)
		move.w	d1,touchtext-d(a5)
		move.w	d1,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret2		rts

.animtab	dc.w	0,4,0,4,0,4,0,4,0,4,0,4,0,4,0,4
		dc.w	0,4,0,4,0,4,0,4,0,4,0,4,0,4,0,4
		dc.w	0,4,0,4,0,4,0,4,0,4,0,4,0,4,0,4
		dc.w	4,4,4,4,4,4,4,4,4,4,4,4,4,4,4,8
		dc.w	12,12,12,12,12,12,12,12,12,12,12,12,12,12,12,12
		dc.w	12,12,12,12,12,12,12,12,12,12,12,12,12,12,8,4

.animadr	dc.l	227*160+12,227*160+16,227*160+20,227*160+24
;------------------------------------------------
objrout		move.w	d1,nmobj(a0)
		cmp.w	takenobj-d(a5),d1
		beq.s	.reset
		move.l	d0,nmdata(a0)
		add.w	nmstartypos(a0),d2
		move.w	d2,nmypos(a0)
		move.l	d1,-(a7)
		bsr	maskblit
		move.l	(a7)+,d1
		tst.w	mancoll-d(a5)
		beq.s	.ret
		clr.w	mancoll-d(a5)
		move.w	#1,touchflag-d(a5)
		move.w	d1,touchtext-d(a5)
		move.w	d1,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret		rts
.reset		clr.w	takenobj-d(a5)
		clr.w	nmenable(a0)
		rts
;------------------------------------------------
move14		moveq	#6,d1			; Kurbel
		moveq	#11,d2
		move.l	#52*160+38,d0
		bra	objrout		
;------------------------------------------------
move15		moveq	#7,d1			; Holz
		moveq	#9,d2
		move.l	#31*160+36,d0
		bra	objrout		
;------------------------------------------------
move16		moveq	#8,d1			; Feuersteine
		moveq	#10,d2
		move.l	#34*160+28,d0
		bra	objrout		
;------------------------------------------------
move17		moveq	#9,d1			; Hammer
		moveq	#10,d2
		move.l	#52*160+36,d0
		bra	objrout		
;------------------------------------------------
move18		moveq	#10,d1			; Kerzen
		moveq	#12,d2
		move.l	#41*160+30,d0
		bra	objrout		
;------------------------------------------------
move19		moveq	#11,d1			; Schlüssel
		moveq	#12,d2
		move.l	#40*160+28,d0
		bra	objrout		
;------------------------------------------------
move20		moveq	#12,d1			; Kristall
		moveq	#9,d2
		move.l	#34*160+30,d0
		bra	objrout		
;------------------------------------------------
move21		moveq	#13,d1			; Paddel
		moveq	#10,d2
		move.l	#25*160+36,d0
		bra	objrout		
;------------------------------------------------
move22		moveq	#14,d1			; kaputte Winde
		moveq	#0,d2
		moveq	#38,d0
		bra	objrout
;------------------------------------------------
move23		moveq	#15,d1			; kaputte Winde
		moveq	#0,d2
		moveq	#0,d0
		bra	objrout
;------------------------------------------------
;------------------------------------------------
move25		moveq	#17,d1
		move.w	d1,nmobj(a0)
		move.l	#nrmbobs+8,nmdata(a0)
		moveq	#0,d5
		bsr	normblit
		tst.w	mancoll-d(a5)
		beq.s	.ret
		clr.w	mancoll-d(a5)
		move.w	#1,touchflag-d(a5)
		move.w	#17,touchtext-d(a5)
		move.w	#17,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret		rts
;------------------------------------------------
move26		moveq	#18,d1			; Nägel
		moveq	#9,d2
		move.l	#16*160+38,d0
		bra	objrout
;------------------------------------------------
move27		moveq	#19,d1			; Seil
		moveq	#2,d2
		move.l	#38*160+36,d0
		bra	objrout
;-------