6)
		move.l	d1,$54(a6)
		move.w	m6mod+2-d(a4),$64(a6)
		move.w	m6mod+2-d(a4),$66(a6)
		move.w	m6size2+2-d(a4),$58(a6)
.c002		move.l	m6bpos11-d(a4),m6bpos12-d(a4)
		move.l	m6bpos21-d(a4),m6bpos22-d(a4)
		move.w	m6mod-d(a4),m6mod+2-d(a4)
		move.l	m6size1-d(a4),m6size2-d(a4)
		addq.l	#4,a4
		dbra	d7,.l001
		rts

;------------------------------------------------
move7		move.w	#1,nmobj(a0)
		move.l	#16*160+32,nmdata(a0)
		bsr	maskblit
		tst.w	mancoll-d(a5)
		beq.s	.ret
		clr.w	mancoll-d(a5)
		move.w	#1,touchflag-d(a5)
		move.l	#objectspr+1*4*16,touchdata-d(a5)
		move.w	#1,touchtext-d(a5)
		move.w	#1,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret		rts
;------------------------------------------------
move8		tst.w	textflag-d(a5)
		bne	maskblitxy
		movem.l	a1/a2/d0/d1,-(a7)
		tst.w	nmstartflag(a0)
		beq	.cont
		move.l	nm(pc),a1
		moveq	#_nmeno-1,d0
.l1		tst.w	nmenable(a1)
		beq.s	.c1
		addq.l	#4,a1
		dbra	d0,.l1
		bra	.cont
.c1		clr.w	nmstartflag(a0)
		move.w	#1,nmenable(a1)
		move.w	#1,nmenable+2(a1)
		moveq	#0,d0
		move.w	d0,nmstartno(a1)
		move.w	d0,nmlevxadd(a1)
		move.l	d0,nmlevyadd(a1)
		move.l	d0,nmxspeed(a1)
		move.l	d0,nmyspeed(a1)
		move.l	_xmem,d0
		add.l	#_ldatofs,d0
		move.l	d0,nmstartblk(a1)
		move.l	nmxpos(a0),nmxpos(a1)
		move.l	nmypos(a0),nmypos(a1)
		move.l	nmxcenter(a0),nmxcenter(a1)
		move.l	nmycenter(a0),nmycenter(a1)
		move.l	nmstartxpos(a0),nmstartxpos(a1)
		move.l	nmstartypos(a0),nmstartypos(a1)
		move.l	nmstartxpos(a0),nmactxpos(a1)
		move.l	nmstartypos(a0),nmactypos(a1)
		move.l	nmxsize(a0),nmxsize(a1)
		move.l	nmysize(a0),nmysize(a1)
		move.l	nmanimpos(a0),nmanimpos(a1)
		move.l	nmanimcount(a0),nmanimcount(a1)
		move.l	#11,nmmove(a1)
		move.l	a1,nmanimpos2(a0)
		
.cont		move.l	#18,nmdata(a0)
		tst.w	nmcoll(a0)
		beq.s	.end
		move.l	#32,nmdata(a0)
		bsr	falling_down
		move.l	nmanimpos2(a0),a1
		clr.w	nmenable+2(a1)
.end		movem.l	(a7)+,a1/a2/d0/d1
		bsr	maskblitxy
;		move.w	mancoll-d(a5),d0
;		or.w	d0,defmancoll-d(a5)
		rts

move8ii		tst.w	textflag-d(a5)
		bne	maskblitxy
		movem.l	d0/d1/a1,-(a7)
		move.l	nmanimpos(a0),d0
		and.w	#$fffe,d0
		add.w	#20,d0
		move.l	d0,nmdata(a0)
		addq.l	#1,nmanimpos(a0)
		cmp.l	#12,nmanimpos(a0)
		bne.s	.c1
		clr.l	nmanimpos(a0)
.c1		lea	sinus-d(a5),a1
		move.l	nmanimcount(a0),d0
		move.w	(a1,d0.w),d1
		asr.w	#8,d1
		asr.w	#2,d1
		add.w	nmactxpos(a0),d1
		move.w	d1,nmxpos(a0)
		swap	d0
		move.w	(a1,d0.w),d1
		asr.w	#8,d1
		asr.w	#2,d1
		add.w	nmactypos(a0),d1
		move.w	d1,nmypos(a0)
		add.w	#6,nmanimcount(a0)
		add.w	#8,nmanimcount+2(a0)
		and.l	#$01ff01ff,nmanimcount(a0)

		tst.w	nmenable+2(a0)
		beq	.off
		
		move.l	absmanxpos-d(a5),d0
		add.w	#72,d0
		sub.w	nmstartxpos(a0),d0
		cmp.w	#150,d0
		bpl	.chk2
		cmp.w	#-150,d0
		bmi	.chk2
		move.l	absmanypos-d(a5),d1
		add.l	#24,d1
		sub.w	nmstartypos(a0),d1
		cmp.w	#80,d1
		bpl	.chk2
		cmp.w	#-80,d1
		bmi	.chk2
		
		move.l	absmanxpos-d(a5),d0
		add.w	#72,d0
		cmp.w	nmactxpos(a0),d0
		bmi.s	.xgreater
		cmp.w	#16,nmxspeed(a0)
		bpl.s	.xcont		
		addq.w	#1,nmxspeed(a0)
		bra.s	.xcont
.xgreater	cmp.w	#-15,nmxspeed(a0)
		bmi.s	.xcont
		subq.w	#1,nmxspeed(a0)
.xcont		move.l	absmanypos-d(a5),d0
		add.l	#24,d0
		cmp.w	nmactypos(a0),d0
		bmi.s	.ygreater
		cmp.w	#16,nmyspeed(a0)
		bpl.s	.ycont		
		addq.w	#1,nmyspeed(a0)
		bra.s	.ycont
.ygreater	cmp.w	#-15,nmyspeed(a0)
		bmi.s	.ycont
		subq.w	#1,nmyspeed(a0)
.ycont		move.w	nmxspeed(a0),d0
		asr.w	#4,d0
		add.w	d0,nmactxpos(a0)
		move.w	nmyspeed(a0),d0
		asr.w	#4,d0
		add.w	d0,nmactypos(a0)
		
		movem.l	(a7)+,d0/d1/a1
		bsr	maskblitxy
		move.w	mancoll-d(a5),d0
		or.w	d0,defmancoll-d(a5)
		rts
		
.off		moveq	#-1,d0
		move.w	d0,nmyspeed(a0)
		clr.w	nmxspeed(a0)
		bra.s	.ycont
		
.chk2		move.w	nmstartxpos(a0),d0
		addq.w	#8,d0
		cmp.w	nmactxpos(a0),d0
		bmi.s	.xgreater3
		cmp.w	#16,nmxspeed(a0)
		bpl.s	.xcont2
		addq.w	#2,nmxspeed(a0)
		bra.s	.xcont2
.xgreater3	cmp.w	#-15,nmxspeed(a0)
		bmi.s	.xcont2
		subq.w	#2,nmxspeed(a0)
.xcont2		move.w	nmstartypos(a0),d0
		addq.w	#8,d0
		cmp.w	nmactypos(a0),d0
		bmi.s	.ygreater2
		cmp.w	#16,nmyspeed(a0)
		bpl.s	.ycont
		addq.w	#2,nmyspeed(a0)
		bra.s	.ycont
.ygreater2	cmp.w	#-15,nmyspeed(a0)
		bmi.s	.ycont
		subq.w	#2,nmyspeed(a0)
		bra.s	.ycont
;------------------------------------------------
move9		move.w	#2,nmobj(a0)
		cmp.w	#2,takenobj-d(a5)	;Leerer Kübel
		beq.s	.reset
		move.l	#34,nmdata(a0)
		bsr	maskblit
		tst.w	mancoll-d(a5)
		beq.s	.ret
		clr.w	mancoll-d(a5)
		move.w	#1,touchflag-d(a5)
		move.l	#objectspr+2*4*16,touchdata-d(a5)
		move.w	#2,touchtext-d(a5)
		move.w	#2,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret		rts
.reset		clr.w	takenobj-d(a5)
		clr.w	nmenable(a0)
		rts
;------------------------------------------------
move10		move.w	#3,nmobj(a0)
		move.l	#nrmbobs,nmdata(a0)	;Boot
		moveq	#0,d5
		bsr	normblit
		tst.w	mancoll-d(a5)
		beq.s	.ret
		clr.w	mancoll-d(a5)
		move.w	#1,touchflag-d(a5)
		move.l	#objectspr+3*4*16,touchdata-d(a5)
		move.w	#3,touchtext-d(a5)
		move.w	#3,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret		rts
;------------------------------------------------
move11		move.w	#4,nmobj(a0)
		cmp.w	#4,takenobj-d(a5)	;Teerkübel
		beq.s	.reset
		move.l	#34,nmdata(a0)
		bsr	maskblit
		tst.w	mancoll-d(a5)
		beq.s	.ret
		clr.w	mancoll-d(a5)
		move.w	#1,touchflag-d(a5)
		move.w	#4,touchtext-d(a5)
		move.w	#4,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret		rts
.reset		clr.w	takenobj-d(a5)
		clr.w	nmenable(a0)
		rts
;------------------------------------------------
move12		move.w	#5,nmobj(a0)
		movem.l	d1/d2,-(a7)		;Gondel
		move.l	a0,baddr-d(a5)
		tst.w	nmstartflag(a0)
		beq.s	.c6
		move.l	nmstartblk(a0),nmstartblk2(a0)
		addq.w	#8,nmxpos(a0)
		clr.w	nmstartflag(a0)
.c6		move.w	nmstartypos(a0),d2
		add.w	#10,d2
		move.w	d2,nmypos(a0)
		
		moveq	#0,d2
		move.w	nmxpos(a0),d2
		sub.w	nmstartxpos(a0),d2
		ext.l	d2
		asr.l	#4,d2
		add.l	d2,d2
		add.l	nmstartblk2(a0),d2
		move.l	d2,nmstartblk(a0)
		
		clr.w	bfallflag-d(a5)
		clr.w	bstandflag-d(a5)
		moveq	#0,d2
		move.w	nmxpos(a0),d2
		sub.w	#64,d2
		move.w	d2,bxborderl-d(a5)
		add.w	#32,d2	
		move.w	d2,bxborderr-d(a5)
		
		moveq	#0,d2
		move.w	nmypos(a0),d2
		sub.w	#39,d2
		cmp.l	absmanypos-d(a5),d2
		bpl.s	.c1
		add.w	#13,d2
		cmp.l	absmanypos-d(a5),d2
		bpl	.c2
		add.w	#16,d2
		cmp.l	absmanypos-d(a5),d2
		bmi.s	.c1
		
		moveq	#0,d2
		move.w	bxborderl-d(a5),d2
		cmp.l	absmanxpos-d(a5),d2
		bpl.s	.c1
		move.w	bxborderr-d(a5),d2
		cmp.l	absmanxpos-d(a5),d2
		bmi.s	.c1
		
		tst.w	ropeflag-d(a5)
		bne.s	.c1
		tst.w	ropedownflag-d(a5)
		bne.s	.c1
		
		move.w	#1,bstandflag-d(a5)
		tst.w	basketflag-d(a5)
		bne.s	.c001
		clr.w	priority-d(a5)
		
.c001		moveq	#0,d2
		move.l	absmanypos-d(a5),d1
		move.w	nmypos(a0),d2
		sub.w	#24,d2
		move.l	d2,absmanypos-d(a5)
		sub.l	d2,d1
		sub.w	d1,manypos-d(a5)
		
.c1		movem.l	(a7)+,d1/d2
		move.l	#5*16*160+14,nmdata(a0)
		bsr	maskblitxy
		tst.w	basketflag-d(a5)
		bne.s	.ret
		tst.w	mancoll-d(a5)
		beq.s	.ret
		clr.w	mancoll-d(a5)
		move.w	#1,touchflag-d(a5)
		move.w	#5,touchtext-d(a5)
		move.w	#5,touchtext2-d(a5)
		move.l	a0,touchpos-d(a5)
.ret		rts

.c2		moveq	#0,d2
		move.w	nmxpos(a0),d2
		sub.w	#64,d2
		move.w	d2,bxborderl-d(a5)
		cmp.l	absmanxpos-d(a5),d2
		bpl.s	.c1
		add.w	#10,d2
		cmp.l	absmanxpos-d(a5),d2
		bpl.s	.c3
		add.w	#22,d2
		move.w	d2,bxborderr-d(a5)
		cmp.l	absmanxpos-d(a5),d2
		bmi.s	.c1
		sub.w	#14,d2
		cmp.l	absmanxpos-d(a5),d2
		bmi.s	.c4
		
.c5		move.w	#1,bfallflag-d(a5)
		bra	.c1
		
.c3		moveq	#0,d2
		move.w	fallspeed-d(a5),d2
		lsr.w	#1,d2
		lsl.w	#3,d2
		add.w	d2,agamanxpos-d(a5)
		add.l	d2,agaabsmanxpos-d(a5)
		bra.s	.c5
	
.c4		moveq	#0,d2
		move.w	fallspeed-d(a5),d2
		lsr.w	#1,d2
		lsl.w	#3,d2
		sub.w	d2,agamanxpos-d(a5)
		sub.l	d2,agaabsmanxpos-d(a5)
		bra.s	.c5
	
;------------------------------------------------
move13		tst.w	nmstartflag(a0)
		beq.s	.c1
		move.w	nmypos(a0),nmactypos(a0)
		move.w	nmxpos(a0),nmactxpos(a0)
		move.l	#2,nmanimpos(a0)
		move.l	#145*160+4,nmdata(a0)
		move.w	#16,nmysize(a0)
		clr.w	nmyspeed(a0)
		clr.l	nmdieyspd(a0)
		clr.w	nmstartflag(a0)
		
.c1		tst.w	nmxdir(a0)
		bne	.right

.left		movem.l	d0/d1/a1/a2,-(a7)
		
		tst.w	nmcoll(a0)
		beq.s	.lc01
		moveq	#2,d1
		bra	.dieanim
		
.lc01		bsr	.teststomp
		moveq	#-14,d0
		move.w	nmanimpos+2(a0),d1
		cmp.w	#1,d1
		beq	.dropl
		cmp.w	#2,d1
		beq	.falldown
		cmp.w	#3,d1
		beq	.pflatschl
		
		bsr	.blktest
		tst.b	(a2,d1.w)
		bne.s	.lc2
		move.l	#1,nmanimpos(a0)
		bra.s	.end
.lc2		cmp.b	#1,(a2,d1.w)
		beq.s	.lc3
		move.w	#1,nmxdir(a0)
		bra.s	.end
.lc3		eor.w	#1,nmanimcount(a0)
		bne.s	.lc1
		subq.w	#1,nmactxpos(a0)
		addq.w	#4,nmanimpos(a0)
		and.w	#28,nmanimpos(a0)
.lc1		lea	.animtabl(pc),a1
		move.w	nmanimpos(a0),d0
		move.l	(a1,d0.w),nmdata(a0)
		move.w	nmactxpos(a0),nmxpos(a0)
		move.w	#6,nmysize(a0)
		move.w	nmactypos(a0),d0
		add.w	#10,d0
		move.w	d0,nmypos(a0)
.end		movem.l	(a7)+,d0/d1/a1/a2
		bsr	maskblitxy
		move.w	mancoll-d(a5),d0
		or.w	d0,defmancoll-d(a5)
		rts
		
.dropl		cmp.w	#32,nmanimpos(a0)
		bmi.s	.dl1
		addq.w	#1,nmanimpos(a0)
		cmp.w	#64,nmanimpos(a0)
		bmi.s	.end
		move.l	#2,nmanimpos(a0)
		add.w	#16,nmactypos(a0)
		clr.w	nmyspeed(a0)
		bra.s	.end
.dl1		lea	.falltabl(pc),a1
		move.w	nmanimpos(a0),d0
		move.l	(a1,d0.w),nmdata(a0)
		lsr.w	#1,d0
		lea	.fallsize(pc),a1
		move.w	(a1,d0.w),nmysize(a0)
		lea	.fallofs(pc),a1
		move.w	(a1,d0.w),d0
		add.w	nmactypos(a0),d0
		move.w	d0,nmypos(a0)
		move.w	nmactxpos(a0),nmxpos(a0)
		eor.w	#1,nmanimcount(a0)
		bne.s	.end
		addq.w	#4,nmanimpos(a0)
		bra.s	.end
		
.pflatschl	cmp.w	#20,nmanimpos(a0)
		bmi.s	.pl1
		addq.w	#1,nmanimpos(a0)
		cmp.w	#48,nmanimpos(a0)
		bmi	.end
		clr.l	nmanimpos(a0)
		subq.w	#4,nmactxpos(a0)
		bra	.end
.pl1		lea	.pfltabl(pc),a1
		move.w	nmanimpos(a0),d0
		move.l	(a1,d0.w),nmdata(a0)
		lsr.w	#1,d0
		lea	.pflsize(pc),a1
		move.w	(a1,d0.w),nmysize(a0)
		lea	.pflofs(pc),a1
		move.w	(a1,d0.w),d1
		add.w	nmactypos(a0),d1
		move.w	d1,nmypos(a0)
		lea	.pflxofs(pc),a1
		move.w	(a1,d0.w),d1
		add.w	nmactxpos(a0),d1
		move.w	d1,nmxpos(a0)
		eor.w	#1,nmanimcount(a0)
		bne	.end
		addq.w	#4,nmanimpos(a0)
		bra	.end
		
.right		movem.l	d0/d1/a1/a2,-(a7)
		
		tst.w	nmcoll(a0)
		beq.s	.rc01
		moveq	#0,d1
		bra	.dieanim
		
.rc01		bsr	.teststomp
		moveq	#-2,d0
		move.w	nmanimpos+2(a0),d1
		cmp.w	#1,d1
		beq	.dropr
		c